libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT([GNU OpenMP Runtime Library], 1.0,,[libgomp])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  14    [Specify that runtime libraries should be installed in a compiler-specific directory],
  15    permit yes|no)
  16 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  17
  18 # We would like our source tree to be readonly. However when releases or
  19 # pre-releases are generated, the flex/bison generated files as well as the
  20 # various formats of manuals need to be included along with the rest of the
  21 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  22 # just that.
  23 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  24 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  25    [put copies of generated files in source dir intended for creating source
  26     tarballs for users without texinfo bison or flex.],
  27    permit yes|no)
  28 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  29 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  30
  31
  32 # -------
  33 # -------
  34
  35 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  36 #
  37 # You will slowly go insane if you do not grok the following fact:  when
  38 # building this library, the top-level /target/ becomes the library's /host/.
  39 #
  40 # configure then causes --target to default to --host, exactly like any
  41 # other package using autoconf.  Therefore, 'target' and 'host' will
  42 # always be the same.  This makes sense both for native and cross compilers
  43 # just think about it for a little while.  :-)
  44 #
  45 # Also, if this library is being configured as part of a cross compiler, the
  46 # top-level configure script will pass the "real" host as $with_cross_host.
  47 #
  48 # Do not delete or change the following two lines.  For why, see
  49 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  50 AC_CANONICAL_SYSTEM
  51 target_alias=${target_alias-$host_alias}
  52
  53 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  54 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  55 #  1.9.0:  minimum required version
  56 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  57 #              of other PACKAGE_* variables will, however, and there's nothing
  58 #              we can do about that; they come from AC_INIT).
  59 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  60 #            file in the top srcdir, etc, etc), so stop complaining.
  61 #  no-dist:  we don't want 'dist' and related rules.
  62 #  -Wall:  turns on all automake warnings...
  63 #  -Wno-portability:  ...except this one, since GNU make is required.
  64 #  -Wno-override: ... and this one, since we do want this in testsuite.
  65 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  66 AM_ENABLE_MULTILIB(, ..)
  67
  68 # Calculate toolexeclibdir
  69 # Also toolexecdir, though it's only used in toolexeclibdir
  70 case ${enable_version_specific_runtime_libs} in
  71   yes)
  72     # Need the gcc compiler version to know where to install libraries
  73     # and header files if --enable-version-specific-runtime-libs option
  74     # is selected.
  75     toolexecdir='$(libdir)/gcc/$(target_alias)'
  76     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  77     ;;
  78   no)
  79     if test -n "$with_cross_host" &&
  80        test x"$with_cross_host" != x"no"; then
  81       # Install a library built with a cross compiler in tooldir, not libdir.
  82       toolexecdir='$(exec_prefix)/$(target_alias)'
  83       toolexeclibdir='$(toolexecdir)/lib'
  84     else
  85       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  86       toolexeclibdir='$(libdir)'
  87     fi
  88     multi_os_directory=`$CC -print-multi-os-directory`
  89     case $multi_os_directory in
  90       .) ;; # Avoid trailing /.
  91       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  92     esac
  93     ;;
  94 esac
  95 AC_SUBST(toolexecdir)
  96 AC_SUBST(toolexeclibdir)
  97
  98 # Check the compiler.
  99 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 100 # We must force CC to /not/ be precious variables; otherwise
 101 # the wrong, non-multilib-adjusted value will be used in multilibs.
 102 # As a side effect, we have to subst CFLAGS ourselves.
 103
 104 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 105 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 106 AC_PROG_CC
 107 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108
 109 AC_SUBST(CFLAGS)
 110
 111 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 112 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 113 # in both places for now and restore CFLAGS at the end of config.
 114 save_CFLAGS="$CFLAGS"
 115
 116 # Add -Wall -Werror if we are using GCC.
 117 if test "x$GCC" = "xyes"; then
 118   XCFLAGS="$XCFLAGS -Wall -Werror"
 119 fi
 120
 121 # Find other programs we need.
 122 AC_CHECK_TOOL(AR, ar)
 123 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 124 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 125 AC_PROG_MAKE_SET
 126 AC_PROG_INSTALL
 127
 128 # See if makeinfo has been installed and is modern enough
 129 # that we can use it.
 130 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 131                    [GNU texinfo.* \([0-9][0-9.]*\)],
 132                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 133 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 134
 135
 136 # Configure libtool
 137 AM_PROG_LIBTOOL
 138 ACX_LT_HOST_FLAGS
 139 AC_SUBST(enable_shared)
 140 AC_SUBST(enable_static)
 141
 142 AM_MAINTAINER_MODE
 143
 144 # Create a spec file, so that compile/link tests don't fail
 145 test -f libgfortran.spec || touch libgfortran.spec
 146 FCFLAGS="$FCFLAGS -L."
 147
 148 # We need gfortran to compile parts of the library
 149 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 150 #AC_PROG_FC(gfortran)
 151 case `echo $GFORTRAN` in
 152   -* | no* )
 153     FC=no ;;
 154   *)
 155     set dummy $GFORTRAN; ac_word=$2
 156     if test -x "$ac_word"; then
 157       FC="$GFORTRAN"
 158     else
 159       FC=no
 160     fi ;;
 161 esac
 162 AC_PROG_FC(gfortran)
 163 FCFLAGS="$FCFLAGS -Wall -L../libgfortran"
 164
 165 # For libtool versioning info, format is CURRENT:REVISION:AGE
 166 libtool_VERSION=1:0:0
 167 AC_SUBST(libtool_VERSION)
 168
 169 # Check header files.
 170 AC_STDC_HEADERS
 171 AC_HEADER_TIME
 172 ACX_HEADER_STRING
 173 AC_CHECK_HEADERS(unistd.h semaphore.h sys/loadavg.h sys/time.h sys/time.h)
 174
 175 GCC_HEADER_STDINT(gstdint.h)
 176
 177 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 178 # In case the pthread.h system header is not found, this test will fail.
 179 XPCFLAGS=""
 180 CFLAGS="$CFLAGS -pthread"
 181 AC_LINK_IFELSE(
 182  [AC_LANG_PROGRAM(
 183   [#include <pthread.h>
 184    void *g(void *d) { return NULL; }],
 185   [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 186  [XPCFLAGS=" -Wc,-pthread"],
 187  [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 188   AC_LINK_IFELSE(
 189    [AC_LANG_PROGRAM(
 190     [#include <pthread.h>
 191      void *g(void *d) { return NULL; }],
 192     [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 193    [],
 194    [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 195
 196 plugin_support=yes
 197 AC_CHECK_LIB(dl, dlsym, , [plugin_support=no])
 198 if test x"$plugin_support" = xyes; then
 199   AC_DEFINE(PLUGIN_SUPPORT, 1,
 200     [Define if all infrastructure, needed for plugins, is supported.])
 201 fi
 202
 203 # Check for functions needed.
 204 AC_CHECK_FUNCS(getloadavg clock_gettime strtoull)
 205
 206 # Check for broken semaphore implementation on darwin.
 207 # sem_init returns: sem_init error: Function not implemented.
 208 case "$host" in
 209   *-darwin*)
 210     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 211         Define if the POSIX Semaphores do not work on your system.)
 212     ;;
 213 esac
 214
 215 GCC_LINUX_FUTEX(:)
 216
 217 # Check for pthread_{,attr_}[sg]etaffinity_np.
 218 AC_LINK_IFELSE(
 219  [AC_LANG_PROGRAM(
 220   [#define _GNU_SOURCE
 221    #include <pthread.h>],
 222   [cpu_set_t cpuset;
 223    pthread_attr_t attr;
 224    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 225    if (CPU_ISSET (0, &cpuset))
 226      CPU_SET (1, &cpuset);
 227    else
 228      CPU_ZERO (&cpuset);
 229    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 230    pthread_attr_init (&attr);
 231    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 232    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 233   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 234 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 235
 236 # At least for glibc, clock_gettime is in librt.  But don't pull that
 237 # in if it still doesn't give us the function we want.
 238 if test $ac_cv_func_clock_gettime = no; then
 239   AC_CHECK_LIB(rt, clock_gettime,
 240     [LIBS="-lrt $LIBS"
 241      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 242                [Define to 1 if you have the `clock_gettime' function.])])
 243 fi
 244
 245 # See if we support thread-local storage.
 246 GCC_CHECK_TLS
 247
 248 # See what sort of export controls are available.
 249 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 250 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 251 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 252 LIBGOMP_ENABLE_SYMVERS
 253
 254 if test $enable_symvers = gnu; then
 255   AC_DEFINE(LIBGOMP_GNU_SYMBOL_VERSIONING, 1,
 256             [Define to 1 if GNU symbol versioning is used for libgomp.])
 257 fi
 258
 259 # Get target configury.
 260 . ${srcdir}/configure.tgt
 261 CFLAGS="$save_CFLAGS $XCFLAGS"
 262
 263 # Check for __sync_val_compare_and_swap, but only after the target has
 264 # had a chance to set XCFLAGS.
 265 LIBGOMP_CHECK_SYNC_BUILTINS
 266
 267 XCFLAGS="$XCFLAGS$XPCFLAGS"
 268
 269 AC_SUBST(config_path)
 270 AC_SUBST(XCFLAGS)
 271 AC_SUBST(XLDFLAGS)
 272
 273 # Cleanup and exit.
 274 CFLAGS="$save_CFLAGS"
 275 AC_CACHE_SAVE
 276
 277 if test ${multilib} = yes; then
 278   multilib_arg="--enable-multilib"
 279 else
 280   multilib_arg=
 281 fi
 282
 283 # Get accel target and path to install tree of accel compiler
 284 offload_additional_options=
 285 offload_additional_lib_paths=
 286 offload_targets=
 287 if test x"$enable_offload_targets" != x; then
 288   for tgt in `echo $enable_offload_targets | sed -e 's#,# #g'`; do
 289     tgt_dir=`echo $tgt | grep '=' | sed 's/.*=//'`
 290     tgt=`echo $tgt | sed 's/=.*//'`
 291     case $tgt in
 292       *-intelmic-* | *-intelmicemul-*)
 293         tgt_name="intelmic" ;;
 294       *)
 295         AC_MSG_ERROR([unknown offload target specified]) ;;
 296     esac
 297     if test x"$offload_targets" = x; then
 298       offload_targets=$tgt_name
 299     else
 300       offload_targets=$offload_targets,$tgt_name
 301     fi
 302     if test x"$tgt_dir" != x; then
 303       offload_additional_options="$offload_additional_options -B$tgt_dir/libexec/gcc/\$(target_alias)/\$(gcc_version) -B$tgt_dir/bin"
 304       offload_additional_lib_paths="$offload_additional_lib_paths:$tgt_dir/lib64:$tgt_dir/lib"
 305     else
 306       offload_additional_options="$offload_additional_options -B\$(libexecdir)/gcc/\$(target_alias)/\$(gcc_version) -B\$(bindir)"
 307       offload_additional_lib_paths="$offload_additional_lib_paths:$toolexeclibdir"
 308     fi
 309   done
 310 fi
 311 AC_DEFINE_UNQUOTED(OFFLOAD_TARGETS, "$offload_targets",
 312   [Define to hold the list of target names suitable for offloading.])
 313 AC_SUBST(offload_targets)
 314 AC_SUBST(offload_additional_options)
 315 AC_SUBST(offload_additional_lib_paths)
 316
 317 # Set up the set of libraries that we need to link against for libgomp.
 318 # Note that the GOMP_SELF_SPEC in gcc.c may force -pthread,
 319 # which will force linkage against -lpthread (or equivalent for the system).
 320 # That's not 100% ideal, but about the best we can do easily.
 321 if test $enable_shared = yes; then
 322   link_gomp="-lgomp %{static: $LIBS}"
 323 else
 324   link_gomp="-lgomp $LIBS"
 325 fi
 326 AC_SUBST(link_gomp)
 327
 328 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 329
 330 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 331 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 332 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 333 # need to copy this macro to our acinclude.m4.
 334 save_CFLAGS="$CFLAGS"
 335 for i in $config_path; do
 336   if test -f $srcdir/config/$i/omp-lock.h; then
 337     CFLAGS="$CFLAGS -include confdefs.h -include $srcdir/config/$i/omp-lock.h"
 338     break
 339   fi
 340 done
 341
 342 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 343   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 344 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 345 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 346 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 347 _AC_COMPUTE_INT([sizeof (omp_lock_25_t)], [OMP_LOCK_25_SIZE],,
 348   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_25_t)])])
 349 _AC_COMPUTE_INT([__alignof (omp_lock_25_t)], [OMP_LOCK_25_ALIGN])
 350 _AC_COMPUTE_INT([sizeof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_SIZE])
 351 _AC_COMPUTE_INT([__alignof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_ALIGN])
 352
 353 # If the lock fits in an integer, then arrange for Fortran to use that
 354 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 355 # Except that we don't have a way at present to multi-lib the installed
 356 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 357 # actual target.
 358 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 359 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 360 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 361   OMP_LOCK_KIND=8
 362 fi
 363 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 364   OMP_NEST_LOCK_KIND=8
 365 fi
 366 OMP_LOCK_25_KIND=$OMP_LOCK_25_SIZE
 367 OMP_NEST_LOCK_25_KIND=$OMP_NEST_LOCK_25_SIZE
 368 if test $OMP_LOCK_25_SIZE -gt 8 || test $OMP_LOCK_25_ALIGN -gt $OMP_LOCK_25_SIZE; then
 369   OMP_LOCK_25_KIND=8
 370 fi
 371 if test $OMP_NEST_LOCK_25_SIZE -gt 8 || test $OMP_NEST_LOCK_25_ALIGN -gt $OMP_NEST_LOCK_25_SIZE; then
 372   OMP_NEST_LOCK_25_KIND=8
 373 fi
 374
 375 AC_SUBST(OMP_LOCK_SIZE)
 376 AC_SUBST(OMP_LOCK_ALIGN)
 377 AC_SUBST(OMP_NEST_LOCK_SIZE)
 378 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 379 AC_SUBST(OMP_LOCK_KIND)
 380 AC_SUBST(OMP_NEST_LOCK_KIND)
 381 AC_SUBST(OMP_LOCK_25_SIZE)
 382 AC_SUBST(OMP_LOCK_25_ALIGN)
 383 AC_SUBST(OMP_NEST_LOCK_25_SIZE)
 384 AC_SUBST(OMP_NEST_LOCK_25_ALIGN)
 385 AC_SUBST(OMP_LOCK_25_KIND)
 386 AC_SUBST(OMP_NEST_LOCK_25_KIND)
 387 CFLAGS="$save_CFLAGS"
 388
 389 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 390 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 391 AC_OUTPUT