libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_INIT([GNU Offloading and Multi Processing Runtime Library], 1.0,,[libgomp])
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # -------
   8 # Options
   9 # -------
  10
  11 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  12 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  13    [Specify that runtime libraries should be installed in a compiler-specific directory],
  14    permit yes|no)
  15 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  16
  17 # We would like our source tree to be readonly. However when releases or
  18 # pre-releases are generated, the flex/bison generated files as well as the
  19 # various formats of manuals need to be included along with the rest of the
  20 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  21 # just that.
  22 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  23 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  24    [put copies of generated files in source dir intended for creating source
  25     tarballs for users without texinfo bison or flex.],
  26    permit yes|no)
  27 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  28 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  29
  30
  31 # -------
  32 # -------
  33
  34 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  35 #
  36 # You will slowly go insane if you do not grok the following fact:  when
  37 # building this library, the top-level /target/ becomes the library's /host/.
  38 #
  39 # configure then causes --target to default to --host, exactly like any
  40 # other package using autoconf.  Therefore, 'target' and 'host' will
  41 # always be the same.  This makes sense both for native and cross compilers
  42 # just think about it for a little while.  :-)
  43 #
  44 # Also, if this library is being configured as part of a cross compiler, the
  45 # top-level configure script will pass the "real" host as $with_cross_host.
  46 #
  47 # Do not delete or change the following two lines.  For why, see
  48 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  49 AC_CANONICAL_SYSTEM
  50 target_alias=${target_alias-$host_alias}
  51
  52 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  53 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  54 #  1.9.0:  minimum required version
  55 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  56 #              of other PACKAGE_* variables will, however, and there's nothing
  57 #              we can do about that; they come from AC_INIT).
  58 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  59 #            file in the top srcdir, etc, etc), so stop complaining.
  60 #  no-dist:  we don't want 'dist' and related rules.
  61 #  -Wall:  turns on all automake warnings...
  62 #  -Wno-portability:  ...except this one, since GNU make is required.
  63 #  -Wno-override: ... and this one, since we do want this in testsuite.
  64 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  65 AM_ENABLE_MULTILIB(, ..)
  66
  67 # Calculate toolexeclibdir
  68 # Also toolexecdir, though it's only used in toolexeclibdir
  69 case ${enable_version_specific_runtime_libs} in
  70   yes)
  71     # Need the gcc compiler version to know where to install libraries
  72     # and header files if --enable-version-specific-runtime-libs option
  73     # is selected.
  74     toolexecdir='$(libdir)/gcc/$(target_alias)'
  75     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  76     ;;
  77   no)
  78     if test -n "$with_cross_host" &&
  79        test x"$with_cross_host" != x"no"; then
  80       # Install a library built with a cross compiler in tooldir, not libdir.
  81       toolexecdir='$(exec_prefix)/$(target_alias)'
  82       toolexeclibdir='$(toolexecdir)/lib'
  83     else
  84       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  85       toolexeclibdir='$(libdir)'
  86     fi
  87     multi_os_directory=`$CC -print-multi-os-directory`
  88     case $multi_os_directory in
  89       .) ;; # Avoid trailing /.
  90       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  91     esac
  92     ;;
  93 esac
  94 AC_SUBST(toolexecdir)
  95 AC_SUBST(toolexeclibdir)
  96
  97 # Check the compiler.
  98 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  99 # We must force CC to /not/ be precious variables; otherwise
 100 # the wrong, non-multilib-adjusted value will be used in multilibs.
 101 # As a side effect, we have to subst CFLAGS ourselves.
 102
 103 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 104 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 105 AC_PROG_CC
 106 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 107
 108 AC_SUBST(CFLAGS)
 109
 110 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 111 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 112 # in both places for now and restore CFLAGS at the end of config.
 113 save_CFLAGS="$CFLAGS"
 114
 115 # Add -Wall -Werror if we are using GCC.
 116 if test "x$GCC" = "xyes"; then
 117   XCFLAGS="$XCFLAGS -Wall -Werror"
 118 fi
 119
 120 # Find other programs we need.
 121 AC_CHECK_TOOL(AR, ar)
 122 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 123 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 124 AC_PROG_MAKE_SET
 125 AC_PROG_INSTALL
 126
 127 # See if makeinfo has been installed and is modern enough
 128 # that we can use it.
 129 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 130                    [GNU texinfo.* \([0-9][0-9.]*\)],
 131                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 132 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 133
 134
 135 # Configure libtool
 136 AM_PROG_LIBTOOL
 137 ACX_LT_HOST_FLAGS
 138 AC_SUBST(enable_shared)
 139 AC_SUBST(enable_static)
 140
 141 AM_MAINTAINER_MODE
 142
 143 # Create a spec file, so that compile/link tests don't fail
 144 test -f libgfortran.spec || touch libgfortran.spec
 145 FCFLAGS="$FCFLAGS -L."
 146
 147 # We need gfortran to compile parts of the library
 148 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 149 #AC_PROG_FC(gfortran)
 150 case `echo $GFORTRAN` in
 151   -* | no* )
 152     FC=no ;;
 153   *)
 154     set dummy $GFORTRAN; ac_word=$2
 155     if test -x "$ac_word"; then
 156       FC="$GFORTRAN"
 157     else
 158       FC=no
 159     fi ;;
 160 esac
 161 AC_PROG_FC(gfortran)
 162 FCFLAGS="$FCFLAGS -Wall -L../libgfortran"
 163
 164 # For libtool versioning info, format is CURRENT:REVISION:AGE
 165 libtool_VERSION=1:0:0
 166 AC_SUBST(libtool_VERSION)
 167
 168 # Check header files.
 169 AC_STDC_HEADERS
 170 AC_HEADER_TIME
 171 ACX_HEADER_STRING
 172 AC_CHECK_HEADERS(pthread.h unistd.h semaphore.h sys/loadavg.h sys/sysctl.h sys/time.h)
 173
 174 XPCFLAGS=""
 175 case "$host" in
 176   *-*-rtems*)
 177     # RTEMS supports Pthreads, but the library is not available at GCC build time.
 178     ;;
 179   nvptx*-*-* | amdgcn*-*-*)
 180     # NVPTX does not support Pthreads, has its own code replacement.
 181     libgomp_use_pthreads=no
 182     # NVPTX is an accelerator-only target
 183     libgomp_offloaded_only=yes
 184     ;;
 185   *)
 186     # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 187     # In case the pthread.h system header is not found, this test will fail.
 188     CFLAGS="$CFLAGS -pthread"
 189     AC_LINK_IFELSE(
 190      [AC_LANG_PROGRAM(
 191       [#include <pthread.h>
 192        void *g(void *d) { return NULL; }],
 193       [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 194      [XPCFLAGS=" -Wc,-pthread"],
 195      [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 196       AC_LINK_IFELSE(
 197        [AC_LANG_PROGRAM(
 198         [#include <pthread.h>
 199          void *g(void *d) { return NULL; }],
 200         [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 201        [],
 202        [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 203 esac
 204
 205 if test x$libgomp_use_pthreads != xno; then
 206   AC_DEFINE(LIBGOMP_USE_PTHREADS, 1,
 207             [Define to 1 if libgomp should use POSIX threads.])
 208 fi
 209
 210 if test x$libgomp_offloaded_only = xyes; then
 211   AC_DEFINE(LIBGOMP_OFFLOADED_ONLY, 1,
 212             [Define to 1 if building libgomp for an accelerator-only target.])
 213 fi
 214
 215 m4_include([plugin/configfrag.ac])
 216
 217 # Check for functions needed.
 218 AC_CHECK_FUNCS(getloadavg clock_gettime strtoull)
 219 AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 220
 221 # Check for broken semaphore implementation on darwin.
 222 # sem_init returns: sem_init error: Function not implemented.
 223 case "$host" in
 224   *-darwin*)
 225     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 226         Define if the POSIX Semaphores do not work on your system.)
 227     ;;
 228 esac
 229
 230 # RTEMS specific checks
 231 case "$host" in
 232   *-*-rtems*)
 233     AC_CHECK_TYPES([struct _Mutex_Control],[],[],[#include <sys/lock.h>])
 234     ;;
 235 esac
 236
 237 GCC_LINUX_FUTEX(:)
 238
 239 # Check for pthread_{,attr_}[sg]etaffinity_np.
 240 AC_LINK_IFELSE(
 241  [AC_LANG_PROGRAM(
 242   [#define _GNU_SOURCE
 243    #include <pthread.h>],
 244   [cpu_set_t cpuset;
 245    pthread_attr_t attr;
 246    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 247    if (CPU_ISSET (0, &cpuset))
 248      CPU_SET (1, &cpuset);
 249    else
 250      CPU_ZERO (&cpuset);
 251    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 252    pthread_attr_init (&attr);
 253    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 254    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 255   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 256 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 257
 258 # At least for glibc, clock_gettime is in librt.  But don't pull that
 259 # in if it still doesn't give us the function we want.
 260 if test $ac_cv_func_clock_gettime = no; then
 261   AC_CHECK_LIB(rt, clock_gettime,
 262     [LIBS="-lrt $LIBS"
 263      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 264                [Define to 1 if you have the `clock_gettime' function.])])
 265 fi
 266
 267 # Check for uname.
 268 AC_COMPILE_IFELSE(
 269  [AC_LANG_PROGRAM(
 270   [#include <string.h>
 271    #include <stdlib.h>
 272    #include <sys/utsname.h>],
 273   [struct utsname buf;
 274    volatile size_t len = 0;
 275    if (!uname (buf))
 276      len = strlen (buf.nodename);])],
 277   AC_DEFINE(HAVE_UNAME, 1,
 278 [       Define if uname is supported and struct utsname has nodename field.]))
 279
 280 # Check for gethostname.
 281 AC_COMPILE_IFELSE(
 282  [AC_LANG_PROGRAM(
 283   [#include <unistd.h>],
 284   [
 285 changequote(,)dnl
 286    char buf[256];
 287    if (gethostname (buf, sizeof (buf) - 1) == 0)
 288      buf[255] = '\0';
 289 changequote([,])dnl
 290   ])],
 291   AC_DEFINE(HAVE_GETHOSTNAME, 1,
 292 [       Define if gethostname is supported.]))
 293
 294 # Check for getpid.
 295 AC_COMPILE_IFELSE(
 296  [AC_LANG_PROGRAM(
 297   [#include <unistd.h>],
 298   [int pid = getpid ();])],
 299   AC_DEFINE(HAVE_GETPID, 1,
 300 [       Define if getpid is supported.]))
 301
 302 # See if we support thread-local storage.
 303 GCC_CHECK_TLS
 304
 305 # See if we have emulated thread-local storage.
 306 GCC_CHECK_EMUTLS
 307
 308 # See what sort of export controls are available.
 309 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 310 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 311 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 312 LIBGOMP_ENABLE_SYMVERS
 313
 314 if test $enable_symvers = gnu; then
 315   AC_DEFINE(LIBGOMP_GNU_SYMBOL_VERSIONING, 1,
 316             [Define to 1 if GNU symbol versioning is used for libgomp.])
 317 fi
 318
 319 # Determine cpu count to limit testsuite parallelism.
 320 AX_COUNT_CPUS
 321 AC_SUBST(CPU_COUNT)
 322
 323 # Get target configury.
 324 . ${srcdir}/configure.tgt
 325 CFLAGS="$save_CFLAGS $XCFLAGS"
 326
 327 # Check for __sync_val_compare_and_swap, but only after the target has
 328 # had a chance to set XCFLAGS.
 329 LIBGOMP_CHECK_SYNC_BUILTINS
 330
 331 XCFLAGS="$XCFLAGS$XPCFLAGS"
 332
 333 # Add CET specific flags if CET is enabled
 334 GCC_CET_FLAGS(CET_FLAGS)
 335 XCFLAGS="$XCFLAGS $CET_FLAGS"
 336 FCFLAGS="$FCFLAGS $CET_FLAGS"
 337
 338 AC_SUBST(config_path)
 339 AC_SUBST(XCFLAGS)
 340 AC_SUBST(XLDFLAGS)
 341
 342 # Cleanup and exit.
 343 CFLAGS="$save_CFLAGS"
 344 AC_CACHE_SAVE
 345
 346 if test ${multilib} = yes; then
 347   multilib_arg="--enable-multilib"
 348 else
 349   multilib_arg=
 350 fi
 351
 352 # Set up the set of libraries that we need to link against for libgomp.
 353 # Note that the GOMP_SELF_SPEC in gcc.c may force -pthread,
 354 # which will force linkage against -lpthread (or equivalent for the system).
 355 # That's not 100% ideal, but about the best we can do easily.
 356 if test $enable_shared = yes; then
 357   link_gomp="-lgomp %{static: $LIBS}"
 358 else
 359   link_gomp="-lgomp $LIBS"
 360 fi
 361 AC_SUBST(link_gomp)
 362
 363 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 364
 365 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 366 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 367 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 368 # need to copy this macro to our acinclude.m4.
 369 save_CFLAGS="$CFLAGS"
 370 for i in $config_path; do
 371   if test -f $srcdir/config/$i/omp-lock.h; then
 372     CFLAGS="$CFLAGS -include confdefs.h -include $srcdir/config/$i/omp-lock.h"
 373     break
 374   fi
 375 done
 376
 377 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 378   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 379 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 380 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 381 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 382 _AC_COMPUTE_INT([sizeof (omp_lock_25_t)], [OMP_LOCK_25_SIZE],,
 383   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_25_t)])])
 384 _AC_COMPUTE_INT([__alignof (omp_lock_25_t)], [OMP_LOCK_25_ALIGN])
 385 _AC_COMPUTE_INT([sizeof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_SIZE])
 386 _AC_COMPUTE_INT([__alignof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_ALIGN])
 387
 388 # If the lock fits in an integer, then arrange for Fortran to use that
 389 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 390 # Except that we don't have a way at present to multi-lib the installed
 391 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 392 # actual target.
 393 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 394 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 395 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 396   OMP_LOCK_KIND=8
 397 fi
 398 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 399   OMP_NEST_LOCK_KIND=8
 400 fi
 401 OMP_LOCK_25_KIND=$OMP_LOCK_25_SIZE
 402 OMP_NEST_LOCK_25_KIND=$OMP_NEST_LOCK_25_SIZE
 403 if test $OMP_LOCK_25_SIZE -gt 8 || test $OMP_LOCK_25_ALIGN -gt $OMP_LOCK_25_SIZE; then
 404   OMP_LOCK_25_KIND=8
 405 fi
 406 if test $OMP_NEST_LOCK_25_SIZE -gt 8 || test $OMP_NEST_LOCK_25_ALIGN -gt $OMP_NEST_LOCK_25_SIZE; then
 407   OMP_NEST_LOCK_25_KIND=8
 408 fi
 409
 410 AC_SUBST(OMP_LOCK_SIZE)
 411 AC_SUBST(OMP_LOCK_ALIGN)
 412 AC_SUBST(OMP_NEST_LOCK_SIZE)
 413 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 414 AC_SUBST(OMP_LOCK_KIND)
 415 AC_SUBST(OMP_NEST_LOCK_KIND)
 416 AC_SUBST(OMP_LOCK_25_SIZE)
 417 AC_SUBST(OMP_LOCK_25_ALIGN)
 418 AC_SUBST(OMP_NEST_LOCK_25_SIZE)
 419 AC_SUBST(OMP_NEST_LOCK_25_ALIGN)
 420 AC_SUBST(OMP_LOCK_25_KIND)
 421 AC_SUBST(OMP_NEST_LOCK_25_KIND)
 422 CFLAGS="$save_CFLAGS"
 423
 424 # Determine what GCC version number to use in filesystem paths.
 425 GCC_BASE_VER
 426
 427 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 428 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 429 AC_CONFIG_FILES([testsuite/libgomp-test-support.pt.exp:testsuite/libgomp-test-support.exp.in])
 430 AC_OUTPUT