libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=1:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign -Wall])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  46 AC_SUBST(WARN_FLAGS)
  47
  48 dnl FIXME: This should be controlled by --enable-maintainer-mode.
  49 WERROR="-Werror"
  50 AC_SUBST(WERROR)
  51
  52 glibgo_toolexecdir=no
  53 glibgo_toolexeclibdir=no
  54 glibgo_prefixdir=$prefix
  55
  56 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  57 AC_ARG_ENABLE([version-specific-runtime-libs],
  58   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  59                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  60   [case "$enableval" in
  61     yes) version_specific_libs=yes ;;
  62     no)  version_specific_libs=no ;;
  63     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  64    esac],
  65   [version_specific_libs=no])
  66 AC_MSG_RESULT($version_specific_libs)
  67
  68 # Version-specific runtime libs processing.
  69 if test $version_specific_libs = yes; then
  70   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  71   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  72 fi
  73
  74 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  75 # Install a library built with a cross compiler in tooldir, not libdir.
  76 if test x"$glibgo_toolexecdir" = x"no"; then
  77   if test -n "$with_cross_host" &&
  78      test x"$with_cross_host" != x"no"; then
  79     glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  80     glibgo_toolexeclibdir='${toolexecdir}/lib'
  81   else
  82     glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  83     glibgo_toolexeclibdir='${libdir}'
  84   fi
  85   multi_os_directory=`$CC -print-multi-os-directory`
  86   case $multi_os_directory in
  87     .) ;; # Avoid trailing /.
  88     *) glibgo_toolexeclibdir=$glibgo_toolexeclibdir/$multi_os_directory ;;
  89   esac
  90 fi
  91
  92 AC_SUBST(glibgo_prefixdir)
  93 AC_SUBST(glibgo_toolexecdir)
  94 AC_SUBST(glibgo_toolexeclibdir)
  95
  96 # See if the user wants to configure without libffi.  Some
  97 # architectures don't support it.  FIXME: We should set a default
  98 # based on the host.
  99 AC_ARG_WITH(libffi,
 100   AS_HELP_STRING([--without-libffi],
 101                  [don't use libffi]),
 102   [:],
 103   [with_libffi=${with_libffi_default-yes}])
 104
 105 LIBFFI=
 106 LIBFFIINCS=
 107 if test "$with_libffi" != no; then
 108    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 109    LIBFFI=../libffi/libffi_convenience.la
 110    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 111 fi
 112 AC_SUBST(LIBFFI)
 113 AC_SUBST(LIBFFIINCS)
 114
 115 is_darwin=no
 116 is_freebsd=no
 117 is_irix=no
 118 is_linux=no
 119 is_rtems=no
 120 is_solaris=no
 121 GOOS=unknown
 122 case ${host} in
 123   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 124   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 125   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 126   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 127   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 128   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 129 esac
 130 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 131 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 132 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 133 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 134 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 135 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 136 AC_SUBST(GOOS)
 137
 138 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 139 is_386=no
 140 is_alpha=no
 141 is_arm=no
 142 is_m68k=no
 143 mips_abi=unknown
 144 is_ppc=no
 145 is_ppc64=no
 146 is_sparc=no
 147 is_sparc64=no
 148 is_x86_64=no
 149 GOARCH=unknown
 150 case ${host} in
 151   alpha*-*-*)
 152     is_alpha=yes
 153     GOARCH=alpha
 154     ;;
 155   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 156     is_arm=yes
 157     GOARCH=arm
 158     ;;
 159 changequote(,)dnl
 160   i[34567]86-*-* | x86_64-*-*)
 161 changequote([,])dnl
 162     AC_COMPILE_IFELSE([
 163 #ifdef __x86_64__
 164 #error 64-bit
 165 #endif],
 166 [is_386=yes], [is_x86_64=yes])
 167     if test "$is_386" = "yes"; then
 168       GOARCH=386
 169     else
 170       GOARCH=amd64
 171     fi
 172     ;;
 173   m68k*-*-*)
 174     is_m68k=yes
 175     GOARCH=m68k
 176     ;;
 177   mips*-*-*)
 178     AC_COMPILE_IFELSE([
 179 #if _MIPS_SIM != _ABIO32
 180 #error not o32
 181 #endif],
 182 [mips_abi="o32"],
 183         [AC_COMPILE_IFELSE([
 184 #if _MIPS_SIM != _ABIN32
 185 #error not n32
 186 #endif],
 187 [mips_abi="n32"],
 188         [AC_COMPILE_IFELSE([
 189 #if _MIPS_SIM != _ABI64
 190 #error not n64
 191 #endif],
 192 [mips_abi="n64"],
 193         [AC_COMPILE_IFELSE([
 194 #if _MIPS_SIM != _ABIO64
 195 #error not o64
 196 #endif],
 197 [mips_abi="o64"],
 198         [AC_MSG_ERROR([unknown MIPS ABI])
 199 [mips_abi="n32"]])])])])
 200     case "$mips_abi" in
 201     "o32") GOARCH=mipso32 ;;
 202     "n32") GOARCH=mipsn32 ;;
 203     "n64") GOARCH=mipsn64 ;;
 204     "o64") GOARCH=mipso64 ;;
 205     esac
 206     ;;
 207   rs6000*-*-* | powerpc*-*-*)
 208     AC_COMPILE_IFELSE([
 209 #ifdef _ARCH_PPC64
 210 #error 64-bit
 211 #endif],
 212 [is_ppc=yes], [is_ppc64=yes])
 213     if test "$is_ppc" = "yes"; then
 214       GOARCH=ppc
 215     else
 216       GOARCH=ppc64
 217     fi
 218     ;;
 219   sparc*-*-*)
 220     AC_COMPILE_IFELSE([
 221 #if defined(__sparcv9) || defined(__arch64__)
 222 #error 64-bit
 223 #endif],
 224 [is_sparc=yes], [is_sparc64=yes])
 225     if test "$is_sparc" = "yes"; then
 226       GOARCH=sparc
 227     else
 228       GOARCH=sparc64
 229     fi
 230     ;;
 231 esac
 232 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 233 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 234 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 235 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 236 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 237 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 238 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 239 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 240 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 241 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 242 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 243 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 244 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 245 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 246 AC_SUBST(GOARCH)
 247
 248 dnl Some files are only present when needed for specific architectures.
 249 GO_SYSCALLS_SYSCALL_OS_ARCH_FILE=
 250 if test -f ${srcdir}/syscalls/syscall_${GOOS}_${GOARCH}.go; then
 251   GO_SYSCALLS_SYSCALL_OS_ARCH_FILE=syscalls/syscall_${GOOS}_${GOARCH}.go
 252 fi
 253 AC_SUBST(GO_SYSCALLS_SYSCALL_OS_ARCH_FILE)
 254
 255 GO_DEBUG_PROC_REGS_OS_ARCH_FILE=
 256 if test -f ${srcdir}/go/debug/proc/regs_${GOOS}_${GOARCH}.go; then
 257   GO_DEBUG_PROC_REGS_OS_ARCH_FILE=go/debug/proc/regs_${GOOS}_${GOARCH}.go
 258 fi
 259 AC_SUBST(GO_DEBUG_PROC_REGS_OS_ARCH_FILE)
 260
 261 dnl Some targets need special flags to build sysinfo.go.
 262 case "$target" in
 263     mips-sgi-irix6.5*)
 264         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 265         # msghdr in <sys/socket.h>.
 266         OSCFLAGS='-D_XOPEN_SOURCE=500'
 267         ;;
 268     *-*-solaris2.[[89]])
 269         # Solaris 8/9 need this so struct msghdr gets the msg_control
 270         # etc. fields in <sys/socket.h> (_XPG4_2).
 271         OSCFLAGS='-D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D__EXTENSIONS__'
 272         ;;
 273     *-*-solaris2.1[[01]])
 274         # Solaris 10+ needs this so struct msghdr gets the msg_control
 275         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=500 as
 276         # above doesn't work with C99.
 277         OSCFLAGS='-D_XOPEN_SOURCE=600 -D__EXTENSIONS__'
 278         ;;
 279 esac
 280 AC_SUBST(OSCFLAGS)
 281
 282 dnl Use -fsplit-stack when compiling C code if available.
 283 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 284 [libgo_cv_c_split_stack_supported],
 285 [CFLAGS_hold=$CFLAGS
 286 CFLAGS="$CFLAGS -fsplit-stack"
 287 AC_COMPILE_IFELSE([[int i;]],
 288 [libgo_cv_c_split_stack_supported=yes],
 289 [libgo_cv_c_split_stack_supported=no])
 290 CFLAGS=$CFLAGS_hold])
 291 if test "$libgo_cv_c_split_stack_supported" = yes; then
 292   SPLIT_STACK=-fsplit-stack
 293   AC_DEFINE(USING_SPLIT_STACK, 1,
 294                 [Define if the compiler supports -fsplit-stack])
 295 else
 296   SPLIT_STACK=
 297 fi
 298 AC_SUBST(SPLIT_STACK)
 299 AM_CONDITIONAL(USING_SPLIT_STACK,
 300         test "$libgo_cv_c_split_stack_supported" = yes)
 301
 302 dnl Check whether the linker does stack munging when calling from
 303 dnl split-stack into non-split-stack code.  We check this by looking
 304 dnl at the --help output.  FIXME: This is only half right: it's
 305 dnl possible for the linker to support this for some targets but not
 306 dnl others.
 307 AC_CACHE_CHECK([whether linker supports split stack],
 308 [libgo_cv_c_linker_supports_split_stack],
 309 libgo_cv_c_linker_supports_split_stack=no
 310 if $LD --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 311   libgo_cv_c_linker_supports_split_stack=yes
 312 fi)
 313 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 314   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 315             [Define if the linker support split stack adjustments])
 316 fi
 317
 318 dnl Test for the -lm library.
 319 MATH_LIBS=
 320 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 321 AC_SUBST(MATH_LIBS)
 322
 323 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 324 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 325   [libgo_cv_lib_sockets=
 326    libgo_check_both=no
 327    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 328    if test "$libgo_check_socket" = "yes"; then
 329      unset ac_cv_func_connect
 330      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 331                   libgo_check_both=yes)
 332    fi
 333    if test "$libgo_check_both" = "yes"; then
 334      libgo_old_libs=$LIBS
 335      LIBS="$LIBS -lsocket -lnsl"
 336      unset ac_cv_func_accept
 337      AC_CHECK_FUNC(accept,
 338                    [libgo_check_nsl=no
 339                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 340      unset ac_cv_func_accept
 341      LIBS=$libgo_old_libs
 342    fi
 343    unset ac_cv_func_gethostbyname
 344    libgo_old_libs="$LIBS"
 345    AC_CHECK_FUNC(gethostbyname, ,
 346                  [AC_CHECK_LIB(nsl, main,
 347                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 348    unset ac_cv_func_gethostbyname
 349    LIBS=$libgo_old_libs
 350 ])
 351 NET_LIBS="$libgo_cv_lib_sockets"
 352 AC_SUBST(NET_LIBS)
 353
 354 dnl Test whether the compiler supports the -pthread option.
 355 AC_CACHE_CHECK([whether -pthread is supported],
 356 [libgo_cv_lib_pthread],
 357 [CFLAGS_hold=$CFLAGS
 358 CFLAGS="$CFLAGS -pthread"
 359 AC_COMPILE_IFELSE([[int i;]],
 360 [libgo_cv_lib_pthread=yes],
 361 [libgo_cv_lib_pthread=no])
 362 CFLAGS=$CFLAGS_hold])
 363 PTHREAD_CFLAGS=
 364 if test "$libgo_cv_lib_pthread" = yes; then
 365   PTHREAD_CFLAGS=-pthread
 366 fi
 367 AC_SUBST(PTHREAD_CFLAGS)
 368
 369 dnl Test for the -lpthread library.
 370 PTHREAD_LIBS=
 371 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 372 AC_SUBST(PTHREAD_LIBS)
 373
 374 dnl Test if -lrt is required for sched_yield.
 375 AC_SEARCH_LIBS([sched_yield], [rt])
 376
 377 AC_C_BIGENDIAN
 378
 379 GCC_CHECK_UNWIND_GETIPINFO
 380
 381 AC_ARG_ENABLE(sjlj-exceptions,
 382   AC_HELP_STRING([--enable-sjlj-exceptions],
 383                  [force use of builtin_setjmp for exceptions]),
 384   [case "$enableval" in
 385    yes|no|auto) ;;
 386    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 387    esac],
 388   [enable_sjlj_exceptions=auto])
 389
 390 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 391 [libgo_cv_lib_sjlj_exceptions],
 392 [AC_LANG_CONFTEST(
 393   [AC_LANG_SOURCE([
 394 void bar ();
 395 void clean (int *);
 396 void foo ()
 397 {
 398   int i __attribute__ ((cleanup (clean)));
 399   bar();
 400 }
 401 ])])
 402 CFLAGS_hold=$CFLAGS
 403 CFLAGS="--save-temps -fexceptions"
 404 libgo_cv_lib_sjlj_exceptions=unknown
 405 AS_IF([ac_fn_c_try_compile],
 406   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 407     libgo_cv_lib_sjlj_exceptions=yes
 408   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 409     libgo_cv_lib_sjlj_exceptions=no
 410   fi])
 411 CFLAGS=$CFLAGS_hold
 412 rm -f conftest*
 413 ])
 414
 415 if test "$enable_sjlj_exceptions" = "auto"; then
 416   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 417 fi
 418
 419 case $enable_sjlj_exceptions in
 420 yes)
 421   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 422         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 423   ;;
 424 no)
 425   ;;
 426 *)
 427   AC_MSG_ERROR([unable to detect exception model])
 428   ;;
 429 esac
 430
 431 AC_CHECK_HEADERS(sys/mman.h syscall.h sys/epoll.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h)
 432 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 433
 434 AC_CHECK_FUNCS(srandom random strerror_r strsignal wait4 mincore setenv)
 435 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 436 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 437
 438 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 439 [libgo_cv_func___sync_bool_compare_and_swap_4],
 440 [AC_LINK_IFELSE([
 441 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 442 uint32 i;
 443 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 444 ],
 445 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 446 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 447 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 448   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 449     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 450 fi
 451
 452 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 453 [libgo_cv_func___sync_fetch_and_add_4],
 454 [AC_LINK_IFELSE([
 455 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 456 uint32 i;
 457 int main() { return __sync_fetch_and_add (&i, 1); }
 458 ],
 459 [libgo_cv_func___sync_fetch_and_add_4=yes],
 460 [libgo_cv_func___sync_fetch_and_add_4=no])])
 461 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 462   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 463     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 464 fi
 465
 466 dnl For x86 we want to use the -minline-all-stringops option to avoid
 467 dnl forcing a stack split when calling memcpy and friends.
 468 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 469 [libgo_cv_c_stringops],
 470 [CFLAGS_hold=$CFLAGS
 471 CFLAGS="$CFLAGS -minline-all-stringops"
 472 AC_COMPILE_IFELSE([int i;],
 473 [libgo_cv_c_stringops=yes],
 474 [libgo_cv_c_stringops=no])
 475 CFLAGS=$CFLAGS_hold])
 476 STRINGOPS_FLAG=
 477 if test "$libgo_cv_c_stringops" = yes; then
 478   STRINGOPS_FLAG=-minline-all-stringops
 479 fi
 480 AC_SUBST(STRINGOPS_FLAG)
 481
 482 CFLAGS_hold=$CFLAGS
 483 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 484 AC_CHECK_TYPES(off64_t)
 485 CFLAGS=$CFLAGS_hold
 486
 487 AC_CACHE_SAVE
 488
 489 if test ${multilib} = yes; then
 490   multilib_arg="--enable-multilib"
 491 else
 492   multilib_arg=
 493 fi
 494
 495 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 496
 497 AC_CONFIG_COMMANDS([default],
 498 [if test -n "$CONFIG_FILES"; then
 499    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 500    # that multilib installs will end up installed in the correct place.
 501    # The testsuite needs it for multilib-aware ABI baseline files.
 502    # To work around this not being passed down from config-ml.in ->
 503    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 504    # append it here.  Only modify Makefiles that have just been created.
 505    #
 506    # Also, get rid of this simulated-VPATH thing that automake does.
 507    cat > vpsed << \_EOF
 508 s!`test -f '$<' || echo '$(srcdir)/'`!!
 509 _EOF
 510    for i in $SUBDIRS; do
 511     case $CONFIG_FILES in
 512      *${i}/Makefile*)
 513        #echo "Adding MULTISUBDIR to $i/Makefile"
 514        sed -f vpsed $i/Makefile > tmp
 515        grep '^MULTISUBDIR =' Makefile >> tmp
 516        mv tmp $i/Makefile
 517        ;;
 518     esac
 519    done
 520    rm vpsed
 521  fi
 522 ],
 523 [
 524 # Variables needed in config.status (file generation) which aren't already
 525 # passed by autoconf.
 526 SUBDIRS="$SUBDIRS"
 527 ])
 528
 529 AC_OUTPUT