libf2c/libI77/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998, 2001 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU Fortran.
   6 #
   7 #GNU Fortran is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU Fortran is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU Fortran; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_PREREQ(2.12.1)
  23 AC_INIT(ftell_.c)
  24 AC_CONFIG_HEADER(config.h)
  25
  26 # These defines are necessary to get 64-bit file size support.
  27
  28 AC_DEFINE(_XOPEN_SOURCE, 500L, [Get Single Unix Specification semantics])
  29 # The following is needed by irix6.2 so that struct timeval is declared.
  30 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [Get Single Unix Specification semantics])
  31 AC_DEFINE(_FILE_OFFSET_BITS, 64, [Get 64-bit file size support])
  32
  33 dnl Checks for programs.
  34
  35 dnl FIXME AC_PROG_CC wants CC to be able to link things, but it may
  36 dnl not be able to.
  37 define([AC_PROG_CC_WORKS],[])
  38
  39 # For g77 we'll set CC to point at the built gcc, but this will get it into
  40 # the makefiles
  41 AC_PROG_CC
  42
  43 test "$AR" || AR=ar
  44 AC_SUBST(AR)
  45 AC_PROG_MAKE_SET
  46
  47 dnl Checks for libraries.
  48
  49 dnl Checks for header files.
  50 # Sanity check for the cross-compilation case:
  51 AC_CHECK_HEADER(stdio.h,:,
  52   [AC_MSG_ERROR([Can't find stdio.h.
  53 You must have a usable C system for the target already installed, at least
  54 including headers and, preferably, the library, before you can configure
  55 the G77 runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  56 then the target library, then build with \`LANGUAGES=f77'.])])
  57
  58 AC_HEADER_STDC
  59 dnl We could do this if we didn't know we were using gcc
  60 dnl AC_MSG_CHECKING(for prototype-savvy compiler)
  61 dnl AC_CACHE_VAL(g77_cv_sys_proto,
  62 dnl   [AC_TRY_LINK(,
  63 dnl dnl looks screwy because TRY_LINK expects a function body
  64 dnl    [return 0;} int foo (int * bar) {],
  65 dnl    g77_cv_sys_proto=yes,
  66 dnl    [g77_cv_sys_proto=no
  67 dnl     AC_DEFINE(KR_headers)])])
  68 dnl AC_MSG_RESULT($g77_cv_sys_proto)
  69
  70 AC_MSG_CHECKING(for posix)
  71 AC_CACHE_VAL(g77_cv_header_posix,
  72   AC_EGREP_CPP(yes,
  73   [#include <sys/types.h>
  74 #include <unistd.h>
  75 #ifdef _POSIX_VERSION
  76   yes
  77 #endif
  78 ],
  79   g77_cv_header_posix=yes,
  80   g77_cv_header_posix=no))
  81 AC_MSG_RESULT($g77_cv_header_posix)
  82
  83 # We can rely on the GNU library being posix-ish.  I guess checking the
  84 # header isn't actually like checking the functions, though...
  85 AC_MSG_CHECKING(for GNU library)
  86 AC_CACHE_VAL(g77_cv_lib_gnu,
  87   AC_EGREP_CPP(yes,
  88     [#include <stdio.h>
  89 #ifdef __GNU_LIBRARY__
  90   yes
  91 #endif
  92 ],
  93   g77_cv_lib_gnu=yes, g77_cv_lib_gnu=no))
  94 AC_MSG_RESULT($g77_cv_lib_gnu)
  95
  96 # Apparently cygwin needs to be special-cased.
  97 AC_MSG_CHECKING([for cyg\`win'32])
  98 AC_CACHE_VAL(g77_cv_sys_cygwin32,
  99   AC_EGREP_CPP(yes,
 100   [#ifdef __CYGWIN32__
 101   yes
 102 #endif
 103 ],
 104   g77_cv_sys_cygwin32=yes,
 105   g77_cv_sys_cygwin32=no))
 106 AC_MSG_RESULT($g77_cv_sys_cygwin32)
 107
 108 # ditto for mingw32.
 109 AC_MSG_CHECKING([for mingw32])
 110 AC_CACHE_VAL(g77_cv_sys_mingw32,
 111   AC_EGREP_CPP(yes,
 112   [#ifdef __MINGW32__
 113   yes
 114 #endif
 115 ],
 116   g77_cv_sys_mingw32=yes,
 117   g77_cv_sys_mingw32=no))
 118 AC_MSG_RESULT($g77_cv_sys_mingw32)
 119
 120
 121 AC_CHECK_HEADER(fcntl.h,
 122    test $g77_cv_header_posix = yes && AC_DEFINE(_POSIX_SOURCE),
 123    AC_DEFINE(NO_FCNTL, 1, [Define if fcntl.h is missing.])
 124    AC_DEFINE(OPEN_DECL, 1, [Define if fcntl.h is missing.]))
 125
 126 dnl Checks for typedefs, structures, and compiler characteristics.
 127 AC_C_CONST
 128 AC_TYPE_SIZE_T
 129
 130 dnl Checks for library functions.
 131
 132 # This should always succeed on unix.
 133 # Apparently positive result on cygwin loses re. NON_UNIX_STDIO
 134 # (as of cygwin b18). Likewise on mingw.
 135 AC_CHECK_FUNC(fstat)
 136 AC_MSG_CHECKING([need for NON_UNIX_STDIO])
 137 if test $g77_cv_sys_cygwin32 = yes \
 138   || test $g77_cv_sys_mingw32 = yes \
 139   || test $ac_cv_func_fstat = no; then
 140   AC_MSG_RESULT(yes)
 141   AC_DEFINE(NON_UNIX_STDIO, 1, [Define if we do not have Unix Stdio.])
 142 else
 143   AC_MSG_RESULT(no)
 144 fi
 145
 146 AC_CHECK_FUNCS(fseeko)
 147 AC_CHECK_FUNCS(ftello)
 148 AC_CHECK_FUNCS(ftruncate)
 149 AC_CHECK_FUNCS(mkstemp)
 150 AC_CHECK_FUNCS(tempnam)
 151
 152 # posix will guarantee the right behaviour for sprintf, else we can't be
 153 # sure; HEADER_STDC wouldn't be the right check in sunos4, for instance.
 154 # However, on my sunos4/gcc setup unistd.h leads us wrongly to believe
 155 # we're posix-conformant, so always do the test.
 156 AC_MSG_CHECKING(for ansi/posix sprintf result)
 157 dnl This loses if included as an argument to AC_CACHE_VAL because the
 158 dnl changequote doesn't take effect and the [] vanish.
 159 dnl fixme: use cached value
 160 AC_TRY_RUN(changequote(<<, >>)dnl
 161   <<#include <stdio.h>
 162     /* does sprintf return the number of chars transferred? */
 163     main () {char foo[2]; (sprintf(foo, "1") == 1) ? exit(0) : exit(1);}
 164 >>changequote([, ]),
 165     g77_cv_sys_sprintf_ansi=yes,
 166     g77_cv_sys_sprintf_ansi=no,
 167     g77_cv_sys_sprintf_ansi=no)
 168 AC_CACHE_VAL(g77_cv_sys_sprintf_ansi,
 169      g77_cv_sys_sprintf_ansi=$g77_cv_sys_sprintf_ansi)
 170 dnl We get a misleading `(cached)' message...
 171 AC_MSG_RESULT($g77_cv_sys_sprintf_ansi)
 172
 173 # The cygwin patch takes steps to avoid defining USE_STRLEN here -- I don't
 174 # understand why.
 175 if test $g77_cv_sys_sprintf_ansi != yes; then
 176   AC_DEFINE(USE_STRLEN, 1, [Define if we use strlen.])
 177 fi
 178
 179 # define NON_ANSI_RW_MODES on unix (can't hurt)
 180 AC_MSG_CHECKING(NON_ANSI_RW_MODES)
 181 AC_EGREP_CPP(yes,
 182 [#ifdef unix
 183   yes
 184 #endif
 185 #ifdef __unix
 186   yes
 187 #endif
 188 #ifdef __unix__
 189   yes
 190 #endif
 191 ], is_unix=yes, is_unix=no)
 192 # NON_ANSI_RW_MODES shouldn't be necessary on cygwin for binary mounts.
 193 if test $g77_cv_sys_cygwin32 = yes || test $g77_cv_sys_mingw32 = yes; then
 194   AC_MSG_RESULT(no)
 195 else
 196   if test $is_unix = yes; then
 197     AC_DEFINE(NON_ANSI_RW_MODES, 1, [Define if we have non ANSI RW modes.])
 198     AC_MSG_RESULT(yes)
 199   else
 200     AC_MSG_RESULT(no)
 201   fi
 202 fi
 203
 204 # This EOF_CHAR is a misfeature on unix.
 205 AC_DEFINE(NO_EOF_CHAR_CHECK, 1, [Always defined.])
 206
 207 AC_TYPE_OFF_T
 208
 209 AC_DEFINE(Skip_f2c_Undefs, 1, [Define to skip f2c undefs.])
 210
 211 AC_OUTPUT(Makefile)
 212
 213 dnl We might have configuration options to:
 214 dnl * change unit preconnexion in err.c (f_init.c)
 215 dnl * -DALWAYS_FLUSH
 216 dnl * -DOMIT_BLANK_CC
 217
 218 dnl Local Variables:
 219 dnl comment-start: "dnl "
 220 dnl comment-end: ""
 221 dnl comment-start-skip: "\\bdnl\\b\\s *"
 222 dnl End: