libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # Find the rest of the source tree framework.
  15 AM_ENABLE_MULTILIB(, ..)
  16
  17 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  18 #
  19 # You will slowly go insane if you do not grok the following fact:  when
  20 # building v3 as part of the compiler, the top-level /target/ becomes the
  21 # library's /host/.  configure then causes --target to default to --host,
  22 # exactly like any other package using autoconf.  Therefore, 'target' and
  23 # 'host' will always be the same.  This makes sense both for native and
  24 # cross compilers, just think about it for a little while.  :-)
  25 #
  26 # Also, if v3 is being configured as part of a cross compiler, the top-level
  27 # configure script will pass the "real" host as $with_cross_host.
  28 #
  29 # Do not delete or change the following two lines.  For why, see
  30 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  31 AC_CANONICAL_SYSTEM
  32 target_alias=${target_alias-$host_alias}
  33
  34 # Handy for debugging:
  35 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  36
  37 if test "$build" != "$host"; then
  38   # We are being configured with some form of cross compiler.
  39   GLIBCXX_IS_NATIVE=false
  40   case "$host","$target" in
  41     # Darwin crosses can use the host system's libraries and headers,
  42     # because of the fat library support.  Of course, it must be the
  43     # same version of Darwin on both sides.  Allow the user to
  44     # just say --target=foo-darwin without a version number to mean
  45     # "the version on this system".
  46       *-*-darwin*,*-*-darwin*)
  47         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  48         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  49         if test $hostos = $targetos -o $targetos = darwin ; then
  50           GLIBCXX_IS_NATIVE=true
  51         fi
  52         ;;
  53
  54       *)
  55         GCC_NO_EXECUTABLES
  56         ;;
  57   esac
  58 else
  59   GLIBCXX_IS_NATIVE=true
  60 fi
  61
  62 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  63 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  64 #  1.x:  minimum required version
  65 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  66 #              of other PACKAGE_* variables will, however, and there's nothing
  67 #              we can do about that; they come from AC_INIT).
  68 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  69 #            file in the top srcdir, etc, etc), so stop complaining.
  70 #  no-dependencies:  turns off auto dependency generation (just for now)
  71 #  no-dist:  we don't want 'dist' and related rules.
  72 #  -Wall:  turns on all automake warnings...
  73 #  -Wno-portability:  ...except this one, since GNU make is now required.
  74 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  75 AH_TEMPLATE(PACKAGE, [Name of package])
  76 AH_TEMPLATE(VERSION, [Version number of package])
  77
  78 # -fno-builtin must be present here so that a non-conflicting form of
  79 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  80
  81 save_CXXFLAGS="$CXXFLAGS"
  82 CXXFLAGS="$CXXFLAGS -fno-builtin"
  83 AC_PROG_CC
  84 AC_PROG_CXX
  85 CXXFLAGS="$save_CXXFLAGS"
  86
  87 # Runs configure.host, and assorted other critical bits.  Sets
  88 # up critical shell variables.
  89 GLIBCXX_CONFIGURE
  90
  91 if test "x${with_newlib}" != "xyes"; then
  92   AC_LIBTOOL_DLOPEN
  93 fi
  94 AM_PROG_LIBTOOL
  95 ACX_LT_HOST_FLAGS
  96 AC_SUBST(enable_shared)
  97 AC_SUBST(enable_static)
  98
  99 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 100 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 101
 102 # Possibly disable most of the library.
 103 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 104 ## than just ignoring the results.  Faster /and/ more correct, win win.
 105 GLIBCXX_ENABLE_HOSTED
 106
 107 # Enable compiler support that doesn't require linking.
 108 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 109 GLIBCXX_ENABLE_PCH($is_hosted)
 110 GLIBCXX_ENABLE_THREADS
 111 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 112 GLIBCXX_ENABLE_DECIMAL_FLOAT
 113 GLIBCXX_ENABLE_INT128_FLOAT128
 114
 115 # Checks for compiler support that doesn't require linking.
 116 GLIBCXX_CHECK_COMPILER_FEATURES
 117
 118 # Enable all the variable C++ runtime options that don't require linking.
 119 GLIBCXX_ENABLE_CSTDIO
 120 GLIBCXX_ENABLE_CLOCALE
 121 GLIBCXX_ENABLE_ALLOCATOR
 122 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 123 GLIBCXX_ENABLE_LONG_LONG([yes])
 124 GLIBCXX_ENABLE_WCHAR_T([yes])
 125 GLIBCXX_ENABLE_C99([yes])
 126 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 127 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0"])
 128 GLIBCXX_ENABLE_DEBUG([no])
 129 GLIBCXX_ENABLE_PARALLEL([yes])
 130 GLIBCXX_ENABLE_CXX_FLAGS
 131 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 132 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 133 GLIBCXX_ENABLE_PYTHON
 134 GLIBCXX_ENABLE_WERROR([yes])
 135
 136 # Checks for operating systems support that doesn't require linking.
 137 GLIBCXX_CHECK_MATH_PROTO
 138 GLIBCXX_CHECK_STDLIB_PROTO
 139 GLIBCXX_CHECK_SYSTEM_ERROR
 140
 141 # For the streamoff typedef.
 142 GLIBCXX_CHECK_INT64_T
 143
 144 # For LFS support.
 145 GLIBCXX_CHECK_LFS
 146
 147 # For showmanyc_helper().
 148 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 149 GLIBCXX_CHECK_POLL
 150 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 151
 152 # For xsputn_2().
 153 AC_CHECK_HEADERS(sys/uio.h)
 154 GLIBCXX_CHECK_WRITEV
 155
 156 # For C99 support to TR1.
 157 GLIBCXX_CHECK_C99_TR1
 158
 159 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 160 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 161
 162 # For gettimeofday support.
 163 GLIBCXX_CHECK_GETTIMEOFDAY
 164
 165 # For clock_gettime, nanosleep and sched_yield support.
 166 # NB: The default is [no], because otherwise it requires linking.
 167 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
 168
 169 AC_LC_MESSAGES
 170
 171 # For hardware_concurrency
 172 AC_CHECK_HEADERS(sys/sysinfo.h)
 173 GLIBCXX_CHECK_GET_NPROCS
 174 AC_CHECK_HEADERS(unistd.h)
 175 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 176 GLIBCXX_CHECK_SC_NPROC_ONLN
 177 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 178 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 179
 180 # Check for available headers.
 181 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 182 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 183 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 184 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 185 wchar.h wctype.h])
 186
 187 # Only do link tests if native. Else, hardcode.
 188 if $GLIBCXX_IS_NATIVE; then
 189
 190   # We can do more elaborate tests that assume a working linker.
 191   CANADIAN=no
 192
 193   GLIBCXX_CHECK_LINKER_FEATURES
 194   GLIBCXX_CHECK_MATH_SUPPORT
 195   GLIBCXX_CHECK_STDLIB_SUPPORT
 196
 197   # For /dev/random and /dev/urandom for TR1.
 198   GLIBCXX_CHECK_RANDOM_TR1
 199
 200   # For TLS support.
 201   GCC_CHECK_TLS
 202
 203   # For iconv support.
 204   AM_ICONV
 205
 206 else
 207
 208   # This lets us hard-code the functionality we know we'll have in the cross
 209   # target environment.  "Let" is a sugar-coated word placed on an especially
 210   # dull and tedious hack, actually.
 211   #
 212   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 213   # that involve linking, can't be used:
 214   #    "cannot open sim-crt0.o"
 215   #    "cannot open crt0.o"
 216   # etc.  All this is because there currently exists no unified, consistent
 217   # way for top level CC information to be passed down to target directories:
 218   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 219   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 220   # crosses can be removed.
 221
 222   # If Canadian cross, then don't pick up tools from the build directory.
 223   # Used only in GLIBCXX_EXPORT_INCLUDES.
 224   if test -n "$with_cross_host" &&
 225      test x"$build_alias" != x"$with_cross_host" &&
 226      test x"$build" != x"$target";
 227   then
 228     CANADIAN=yes
 229   else
 230     CANADIAN=no
 231   fi
 232
 233   # Construct crosses by hand, eliminating bits that need ld...
 234   # GLIBCXX_CHECK_MATH_SUPPORT
 235
 236   # First, test for "known" system libraries.  We may be using newlib even
 237   # on a hosted environment.
 238   if test "x${with_newlib}" = "xyes"; then
 239     os_include_dir="os/newlib"
 240     AC_DEFINE(HAVE_HYPOT)
 241
 242     # GLIBCXX_CHECK_STDLIB_SUPPORT
 243     AC_DEFINE(HAVE_STRTOF)
 244
 245     AC_DEFINE(HAVE_ACOSF)
 246     AC_DEFINE(HAVE_ASINF)
 247     AC_DEFINE(HAVE_ATAN2F)
 248     AC_DEFINE(HAVE_ATANF)
 249     AC_DEFINE(HAVE_CEILF)
 250     AC_DEFINE(HAVE_COSF)
 251     AC_DEFINE(HAVE_COSHF)
 252     AC_DEFINE(HAVE_EXPF)
 253     AC_DEFINE(HAVE_FABSF)
 254     AC_DEFINE(HAVE_FLOORF)
 255     AC_DEFINE(HAVE_FMODF)
 256     AC_DEFINE(HAVE_FREXPF)
 257     AC_DEFINE(HAVE_LDEXPF)
 258     AC_DEFINE(HAVE_LOG10F)
 259     AC_DEFINE(HAVE_LOGF)
 260     AC_DEFINE(HAVE_MODFF)
 261     AC_DEFINE(HAVE_POWF)
 262     AC_DEFINE(HAVE_SINF)
 263     AC_DEFINE(HAVE_SINHF)
 264     AC_DEFINE(HAVE_SQRTF)
 265     AC_DEFINE(HAVE_TANF)
 266     AC_DEFINE(HAVE_TANHF)
 267
 268     AC_DEFINE(HAVE_ICONV)
 269   else
 270     GLIBCXX_CROSSCONFIG
 271   fi
 272
 273   # At some point, we should differentiate between architectures
 274   # like x86, which have long double versions, and alpha/powerpc/etc.,
 275   # which don't. For the time being, punt.
 276   if test x"long_double_math_on_this_cpu" = x"yes"; then
 277     AC_DEFINE(HAVE_ACOSL)
 278     AC_DEFINE(HAVE_ASINL)
 279     AC_DEFINE(HAVE_ATAN2L)
 280     AC_DEFINE(HAVE_ATANL)
 281     AC_DEFINE(HAVE_CEILL)
 282     AC_DEFINE(HAVE_COSL)
 283     AC_DEFINE(HAVE_COSHL)
 284     AC_DEFINE(HAVE_EXPL)
 285     AC_DEFINE(HAVE_FABSL)
 286     AC_DEFINE(HAVE_FLOORL)
 287     AC_DEFINE(HAVE_FMODL)
 288     AC_DEFINE(HAVE_FREXPL)
 289     AC_DEFINE(HAVE_LDEXPL)
 290     AC_DEFINE(HAVE_LOG10L)
 291     AC_DEFINE(HAVE_LOGL)
 292     AC_DEFINE(HAVE_MODFL)
 293     AC_DEFINE(HAVE_POWL)
 294     AC_DEFINE(HAVE_SINCOSL)
 295     AC_DEFINE(HAVE_SINL)
 296     AC_DEFINE(HAVE_SINHL)
 297     AC_DEFINE(HAVE_SQRTL)
 298     AC_DEFINE(HAVE_TANL)
 299     AC_DEFINE(HAVE_TANHL)
 300   fi
 301 fi
 302
 303 # Check for _Unwind_GetIPInfo.
 304 GCC_CHECK_UNWIND_GETIPINFO
 305
 306 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 307
 308 GCC_HEADER_STDINT(include/gstdint.h)
 309
 310 GLIBCXX_ENABLE_SYMVERS([yes])
 311 AC_SUBST(libtool_VERSION)
 312
 313 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 314
 315 ac_ldbl_compat=no
 316 case "$target" in
 317   powerpc*-*-linux* | \
 318   sparc*-*-linux* | \
 319   s390*-*-linux* | \
 320   alpha*-*-linux*)
 321   AC_TRY_COMPILE(, [
 322 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 323 #error no need for long double compatibility
 324 #endif
 325   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 326   if test "$ac_ldbl_compat" = yes; then
 327     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 328               [Define if compatibility should be provided for -mlong-double-64.])
 329     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 330   fi
 331 esac
 332 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 333
 334 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 335 GLIBCXX_CONFIGURE_TESTSUITE
 336
 337 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 338 GLIBCXX_CHECK_GTHREADS
 339
 340 # Define documentation rules conditionally.
 341
 342 # See if makeinfo has been installed and is modern enough
 343 # that we can use it.
 344 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 345                    [GNU texinfo.* \([0-9][0-9.]*\)],
 346                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 347 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 348
 349 # Check for doxygen
 350 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 351 AC_CHECK_PROG([DOT], dot, yes, no)
 352
 353 # Check for docbook
 354 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 355 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 356 GLIBCXX_CONFIGURE_DOCBOOK
 357
 358 # Check for xml/html dependencies.
 359 AM_CONDITIONAL(BUILD_XML,
 360                test $ac_cv_prog_DOXYGEN = "yes" &&
 361                test $ac_cv_prog_DOT = "yes" &&
 362                test $ac_cv_prog_XSLTPROC = "yes" &&
 363                test $ac_cv_prog_XMLLINT = "yes" &&
 364                test $glibcxx_stylesheets = "yes")
 365
 366 AM_CONDITIONAL(BUILD_HTML,
 367                test $ac_cv_prog_DOXYGEN = "yes" &&
 368                test $ac_cv_prog_DOT = "yes" &&
 369                test $ac_cv_prog_XSLTPROC = "yes" &&
 370                test $ac_cv_prog_XMLLINT = "yes" &&
 371                test $glibcxx_stylesheets = "yes")
 372
 373 # Check for man dependencies.
 374 AM_CONDITIONAL(BUILD_MAN,
 375                test $ac_cv_prog_DOXYGEN = "yes" &&
 376                test $ac_cv_prog_DOT = "yes")
 377
 378 # Check for pdf dependencies.
 379 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 380 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 381 AM_CONDITIONAL(BUILD_PDF,
 382                test $ac_cv_prog_DBLATEX = "yes" &&
 383                test $ac_cv_prog_PDFLATEX = "yes")
 384
 385
 386 # Propagate the target-specific source directories through the build chain.
 387 ATOMICITY_SRCDIR=config/${atomicity_dir}
 388 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 389 ATOMIC_FLAGS=${atomic_flags}
 390 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 391 OS_INC_SRCDIR=config/${os_include_dir}
 392 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 393 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 394 AC_SUBST(ATOMICITY_SRCDIR)
 395 AC_SUBST(ATOMIC_WORD_SRCDIR)
 396 AC_SUBST(ATOMIC_FLAGS)
 397 AC_SUBST(CPU_DEFINES_SRCDIR)
 398 AC_SUBST(ABI_TWEAKS_SRCDIR)
 399 AC_SUBST(OS_INC_SRCDIR)
 400 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 401
 402
 403 # Determine cross-compile flags and AM_CONDITIONALs.
 404 #AC_SUBST(GLIBCXX_IS_NATIVE)
 405 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 406 GLIBCXX_EVALUATE_CONDITIONALS
 407
 408 AC_CACHE_SAVE
 409
 410 if test ${multilib} = yes; then
 411   multilib_arg="--enable-multilib"
 412 else
 413   multilib_arg=
 414 fi
 415
 416 # Export all the install information.
 417 GLIBCXX_EXPORT_INSTALL_INFO
 418
 419 # Export all the include and flag information to Makefiles.
 420 GLIBCXX_EXPORT_INCLUDES
 421 GLIBCXX_EXPORT_FLAGS
 422
 423 if test "$enable_shared" = yes; then
 424   PIC_CXXFLAGS="-prefer-pic"
 425 else
 426   PIC_CXXFLAGS=
 427 fi
 428 AC_SUBST(PIC_CXXFLAGS)
 429
 430 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 431 dnl which can all be called multiple times as needed, plus one (different)
 432 dnl AC_OUTPUT macro.  This one lists the files to be created:
 433 AC_CONFIG_FILES(Makefile)
 434 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 435 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 436
 437 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 438 # that multilib installs will end up installed in the correct place.
 439 # The testsuite needs it for multilib-aware ABI baseline files.
 440 # To work around this not being passed down from config-ml.in ->
 441 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 442 # append it here.  Only modify Makefiles that have just been created.
 443 #
 444 # Also, get rid of this simulated-VPATH thing that automake does.
 445 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 446   [cat > vpsed$$ << \_EOF
 447 s!`test -f '$<' || echo '$(srcdir)/'`!!
 448 _EOF
 449    sed -f vpsed$$ $ac_file > tmp$$
 450    mv tmp$$ $ac_file
 451    rm vpsed$$
 452    echo 'MULTISUBDIR =' >> $ac_file
 453    ml_norecursion=yes
 454    . ${multi_basedir}/config-ml.in
 455    AS_UNSET([ml_norecursion])
 456 ])
 457
 458 AC_CONFIG_COMMANDS([generate-headers],
 459   [(cd include && ${MAKE-make} pch_build= )])
 460
 461 dnl And this actually makes things happen:
 462 AC_OUTPUT