gcc/ada/s-caun16.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --     S Y S T E M . C O M P A R E _ A R R A Y _ U N S I G N E D _ 1 6      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Address_Operations; use System.Address_Operations;
  35
  36 with Ada.Unchecked_Conversion;
  37
  38 package body System.Compare_Array_Unsigned_16 is
  39
  40    type Word is mod 2 ** 32;
  41    --  Used to process operands by words
  42
  43    type Half is mod 2 ** 16;
  44    for Half'Size use 16;
  45    --  Used to process operands by half words
  46
  47    type Uhalf is new Half;
  48    for Uhalf'Alignment use 1;
  49    --  Used to process operands when unaligned
  50
  51    type WP is access Word;
  52    type HP is access Half;
  53    type UP is access Uhalf;
  54
  55    function W is new Ada.Unchecked_Conversion (Address, WP);
  56    function H is new Ada.Unchecked_Conversion (Address, HP);
  57    function U is new Ada.Unchecked_Conversion (Address, UP);
  58
  59    -----------------------
  60    -- Compare_Array_U16 --
  61    -----------------------
  62
  63    function Compare_Array_U16
  64      (Left      : System.Address;
  65       Right     : System.Address;
  66       Left_Len  : Natural;
  67       Right_Len : Natural) return Integer
  68    is
  69       Clen : Natural := Natural'Min (Left_Len, Right_Len);
  70       --  Number of elements left to compare
  71
  72       L : Address := Left;
  73       R : Address := Right;
  74       --  Pointers to next elements to compare
  75
  76    begin
  77       --  Go by words if possible
  78
  79       if ModA (OrA (Left, Right), 4) = 0 then
  80          while Clen > 1
  81            and then W (L).all = W (R).all
  82          loop
  83             Clen := Clen - 2;
  84             L := AddA (L, 4);
  85             R := AddA (R, 4);
  86          end loop;
  87       end if;
  88
  89       --  Case of going by aligned half words
  90
  91       if ModA (OrA (Left, Right), 2) = 0 then
  92          while Clen /= 0 loop
  93             if H (L).all /= H (R).all then
  94                if H (L).all > H (R).all then
  95                   return +1;
  96                else
  97                   return -1;
  98                end if;
  99             end if;
 100
 101             Clen := Clen - 1;
 102             L := AddA (L, 2);
 103             R := AddA (R, 2);
 104          end loop;
 105
 106       --  Case of going by unaligned half words
 107
 108       else
 109          while Clen /= 0 loop
 110             if U (L).all /= U (R).all then
 111                if U (L).all > U (R).all then
 112                   return +1;
 113                else
 114                   return -1;
 115                end if;
 116             end if;
 117
 118             Clen := Clen - 1;
 119             L := AddA (L, 2);
 120             R := AddA (R, 2);
 121          end loop;
 122       end if;
 123
 124       --  Here if common section equal, result decided by lengths
 125
 126       if Left_Len = Right_Len then
 127          return 0;
 128       elsif Left_Len > Right_Len then
 129          return +1;
 130       else
 131          return -1;
 132       end if;
 133    end Compare_Array_U16;
 134
 135 end System.Compare_Array_Unsigned_16;