gcc/ada/s-memory.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                         S Y S T E M . M E M O R Y                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --          Copyright (C) 2001-2002 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  25 -- MA 02111-1307, USA.                                                      --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- GNAT was originally developed  by the GNAT team at  New York University. --
  35 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  36 --                                                                          --
  37 ------------------------------------------------------------------------------
  38
  39 --  This is the default implementation of this package.
  40
  41 --  This implementation assumes that the underlying malloc/free/realloc
  42 --  implementation is thread safe, and thus, no additional lock is required.
  43 --  Note that we still need to defer abortion because on most systems,
  44 --  an asynchronous signal (as used for implementing asynchronous abortion
  45 --  of task) cannot safely be handled while malloc is executing.
  46
  47 --  If you are not using Ada constructs containing the "abort" keyword,
  48 --  then you can remove the calls to Abort_Defer.all and Abort_Undefer.all
  49 --  from this unit.
  50
  51 with Ada.Exceptions;
  52 with System.Soft_Links;
  53 with System.Parameters;
  54
  55 package body System.Memory is
  56
  57    use Ada.Exceptions;
  58    use System.Soft_Links;
  59
  60    function c_malloc (Size : size_t) return System.Address;
  61    pragma Import (C, c_malloc, "malloc");
  62
  63    procedure c_free (Ptr : System.Address);
  64    pragma Import (C, c_free, "free");
  65
  66    function c_realloc
  67      (Ptr : System.Address; Size : size_t) return System.Address;
  68    pragma Import (C, c_realloc, "realloc");
  69
  70    -----------
  71    -- Alloc --
  72    -----------
  73
  74    function Alloc (Size : size_t) return System.Address is
  75       Result      : System.Address;
  76       Actual_Size : size_t := Size;
  77
  78    begin
  79       if Size = size_t'Last then
  80          Raise_Exception (Storage_Error'Identity, "object too large");
  81       end if;
  82
  83       --  Change size from zero to non-zero. We still want a proper pointer
  84       --  for the zero case because pointers to zero length objects have to
  85       --  be distinct, but we can't just go ahead and allocate zero bytes,
  86       --  since some malloc's return zero for a zero argument.
  87
  88       if Size = 0 then
  89          Actual_Size := 1;
  90       end if;
  91
  92       if Parameters.No_Abort then
  93          Result := c_malloc (Actual_Size);
  94       else
  95          Abort_Defer.all;
  96          Result := c_malloc (Actual_Size);
  97          Abort_Undefer.all;
  98       end if;
  99
 100       if Result = System.Null_Address then
 101          Raise_Exception (Storage_Error'Identity, "heap exhausted");
 102       end if;
 103
 104       return Result;
 105    end Alloc;
 106
 107    ----------
 108    -- Free --
 109    ----------
 110
 111    procedure Free (Ptr : System.Address) is
 112    begin
 113       if Parameters.No_Abort then
 114          c_free (Ptr);
 115       else
 116          Abort_Defer.all;
 117          c_free (Ptr);
 118          Abort_Undefer.all;
 119       end if;
 120    end Free;
 121
 122    -------------
 123    -- Realloc --
 124    -------------
 125
 126    function Realloc
 127      (Ptr  : System.Address;
 128       Size : size_t)
 129       return System.Address
 130    is
 131       Result      : System.Address;
 132       Actual_Size : size_t := Size;
 133
 134    begin
 135       if Size = size_t'Last then
 136          Raise_Exception (Storage_Error'Identity, "object too large");
 137       end if;
 138
 139       if Parameters.No_Abort then
 140          Result := c_realloc (Ptr, Actual_Size);
 141       else
 142          Abort_Defer.all;
 143          Result := c_realloc (Ptr, Actual_Size);
 144          Abort_Undefer.all;
 145       end if;
 146
 147       if Result = System.Null_Address then
 148          Raise_Exception (Storage_Error'Identity, "heap exhausted");
 149       end if;
 150
 151       return Result;
 152    end Realloc;
 153
 154 end System.Memory;