gcc/configure.in

   1 # configure.in for GNU CC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5
   6 #This file is part of GNU CC.
   7
   8 #GNU CC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12
  13 #GNU CC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GNU CC; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 59 Temple Place - Suite 330,
  21 #Boston, MA 02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(tree.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for bogus environment variables.
  34 # Test if LIBRARY_PATH contains the notation for the current directory
  35 # since this would lead to problems installing/building glibc.
  36 # LIBRARY_PATH contains the current directory if one of the following
  37 # is true:
  38 # - one of the terminals (":" and ";") is the first or last sign
  39 # - two terminals occur directly after each other
  40 # - the path contains an element with a dot in it
  41 AC_MSG_CHECKING(LIBRARY_PATH variable)
  42 changequote(,)dnl
  43 case ${LIBRARY_PATH} in
  44   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  45     library_path_setting="contains current directory"
  46     ;;
  47   *)
  48     library_path_setting="ok"
  49     ;;
  50 esac
  51 changequote([,])dnl
  52 AC_MSG_RESULT($library_path_setting)
  53 if test "$library_path_setting" != "ok"; then
  54 AC_MSG_ERROR([
  55 *** LIBRARY_PATH shouldn't contain the current directory when
  56 *** building gcc. Please change the environment variable
  57 *** and run configure again.])
  58 fi
  59
  60 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  61 # since this would lead to problems installing/building glibc.
  62 # GCC_EXEC_PREFIX contains the current directory if one of the following
  63 # is true:
  64 # - one of the terminals (":" and ";") is the first or last sign
  65 # - two terminals occur directly after each other
  66 # - the path contains an element with a dot in it
  67 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  68 changequote(,)dnl
  69 case ${GCC_EXEC_PREFIX} in
  70   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  71     gcc_exec_prefix_setting="contains current directory"
  72     ;;
  73   *)
  74     gcc_exec_prefix_setting="ok"
  75     ;;
  76 esac
  77 changequote([,])dnl
  78 AC_MSG_RESULT($gcc_exec_prefix_setting)
  79 if test "$gcc_exec_prefix_setting" != "ok"; then
  80 AC_MSG_ERROR([
  81 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  82 *** building gcc. Please change the environment variable
  83 *** and run configure again.])
  84 fi
  85
  86 # Check for additional parameters
  87
  88 # With GNU ld
  89 AC_ARG_WITH(gnu-ld,
  90 [  --with-gnu-ld           arrange to work with GNU ld.],
  91 gnu_ld_flag="$with_gnu_ld",
  92 gnu_ld_flag=no)
  93
  94 # With pre-defined ld
  95 AC_ARG_WITH(ld,
  96 [  --with-ld               arrange to use the specified ld (full pathname)],
  97 DEFAULT_LINKER="$with_ld")
  98 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  99   if test ! -x "$DEFAULT_LINKER"; then
 100     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 101   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 102     gnu_ld_flag=yes
 103   fi
 104   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 105         [Define to enable the use of a default linker.])
 106 fi
 107
 108 # With GNU as
 109 AC_ARG_WITH(gnu-as,
 110 [  --with-gnu-as           arrange to work with GNU as],
 111 gas_flag="$with_gnu_as",
 112 gas_flag=no)
 113
 114 AC_ARG_WITH(as,
 115 [  --with-as               arrange to use the specified as (full pathname)],
 116 DEFAULT_ASSEMBLER="$with_as")
 117 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 118   if test ! -x "$DEFAULT_ASSEMBLER"; then
 119     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 120   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 121     gas_flag=yes
 122   fi
 123   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 124         [Define to enable the use of a default assembler.])
 125 fi
 126
 127 # With stabs
 128 AC_ARG_WITH(stabs,
 129 [  --with-stabs            arrange to use stabs instead of host debug format],
 130 stabs="$with_stabs",
 131 stabs=no)
 132
 133 # With ELF
 134 AC_ARG_WITH(elf,
 135 [  --with-elf              arrange to use ELF instead of host debug format],
 136 elf="$with_elf",
 137 elf=no)
 138
 139 # Specify the local prefix
 140 local_prefix=
 141 AC_ARG_WITH(local-prefix,
 142 [  --with-local-prefix=DIR specifies directory to put local include],
 143 [case "${withval}" in
 144 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 145 no)     ;;
 146 *)      local_prefix=$with_local_prefix ;;
 147 esac])
 148
 149 # Default local prefix if it is empty
 150 if test x$local_prefix = x; then
 151         local_prefix=/usr/local
 152 fi
 153
 154 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 155 # passed in by the toplevel make and thus we'd get different behavior
 156 # depending on where we built the sources.
 157 gcc_gxx_include_dir=
 158 # Specify the g++ header file directory
 159 AC_ARG_WITH(gxx-include-dir,
 160 [  --with-gxx-include-dir=DIR
 161                           specifies directory to put g++ header files],
 162 [case "${withval}" in
 163 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 164 no)     ;;
 165 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 166 esac])
 167
 168 if test x${gcc_gxx_include_dir} = x; then
 169   if test x${enable_version_specific_runtime_libs} = xyes; then
 170     gcc_gxx_include_dir='${libsubdir}/include/g++'
 171   else
 172     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 173 changequote(<<, >>)dnl
 174     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 175 changequote([, ])dnl
 176   fi
 177 fi
 178
 179 # Determine whether or not multilibs are enabled.
 180 AC_ARG_ENABLE(multilib,
 181 [  --enable-multilib       enable library support for multiple ABIs],
 182 [], [enable_multilib=yes])
 183 AC_SUBST(enable_multilib)
 184
 185 # Enable expensive internal checks
 186 AC_ARG_ENABLE(checking,
 187 [  --enable-checking[=LIST]
 188                           enable expensive run-time checks.  With LIST,
 189                           enable only specific categories of checks.
 190                           Categories are: misc,tree,rtl,gc,gcac; default
 191                           is misc,tree,gc],
 192 [ac_checking=
 193 ac_tree_checking=
 194 ac_rtl_checking=
 195 ac_gc_checking=
 196 ac_gc_always_collect=
 197 case "${enableval}" in
 198 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;;
 199 no)     ;;
 200 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 201         set fnord $enableval; shift
 202         IFS="$ac_save_IFS"
 203         for check
 204         do
 205                 case $check in
 206                 misc)   ac_checking=1 ;;
 207                 tree)   ac_tree_checking=1 ;;
 208                 rtl)    ac_rtl_checking=1 ;;
 209                 gc)     ac_gc_checking=1 ;;
 210                 gcac)   ac_gc_always_collect=1 ;;
 211                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 212                 esac
 213         done
 214         ;;
 215 esac
 216 ],
 217 # Enable some checks by default for development versions of GCC
 218 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1;])
 219 if test x$ac_checking != x ; then
 220   AC_DEFINE(ENABLE_CHECKING, 1,
 221 [Define if you want more run-time sanity checks.  This one gets a grab
 222    bag of miscellaneous but relatively cheap checks.])
 223 fi
 224 if test x$ac_tree_checking != x ; then
 225   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 226 [Define if you want all operations on trees (the basic data
 227    structure of the front ends) to be checked for dynamic type safety
 228    at runtime.  This is moderately expensive.])
 229 fi
 230 if test x$ac_rtl_checking != x ; then
 231   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 232 [Define if you want all operations on RTL (the basic data structure
 233    of the optimizer and back end) to be checked for dynamic type safety
 234    at runtime.  This is quite expensive.])
 235 fi
 236 if test x$ac_gc_checking != x ; then
 237   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 238 [Define if you want the garbage collector to do object poisoning and
 239    other memory allocation checks.  This is quite expensive.])
 240 fi
 241 if test x$ac_gc_always_collect != x ; then
 242   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 243 [Define if you want the garbage collector to operate in maximally
 244    paranoid mode, validating the entire heap and collecting garbage at
 245    every opportunity.  This is extremely expensive.])
 246 fi
 247
 248
 249 AC_ARG_ENABLE(cpp,
 250 [  --disable-cpp           don't provide a user-visible C preprocessor],
 251 [], [enable_cpp=yes])
 252
 253 AC_ARG_WITH(cpp_install_dir,
 254 [  --with-cpp-install-dir=DIR
 255                           install the user visible C preprocessor in DIR
 256                           (relative to PREFIX) as well as PREFIX/bin],
 257 [if test x$withval = xyes; then
 258   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 259 elif test x$withval != xno; then
 260   cpp_install_dir=$withval
 261 fi])
 262
 263 # Enable Multibyte Characters for C/C++
 264 AC_ARG_ENABLE(c-mbchar,
 265 [  --enable-c-mbchar       enable multibyte characters for C and C++],
 266 if test x$enable_c_mbchar != xno; then
 267   AC_DEFINE(MULTIBYTE_CHARS, 1,
 268   [Define if you want the C and C++ compilers to support multibyte
 269    character sets for source code.])
 270 fi)
 271
 272 # Enable threads
 273 # Pass with no value to take the default
 274 # Pass with a value to specify a thread package
 275 AC_ARG_ENABLE(threads,
 276 [  --enable-threads        enable thread usage for target GCC
 277   --enable-threads=LIB    use LIB thread package for target GCC],,
 278 enable_threads='')
 279
 280 enable_threads_flag=$enable_threads
 281 # Check if a valid thread package
 282 case x${enable_threads_flag} in
 283         x | xno)
 284                 # No threads
 285                 target_thread_file='single'
 286                 ;;
 287         xyes)
 288                 # default
 289                 target_thread_file=''
 290                 ;;
 291         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 292         xsolaris | xwin32 | xdce | xvxworks | xaix)
 293                 target_thread_file=$enable_threads_flag
 294                 ;;
 295         *)
 296                 echo "$enable_threads is an unknown thread package" 1>&2
 297                 exit 1
 298                 ;;
 299 esac
 300
 301 AC_ARG_ENABLE(objc-gc,
 302 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 303                           the GNU Objective-C runtime],
 304 if test x$enable_objc_gc = xno; then
 305         objc_boehm_gc=''
 306 else
 307         objc_boehm_gc=1
 308 fi,
 309 objc_boehm_gc='')
 310
 311 AC_ARG_WITH(dwarf2,
 312 [  --with-dwarf2           force the default debug format to be DWARF 2],
 313 dwarf2="$with_dwarf2",
 314 dwarf2=no)
 315
 316 AC_ARG_ENABLE(shared,
 317 [  --disable-shared        don't provide a shared libgcc],
 318 [
 319   case $enable_shared in
 320   yes | no) ;;
 321   *)
 322     enable_shared=no
 323     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 324     for pkg in $enableval; do
 325       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 326         enable_shared=yes
 327       fi
 328     done
 329     IFS="$ac_save_ifs"
 330     ;;
 331   esac
 332 ], [enable_shared=yes])
 333 AC_SUBST(enable_shared)
 334
 335 # Determine the host, build, and target systems
 336 AC_CANONICAL_SYSTEM
 337
 338 # Find the native compiler
 339 AC_PROG_CC
 340 AC_PROG_CC_C_O
 341 # autoconf is lame and doesn't give us any substitution variable for this.
 342 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 343   NO_MINUS_C_MINUS_O=yes
 344 else
 345   OUTPUT_OPTION='-o $@'
 346 fi
 347 AC_SUBST(NO_MINUS_C_MINUS_O)
 348 AC_SUBST(OUTPUT_OPTION)
 349
 350 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 351 ac_cv_prog_cc_no_long_long,
 352 [save_CFLAGS="$CFLAGS"
 353 CFLAGS="-Wno-long-long"
 354 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 355                ac_cv_prog_cc_no_long_long=no)
 356 CFLAGS="$save_CFLAGS"])
 357 strict1_warn=
 358 if test $ac_cv_prog_cc_no_long_long = yes; then
 359   strict1_warn="-pedantic -Wno-long-long"
 360 fi
 361 AC_SUBST(strict1_warn)
 362
 363 AC_PROG_CPP
 364 AC_C_INLINE
 365 gcc_AC_C_VOLATILE
 366
 367 gcc_AC_C_LONG_DOUBLE
 368 gcc_AC_C_LONG_LONG
 369 gcc_AC_C__BOOL
 370
 371 # sizeof(char) is 1 by definition.
 372 gcc_AC_COMPILE_CHECK_SIZEOF(short)
 373 gcc_AC_COMPILE_CHECK_SIZEOF(int)
 374 gcc_AC_COMPILE_CHECK_SIZEOF(long)
 375 if test $ac_cv_c_long_long = yes; then
 376   gcc_AC_COMPILE_CHECK_SIZEOF(long long)
 377 fi
 378 if test $ac_cv_c___int64 = yes; then
 379   gcc_AC_COMPILE_CHECK_SIZEOF(__int64)
 380 fi
 381
 382 gcc_AC_C_CHARSET
 383
 384 # If the native compiler is GCC, we can enable warnings even in stage1.
 385 # That's useful for people building cross-compilers, or just running a
 386 # quick `make'.
 387 warn_cflags=
 388 if test "x$GCC" = "xyes"; then
 389   warn_cflags='$(GCC_WARN_CFLAGS)'
 390 fi
 391 AC_SUBST(warn_cflags)
 392
 393 # Stage specific cflags for build.
 394 stage1_cflags=
 395 case $build in
 396 vax-*-*)
 397   if test x$GCC = xyes
 398   then
 399     stage1_cflags="-Wa,-J"
 400   else
 401     stage1_cflags="-J"
 402   fi
 403   ;;
 404 esac
 405 AC_SUBST(stage1_cflags)
 406
 407 AC_PROG_MAKE_SET
 408
 409 AC_MSG_CHECKING([whether a default assembler was specified])
 410 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 411     if test x"$gas_flag" = x"no"; then
 412         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 413     else
 414         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 415     fi
 416 else
 417     AC_MSG_RESULT(no)
 418 fi
 419
 420 AC_MSG_CHECKING([whether a default linker was specified])
 421 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 422     if test x"$gnu_ld_flag" = x"no"; then
 423         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 424     else
 425         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 426     fi
 427 else
 428     AC_MSG_RESULT(no)
 429 fi
 430
 431 AC_MSG_CHECKING(for GNU C library)
 432 AC_CACHE_VAL(gcc_cv_glibc,
 433 [AC_TRY_COMPILE(
 434   [#include <features.h>],[
 435 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 436 #error Not a GNU C library system
 437 #endif],
 438   [gcc_cv_glibc=yes],
 439   gcc_cv_glibc=no)])
 440 AC_MSG_RESULT($gcc_cv_glibc)
 441 if test $gcc_cv_glibc = yes; then
 442   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 443 fi
 444
 445 # Find some useful tools
 446 AC_PROG_AWK
 447 gcc_AC_PROG_LN
 448 gcc_AC_PROG_LN_S
 449 AC_PROG_RANLIB
 450 gcc_AC_PROG_INSTALL
 451
 452 AC_HEADER_STDC
 453 AC_HEADER_TIME
 454 gcc_AC_HEADER_STDBOOL
 455 gcc_AC_HEADER_STRING
 456 AC_HEADER_SYS_WAIT
 457 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 458                  fcntl.h unistd.h sys/file.h sys/time.h \
 459                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 460                  direct.h malloc.h langinfo.h iconv.h)
 461
 462 # Check for thread headers.
 463 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 464 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 465
 466 # These tests can't be done till we know if we have limits.h.
 467 gcc_AC_C_CHAR_BIT
 468 gcc_AC_C_COMPILE_ENDIAN
 469 gcc_AC_C_FLOAT_FORMAT
 470
 471 # See if GNAT has been installed
 472 AC_CHECK_PROG(have_gnat, gnatbind, yes, no)
 473
 474 # See if we have the mktemp command.
 475 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 476
 477 # Do we have a single-tree copy of texinfo?
 478 if test -f $srcdir/../texinfo/Makefile.in; then
 479   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 480   gcc_cv_prog_makeinfo_modern=yes
 481   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 482 else
 483   # See if makeinfo has been installed and is modern enough
 484   # that we can use it.
 485   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 486   [GNU texinfo.* \([0-9][0-9.]*\)],
 487   [4.*])
 488 fi
 489
 490 if test $gcc_cv_prog_makeinfo_modern = no; then
 491   AC_MSG_WARN([
 492 *** Makeinfo is missing or too old.
 493 *** Info documentation will not be built.])
 494   BUILD_INFO=
 495 else
 496   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 497 fi
 498
 499 # Is pod2man recent enough to regenerate manpages?
 500 AC_MSG_CHECKING([for recent Pod::Man])
 501 if perl -e 'use 1.10 Pod::Man' >/dev/null 2>&1; then
 502   AC_MSG_RESULT(yes)
 503   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 504 else
 505   AC_MSG_RESULT(no)
 506   GENERATED_MANPAGES=
 507 fi
 508
 509 # How about lex?
 510 dnl Don't use AC_PROG_LEX; we insist on flex.
 511 dnl LEXLIB is not useful in gcc.
 512 if test -f $srcdir/../flex/skel.c; then
 513   FLEX='$(objdir)/../flex/flex'
 514 else
 515   AC_CHECK_PROG(FLEX, flex, flex, false)
 516 fi
 517
 518 # Bison?
 519 # The -L switch is so bison can find its skeleton file.
 520 if test -f $srcdir/../bison/bison.simple; then
 521   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 522 else
 523   AC_CHECK_PROG(BISON, bison, bison, false)
 524 fi
 525
 526 # These libraries may be used by collect2.
 527 # We may need a special search path to get them linked.
 528 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 529 [save_LIBS="$LIBS"
 530 for libs in '' -lld -lmld \
 531                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 532                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 533 do
 534         LIBS="$libs"
 535         AC_TRY_LINK_FUNC(ldopen,
 536                 [gcc_cv_collect2_libs="$libs"; break])
 537 done
 538 LIBS="$save_LIBS"
 539 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 540 case $gcc_cv_collect2_libs in
 541         "none required")        ;;
 542         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 543 esac
 544 AC_SUBST(COLLECT2_LIBS)
 545
 546 # When building Ada code on Alpha, we need exc_resume which is usually in
 547 # -lexc.  So test for it.
 548 save_LIBS="$LIBS"
 549 LIBS=
 550 AC_SEARCH_LIBS(exc_resume, exc)
 551 GNAT_LIBEXC="$LIBS"
 552 LIBS="$save_LIBS"
 553 AC_SUBST(GNAT_LIBEXC)
 554
 555 # See if the stage1 system preprocessor understands the ANSI C
 556 # preprocessor stringification operator.  (Used by symcat.h.)
 557 AC_C_STRINGIZE
 558
 559 # Use <inttypes.h> only if it exists,
 560 # doesn't clash with <sys/types.h>, and declares intmax_t.
 561 AC_MSG_CHECKING(for inttypes.h)
 562 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 563 [AC_TRY_COMPILE(
 564   [#include <sys/types.h>
 565 #include <inttypes.h>],
 566   [intmax_t i = -1;],
 567   [gcc_cv_header_inttypes_h=yes],
 568   gcc_cv_header_inttypes_h=no)])
 569 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 570 if test $gcc_cv_header_inttypes_h = yes; then
 571   AC_DEFINE(HAVE_INTTYPES_H, 1,
 572         [Define if you have a working <inttypes.h> header file.])
 573 fi
 574
 575 dnl Disabled until we have a complete test for buggy enum bitfields.
 576 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 577
 578 AC_CHECK_FUNCS(strtoul bsearch popen times clock \
 579         strchr strrchr kill getrlimit setrlimit atoll atoq \
 580         sysconf isascii gettimeofday strsignal putc_unlocked fputc_unlocked \
 581         fputs_unlocked getrusage iconv nl_langinfo lstat)
 582
 583 AC_CHECK_TYPE(ssize_t, int)
 584
 585 # Try to determine the array type of the second argument of getgroups
 586 # for the target system (int or gid_t).
 587 AC_TYPE_GETGROUPS
 588 if test "${target}" = "${build}"; then
 589   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 590 else
 591   case "${target}" in
 592         # This condition may need some tweaking.  It should include all
 593         # targets where the array type of the second argument of getgroups
 594         # is int and the type of gid_t is not equivalent to int.
 595         *-*-sunos* | *-*-ultrix*)
 596                 TARGET_GETGROUPS_T=int
 597                 ;;
 598         *)
 599                 TARGET_GETGROUPS_T=gid_t
 600                 ;;
 601   esac
 602 fi
 603 AC_SUBST(TARGET_GETGROUPS_T)
 604
 605 gcc_AC_FUNC_VFPRINTF_DOPRNT
 606 gcc_AC_FUNC_STRSTR
 607 gcc_AC_FUNC_PRINTF_PTR
 608
 609 case "${host}" in
 610 *-*-uwin*)
 611   AC_MSG_ERROR([
 612 *** UWIN may not be used as a host platform because
 613 *** linking with posix.dll is not allowed by the GNU GPL])
 614   ;;
 615 esac
 616 AC_FUNC_VFORK
 617 AC_FUNC_MMAP_ANYWHERE
 618 AC_FUNC_MMAP_FILE
 619
 620 # We will need to find libiberty.h and ansidecl.h
 621 saved_CFLAGS="$CFLAGS"
 622 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 623 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 624         strsignal putc_unlocked fputs_unlocked strstr environ errno \
 625         malloc realloc calloc free basename getopt clock, , ,[
 626 #include "ansidecl.h"
 627 #include "system.h"])
 628
 629 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 630 #include "ansidecl.h"
 631 #include "system.h"
 632 #ifdef HAVE_SYS_RESOURCE_H
 633 #include <sys/resource.h>
 634 #endif
 635 ])
 636
 637 gcc_AC_CHECK_DECLS(times, , ,[
 638 #include "ansidecl.h"
 639 #include "system.h"
 640 #ifdef HAVE_SYS_TIMES_H
 641 #include <sys/times.h>
 642 #endif
 643 ])
 644
 645 # More time-related stuff.
 646 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 647 AC_TRY_COMPILE([
 648 #include "ansidecl.h"
 649 #include "system.h"
 650 #ifdef HAVE_SYS_TIMES_H
 651 #include <sys/times.h>
 652 #endif
 653 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 654 if test $ac_cv_struct_tms = yes; then
 655   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 656   [Define if <sys/times.h> defines struct tms.])
 657 fi
 658
 659 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 660 # revisit after autoconf 2.50.
 661 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 662 AC_TRY_COMPILE([
 663 #include "ansidecl.h"
 664 #include "system.h"
 665 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 666 if test $gcc_cv_type_clock_t = yes; then
 667   AC_DEFINE(HAVE_CLOCK_T, 1,
 668   [Define if <time.h> defines clock_t.])
 669 fi
 670
 671 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 672 CFLAGS="$saved_CFLAGS"
 673
 674 # mkdir takes a single argument on some systems.
 675 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 676
 677 # File extensions
 678 manext='.1'
 679 objext='.o'
 680 AC_SUBST(manext)
 681 AC_SUBST(objext)
 682
 683 build_xm_file=
 684 build_xm_defines=
 685 build_install_headers_dir=install-headers-tar
 686 build_exeext=
 687 host_xm_file=
 688 host_xm_defines=
 689 host_xmake_file=
 690 host_truncate_target=
 691 host_exeext=
 692
 693 # Decode the host machine, then the target machine.
 694 # For the host machine, we save the xm_file variable as host_xm_file;
 695 # then we decode the target machine and forget everything else
 696 # that came from the host machine.
 697 for machine in $build $host $target; do
 698         . ${srcdir}/config.gcc
 699 done
 700
 701 extra_objs="${host_extra_objs} ${extra_objs}"
 702
 703 # Default the target-machine variables that were not explicitly set.
 704 if test x"$tm_file" = x
 705 then tm_file=$cpu_type/$cpu_type.h; fi
 706
 707 if test x"$extra_headers" = x
 708 then extra_headers=; fi
 709
 710 if test x$md_file = x
 711 then md_file=$cpu_type/$cpu_type.md; fi
 712
 713 if test x$out_file = x
 714 then out_file=$cpu_type/$cpu_type.c; fi
 715
 716 if test x"$tmake_file" = x
 717 then tmake_file=$cpu_type/t-$cpu_type
 718 fi
 719
 720 if test x"$dwarf2" = xyes
 721 then tm_file="$tm_file tm-dwarf2.h"
 722 fi
 723
 724 if test x$float_format = x
 725 then float_format=i64
 726 fi
 727
 728 if test $float_format = none
 729 then float_h_file=Makefile.in
 730 else float_h_file=float-$float_format.h
 731 fi
 732
 733 # Handle cpp installation.
 734 if test x$enable_cpp != xno
 735 then
 736   tmake_file="$tmake_file t-install-cpp"
 737 fi
 738
 739 # Say what files are being used for the output code and MD file.
 740 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
 741 echo "Using \`$srcdir/config/$md_file' as machine description file."
 742
 743 # If any of the xm_file variables contain nonexistent files, warn
 744 # about them and drop them.
 745
 746 bx=
 747 for x in $build_xm_file; do
 748   if    test -f $srcdir/config/$x
 749   then      bx="$bx $x"
 750   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 751   fi
 752 done
 753 build_xm_file="$bx"
 754
 755 hx=
 756 for x in $host_xm_file; do
 757   if    test -f $srcdir/config/$x
 758   then      hx="$hx $x"
 759   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 760   fi
 761 done
 762 host_xm_file="$hx"
 763
 764 tx=
 765 for x in $xm_file; do
 766   if    test -f $srcdir/config/$x
 767   then      tx="$tx $x"
 768   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 769   fi
 770 done
 771 xm_file="$tx"
 772
 773 count=a
 774 for f in $tm_file; do
 775         count=${count}x
 776 done
 777 if test $count = ax; then
 778         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
 779 else
 780         echo "Using the following target machine macro files:"
 781         for f in $tm_file; do
 782                 echo "  $srcdir/config/$f"
 783         done
 784 fi
 785
 786 count=a
 787 for f in $host_xm_file; do
 788         count=${count}x
 789 done
 790 if test $count = a; then
 791         :
 792 elif test $count = ax; then
 793         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
 794 else
 795         echo "Using the following host machine macro files:"
 796         for f in $host_xm_file; do
 797                 echo "  $srcdir/config/$f"
 798         done
 799 fi
 800
 801 if test "$host_xm_file" != "$build_xm_file"; then
 802         count=a
 803         for f in $build_xm_file; do
 804                 count=${count}x
 805         done
 806         if test $count = a; then
 807                 :
 808         elif test $count = ax; then
 809                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
 810         else
 811                 echo "Using the following build machine macro files:"
 812                 for f in $build_xm_file; do
 813                         echo "  $srcdir/config/$f"
 814                 done
 815         fi
 816 fi
 817
 818 if test x$thread_file = x; then
 819         if test x$target_thread_file != x; then
 820                 thread_file=$target_thread_file
 821         else
 822                 thread_file='single'
 823         fi
 824 fi
 825
 826 # auto-host.h is the file containing items generated by autoconf and is
 827 # the first file included by config.h.
 828 # If host=build, it is correct to have hconfig include auto-host.h
 829 # as well.  If host!=build, we are in error and need to do more
 830 # work to find out the build config parameters.
 831 if test x$host = x$build
 832 then
 833         build_auto=auto-host.h
 834 else
 835         # We create a subdir, then run autoconf in the subdir.
 836         # To prevent recursion we set host and build for the new
 837         # invocation of configure to the build for this invocation
 838         # of configure.
 839         tempdir=build.$$
 840         rm -rf $tempdir
 841         mkdir $tempdir
 842         cd $tempdir
 843         case ${srcdir} in
 844         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 845         *) realsrcdir=../${srcdir};;
 846         esac
 847         saved_CFLAGS="${CFLAGS}"
 848         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
 849         ${realsrcdir}/configure \
 850                 --target=$target --host=$build --build=$build
 851         CFLAGS="${saved_CFLAGS}"
 852
 853         # We just finished tests for the build machine, so rename
 854         # the file auto-build.h in the gcc directory.
 855         mv auto-host.h ../auto-build.h
 856         cd ..
 857         rm -rf $tempdir
 858         build_auto=auto-build.h
 859 fi
 860
 861 tm_file="${tm_file} defaults.h"
 862 host_xm_file="auto-host.h ansidecl.h ${host_xm_file} ${tm_file}"
 863 build_xm_file="${build_auto} ansidecl.h ${build_xm_file} ${tm_file}"
 864 xm_file="ansidecl.h ${xm_file} ${tm_file}"
 865
 866 # Truncate the target if necessary
 867 if test x$host_truncate_target != x; then
 868         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 869 fi
 870
 871 # Get the version trigger filename from the toplevel
 872 if test "${with_gcc_version_trigger+set}" = set; then
 873         gcc_version_trigger=$with_gcc_version_trigger
 874 else
 875         gcc_version_trigger=${srcdir}/version.c
 876 fi
 877 changequote(,)dnl
 878 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
 879 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 880
 881 # Compile in configure arguments.
 882 if test -f configargs.h ; then
 883         # Being re-configured.
 884         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
 885         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 886 else
 887         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 888 fi
 889 cat > configargs.h <<EOF
 890 /* Generated automatically. */
 891 static const char configuration_arguments[] = "$gcc_config_arguments";
 892 static const char thread_model[] = "$thread_file";
 893 EOF
 894 changequote([,])dnl
 895
 896 # Internationalization
 897 PACKAGE=gcc
 898 VERSION="$gcc_version"
 899 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
 900         [Define to the name of the distribution.])
 901 AC_DEFINE_UNQUOTED(VERSION, "$VERSION",
 902         [Define to the version of the distribution.])
 903 AC_SUBST(PACKAGE)
 904 AC_SUBST(VERSION)
 905
 906 ALL_LINGUAS="sv"
 907
 908 # Enable NLS support by default
 909 AC_ARG_ENABLE(nls,
 910   [  --enable-nls            use Native Language Support (default)],
 911   , enable_nls=yes)
 912
 913 # if cross compiling, disable NLS support.
 914 # It's not worth the trouble, at least for now.
 915
 916 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
 917   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
 918   enable_nls=no
 919 fi
 920
 921 # if NLS is enabled, also enable check in po subdir
 922 if test $enable_nls = yes; then
 923   CHECK_PO=check-po
 924 else
 925   CHECK_PO=""
 926 fi
 927
 928 AC_SUBST(CHECK_PO)
 929
 930 AM_GNU_GETTEXT
 931 XGETTEXT="AWK='$AWK' \$(SHELL) \$(top_srcdir)/exgettext $XGETTEXT"
 932
 933 # Windows32 Registry support for specifying GCC installation paths.
 934 AC_ARG_ENABLE(win32-registry,
 935 [  --disable-win32-registry
 936                           disable lookup of installation paths in the
 937                           Registry on Windows hosts
 938   --enable-win32-registry enable registry lookup (default)
 939   --enable-win32-registry=KEY
 940                           use KEY instead of GCC version as the last portion
 941                           of the registry key],,)
 942 case $host_os in
 943         win32 | pe | cygwin* | mingw32* | uwin*)
 944 AC_MSG_CHECKING(whether windows registry support is requested)
 945 if test "x$enable_win32_registry" != xno; then
 946   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
 947 [Define to 1 if installation paths should be looked up in Windows32
 948    Registry. Ignored on non windows32 hosts.])
 949   AC_MSG_RESULT(yes)
 950   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
 951 else
 952   AC_MSG_RESULT(no)
 953 fi
 954
 955 # Check if user specified a different registry key.
 956 case "x${enable_win32_registry}" in
 957 x | xyes)
 958   # default.
 959   gcc_cv_win32_registry_key="$VERSION"
 960   ;;
 961 xno)
 962   # no registry lookup.
 963   gcc_cv_win32_registry_key=''
 964   ;;
 965 *)
 966   # user-specified key.
 967   gcc_cv_win32_registry_key="$enable_win32_registry"
 968   ;;
 969 esac
 970
 971 if test "x$enable_win32_registry" != xno; then
 972   AC_MSG_CHECKING(registry key on windows hosts)
 973   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
 974         [Define to be the last portion of registry key on windows hosts.])
 975   AC_MSG_RESULT($gcc_cv_win32_registry_key)
 976 fi
 977 ;;
 978 esac
 979
 980 # Get an absolute path to the GCC top-level source directory
 981 holddir=`pwd`
 982 cd $srcdir
 983 topdir=`pwd`
 984 cd $holddir
 985
 986 # Conditionalize the makefile for this host machine.
 987 # Make-host contains the concatenation of all host makefile fragments
 988 # [there can be more than one].  This file is built by configure.frag.
 989 host_overrides=Make-host
 990 dep_host_xmake_file=
 991 for f in .. ${host_xmake_file}
 992 do
 993         if test -f ${srcdir}/config/$f
 994         then
 995                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
 996         fi
 997 done
 998
 999 # Conditionalize the makefile for this target machine.
1000 # Make-target contains the concatenation of all host makefile fragments
1001 # [there can be more than one].  This file is built by configure.frag.
1002 target_overrides=Make-target
1003 dep_tmake_file=
1004 for f in .. ${tmake_file}
1005 do
1006         if test -f ${srcdir}/config/$f
1007         then
1008                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
1009         fi
1010 done
1011
1012 # If the host doesn't support symlinks, modify CC in
1013 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1014 # Otherwise, we can use "CC=$(CC)".
1015 rm -f symtest.tem
1016 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1017 then
1018         cc_set_by_configure="\$(CC)"
1019         quoted_cc_set_by_configure="\$(CC)"
1020         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1021 else
1022         rm -f symtest.tem
1023         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1024         then
1025                 symbolic_link="cp -p"
1026         else
1027                 symbolic_link="cp"
1028         fi
1029         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1030         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1031         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1032 fi
1033 rm -f symtest.tem
1034
1035 out_object_file=`basename $out_file .c`.o
1036
1037 tm_file_list=
1038 for f in $tm_file; do
1039   case $f in
1040     ansidecl.h )
1041        tm_file_list="${tm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1042     defaults.h )
1043        tm_file_list="${tm_file_list} $f" ;;
1044     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
1045   esac
1046 done
1047
1048 tm_p_file_list=
1049 for f in $tm_p_file; do
1050     tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1051 done
1052
1053 host_xm_file_list=
1054 for f in $host_xm_file; do
1055   case $f in
1056     ansidecl.h )
1057        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1058     auto-host.h | defaults.h )
1059        host_xm_file_list="${host_xm_file_list} $f" ;;
1060     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
1061   esac
1062 done
1063
1064 build_xm_file_list=
1065 for f in $build_xm_file; do
1066   case $f in
1067     ansidecl.h )
1068        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1069     auto-build.h | auto-host.h | defaults.h )
1070        build_xm_file_list="${build_xm_file_list} $f" ;;
1071     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1072   esac
1073 done
1074
1075 # Define macro CROSS_COMPILE in compilation
1076 # if this is a cross-compiler.
1077 # Also use all.cross instead of all.internal
1078 # and add cross-make to Makefile.
1079 cross_overrides="/dev/null"
1080 if test x$host != x$target
1081 then
1082         cross_defines="CROSS=-DCROSS_COMPILE"
1083         cross_overrides="${topdir}/cross-make"
1084 fi
1085
1086 # If this is a cross-compiler that does not
1087 # have its own set of headers then define
1088 # inhibit_libc
1089
1090 # If this is using newlib, then define inhibit_libc in LIBGCC2_CFLAGS.
1091 # This prevents libgcc2 from containing any code which requires libc
1092 # support.
1093 inhibit_libc=
1094 if [test x$host != x$target] && [test x$with_headers = x]; then
1095        inhibit_libc=-Dinhibit_libc
1096 else
1097        if [test x$with_newlib = xyes]; then
1098                inhibit_libc=-Dinhibit_libc
1099        fi
1100 fi
1101 AC_SUBST(inhibit_libc)
1102
1103 # When building gcc with a cross-compiler, we need to fix a few things.
1104 # This must come after cross-make as we want all.build to override
1105 # all.cross.
1106 build_overrides="/dev/null"
1107 if test x$build != x$host
1108 then
1109         build_overrides="${topdir}/build-make"
1110 fi
1111
1112 # Expand extra_headers to include complete path.
1113 # This substitutes for lots of t-* files.
1114 extra_headers_list=
1115 if test "x$extra_headers" = x
1116 then true
1117 else
1118         # Prepend ${srcdir}/ginclude/ to every entry in extra_headers.
1119         for file in $extra_headers;
1120         do
1121                 extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/${file}"
1122         done
1123 fi
1124
1125 if test x$use_collect2 = xno; then
1126         use_collect2=
1127 fi
1128
1129 # Add a definition of USE_COLLECT2 if system wants one.
1130 # Also tell toplev.c what to do.
1131 # This substitutes for lots of t-* files.
1132 if test x$use_collect2 = x
1133 then
1134         will_use_collect2=
1135         maybe_use_collect2=
1136 else
1137         will_use_collect2="collect2"
1138         maybe_use_collect2="-DUSE_COLLECT2"
1139 fi
1140
1141 # If we have gas in the build tree, make a link to it.
1142 if test -f ../gas/Makefile; then
1143         rm -f as; $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1144 fi
1145
1146 # If we have nm in the build tree, make a link to it.
1147 if test -f ../binutils/Makefile; then
1148         rm -f nm; $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1149 fi
1150
1151 # If we have ld in the build tree, make a link to it.
1152 if test -f ../ld/Makefile; then
1153 #       if test x$use_collect2 = x; then
1154 #               rm -f ld; $symbolic_link ../ld/ld-new$host_exeext ld$host_exeext 2>/dev/null
1155 #       else
1156                 rm -f collect-ld; $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1157 #       fi
1158 fi
1159
1160 # Figure out what assembler we will be using.
1161 AC_MSG_CHECKING(what assembler to use)
1162 gcc_cv_as=
1163 gcc_cv_gas_major_version=
1164 gcc_cv_gas_minor_version=
1165 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1166 if test -x "$DEFAULT_ASSEMBLER"; then
1167         gcc_cv_as="$DEFAULT_ASSEMBLER"
1168 elif test -x "$AS"; then
1169         gcc_cv_as="$AS"
1170 elif test -x as$host_exeext; then
1171         # Build using assembler in the current directory.
1172         gcc_cv_as=./as$host_exeext
1173 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
1174         # Single tree build which includes gas.
1175         for f in $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
1176         do
1177 changequote(,)dnl
1178                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1179 changequote([,])dnl
1180                 if test x$gcc_cv_gas_version != x; then
1181                         break
1182                 fi
1183         done
1184 changequote(,)dnl
1185         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
1186         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1187 changequote([,])dnl
1188 fi
1189
1190 if test "x$gcc_cv_as" = x -a x$host = x$target; then
1191         # Native build.
1192         # Search the same directories that the installed compiler will
1193         # search.  Else we may find the wrong assembler and lose.  If we
1194         # do not find a suitable assembler binary, then try the user's
1195         # path.
1196         #
1197         # Also note we have to check MD_EXEC_PREFIX before checking the
1198         # user's path.  Unfortunately, there is no good way to get at the
1199         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1200         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1201         # to be fixed as part of the make/configure rewrite too.
1202
1203         if test "x$exec_prefix" = xNONE; then
1204                 if test "x$prefix" = xNONE; then
1205                         test_prefix=/usr/local
1206                 else
1207                         test_prefix=$prefix
1208                 fi
1209         else
1210                 test_prefix=$exec_prefix
1211         fi
1212
1213         # If the loop below does not find an assembler, then use whatever
1214         # one we can find in the users's path.
1215         # user's path.
1216         gcc_cv_as=as$host_exeext
1217
1218         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1219                    $test_prefix/lib/gcc-lib/$target \
1220                    /usr/lib/gcc/$target/$gcc_version \
1221                    /usr/lib/gcc/$target \
1222                    $test_prefix/$target/bin/$target/$gcc_version \
1223                    $test_prefix/$target/bin \
1224                    /usr/libexec \
1225                    /usr/ccs/gcc \
1226                    /usr/ccs/bin \
1227                    /udk/usr/ccs/bin \
1228                    /bsd43/usr/lib/cmplrs/cc \
1229                    /usr/cross64/usr/bin \
1230                    /usr/lib/cmplrs/cc \
1231                    /sysv/usr/lib/cmplrs/cc \
1232                    /svr4/usr/lib/cmplrs/cc \
1233                    /usr/bin"
1234
1235         for dir in $test_dirs; do
1236                 if test -f $dir/as$host_exeext; then
1237                         gcc_cv_as=$dir/as$host_exeext
1238                         break;
1239                 fi
1240         done
1241 fi
1242 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1243   AC_MSG_RESULT("newly built gas")
1244 else
1245   AC_MSG_RESULT($gcc_cv_as)
1246 fi
1247
1248 # Figure out what nm we will be using.
1249 AC_MSG_CHECKING(what nm to use)
1250 if test -x nm$host_exeext; then
1251         gcc_cv_nm=./nm$host_exeext
1252 elif test x$host = x$target; then
1253         # Native build.
1254         gcc_cv_nm=nm$host_exeext
1255 fi
1256 AC_MSG_RESULT($gcc_cv_nm)
1257
1258 # Figure out what assembler alignment features are present.
1259 AC_MSG_CHECKING(assembler alignment features)
1260 gcc_cv_as_alignment_features=none
1261 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1262         # Gas version 2.6 and later support for .balign and .p2align.
1263         # bytes to skip when using .p2align.
1264         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 6 -o "$gcc_cv_gas_major_version" -gt 2; then
1265                 gcc_cv_as_alignment_features=".balign and .p2align"
1266                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1267         fi
1268         # Gas version 2.8 and later support specifying the maximum
1269         # bytes to skip when using .p2align.
1270         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 8 -o "$gcc_cv_gas_major_version" -gt 2; then
1271                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1272                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1273         fi
1274 elif test x$gcc_cv_as != x; then
1275         # Check if we have .balign and .p2align
1276         echo ".balign  4" > conftest.s
1277         echo ".p2align  2" >> conftest.s
1278         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1279                 gcc_cv_as_alignment_features=".balign and .p2align"
1280                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1281         fi
1282         rm -f conftest.s conftest.o
1283         # Check if specifying the maximum bytes to skip when
1284         # using .p2align is supported.
1285         echo ".p2align 4,,7" > conftest.s
1286         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1287                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1288                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1289         fi
1290         rm -f conftest.s conftest.o
1291 fi
1292 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1293
1294 AC_MSG_CHECKING(assembler subsection support)
1295 gcc_cv_as_subsections=no
1296 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1297   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1298     gcc_cv_as_subsections="working .subsection -1"
1299   fi
1300 elif test x$gcc_cv_as != x; then
1301         # Check if we have .subsection
1302         echo ".subsection 1" > conftest.s
1303         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1304                 gcc_cv_as_subsections=".subsection"
1305                 if test x$gcc_cv_nm != x; then
1306                         cat > conftest.s <<EOF
1307 conftest_label1: .word 0
1308 .subsection -1
1309 conftest_label2: .word 0
1310 .previous
1311 EOF
1312                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1313                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1314                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1315                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1316                                         :
1317                                 else
1318                                         gcc_cv_as_subsections="working .subsection -1"
1319                                 fi
1320                         fi
1321                 fi
1322         fi
1323         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1324 fi
1325 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1326         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1327 [Define if your assembler supports .subsection and .subsection -1 starts
1328    emitting at the beginning of your section.])
1329 fi
1330 AC_MSG_RESULT($gcc_cv_as_subsections)
1331
1332 AC_MSG_CHECKING(assembler weak support)
1333 gcc_cv_as_weak=no
1334 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1335   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 2 -o "$gcc_cv_gas_major_version" -gt 2; then
1336     gcc_cv_as_weak="yes"
1337   fi
1338 elif test x$gcc_cv_as != x; then
1339         # Check if we have .weak
1340         echo "  .weak foobar" > conftest.s
1341         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1342                 gcc_cv_as_weak="yes"
1343         fi
1344         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1345 fi
1346 if test x"$gcc_cv_as_weak" = xyes; then
1347         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1348 fi
1349 AC_MSG_RESULT($gcc_cv_as_weak)
1350
1351 AC_MSG_CHECKING(assembler hidden support)
1352 gcc_cv_as_hidden=no
1353 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1354   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1355     gcc_cv_as_hidden="yes"
1356   fi
1357 elif test x$gcc_cv_as != x; then
1358         # Check if we have .hidden
1359         echo "  .hidden foobar" > conftest.s
1360         echo "foobar:" >> conftest.s
1361         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1362                 gcc_cv_as_hidden="yes"
1363         fi
1364         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1365 fi
1366 if test x"$gcc_cv_as_hidden" = xyes; then
1367         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1368                 [Define if your assembler supports .hidden.])
1369 fi
1370 AC_MSG_RESULT($gcc_cv_as_hidden)
1371
1372 AC_MSG_CHECKING(assembler leb128 support)
1373 gcc_cv_as_leb128=no
1374 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1375   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 11 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1376     gcc_cv_as_leb128="yes"
1377   fi
1378 elif test x$gcc_cv_as != x; then
1379         # Check if we have .[us]leb128, and support symbol arithmetic with it.
1380         cat > conftest.s <<EOF
1381         .data
1382         .uleb128 L2 - L1
1383 L1:
1384         .uleb128 1280
1385         .sleb128 -1010
1386 L2:
1387 EOF
1388         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1389                 gcc_cv_as_leb128="yes"
1390
1391                 # GAS versions before 2.11 do not support uleb128,
1392                 # despite appearing to.
1393                 # ??? There exists an elf-specific test that will crash
1394                 # the assembler.  Perhaps it's better to figure out whether
1395                 # arbitrary sections are supported and try the test.
1396                 as_ver=`$gcc_cv_as --version 2>/dev/null | head -1`
1397                 if echo "$as_ver" | grep GNU > /dev/null; then
1398                         as_ver=`echo $as_ver | sed -e 's/.* //'`
1399                         as_major=`echo $as_ver | sed 's/\..*//'`
1400 changequote(,)dnl
1401                         as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1402 changequote([,])dnl
1403                         if test $as_major -eq 2 -a $as_minor -lt 11; then
1404                                 gcc_cv_as_leb128="no"
1405                         fi
1406                 fi
1407         fi
1408         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1409 fi
1410 if test x"$gcc_cv_as_leb128" = xyes; then
1411         AC_DEFINE(HAVE_AS_LEB128, 1,
1412                 [Define if your assembler supports .uleb128.])
1413 fi
1414 AC_MSG_RESULT($gcc_cv_as_leb128)
1415
1416 AC_MSG_CHECKING(assembler eh_frame optimization)
1417 gcc_cv_as_eh_frame=no
1418 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1419   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1420     gcc_cv_as_eh_frame="yes"
1421   fi
1422 elif test x$gcc_cv_as != x; then
1423         # Check if this is GAS.
1424         as_ver=`$gcc_cv_as --version < /dev/null 2> /dev/null | head -1`
1425         rm -f a.out 2> /dev/null
1426         if echo "$as_ver" | grep GNU > /dev/null; then
1427                 # Versions up to and including 2.11.0 may mis-optimize
1428                 # .eh_frame data.  Try something.
1429                 cat > conftest.s <<EOF
1430         .text
1431 .LFB1:
1432         .4byte  0
1433 .L1:
1434         .4byte  0
1435 .LFE1:
1436         .section        .eh_frame,"aw",@progbits
1437 __FRAME_BEGIN__:
1438         .4byte  .LECIE1-.LSCIE1
1439 .LSCIE1:
1440         .4byte  0x0
1441         .byte   0x1
1442         .ascii "z\0"
1443         .byte   0x1
1444         .byte   0x78
1445         .byte   0x1a
1446         .byte   0x0
1447         .byte   0x4
1448         .4byte  1
1449         .p2align 1
1450 .LECIE1:
1451 .LSFDE1:
1452         .4byte  .LEFDE1-.LASFDE1
1453 .LASFDE1:
1454         .4byte  .LASFDE1-__FRAME_BEGIN__
1455         .4byte  .LFB1
1456         .4byte  .LFE1-.LFB1
1457         .byte   0x4
1458         .4byte  .LFE1-.LFB1
1459         .byte   0x4
1460         .4byte  .L1-.LFB1
1461 .LEFDE1:
1462 EOF
1463                 cat > conftest.exp <<EOF
1464  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1465  0010 01000000 12000000 18000000 00000000  ................
1466  0020 08000000 04080000 0044               .........D
1467 EOF
1468                 # If the assembler didn't choke, and we can objdump,
1469                 # and we got the correct data, then succeed.
1470                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1471                    && objdump -s -j .eh_frame conftest.o 2>/dev/null \
1472                       | tail -3 > conftest.got \
1473                    && cmp conftest.exp conftest.got > /dev/null 2>&1
1474                 then
1475                         gcc_cv_as_eh_frame="yes"
1476                 else
1477                         gcc_cv_as_eh_frame="bad"
1478                         if $gcc_cv_as -o conftest.o --traditional-format /dev/null; then
1479                                 AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
1480         [Define if your assembler mis-optimizes .eh_frame data.])
1481                         fi
1482                 fi
1483         fi
1484         rm -f conftest.*
1485 fi
1486 AC_MSG_RESULT($gcc_cv_as_eh_frame)
1487
1488 case "$target" in
1489   sparc*-*-*)
1490     AC_CACHE_CHECK([assembler .register pseudo-op support],
1491         gcc_cv_as_register_pseudo_op, [
1492         gcc_cv_as_register_pseudo_op=unknown
1493         if test x$gcc_cv_as != x; then
1494             # Check if we have .register
1495             echo ".register %g2, #scratch" > conftest.s
1496             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1497                 gcc_cv_as_register_pseudo_op=yes
1498             else
1499                 gcc_cv_as_register_pseudo_op=no
1500             fi
1501             rm -f conftest.s conftest.o
1502         fi
1503     ])
1504     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
1505         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
1506                 [Define if your assembler supports .register.])
1507     fi
1508
1509     AC_CACHE_CHECK([assembler supports -relax],
1510         gcc_cv_as_relax_opt, [
1511         gcc_cv_as_relax_opt=unknown
1512         if test x$gcc_cv_as != x; then
1513             # Check if gas supports -relax
1514             echo ".text" > conftest.s
1515             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
1516                 gcc_cv_as_relax_opt=yes
1517             else
1518                 gcc_cv_as_relax_opt=no
1519             fi
1520             rm -f conftest.s conftest.o
1521         fi
1522     ])
1523     if test "x$gcc_cv_as_relax_opt" = xyes; then
1524         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
1525                 [Define if your assembler supports -relax option.])
1526     fi
1527
1528     case "$tm_file" in
1529     *64*)
1530         AC_CACHE_CHECK([for 64 bit support in assembler ($gcc_cv_as)],
1531             gcc_cv_as_flags64, [
1532                 if test -n "$gcc_cv_as"; then
1533                     echo ".xword foo" > conftest.s
1534                     gcc_cv_as_flags64=no
1535                     for flag in "-xarch=v9" "-64 -Av9"; do
1536                         if $gcc_cv_as $flag -o conftest.o conftest.s \
1537                             > /dev/null 2>&1; then
1538                             gcc_cv_as_flags64=$flag
1539                             break
1540                         fi
1541                     done
1542                     rm -f conftest.s conftest.o
1543                 else
1544                     if test "$gas" = yes; then
1545                         gcc_cv_as_flags64="-64 -Av9"
1546                     else
1547                         gcc_cv_as_flags64="-xarch=v9"
1548                     fi
1549                 fi
1550         ])
1551         if test "x$gcc_cv_as_flags64" = xno; then
1552 changequote(, )
1553             tmake_file=`echo " $tmake_file " | sed -e 's, sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1554             dep_tmake_file=`echo " $dep_tmake_file " | sed -e 's, [^ ]*/config/sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1555 changequote([, ])
1556         else
1557             AC_DEFINE_UNQUOTED(AS_SPARC64_FLAG, "$gcc_cv_as_flags64",
1558                         [Define if the assembler supports 64bit sparc.])
1559         fi
1560         ;;
1561     *) gcc_cv_as_flags64=${gcc_cv_as_flags64-no}
1562         ;;
1563     esac
1564
1565     if test "x$gcc_cv_as_flags64" != xno; then
1566         AC_CACHE_CHECK([for assembler offsetable %lo() support],
1567             gcc_cv_as_offsetable_lo10, [
1568             gcc_cv_as_offsetable_lo10=unknown
1569             if test "x$gcc_cv_as" != x; then
1570                 # Check if assembler has offsetable %lo()
1571                 echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
1572                 echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
1573                 if $gcc_cv_as $gcc_cv_as_flags64 -o conftest.o conftest.s \
1574                         > /dev/null 2>&1 &&
1575                    $gcc_cv_as $gcc_cv_as_flags64 -o conftest1.o conftest1.s \
1576                         > /dev/null 2>&1; then
1577                     if cmp conftest.o conftest1.o > /dev/null 2>&1; then
1578                         gcc_cv_as_offsetable_lo10=no
1579                     else
1580                         gcc_cv_as_offsetable_lo10=yes
1581                     fi
1582                 else
1583                     gcc_cv_as_offsetable_lo10=no
1584                 fi
1585                 rm -f conftest.s conftest.o conftest1.s conftest1.o
1586             fi
1587         ])
1588         if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
1589             AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
1590                 [Define if your assembler supports offsetable %lo().])
1591         fi
1592     fi
1593
1594     ;;
1595
1596 changequote(,)dnl
1597   i[34567]86-*-*)
1598 changequote([,])dnl
1599     AC_MSG_CHECKING(assembler instructions)
1600     gcc_cv_as_instructions=
1601     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1602       if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2; then
1603         gcc_cv_as_instructions="filds fists"
1604       fi
1605     elif test x$gcc_cv_as != x; then
1606         set "filds fists" "filds mem; fists mem"
1607         while test $# -gt 0
1608         do
1609                 echo "$2" > conftest.s
1610                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1611                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
1612                 fi
1613                 shift 2
1614         done
1615         rm -f conftest.s conftest.o
1616     fi
1617     if test x"$gcc_cv_as_instructions" != x; then
1618         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
1619     fi
1620     AC_MSG_RESULT($gcc_cv_as_instructions)
1621     ;;
1622 esac
1623
1624 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
1625 gcc_cv_as_dwarf2_debug_line=no
1626 # ??? Not all targets support dwarf2 debug_line, even within a version
1627 # of gas.  Moreover, we need to emit a valid instruction to trigger any
1628 # info to the output file.  So, as supported targets are added to gas 2.11,
1629 # add some instruction here to (also) show we expect this might work.
1630 # ??? Once 2.11 is released, probably need to add first known working
1631 # version to the per-target configury.
1632 case "$target" in
1633   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-*)
1634     insn="nop"
1635     ;;
1636   ia64*-*-*)
1637     insn="nop 0"
1638     ;;
1639   esac
1640 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1641 then
1642   if test "$gcc_cv_gas_major_version" -eq 2 \
1643         -a "$gcc_cv_gas_minor_version" -ge 11 \
1644         -o "$gcc_cv_gas_major_version" -gt 2 \
1645      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1646      && test x"$insn" != x ; then
1647     gcc_cv_as_dwarf2_debug_line="yes"
1648   fi
1649 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1650         echo '  .file 1 "conftest.s"' > conftest.s
1651         echo '  .loc 1 3 0' >> conftest.s
1652         echo "  $insn" >> conftest.s
1653         # ??? This fails with non-gnu grep.
1654         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1655            && grep debug_line conftest.o > /dev/null 2>&1 ; then
1656                 # The .debug_line file table must be in the exact order that
1657                 # we specified the files, since these indicies are also used
1658                 # by DW_AT_decl_file.  Approximate this test by testing if
1659                 # the assembler bitches if the same index is assigned twice.
1660                 echo '  .file 1 "foo.s"' > conftest.s
1661                 echo '  .file 1 "bar.s"' >> conftest.s
1662                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1
1663                 then
1664                   gcc_cv_as_dwarf2_debug_line="no"
1665                 else
1666                   gcc_cv_as_dwarf2_debug_line="yes"
1667                 fi
1668         fi
1669         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1670 fi
1671 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
1672         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
1673 [Define if your assembler supports dwarf2 .file/.loc directives,
1674    and preserves file table indicies exactly as given.])
1675 fi
1676 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
1677
1678 # Figure out what language subdirectories are present.
1679 # Look if the user specified --enable-languages="..."; if not, use
1680 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1681 # go away some day.
1682 if test x"${enable_languages+set}" != xset; then
1683         if test x"${LANGUAGES+set}" = xset; then
1684                 enable_languages="`echo ${LANGUAGES} | tr ' ' ','`"
1685         else
1686                 enable_languages=all
1687         fi
1688 else
1689         if test x"${enable_languages}" = x; then
1690                 AC_MSG_ERROR([--enable-languages needs at least one argument])
1691         fi
1692 fi
1693
1694 # First scan to see if an enabled language requires some other language.
1695 # We assume that a given config-lang.in will list all the language
1696 # front ends it requires, even if some are required indirectly.
1697 for lang in ${srcdir}/*/config-lang.in ..
1698 do
1699    case $lang in
1700     ..)
1701        ;;
1702     # The odd quoting in the next line works around
1703     # an apparent bug in bash 1.12 on linux.
1704 changequote(,)dnl
1705     ${srcdir}/[*]/config-lang.in)
1706        ;;
1707     *)
1708        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
1709        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
1710        for other in $this_lang_requires
1711        do
1712           case ,${enable_languages}, in
1713            *,$other,*)
1714               ;;
1715            *,all,*)
1716               ;;
1717            *,$lang_alias,*)
1718               enable_languages="$enable_languages,$other"
1719               ;;
1720           esac
1721        done
1722        ;;
1723 changequote([,])dnl
1724    esac
1725 done
1726
1727 subdirs=
1728 for lang in ${srcdir}/*/config-lang.in ..
1729 do
1730         case $lang in
1731         ..) ;;
1732         # The odd quoting in the next line works around
1733         # an apparent bug in bash 1.12 on linux.
1734 changequote(,)dnl
1735         ${srcdir}/[*]/config-lang.in) ;;
1736         *)
1737           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
1738           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
1739           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
1740           if test "x$lang_alias" = x
1741           then
1742                 echo "$lang doesn't set \$language." 1>&2
1743                 exit 1
1744           fi
1745           case ${build_by_default},${enable_languages}, in
1746           *,$lang_alias,*) add_this_lang=yes ;;
1747           no,*) add_this_lang=no ;;
1748           *,all,*) add_this_lang=yes ;;
1749           *) add_this_lang=no ;;
1750           esac
1751           if test x"${add_this_lang}" = xyes; then
1752                 case $lang in
1753                     ${srcdir}/ada/config-lang.in)
1754                         if test x$have_gnat = xyes ; then
1755                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1756                         fi
1757                         ;;
1758                     *)
1759                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1760                         ;;
1761                 esac
1762           fi
1763           ;;
1764 changequote([,])dnl
1765         esac
1766 done
1767
1768 # Make gthr-default.h if we have a thread file.
1769 gthread_flags=
1770 if test $thread_file != single; then
1771     rm -f gthr-default.h
1772     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1773     gthread_flags=-DHAVE_GTHR_DEFAULT
1774 fi
1775 AC_SUBST(gthread_flags)
1776
1777 # Find out what GC implementation we want, or may, use.
1778 AC_ARG_WITH(gc,
1779 [  --with-gc={simple,page} choose the garbage collection mechanism to use
1780                           with the compiler],
1781 [case "$withval" in
1782   simple | page)
1783     GGC=ggc-$withval
1784     ;;
1785   *)
1786     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
1787     ;;
1788 esac],
1789 [GGC=ggc-page])
1790 AC_SUBST(GGC)
1791 echo "Using $GGC for garbage collection."
1792
1793 # Use the system's zlib library.
1794 zlibdir=-L../zlib
1795 zlibinc="-I\$(srcdir)/../zlib"
1796 AC_ARG_WITH(system-zlib,
1797 [  --with-system-zlib      use installed libz],
1798 zlibdir=
1799 zlibinc=
1800 )
1801 AC_SUBST(zlibdir)
1802 AC_SUBST(zlibinc)
1803
1804 dnl Very limited version of automake's enable-maintainer-mode
1805
1806 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1807   dnl maintainer-mode is disabled by default
1808   AC_ARG_ENABLE(maintainer-mode,
1809 [  --enable-maintainer-mode
1810                           enable make rules and dependencies not useful
1811                           (and sometimes confusing) to the casual installer],
1812       maintainer_mode=$enableval,
1813       maintainer_mode=no)
1814
1815 AC_MSG_RESULT($maintainer_mode)
1816
1817 if test "$maintainer_mode" = "yes"; then
1818   MAINT=''
1819 else
1820   MAINT='#'
1821 fi
1822 AC_SUBST(MAINT)dnl
1823
1824 # With Setjmp/Longjmp based exception handling.
1825 AC_ARG_ENABLE(sjlj-exceptions,
1826 [  --enable-sjlj-exceptions
1827                           arrange to use setjmp/longjmp exception handling],
1828 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1829 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1830   [Define 0/1 to force the choice for exception handling model.])])
1831
1832 # Make empty files to contain the specs and options for each language.
1833 # Then add #include lines to for a compiler that has specs and/or options.
1834
1835 lang_specs_files=
1836 lang_options_files=
1837 lang_tree_files=
1838 rm -f specs.h options.h gencheck.h
1839 touch specs.h options.h gencheck.h
1840 for subdir in . $subdirs
1841 do
1842         if test -f $srcdir/$subdir/lang-specs.h; then
1843                 echo "#include \"$subdir/lang-specs.h\"" >>specs.h
1844                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
1845         fi
1846         if test -f $srcdir/$subdir/lang-options.h; then
1847                 echo "#include \"$subdir/lang-options.h\"" >>options.h
1848                 lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
1849         fi
1850         if test -f $srcdir/$subdir/$subdir-tree.def; then
1851                 echo "#include \"$subdir/$subdir-tree.def\"" >>gencheck.h
1852                 lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
1853         fi
1854 done
1855
1856 # These (without "all_") are set in each config-lang.in.
1857 # `language' must be a single word so is spelled singularly.
1858 all_languages=
1859 all_boot_languages=
1860 all_compilers=
1861 all_stagestuff=
1862 all_diff_excludes=
1863 all_outputs='Makefile intl/Makefile po/Makefile.in fixinc/Makefile gccbug mklibgcc'
1864 # List of language makefile fragments.
1865 all_lang_makefiles=
1866 all_headers=
1867 all_lib2funcs=
1868
1869 # Add the language fragments.
1870 # Languages are added via two mechanisms.  Some information must be
1871 # recorded in makefile variables, these are defined in config-lang.in.
1872 # We accumulate them and plug them into the main Makefile.
1873 # The other mechanism is a set of hooks for each of the main targets
1874 # like `clean', `install', etc.
1875
1876 language_fragments="Make-lang"
1877 language_hooks="Make-hooks"
1878
1879 for s in .. $subdirs
1880 do
1881         if test $s != ".."
1882         then
1883                 language=
1884                 boot_language=
1885                 compilers=
1886                 stagestuff=
1887                 diff_excludes=
1888                 headers=
1889                 outputs=
1890                 lib2funcs=
1891                 . ${srcdir}/$s/config-lang.in
1892                 if test "x$language" = x
1893                 then
1894                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
1895                         exit 1
1896                 fi
1897                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
1898                 if test -f ${srcdir}/$s/Makefile.in
1899                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
1900                 fi
1901                 all_languages="$all_languages $language"
1902                 if test "x$boot_language" = xyes
1903                 then
1904                         all_boot_languages="$all_boot_languages $language"
1905                 fi
1906                 all_compilers="$all_compilers $compilers"
1907                 all_stagestuff="$all_stagestuff $stagestuff"
1908                 all_diff_excludes="$all_diff_excludes $diff_excludes"
1909                 all_headers="$all_headers $headers"
1910                 all_outputs="$all_outputs $outputs"
1911                 all_lib2funcs="$all_lib2funcs $lib2funcs"
1912         fi
1913 done
1914
1915 check_languages=
1916 for language in .. $all_languages
1917 do
1918         if test $language != ".."
1919         then
1920                 check_languages="$check_languages check-$language"
1921         fi
1922 done
1923
1924 # Since we can't use `::' targets, we link each language in
1925 # with a set of hooks, reached indirectly via lang.${target}.
1926
1927 rm -f Make-hooks
1928 touch Make-hooks
1929 target_list="all.build all.cross start.encap rest.encap \
1930         info dvi \
1931         install-normal install-common install-info install-man \
1932         uninstall \
1933         mostlyclean clean distclean extraclean maintainer-clean \
1934         stage1 stage2 stage3 stage4"
1935 for t in $target_list
1936 do
1937         x=
1938         for lang in .. $all_languages
1939         do
1940                 if test $lang != ".."; then
1941                         x="$x $lang.$t"
1942                 fi
1943         done
1944         echo "lang.$t: $x" >> Make-hooks
1945 done
1946
1947 # Create .gdbinit.
1948
1949 echo "dir ." > .gdbinit
1950 echo "dir ${srcdir}" >> .gdbinit
1951 if test x$gdb_needs_out_file_path = xyes
1952 then
1953         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
1954 fi
1955 if test "x$subdirs" != x; then
1956         for s in $subdirs
1957         do
1958                 echo "dir ${srcdir}/$s" >> .gdbinit
1959         done
1960 fi
1961 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
1962
1963 # Define variables host_canonical and build_canonical
1964 # because some Cygnus local changes in the Makefile depend on them.
1965 build_canonical=${build}
1966 host_canonical=${host}
1967 target_subdir=
1968 if test "${host}" != "${target}" ; then
1969     target_subdir=${target_alias}/
1970 fi
1971 AC_SUBST(build_canonical)
1972 AC_SUBST(host_canonical)
1973 AC_SUBST(target_subdir)
1974
1975 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
1976 # absolute path for gcc_tooldir based on inserting the number of up-directory
1977 # movements required to get from $(exec_prefix) to $(prefix) into the basic
1978 # $(libsubdir)/@(unlibsubdir) based path.
1979 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
1980 # make and thus we'd get different behavior depending on where we built the
1981 # sources.
1982 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
1983     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
1984 else
1985 changequote(<<, >>)dnl
1986 # An explanation of the sed strings:
1987 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
1988 #  -e 's|/$||'            match a trailing forward slash and eliminates it
1989 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
1990 #  -e 's|/[^/]*|../|g'    replaces each occurance of /<directory> with ../
1991 #
1992 # (*) Note this pattern overwrites the first character of the string
1993 # with a forward slash if one is not already present.  This is not a
1994 # problem because the exact names of the sub-directories concerned is
1995 # unimportant, just the number of them matters.
1996 #
1997 # The practical upshot of these patterns is like this:
1998 #
1999 #  prefix     exec_prefix        result
2000 #  ------     -----------        ------
2001 #   /foo        /foo/bar          ../
2002 #   /foo/       /foo/bar          ../
2003 #   /foo        /foo/bar/         ../
2004 #   /foo/       /foo/bar/         ../
2005 #   /foo        /foo/bar/ugg      ../../
2006 #
2007     dollar='$$'
2008     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
2009 changequote([, ])dnl
2010 fi
2011 AC_SUBST(gcc_tooldir)
2012 AC_SUBST(dollar)
2013
2014 # Find a directory in which to install a shared libgcc.
2015
2016 AC_ARG_ENABLE(version-specific-runtime-libs,
2017 [  --enable-version-specific-runtime-libs
2018                           specify that runtime libraries should be
2019                           installed in a compiler-specific directory])
2020
2021 AC_ARG_WITH(slibdir,
2022 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2023 slibdir="$with_slibdir",
2024 if test "${enable_version_specific_runtime_libs+set}" = set; then
2025   slibdir='$(libsubdir)'
2026 elif test "$host" != "$target"; then
2027   slibdir='$(build_tooldir)/lib'
2028 else
2029   slibdir='$(libdir)'
2030 fi)
2031 AC_SUBST(slibdir)
2032
2033 # Nothing to do for FLOAT_H, float_format already handled.
2034 objdir=`pwd`
2035 AC_SUBST(objdir)
2036
2037 # Process the language and host/target makefile fragments.
2038 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
2039
2040 # Substitute configuration variables
2041 AC_SUBST(subdirs)
2042 AC_SUBST(all_boot_languages)
2043 AC_SUBST(all_compilers)
2044 AC_SUBST(all_diff_excludes)
2045 AC_SUBST(all_headers)
2046 AC_SUBST(all_lang_makefiles)
2047 AC_SUBST(all_languages)
2048 AC_SUBST(all_lib2funcs)
2049 AC_SUBST(all_stagestuff)
2050 AC_SUBST(build_exeext)
2051 AC_SUBST(build_install_headers_dir)
2052 AC_SUBST(build_xm_file_list)
2053 AC_SUBST(build_xm_file)
2054 AC_SUBST(build_xm_defines)
2055 AC_SUBST(check_languages)
2056 AC_SUBST(cc_set_by_configure)
2057 AC_SUBST(quoted_cc_set_by_configure)
2058 AC_SUBST(cpp_install_dir)
2059 AC_SUBST(dep_host_xmake_file)
2060 AC_SUBST(dep_tmake_file)
2061 AC_SUBST(extra_c_flags)
2062 AC_SUBST(extra_headers_list)
2063 AC_SUBST(extra_objs)
2064 AC_SUBST(extra_parts)
2065 AC_SUBST(extra_passes)
2066 AC_SUBST(extra_programs)
2067 AC_SUBST(float_h_file)
2068 AC_SUBST(gcc_config_arguments)
2069 AC_SUBST(gcc_gxx_include_dir)
2070 AC_SUBST(libstdcxx_incdir)
2071 AC_SUBST(gcc_version)
2072 AC_SUBST(gcc_version_full)
2073 AC_SUBST(gcc_version_trigger)
2074 AC_SUBST(host_exeext)
2075 AC_SUBST(host_extra_gcc_objs)
2076 AC_SUBST(host_xm_file_list)
2077 AC_SUBST(host_xm_file)
2078 AC_SUBST(host_xm_defines)
2079 AC_SUBST(install)
2080 AC_SUBST(lang_options_files)
2081 AC_SUBST(lang_specs_files)
2082 AC_SUBST(lang_tree_files)
2083 AC_SUBST(local_prefix)
2084 AC_SUBST(maybe_use_collect2)
2085 AC_SUBST(md_file)
2086 AC_SUBST(objc_boehm_gc)
2087 AC_SUBST(out_file)
2088 AC_SUBST(out_object_file)
2089 AC_SUBST(stage_prefix_set_by_configure)
2090 AC_SUBST(symbolic_link)
2091 AC_SUBST(thread_file)
2092 AC_SUBST(tm_file_list)
2093 AC_SUBST(tm_file)
2094 AC_SUBST(tm_p_file_list)
2095 AC_SUBST(tm_p_file)
2096 AC_SUBST(xm_file)
2097 AC_SUBST(xm_defines)
2098 AC_SUBST(will_use_collect2)
2099 AC_SUBST(c_target_objs)
2100 AC_SUBST(cxx_target_objs)
2101 AC_SUBST(target_cpu_default)
2102
2103 AC_SUBST_FILE(target_overrides)
2104 AC_SUBST_FILE(host_overrides)
2105 AC_SUBST(cross_defines)
2106 AC_SUBST_FILE(cross_overrides)
2107 AC_SUBST_FILE(build_overrides)
2108 AC_SUBST_FILE(language_fragments)
2109 AC_SUBST_FILE(language_hooks)
2110
2111 # Echo that links are built
2112 if test x$host = x$target
2113 then
2114         str1="native "
2115 else
2116         str1="cross-"
2117         str2=" from $host"
2118 fi
2119
2120 if test x$host != x$build
2121 then
2122         str3=" on a $build system"
2123 fi
2124
2125 if test "x$str2" != x || test "x$str3" != x
2126 then
2127         str4=
2128 fi
2129
2130 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
2131
2132 if test "x$str2" != x || test "x$str3" != x
2133 then
2134         echo " ${str2}${str3}." 1>&2
2135 fi
2136
2137 # Truncate the target if necessary
2138 if test x$host_truncate_target != x; then
2139         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
2140 fi
2141
2142 # Configure the subdirectories
2143 # AC_CONFIG_SUBDIRS($subdirs)
2144
2145 # Create the Makefile
2146 # and configure language subdirectories
2147 AC_OUTPUT($all_outputs,
2148 [
2149 case x$CONFIG_HEADERS in
2150 xauto-host.h:config.in)
2151 echo > cstamp-h ;;
2152 esac
2153 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
2154 # bootstrapping and the installation procedure can still use
2155 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
2156 # FLAGS_TO_PASS has been modified to solve the problem there.
2157 # This is virtually a duplicate of what happens in configure.lang; we do
2158 # an extra check to make sure this only happens if ln -s can be used.
2159 if test "$symbolic_link" = "ln -s"; then
2160  for d in .. ${subdirs} ; do
2161    if test $d != ..; then
2162         STARTDIR=`pwd`
2163         cd $d
2164         for t in stage1 stage2 stage3 stage4 include
2165         do
2166                 rm -f $t
2167                 $symbolic_link ../$t $t 2>/dev/null
2168         done
2169         cd $STARTDIR
2170    fi
2171  done
2172 else true ; fi
2173 # Avoid having to add intl to our include paths.
2174 if test -f intl/libintl.h; then
2175   echo creating libintl.h
2176   echo '#include "intl/libintl.h"' >libintl.h
2177 fi
2178 ],
2179 [
2180 host='${host}'
2181 build='${build}'
2182 target='${target}'
2183 target_alias='${target_alias}'
2184 srcdir='${srcdir}'
2185 subdirs='${subdirs}'
2186 symbolic_link='${symbolic_link}'
2187 program_transform_set='${program_transform_set}'
2188 program_transform_name='${program_transform_name}'
2189 dep_host_xmake_file='${dep_host_xmake_file}'
2190 host_xmake_file='${host_xmake_file}'
2191 dep_tmake_file='${dep_tmake_file}'
2192 tmake_file='${tmake_file}'
2193 thread_file='${thread_file}'
2194 gcc_config_arguments='${gcc_config_arguments}'
2195 gcc_version='${gcc_version}'
2196 gcc_version_full='${gcc_version_full}'
2197 gcc_version_trigger='${gcc_version_trigger}'
2198 local_prefix='${local_prefix}'
2199 build_install_headers_dir='${build_install_headers_dir}'
2200 build_exeext='${build_exeext}'
2201 host_exeext='${host_exeext}'
2202 out_file='${out_file}'
2203 gdb_needs_out_file_path='${gdb_needs_out_file_path}'
2204 SET_MAKE='${SET_MAKE}'
2205 target_list='${target_list}'
2206 target_overrides='${target_overrides}'
2207 host_overrides='${host_overrides}'
2208 cross_defines='${cross_defines}'
2209 cross_overrides='${cross_overrides}'
2210 build_overrides='${build_overrides}'
2211 cpp_install_dir='${cpp_install_dir}'
2212 ])