gcc/ada/a-cihama.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                      A D A . C O N T A I N E R S .                       --
   6 --               I N D E F I N I T E _ H A S H E D _ M A P S                --
   7 --                                                                          --
   8 --                                 S p e c                                  --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2005, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  25 -- Boston, MA 02110-1301, USA.                                              --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- This unit was originally developed by Matthew J Heaney.                  --
  35 ------------------------------------------------------------------------------
  36
  37 with Ada.Containers.Hash_Tables;
  38 with Ada.Streams;
  39 with Ada.Finalization;
  40
  41 generic
  42    type Key_Type (<>) is private;
  43    type Element_Type (<>) is private;
  44
  45    with function Hash (Key : Key_Type) return Hash_Type;
  46    with function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
  47    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  48
  49 package Ada.Containers.Indefinite_Hashed_Maps is
  50    pragma Preelaborate;
  51
  52    type Map is tagged private;
  53    type Cursor is private;
  54
  55    Empty_Map  : constant Map;
  56    No_Element : constant Cursor;
  57
  58    function "=" (Left, Right : Map) return Boolean;
  59
  60    function Capacity (Container : Map) return Count_Type;
  61
  62    procedure Reserve_Capacity
  63      (Container : in out Map;
  64       Capacity  : Count_Type);
  65
  66    function Length (Container : Map) return Count_Type;
  67
  68    function Is_Empty (Container : Map) return Boolean;
  69
  70    procedure Clear (Container : in out Map);
  71
  72    function Key (Position : Cursor) return Key_Type;
  73
  74    function Element (Position : Cursor) return Element_Type;
  75
  76    procedure Replace_Element
  77      (Container : in out Map;
  78       Position  : Cursor;
  79       New_Item  : Element_Type);
  80
  81    procedure Query_Element
  82      (Position : Cursor;
  83       Process  : not null access procedure (Key     : Key_Type;
  84                                             Element : Element_Type));
  85
  86    procedure Update_Element
  87      (Container : in out Map;
  88       Position  : Cursor;
  89       Process   : not null access procedure (Key     : Key_Type;
  90                                             Element : in out Element_Type));
  91
  92    procedure Move (Target : in out Map; Source : in out Map);
  93
  94    procedure Insert
  95      (Container : in out Map;
  96       Key       : Key_Type;
  97       New_Item  : Element_Type;
  98       Position  : out Cursor;
  99       Inserted  : out Boolean);
 100
 101    procedure Insert
 102      (Container : in out Map;
 103       Key       : Key_Type;
 104       New_Item  : Element_Type);
 105
 106    procedure Include
 107      (Container : in out Map;
 108       Key       : Key_Type;
 109       New_Item  : Element_Type);
 110
 111    procedure Replace
 112      (Container : in out Map;
 113       Key       : Key_Type;
 114       New_Item  : Element_Type);
 115
 116    procedure Exclude (Container : in out Map; Key : Key_Type);
 117
 118    procedure Delete (Container : in out Map; Key : Key_Type);
 119
 120    procedure Delete (Container : in out Map; Position : in out Cursor);
 121
 122    function First (Container : Map) return Cursor;
 123
 124    function Next (Position : Cursor) return Cursor;
 125
 126    procedure Next (Position : in out Cursor);
 127
 128    function Find (Container : Map; Key : Key_Type) return Cursor;
 129
 130    function Contains (Container : Map; Key : Key_Type) return Boolean;
 131
 132    function Element (Container : Map; Key : Key_Type) return Element_Type;
 133
 134    function Has_Element (Position : Cursor) return Boolean;
 135
 136    function Equivalent_Keys (Left, Right : Cursor) return Boolean;
 137
 138    function Equivalent_Keys (Left : Cursor; Right : Key_Type) return Boolean;
 139
 140    function Equivalent_Keys (Left : Key_Type; Right : Cursor) return Boolean;
 141
 142    procedure Iterate
 143      (Container : Map;
 144       Process   : not null access procedure (Position : Cursor));
 145
 146 private
 147    pragma Inline ("=");
 148    pragma Inline (Length);
 149    pragma Inline (Is_Empty);
 150    pragma Inline (Clear);
 151    pragma Inline (Key);
 152    pragma Inline (Element);
 153    pragma Inline (Move);
 154    pragma Inline (Contains);
 155    pragma Inline (Capacity);
 156    pragma Inline (Reserve_Capacity);
 157    pragma Inline (Has_Element);
 158    pragma Inline (Equivalent_Keys);
 159
 160    type Node_Type;
 161    type Node_Access is access Node_Type;
 162
 163    type Key_Access is access Key_Type;
 164    type Element_Access is access Element_Type;
 165
 166    type Node_Type is limited record
 167       Key     : Key_Access;
 168       Element : Element_Access;
 169       Next    : Node_Access;
 170    end record;
 171
 172    package HT_Types is new Hash_Tables.Generic_Hash_Table_Types
 173      (Node_Type,
 174       Node_Access);
 175
 176    type Map is new Ada.Finalization.Controlled with record
 177       HT : HT_Types.Hash_Table_Type;
 178    end record;
 179
 180    use HT_Types;
 181    use Ada.Finalization;
 182    use Ada.Streams;
 183
 184    procedure Adjust (Container : in out Map);
 185
 186    procedure Finalize (Container : in out Map);
 187
 188    type Map_Access is access constant Map;
 189    for Map_Access'Storage_Size use 0;
 190
 191    type Cursor is
 192       record
 193          Container : Map_Access;
 194          Node      : Node_Access;
 195       end record;
 196
 197    procedure Write
 198      (Stream : access Root_Stream_Type'Class;
 199       Item   : Cursor);
 200
 201    for Cursor'Write use Write;
 202
 203    procedure Read
 204      (Stream : access Root_Stream_Type'Class;
 205       Item   : out Cursor);
 206
 207    for Cursor'Read use Read;
 208
 209    No_Element : constant Cursor :=
 210      (Container => null,
 211       Node      => null);
 212
 213    procedure Write
 214      (Stream    : access Root_Stream_Type'Class;
 215       Container : Map);
 216
 217    for Map'Write use Write;
 218
 219    procedure Read
 220      (Stream    : access Root_Stream_Type'Class;
 221       Container : out Map);
 222
 223    for Map'Read use Read;
 224
 225    Empty_Map : constant Map := (Controlled with HT => (null, 0, 0, 0));
 226
 227 end Ada.Containers.Indefinite_Hashed_Maps;