libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_INIT([GNU Offloading and Multi Processing Runtime Library], 1.0,,[libgomp])
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # -------
   8 # Options
   9 # -------
  10
  11 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  12 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  13    [Specify that runtime libraries should be installed in a compiler-specific directory],
  14    permit yes|no)
  15 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  16
  17 # We would like our source tree to be readonly. However when releases or
  18 # pre-releases are generated, the flex/bison generated files as well as the
  19 # various formats of manuals need to be included along with the rest of the
  20 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  21 # just that.
  22 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  23 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  24    [put copies of generated files in source dir intended for creating source
  25     tarballs for users without texinfo bison or flex.],
  26    permit yes|no)
  27 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  28 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  29
  30
  31 # -------
  32 # -------
  33
  34 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  35 #
  36 # You will slowly go insane if you do not grok the following fact:  when
  37 # building this library, the top-level /target/ becomes the library's /host/.
  38 #
  39 # configure then causes --target to default to --host, exactly like any
  40 # other package using autoconf.  Therefore, 'target' and 'host' will
  41 # always be the same.  This makes sense both for native and cross compilers
  42 # just think about it for a little while.  :-)
  43 #
  44 # Also, if this library is being configured as part of a cross compiler, the
  45 # top-level configure script will pass the "real" host as $with_cross_host.
  46 #
  47 # Do not delete or change the following two lines.  For why, see
  48 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  49 AC_CANONICAL_SYSTEM
  50 target_alias=${target_alias-$host_alias}
  51
  52 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  53 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  54 #  1.9.0:  minimum required version
  55 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  56 #              of other PACKAGE_* variables will, however, and there's nothing
  57 #              we can do about that; they come from AC_INIT).
  58 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  59 #            file in the top srcdir, etc, etc), so stop complaining.
  60 #  no-dist:  we don't want 'dist' and related rules.
  61 #  -Wall:  turns on all automake warnings...
  62 #  -Wno-portability:  ...except this one, since GNU make is required.
  63 #  -Wno-override: ... and this one, since we do want this in testsuite.
  64 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  65 AM_ENABLE_MULTILIB(, ..)
  66
  67 # Calculate toolexeclibdir
  68 # Also toolexecdir, though it's only used in toolexeclibdir
  69 case ${enable_version_specific_runtime_libs} in
  70   yes)
  71     # Need the gcc compiler version to know where to install libraries
  72     # and header files if --enable-version-specific-runtime-libs option
  73     # is selected.
  74     toolexecdir='$(libdir)/gcc/$(target_alias)'
  75     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  76     ;;
  77   no)
  78     if test -n "$with_cross_host" &&
  79        test x"$with_cross_host" != x"no"; then
  80       # Install a library built with a cross compiler in tooldir, not libdir.
  81       toolexecdir='$(exec_prefix)/$(target_alias)'
  82       toolexeclibdir='$(toolexecdir)/lib'
  83     else
  84       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  85       toolexeclibdir='$(libdir)'
  86     fi
  87     multi_os_directory=`$CC -print-multi-os-directory`
  88     case $multi_os_directory in
  89       .) ;; # Avoid trailing /.
  90       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  91     esac
  92     ;;
  93 esac
  94 AC_SUBST(toolexecdir)
  95 AC_SUBST(toolexeclibdir)
  96
  97 # Check the compiler.
  98 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  99 # We must force CC to /not/ be precious variables; otherwise
 100 # the wrong, non-multilib-adjusted value will be used in multilibs.
 101 # As a side effect, we have to subst CFLAGS ourselves.
 102
 103 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 104 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 105 AC_PROG_CC
 106 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 107
 108 AC_SUBST(CFLAGS)
 109
 110 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 111 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 112 # in both places for now and restore CFLAGS at the end of config.
 113 save_CFLAGS="$CFLAGS"
 114
 115 # Add -Wall -Werror if we are using GCC.
 116 if test "x$GCC" = "xyes"; then
 117   XCFLAGS="$XCFLAGS -Wall -Werror"
 118 fi
 119
 120 # Find other programs we need.
 121 AC_CHECK_TOOL(AR, ar)
 122 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 123 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 124 AC_PROG_MAKE_SET
 125 AC_PROG_INSTALL
 126
 127 # See if makeinfo has been installed and is modern enough
 128 # that we can use it.
 129 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 130                    [GNU texinfo.* \([0-9][0-9.]*\)],
 131                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 132 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 133
 134
 135 # Configure libtool
 136 AM_PROG_LIBTOOL
 137 ACX_LT_HOST_FLAGS
 138 AC_SUBST(enable_shared)
 139 AC_SUBST(enable_static)
 140
 141 AM_MAINTAINER_MODE
 142
 143 # Create a spec file, so that compile/link tests don't fail
 144 test -f libgfortran.spec || touch libgfortran.spec
 145 FCFLAGS="$FCFLAGS -L."
 146
 147 # We need gfortran to compile parts of the library
 148 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 149 #AC_PROG_FC(gfortran)
 150 case `echo $GFORTRAN` in
 151   -* | no* )
 152     FC=no ;;
 153   *)
 154     set dummy $GFORTRAN; ac_word=$2
 155     if test -x "$ac_word"; then
 156       FC="$GFORTRAN"
 157     else
 158       FC=no
 159     fi ;;
 160 esac
 161 AC_PROG_FC(gfortran)
 162 FCFLAGS="$FCFLAGS -Wall -L../libgfortran"
 163
 164 # For libtool versioning info, format is CURRENT:REVISION:AGE
 165 libtool_VERSION=1:0:0
 166 AC_SUBST(libtool_VERSION)
 167
 168 # Check header files.
 169 AC_STDC_HEADERS
 170 AC_HEADER_TIME
 171 ACX_HEADER_STRING
 172 AC_CHECK_HEADERS(pthread.h unistd.h semaphore.h sys/loadavg.h sys/sysctl.h sys/time.h)
 173
 174 GCC_HEADER_STDINT(gstdint.h)
 175
 176 XPCFLAGS=""
 177 case "$host" in
 178   *-*-rtems*)
 179     # RTEMS supports Pthreads, but the library is not available at GCC build time.
 180     ;;
 181   nvptx*-*-*)
 182     # NVPTX does not support Pthreads, has its own code replacement.
 183     libgomp_use_pthreads=no
 184     # NVPTX is an accelerator-only target
 185     libgomp_offloaded_only=yes
 186     ;;
 187   *)
 188     # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 189     # In case the pthread.h system header is not found, this test will fail.
 190     CFLAGS="$CFLAGS -pthread"
 191     AC_LINK_IFELSE(
 192      [AC_LANG_PROGRAM(
 193       [#include <pthread.h>
 194        void *g(void *d) { return NULL; }],
 195       [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 196      [XPCFLAGS=" -Wc,-pthread"],
 197      [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 198       AC_LINK_IFELSE(
 199        [AC_LANG_PROGRAM(
 200         [#include <pthread.h>
 201          void *g(void *d) { return NULL; }],
 202         [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 203        [],
 204        [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 205 esac
 206
 207 if test x$libgomp_use_pthreads != xno; then
 208   AC_DEFINE(LIBGOMP_USE_PTHREADS, 1,
 209             [Define to 1 if libgomp should use POSIX threads.])
 210 fi
 211
 212 if test x$libgomp_offloaded_only = xyes; then
 213   AC_DEFINE(LIBGOMP_OFFLOADED_ONLY, 1,
 214             [Define to 1 if building libgomp for an accelerator-only target.])
 215 fi
 216
 217 m4_include([plugin/configfrag.ac])
 218
 219 # Check for functions needed.
 220 AC_CHECK_FUNCS(getloadavg clock_gettime strtoull)
 221 AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 222
 223 # Check for broken semaphore implementation on darwin.
 224 # sem_init returns: sem_init error: Function not implemented.
 225 case "$host" in
 226   *-darwin*)
 227     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 228         Define if the POSIX Semaphores do not work on your system.)
 229     ;;
 230 esac
 231
 232 # RTEMS specific checks
 233 case "$host" in
 234   *-*-rtems*)
 235     AC_CHECK_TYPES([struct _Mutex_Control],[],[],[#include <sys/lock.h>])
 236     ;;
 237 esac
 238
 239 GCC_LINUX_FUTEX(:)
 240
 241 # Check for pthread_{,attr_}[sg]etaffinity_np.
 242 AC_LINK_IFELSE(
 243  [AC_LANG_PROGRAM(
 244   [#define _GNU_SOURCE
 245    #include <pthread.h>],
 246   [cpu_set_t cpuset;
 247    pthread_attr_t attr;
 248    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 249    if (CPU_ISSET (0, &cpuset))
 250      CPU_SET (1, &cpuset);
 251    else
 252      CPU_ZERO (&cpuset);
 253    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 254    pthread_attr_init (&attr);
 255    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 256    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 257   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 258 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 259
 260 # At least for glibc, clock_gettime is in librt.  But don't pull that
 261 # in if it still doesn't give us the function we want.
 262 if test $ac_cv_func_clock_gettime = no; then
 263   AC_CHECK_LIB(rt, clock_gettime,
 264     [LIBS="-lrt $LIBS"
 265      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 266                [Define to 1 if you have the `clock_gettime' function.])])
 267 fi
 268
 269 # Check for uname.
 270 AC_COMPILE_IFELSE(
 271  [AC_LANG_PROGRAM(
 272   [#include <string.h>
 273    #include <stdlib.h>
 274    #include <sys/utsname.h>],
 275   [struct utsname buf;
 276    volatile size_t len = 0;
 277    if (!uname (buf))
 278      len = strlen (buf.nodename);])],
 279   AC_DEFINE(HAVE_UNAME, 1,
 280 [       Define if uname is supported and struct utsname has nodename field.]))
 281
 282 # Check for gethostname.
 283 AC_COMPILE_IFELSE(
 284  [AC_LANG_PROGRAM(
 285   [#include <unistd.h>],
 286   [
 287 changequote(,)dnl
 288    char buf[256];
 289    if (gethostname (buf, sizeof (buf) - 1) == 0)
 290      buf[255] = '\0';
 291 changequote([,])dnl
 292   ])],
 293   AC_DEFINE(HAVE_GETHOSTNAME, 1,
 294 [       Define if gethostname is supported.]))
 295
 296 # Check for getpid.
 297 AC_COMPILE_IFELSE(
 298  [AC_LANG_PROGRAM(
 299   [#include <unistd.h>],
 300   [int pid = getpid ();])],
 301   AC_DEFINE(HAVE_GETPID, 1,
 302 [       Define if getpid is supported.]))
 303
 304 # See if we support thread-local storage.
 305 GCC_CHECK_TLS
 306
 307 # See if we have emulated thread-local storage.
 308 GCC_CHECK_EMUTLS
 309
 310 # See what sort of export controls are available.
 311 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 312 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 313 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 314 LIBGOMP_ENABLE_SYMVERS
 315
 316 if test $enable_symvers = gnu; then
 317   AC_DEFINE(LIBGOMP_GNU_SYMBOL_VERSIONING, 1,
 318             [Define to 1 if GNU symbol versioning is used for libgomp.])
 319 fi
 320
 321 # Determine cpu count to limit testsuite parallelism.
 322 AX_COUNT_CPUS
 323 AC_SUBST(CPU_COUNT)
 324
 325 # Get target configury.
 326 . ${srcdir}/configure.tgt
 327 CFLAGS="$save_CFLAGS $XCFLAGS"
 328
 329 # Check for __sync_val_compare_and_swap, but only after the target has
 330 # had a chance to set XCFLAGS.
 331 LIBGOMP_CHECK_SYNC_BUILTINS
 332
 333 XCFLAGS="$XCFLAGS$XPCFLAGS"
 334
 335 # Add CET specific flags if CET is enabled
 336 GCC_CET_FLAGS(CET_FLAGS)
 337 XCFLAGS="$XCFLAGS $CET_FLAGS"
 338 FCFLAGS="$FCFLAGS $CET_FLAGS"
 339
 340 AC_SUBST(config_path)
 341 AC_SUBST(XCFLAGS)
 342 AC_SUBST(XLDFLAGS)
 343
 344 # Cleanup and exit.
 345 CFLAGS="$save_CFLAGS"
 346 AC_CACHE_SAVE
 347
 348 if test ${multilib} = yes; then
 349   multilib_arg="--enable-multilib"
 350 else
 351   multilib_arg=
 352 fi
 353
 354 # Set up the set of libraries that we need to link against for libgomp.
 355 # Note that the GOMP_SELF_SPEC in gcc.c may force -pthread,
 356 # which will force linkage against -lpthread (or equivalent for the system).
 357 # That's not 100% ideal, but about the best we can do easily.
 358 if test $enable_shared = yes; then
 359   link_gomp="-lgomp %{static: $LIBS}"
 360 else
 361   link_gomp="-lgomp $LIBS"
 362 fi
 363 AC_SUBST(link_gomp)
 364
 365 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 366
 367 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 368 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 369 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 370 # need to copy this macro to our acinclude.m4.
 371 save_CFLAGS="$CFLAGS"
 372 for i in $config_path; do
 373   if test -f $srcdir/config/$i/omp-lock.h; then
 374     CFLAGS="$CFLAGS -include confdefs.h -include $srcdir/config/$i/omp-lock.h"
 375     break
 376   fi
 377 done
 378
 379 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 380   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 381 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 382 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 383 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 384 _AC_COMPUTE_INT([sizeof (omp_lock_25_t)], [OMP_LOCK_25_SIZE],,
 385   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_25_t)])])
 386 _AC_COMPUTE_INT([__alignof (omp_lock_25_t)], [OMP_LOCK_25_ALIGN])
 387 _AC_COMPUTE_INT([sizeof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_SIZE])
 388 _AC_COMPUTE_INT([__alignof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_ALIGN])
 389
 390 # If the lock fits in an integer, then arrange for Fortran to use that
 391 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 392 # Except that we don't have a way at present to multi-lib the installed
 393 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 394 # actual target.
 395 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 396 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 397 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 398   OMP_LOCK_KIND=8
 399 fi
 400 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 401   OMP_NEST_LOCK_KIND=8
 402 fi
 403 OMP_LOCK_25_KIND=$OMP_LOCK_25_SIZE
 404 OMP_NEST_LOCK_25_KIND=$OMP_NEST_LOCK_25_SIZE
 405 if test $OMP_LOCK_25_SIZE -gt 8 || test $OMP_LOCK_25_ALIGN -gt $OMP_LOCK_25_SIZE; then
 406   OMP_LOCK_25_KIND=8
 407 fi
 408 if test $OMP_NEST_LOCK_25_SIZE -gt 8 || test $OMP_NEST_LOCK_25_ALIGN -gt $OMP_NEST_LOCK_25_SIZE; then
 409   OMP_NEST_LOCK_25_KIND=8
 410 fi
 411
 412 AC_SUBST(OMP_LOCK_SIZE)
 413 AC_SUBST(OMP_LOCK_ALIGN)
 414 AC_SUBST(OMP_NEST_LOCK_SIZE)
 415 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 416 AC_SUBST(OMP_LOCK_KIND)
 417 AC_SUBST(OMP_NEST_LOCK_KIND)
 418 AC_SUBST(OMP_LOCK_25_SIZE)
 419 AC_SUBST(OMP_LOCK_25_ALIGN)
 420 AC_SUBST(OMP_NEST_LOCK_25_SIZE)
 421 AC_SUBST(OMP_NEST_LOCK_25_ALIGN)
 422 AC_SUBST(OMP_LOCK_25_KIND)
 423 AC_SUBST(OMP_NEST_LOCK_25_KIND)
 424 CFLAGS="$save_CFLAGS"
 425
 426 # Determine what GCC version number to use in filesystem paths.
 427 GCC_BASE_VER
 428
 429 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 430 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 431 AC_CONFIG_FILES([testsuite/libgomp-test-support.pt.exp:testsuite/libgomp-test-support.exp.in])
 432 AC_OUTPUT