gcc/ada/par-ch10.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             P A R . C H 1 0                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 pragma Style_Checks (All_Checks);
  27 --  Turn off subprogram body ordering check. Subprograms are in order
  28 --  by RM section rather than alphabetical
  29
  30 with Fname.UF; use Fname.UF;
  31 with Uname;    use Uname;
  32
  33 separate (Par)
  34 package body Ch10 is
  35
  36    --  Local functions, used only in this chapter
  37
  38    function P_Context_Clause    return List_Id;
  39    function P_Subunit           return Node_Id;
  40
  41    function Set_Location return Source_Ptr;
  42    --  The current compilation unit starts with Token at Token_Ptr. This
  43    --  function determines the corresponding source location for the start
  44    --  of the unit, including any preceding comment lines.
  45
  46    procedure Unit_Display
  47      (Cunit      : Node_Id;
  48       Loc        : Source_Ptr;
  49       SR_Present : Boolean);
  50    --  This procedure is used to generate a line of output for a unit in
  51    --  the source program. Cunit is the node for the compilation unit, and
  52    --  Loc is the source location for the start of the unit in the source
  53    --  file (which is not necessarily the Sloc of the Cunit node). This
  54    --  output is written to the standard output file for use by gnatchop.
  55
  56    procedure Unit_Location (Sind : Source_File_Index; Loc : Source_Ptr);
  57    --  This routine has the same calling sequence as Unit_Display, but
  58    --  it outputs only the line number and offset of the location, Loc,
  59    --  using Cunit to obtain the proper source file index.
  60
  61    -------------------------
  62    -- 10.1.1  Compilation --
  63    -------------------------
  64
  65    --  COMPILATION ::= {COMPILATION_UNIT}
  66
  67    --  There is no specific parsing routine for a compilation, since we only
  68    --  permit a single compilation in a source file, so there is no explicit
  69    --  occurrence of compilations as such (our representation of a compilation
  70    --  is a series of separate source files).
  71
  72    ------------------------------
  73    -- 10.1.1  Compilation unit --
  74    ------------------------------
  75
  76    --  COMPILATION_UNIT ::=
  77    --    CONTEXT_CLAUSE LIBRARY_ITEM
  78    --  | CONTEXT_CLAUSE SUBUNIT
  79
  80    --  LIBRARY_ITEM ::=
  81    --    private LIBRARY_UNIT_DECLARATION
  82    --  | LIBRARY_UNIT_BODY
  83    --  | [private] LIBRARY_UNIT_RENAMING_DECLARATION
  84
  85    --  LIBRARY_UNIT_DECLARATION ::=
  86    --    SUBPROGRAM_DECLARATION | PACKAGE_DECLARATION
  87    --  | GENERIC_DECLARATION    | GENERIC_INSTANTIATION
  88
  89    --  LIBRARY_UNIT_RENAMING_DECLARATION ::=
  90    --    PACKAGE_RENAMING_DECLARATION
  91    --  | GENERIC_RENAMING_DECLARATION
  92    --  | SUBPROGRAM_RENAMING_DECLARATION
  93
  94    --  LIBRARY_UNIT_BODY ::= SUBPROGRAM_BODY | PACKAGE_BODY
  95
  96    --  Error recovery: cannot raise Error_Resync. If an error occurs, tokens
  97    --  are skipped up to the next possible beginning of a compilation unit.
  98
  99    --  Note: if only configuration pragmas are found, Empty is returned
 100
 101    --  Note: in syntax-only mode, it is possible for P_Compilation_Unit
 102    --  to return strange things that are not really compilation units.
 103    --  This is done to help out gnatchop when it is faced with nonsense.
 104
 105    function P_Compilation_Unit return Node_Id is
 106       Scan_State         : Saved_Scan_State;
 107       Body_Node          : Node_Id;
 108       Specification_Node : Node_Id;
 109       Unit_Node          : Node_Id;
 110       Comp_Unit_Node     : Node_Id;
 111       Name_Node          : Node_Id;
 112       Item               : Node_Id;
 113       Private_Sloc       : Source_Ptr := No_Location;
 114       Config_Pragmas     : List_Id;
 115       P                  : Node_Id;
 116       SR_Present         : Boolean;
 117
 118       Cunit_Error_Flag   : Boolean := False;
 119       --  This flag is set True if we have to scan for a compilation unit
 120       --  token. It is used to ensure clean termination in such cases by
 121       --  not insisting on being at the end of file, and, in the syntax only
 122       --  case by not scanning for additional compilation units.
 123
 124       Cunit_Location : Source_Ptr;
 125       --  Location of unit for unit identification output (List_Unit option)
 126
 127    begin
 128       Num_Library_Units := Num_Library_Units + 1;
 129
 130       --  Set location of the compilation unit if unit list option set
 131       --  and we are in syntax check only mode
 132
 133       if List_Units and then Operating_Mode = Check_Syntax then
 134          Cunit_Location := Set_Location;
 135       else
 136          Cunit_Location := No_Location;
 137       end if;
 138
 139       --  Deal with initial pragmas
 140
 141       Config_Pragmas := No_List;
 142
 143       --  If we have an initial Source_Reference pragma, then remember
 144       --  the fact to generate an NR parameter in the output line.
 145
 146       SR_Present := False;
 147
 148       if Token = Tok_Pragma then
 149          Save_Scan_State (Scan_State);
 150          Item := P_Pragma;
 151
 152          if Item = Error
 153            or else Pragma_Name (Item) /= Name_Source_Reference
 154          then
 155             Restore_Scan_State (Scan_State);
 156
 157          else
 158             SR_Present := True;
 159
 160             --  If first unit, record the file name for gnatchop use
 161
 162             if Operating_Mode = Check_Syntax
 163               and then List_Units
 164               and then Num_Library_Units = 1
 165             then
 166                Write_Str ("Source_Reference pragma for file """);
 167                Write_Name (Full_Ref_Name (Current_Source_File));
 168                Write_Char ('"');
 169                Write_Eol;
 170             end if;
 171
 172             Config_Pragmas := New_List (Item);
 173          end if;
 174       end if;
 175
 176       --  Scan out any configuration pragmas
 177
 178       while Token = Tok_Pragma loop
 179          Save_Scan_State (Scan_State);
 180          Item := P_Pragma;
 181
 182          if Item = Error
 183            or else not
 184              Is_Configuration_Pragma_Name (Pragma_Name (Item))
 185          then
 186             Restore_Scan_State (Scan_State);
 187             exit;
 188          end if;
 189
 190          if Config_Pragmas = No_List then
 191             Config_Pragmas := Empty_List;
 192
 193             if Operating_Mode = Check_Syntax and then List_Units then
 194                Write_Str ("Configuration pragmas at");
 195                Unit_Location (Current_Source_File, Cunit_Location);
 196                Write_Eol;
 197             end if;
 198          end if;
 199
 200          Append (Item, Config_Pragmas);
 201          Cunit_Location := Set_Location;
 202       end loop;
 203
 204       --  Establish compilation unit node and scan context items
 205
 206       Comp_Unit_Node := New_Node (N_Compilation_Unit, No_Location);
 207       Set_Cunit (Current_Source_Unit, Comp_Unit_Node);
 208       Set_Context_Items (Comp_Unit_Node, P_Context_Clause);
 209       Set_Aux_Decls_Node
 210         (Comp_Unit_Node, New_Node (N_Compilation_Unit_Aux, No_Location));
 211
 212       if Present (Config_Pragmas) then
 213
 214          --  Check for case of only configuration pragmas present
 215
 216          if Token = Tok_EOF
 217            and then Is_Empty_List (Context_Items (Comp_Unit_Node))
 218          then
 219             if Operating_Mode = Check_Syntax then
 220                return Empty;
 221
 222             else
 223                Item := First (Config_Pragmas);
 224                Error_Msg_N
 225                  ("cannot compile configuration pragmas with gcc!", Item);
 226                Error_Msg_N
 227                  ("\use gnatchop -c to process configuration pragmas!", Item);
 228                raise Unrecoverable_Error;
 229             end if;
 230
 231          --  Otherwise configuration pragmas are simply prepended to the
 232          --  context of the current unit.
 233
 234          else
 235             Append_List (Context_Items (Comp_Unit_Node), Config_Pragmas);
 236             Set_Context_Items (Comp_Unit_Node, Config_Pragmas);
 237          end if;
 238       end if;
 239
 240       --  Check for PRIVATE. Note that for the moment we allow this in
 241       --  Ada_83 mode, since we do not yet know if we are compiling a
 242       --  predefined unit, and if we are then it would be allowed anyway.
 243
 244       if Token = Tok_Private then
 245          Private_Sloc := Token_Ptr;
 246          Set_Keyword_Casing (Current_Source_File, Determine_Token_Casing);
 247          if Style_Check then
 248             Style.Check_Indentation;
 249          end if;
 250
 251          Save_Scan_State (Scan_State); -- at PRIVATE
 252          Scan; -- past PRIVATE
 253
 254          if Token = Tok_Separate then
 255             Error_Msg_SP ("cannot have private subunits!");
 256
 257          elsif Token = Tok_Package then
 258             Scan; -- past PACKAGE
 259
 260             if Token = Tok_Body then
 261                Restore_Scan_State (Scan_State); -- to PRIVATE
 262                Error_Msg_SC ("cannot have private package body!");
 263                Scan; -- ignore PRIVATE
 264
 265             else
 266                Restore_Scan_State (Scan_State); -- to PRIVATE
 267                Scan; -- past PRIVATE
 268                Set_Private_Present (Comp_Unit_Node, True);
 269             end if;
 270
 271          elsif Token = Tok_Procedure
 272            or else Token = Tok_Function
 273            or else Token = Tok_Generic
 274          then
 275             Set_Private_Present (Comp_Unit_Node, True);
 276          end if;
 277       end if;
 278
 279       --  Loop to find our way to a compilation unit token
 280
 281       loop
 282          exit when Token in Token_Class_Cunit and then Token /= Tok_With;
 283
 284          exit when Bad_Spelling_Of (Tok_Package)
 285            or else Bad_Spelling_Of (Tok_Function)
 286            or else Bad_Spelling_Of (Tok_Generic)
 287            or else Bad_Spelling_Of (Tok_Separate)
 288            or else Bad_Spelling_Of (Tok_Procedure);
 289
 290          --  Allow task and protected for nice error recovery purposes
 291
 292          exit when Token = Tok_Task
 293            or else Token = Tok_Protected;
 294
 295          if Token = Tok_With then
 296             Error_Msg_SC ("misplaced WITH");
 297             Append_List (P_Context_Clause, Context_Items (Comp_Unit_Node));
 298
 299          elsif Bad_Spelling_Of (Tok_With) then
 300             Append_List (P_Context_Clause, Context_Items (Comp_Unit_Node));
 301
 302          else
 303             if Operating_Mode = Check_Syntax and then Token = Tok_EOF then
 304                Error_Msg_SC ("?file contains no compilation units");
 305             else
 306                Error_Msg_SC ("compilation unit expected");
 307                Cunit_Error_Flag := True;
 308                Resync_Cunit;
 309             end if;
 310
 311             --  If we are at an end of file, then just quit, the above error
 312             --  message was complaint enough.
 313
 314             if Token = Tok_EOF then
 315                return Error;
 316             end if;
 317          end if;
 318       end loop;
 319
 320       --  We have a compilation unit token, so that's a reasonable choice for
 321       --  determining the standard casing convention used for keywords in case
 322       --  it hasn't already been done on seeing a WITH or PRIVATE.
 323
 324       Set_Keyword_Casing (Current_Source_File, Determine_Token_Casing);
 325       if Style_Check then
 326          Style.Check_Indentation;
 327       end if;
 328
 329       --  Remaining processing depends on particular type of compilation unit
 330
 331       if Token = Tok_Package then
 332
 333          --  A common error is to omit the body keyword after package. We can
 334          --  often diagnose this early on (before getting loads of errors from
 335          --  contained subprogram bodies), by knowing that that the file we
 336          --  are compiling has a name that requires a body to be found.
 337
 338          Save_Scan_State (Scan_State);
 339          Scan; -- past Package keyword
 340
 341          if Token /= Tok_Body
 342            and then
 343              Get_Expected_Unit_Type
 344                (File_Name (Current_Source_File)) = Expect_Body
 345          then
 346             Error_Msg_BC ("keyword BODY expected here [see file name]");
 347             Restore_Scan_State (Scan_State);
 348             Set_Unit (Comp_Unit_Node, P_Package (Pf_Pbod));
 349          else
 350             Restore_Scan_State (Scan_State);
 351             Set_Unit (Comp_Unit_Node, P_Package (Pf_Decl_Gins_Pbod_Rnam));
 352          end if;
 353
 354       elsif Token = Tok_Generic then
 355          Set_Unit (Comp_Unit_Node, P_Generic);
 356
 357       elsif Token = Tok_Separate then
 358          Set_Unit (Comp_Unit_Node, P_Subunit);
 359
 360       elsif Token = Tok_Function
 361         or else Token = Tok_Not
 362         or else Token = Tok_Overriding
 363         or else Token = Tok_Procedure
 364       then
 365          Set_Unit (Comp_Unit_Node, P_Subprogram (Pf_Decl_Gins_Pbod_Rnam));
 366
 367          --  A little bit of an error recovery check here. If we just scanned
 368          --  a subprogram declaration (as indicated by an SIS entry being
 369          --  active), then if the following token is BEGIN or an identifier,
 370          --  or a token which can reasonably start a declaration but cannot
 371          --  start a compilation unit, then we assume that the semicolon in
 372          --  the declaration should have been IS.
 373
 374          if SIS_Entry_Active then
 375
 376             if Token = Tok_Begin
 377                or else Token = Tok_Identifier
 378                or else Token in Token_Class_Deckn
 379             then
 380                Push_Scope_Stack;
 381                Scope.Table (Scope.Last).Etyp := E_Name;
 382                Scope.Table (Scope.Last).Sloc := SIS_Sloc;
 383                Scope.Table (Scope.Last).Ecol := SIS_Ecol;
 384                Scope.Table (Scope.Last).Lreq := False;
 385                SIS_Entry_Active := False;
 386
 387                --  If we had a missing semicolon in the declaration, then
 388                --  change the message to from <missing ";"> to <missing "is">
 389
 390                if SIS_Missing_Semicolon_Message /= No_Error_Msg then
 391                   Change_Error_Text     -- Replace: "missing "";"" "
 392                     (SIS_Missing_Semicolon_Message, "missing IS");
 393
 394                --  Otherwise we saved the semicolon position, so complain
 395
 396                else
 397                   Error_Msg (""";"" should be IS", SIS_Semicolon_Sloc);
 398                end if;
 399
 400                Body_Node := Unit (Comp_Unit_Node);
 401                Specification_Node := Specification (Body_Node);
 402                Change_Node (Body_Node, N_Subprogram_Body);
 403                Set_Specification (Body_Node, Specification_Node);
 404                Parse_Decls_Begin_End (Body_Node);
 405                Set_Unit (Comp_Unit_Node, Body_Node);
 406             end if;
 407
 408          --  If we scanned a subprogram body, make sure we did not have private
 409
 410          elsif Private_Sloc /= No_Location
 411            and then
 412              Nkind (Unit (Comp_Unit_Node)) not in N_Subprogram_Instantiation
 413            and then
 414              Nkind (Unit (Comp_Unit_Node)) /= N_Subprogram_Renaming_Declaration
 415          then
 416             Error_Msg ("cannot have private subprogram body", Private_Sloc);
 417
 418          --  P_Subprogram can yield an abstract subprogram, but this cannot
 419          --  be a compilation unit. Treat as a subprogram declaration.
 420
 421          elsif
 422            Nkind (Unit (Comp_Unit_Node)) = N_Abstract_Subprogram_Declaration
 423          then
 424             Error_Msg_N
 425               ("compilation unit cannot be abstract subprogram",
 426                  Unit (Comp_Unit_Node));
 427
 428             Unit_Node :=
 429               New_Node (N_Subprogram_Declaration, Sloc (Comp_Unit_Node));
 430             Set_Specification (Unit_Node,
 431               Specification (Unit (Comp_Unit_Node)));
 432             Set_Unit (Comp_Unit_Node, Unit_Node);
 433          end if;
 434
 435       --  Otherwise we have TASK. This is not really an acceptable token,
 436       --  but we accept it to improve error recovery.
 437
 438       elsif Token = Tok_Task then
 439          Scan; -- Past TASK
 440
 441          if Token = Tok_Type then
 442             Error_Msg_SP
 443               ("task type cannot be used as compilation unit");
 444          else
 445             Error_Msg_SP
 446               ("task declaration cannot be used as compilation unit");
 447          end if;
 448
 449          --  If in check syntax mode, accept the task anyway. This is done
 450          --  particularly to improve the behavior of GNATCHOP in this case.
 451
 452          if Operating_Mode = Check_Syntax then
 453             Set_Unit (Comp_Unit_Node, P_Task);
 454
 455          --  If not in syntax only mode, treat this as horrible error
 456
 457          else
 458             Cunit_Error_Flag := True;
 459             return Error;
 460          end if;
 461
 462       else pragma Assert (Token = Tok_Protected);
 463          Scan; -- Past PROTECTED
 464
 465          if Token = Tok_Type then
 466             Error_Msg_SP
 467               ("protected type cannot be used as compilation unit");
 468          else
 469             Error_Msg_SP
 470               ("protected declaration cannot be used as compilation unit");
 471          end if;
 472
 473          --  If in check syntax mode, accept protected anyway. This is done
 474          --  particularly to improve the behavior of GNATCHOP in this case.
 475
 476          if Operating_Mode = Check_Syntax then
 477             Set_Unit (Comp_Unit_Node, P_Protected);
 478
 479          --  If not in syntax only mode, treat this as horrible error
 480
 481          else
 482             Cunit_Error_Flag := True;
 483             return Error;
 484          end if;
 485       end if;
 486
 487       --  Here is where locate the compilation unit entity. This is a little
 488       --  tricky, since it is buried in various places.
 489
 490       Unit_Node := Unit (Comp_Unit_Node);
 491
 492       --  Another error from which it is hard to recover
 493
 494       if Nkind (Unit_Node) = N_Subprogram_Body_Stub
 495         or else Nkind (Unit_Node) = N_Package_Body_Stub
 496       then
 497          Cunit_Error_Flag := True;
 498          return Error;
 499       end if;
 500
 501       --  Only try this if we got an OK unit!
 502
 503       if Unit_Node /= Error then
 504          if Nkind (Unit_Node) = N_Subunit then
 505             Unit_Node := Proper_Body (Unit_Node);
 506          end if;
 507
 508          if Nkind (Unit_Node) in N_Generic_Declaration then
 509             Unit_Node := Specification (Unit_Node);
 510          end if;
 511
 512          if Nkind (Unit_Node) = N_Package_Declaration
 513            or else Nkind (Unit_Node) = N_Subprogram_Declaration
 514            or else Nkind (Unit_Node) = N_Subprogram_Body
 515            or else Nkind (Unit_Node) = N_Subprogram_Renaming_Declaration
 516          then
 517             Unit_Node := Specification (Unit_Node);
 518
 519          elsif Nkind (Unit_Node) = N_Subprogram_Renaming_Declaration then
 520             if Ada_Version = Ada_83 then
 521                Error_Msg_N
 522                  ("(Ada 83) library unit renaming not allowed", Unit_Node);
 523             end if;
 524          end if;
 525
 526          if Nkind (Unit_Node) = N_Task_Body
 527            or else Nkind (Unit_Node) = N_Protected_Body
 528            or else Nkind (Unit_Node) = N_Task_Type_Declaration
 529            or else Nkind (Unit_Node) = N_Protected_Type_Declaration
 530            or else Nkind (Unit_Node) = N_Single_Task_Declaration
 531            or else Nkind (Unit_Node) = N_Single_Protected_Declaration
 532          then
 533             Name_Node := Defining_Identifier (Unit_Node);
 534
 535          elsif Nkind (Unit_Node) = N_Function_Instantiation
 536            or else Nkind (Unit_Node) = N_Function_Specification
 537            or else Nkind (Unit_Node) = N_Generic_Function_Renaming_Declaration
 538            or else Nkind (Unit_Node) = N_Generic_Package_Renaming_Declaration
 539            or else Nkind (Unit_Node) = N_Generic_Procedure_Renaming_Declaration
 540            or else Nkind (Unit_Node) = N_Package_Body
 541            or else Nkind (Unit_Node) = N_Package_Instantiation
 542            or else Nkind (Unit_Node) = N_Package_Renaming_Declaration
 543            or else Nkind (Unit_Node) = N_Package_Specification
 544            or else Nkind (Unit_Node) = N_Procedure_Instantiation
 545            or else Nkind (Unit_Node) = N_Procedure_Specification
 546          then
 547             Name_Node := Defining_Unit_Name (Unit_Node);
 548
 549          --  Anything else is a serious error, abandon scan
 550
 551          else
 552             raise Error_Resync;
 553          end if;
 554
 555          Set_Sloc (Comp_Unit_Node, Sloc (Name_Node));
 556          Set_Sloc (Aux_Decls_Node (Comp_Unit_Node), Sloc (Name_Node));
 557
 558          --  Set Entity field in file table. Easier now that we have name!
 559          --  Note that this is also skipped if we had a bad unit
 560
 561          if Nkind (Name_Node) = N_Defining_Program_Unit_Name then
 562             Set_Cunit_Entity
 563               (Current_Source_Unit, Defining_Identifier (Name_Node));
 564          else
 565             Set_Cunit_Entity (Current_Source_Unit, Name_Node);
 566          end if;
 567
 568          Set_Unit_Name
 569            (Current_Source_Unit, Get_Unit_Name (Unit (Comp_Unit_Node)));
 570
 571       --  If we had a bad unit, make sure the fatal flag is set in the file
 572       --  table entry, since this is surely a fatal error and also set our
 573       --  flag to inhibit the requirement that we be at end of file.
 574
 575       else
 576          Cunit_Error_Flag := True;
 577          Set_Fatal_Error (Current_Source_Unit);
 578       end if;
 579
 580       --  Clear away any missing semicolon indication, we are done with that
 581       --  unit, so what's done is done, and we don't want anything hanging
 582       --  around from the attempt to parse it!
 583
 584       SIS_Entry_Active := False;
 585
 586       --  Scan out pragmas after unit
 587
 588       while Token = Tok_Pragma loop
 589          Save_Scan_State (Scan_State);
 590
 591          --  If we are in syntax scan mode allowing multiple units, then start
 592          --  the next unit if we encounter a configuration pragma, or a source
 593          --  reference pragma. We take care not to actually scan the pragma in
 594          --  this case (we don't want it to take effect for the current unit).
 595
 596          if Operating_Mode = Check_Syntax then
 597             Scan;  -- past Pragma
 598
 599             if Token = Tok_Identifier
 600               and then
 601                 (Is_Configuration_Pragma_Name (Token_Name)
 602                    or else Token_Name = Name_Source_Reference)
 603             then
 604                Restore_Scan_State (Scan_State); -- to Pragma
 605                exit;
 606             end if;
 607          end if;
 608
 609          --  Otherwise eat the pragma, it definitely belongs with the
 610          --  current unit, and not with the following unit.
 611
 612          Restore_Scan_State (Scan_State); -- to Pragma
 613          P := P_Pragma;
 614
 615          if No (Pragmas_After (Aux_Decls_Node (Comp_Unit_Node))) then
 616             Set_Pragmas_After
 617               (Aux_Decls_Node (Comp_Unit_Node), New_List);
 618          end if;
 619
 620          Append (P, Pragmas_After (Aux_Decls_Node (Comp_Unit_Node)));
 621       end loop;
 622
 623       --  Cancel effect of any outstanding pragma Warnings (Off)
 624
 625       Set_Warnings_Mode_On (Scan_Ptr);
 626
 627       --  Ada 83 error checks
 628
 629       if Ada_Version = Ada_83 then
 630
 631          --  Check we did not with any child units
 632
 633          Item := First (Context_Items (Comp_Unit_Node));
 634
 635          while Present (Item) loop
 636             if Nkind (Item) = N_With_Clause
 637               and then Nkind (Name (Item)) /= N_Identifier
 638             then
 639                Error_Msg_N ("(Ada 83) child units not allowed", Item);
 640             end if;
 641
 642             Next (Item);
 643          end loop;
 644
 645          --  Check that we did not have a PRIVATE keyword present
 646
 647          if Private_Present (Comp_Unit_Node) then
 648             Error_Msg
 649               ("(Ada 83) private units not allowed", Private_Sloc);
 650          end if;
 651       end if;
 652
 653       --  If no serious error, then output possible unit information line
 654       --  for gnatchop if we are in syntax only, list units mode.
 655
 656       if not Cunit_Error_Flag
 657         and then List_Units
 658         and then Operating_Mode = Check_Syntax
 659       then
 660          Unit_Display (Comp_Unit_Node, Cunit_Location, SR_Present);
 661       end if;
 662
 663       --  And now we should be at the end of file
 664
 665       if Token /= Tok_EOF then
 666
 667          --  If we already had to scan for a compilation unit, then don't
 668          --  give any further error message, since it just seems to make
 669          --  things worse, and we already gave a serious error message.
 670
 671          if Cunit_Error_Flag then
 672             null;
 673
 674          --  If we are in check syntax mode, then we allow multiple units
 675          --  so we just return with Token not set to Tok_EOF and no message.
 676
 677          elsif Operating_Mode = Check_Syntax then
 678             return Comp_Unit_Node;
 679
 680          --  We also allow multiple units if we are in multiple unit mode
 681
 682          elsif Multiple_Unit_Index /= 0 then
 683
 684             --  Skip tokens to end of file, so that the -gnatl listing
 685             --  will be complete in this situation, but no need to parse
 686             --  the remaining units; no style checking either.
 687
 688             declare
 689                Save_Style_Check : constant Boolean := Style_Check;
 690
 691             begin
 692                Style_Check := False;
 693
 694                while Token /= Tok_EOF loop
 695                   Scan;
 696                end loop;
 697
 698                Style_Check := Save_Style_Check;
 699             end;
 700
 701             return Comp_Unit_Node;
 702
 703          --  Otherwise we have an error. We suppress the error message
 704          --  if we already had a fatal error, since this stops junk
 705          --  cascaded messages in some situations.
 706
 707          else
 708             if not Fatal_Error (Current_Source_Unit) then
 709                if Token in Token_Class_Cunit then
 710                   Error_Msg_SC
 711                     ("end of file expected, " &
 712                      "file can have only one compilation unit");
 713                else
 714                   Error_Msg_SC ("end of file expected");
 715                end if;
 716             end if;
 717          end if;
 718
 719          --  Skip tokens to end of file, so that the -gnatl listing
 720          --  will be complete in this situation, but no error checking
 721          --  other than that provided at the token level.
 722
 723          while Token /= Tok_EOF loop
 724             Scan;
 725          end loop;
 726
 727          return Error;
 728
 729       --  Normal return (we were at the end of file as expected)
 730
 731       else
 732          return Comp_Unit_Node;
 733       end if;
 734
 735    exception
 736
 737       --  An error resync is a serious bomb, so indicate result unit no good
 738
 739       when Error_Resync =>
 740          Set_Fatal_Error (Current_Source_Unit);
 741          return Error;
 742    end P_Compilation_Unit;
 743
 744    --------------------------
 745    -- 10.1.1  Library Item --
 746    --------------------------
 747
 748    --  Parsed by P_Compilation_Unit (10.1.1)
 749
 750    --------------------------------------
 751    -- 10.1.1  Library Unit Declaration --
 752    --------------------------------------
 753
 754    --  Parsed by P_Compilation_Unit (10.1.1)
 755
 756    ------------------------------------------------
 757    -- 10.1.1  Library Unit Renaming Declaration  --
 758    ------------------------------------------------
 759
 760    --  Parsed by P_Compilation_Unit (10.1.1)
 761
 762    -------------------------------
 763    -- 10.1.1  Library Unit Body --
 764    -------------------------------
 765
 766    --  Parsed by P_Compilation_Unit (10.1.1)
 767
 768    ------------------------------
 769    -- 10.1.1  Parent Unit Name --
 770    ------------------------------
 771
 772    --  Parsed (as a name) by its parent construct
 773
 774    ----------------------------
 775    -- 10.1.2  Context Clause --
 776    ----------------------------
 777
 778    --  CONTEXT_CLAUSE ::= {CONTEXT_ITEM}
 779
 780    --  CONTEXT_ITEM ::= WITH_CLAUSE | USE_CLAUSE | WITH_TYPE_CLAUSE
 781
 782    --  WITH_CLAUSE ::=
 783    --  [LIMITED] [PRIVATE]  with library_unit_NAME {,library_unit_NAME};
 784    --  Note: the two qualifiers are Ada 2005 extensions.
 785
 786    --  WITH_TYPE_CLAUSE ::=
 787    --    with type type_NAME is access; | with type type_NAME is tagged;
 788    --  Note: this form is obsolete (old GNAT extension).
 789
 790    --  Error recovery: Cannot raise Error_Resync
 791
 792    function P_Context_Clause return List_Id is
 793       Item_List   : List_Id;
 794       Has_Limited : Boolean := False;
 795       Has_Private : Boolean := False;
 796       Scan_State  : Saved_Scan_State;
 797       With_Node   : Node_Id;
 798       First_Flag  : Boolean;
 799
 800    begin
 801       Item_List := New_List;
 802
 803       --  Get keyword casing from WITH keyword in case not set yet
 804
 805       if Token = Tok_With then
 806          Set_Keyword_Casing (Current_Source_File, Determine_Token_Casing);
 807       end if;
 808
 809       --  Loop through context items
 810
 811       loop
 812          if Style_Check then
 813             Style.Check_Indentation;
 814          end if;
 815
 816          --  Gather any pragmas appearing in the context clause
 817
 818          P_Pragmas_Opt (Item_List);
 819
 820          --  Processing for WITH clause
 821
 822          --  Ada 2005 (AI-50217, AI-262): First check for LIMITED WITH,
 823          --  PRIVATE WITH, or both.
 824
 825          if Token = Tok_Limited then
 826             Has_Limited := True;
 827             Has_Private := False;
 828             Scan; -- past LIMITED
 829
 830             --  In the context, LIMITED can only appear in a with_clause
 831
 832             if Token = Tok_Private then
 833                Has_Private := True;
 834                Scan;  -- past PRIVATE
 835             end if;
 836
 837             if Token /= Tok_With then
 838                Error_Msg_SC ("unexpected LIMITED ignored");
 839             end if;
 840
 841             if Ada_Version < Ada_05 then
 842                Error_Msg_SP ("LIMITED WITH is an Ada 2005 extension");
 843                Error_Msg_SP
 844                  ("\unit must be compiled with -gnat05 switch");
 845             end if;
 846
 847          elsif Token = Tok_Private then
 848             Has_Limited := False;
 849             Has_Private := True;
 850             Save_Scan_State (Scan_State);
 851             Scan;  -- past PRIVATE
 852
 853             if Token /= Tok_With then
 854
 855                --  Keyword is beginning of private child unit
 856
 857                Restore_Scan_State (Scan_State); -- to PRIVATE
 858                return Item_List;
 859
 860             elsif Ada_Version < Ada_05 then
 861                Error_Msg_SP ("`PRIVATE WITH` is an Ada 2005 extension");
 862                Error_Msg_SP
 863                  ("\unit must be compiled with -gnat05 switch");
 864             end if;
 865
 866          else
 867             Has_Limited := False;
 868             Has_Private := False;
 869          end if;
 870
 871          if Token = Tok_With then
 872             Scan; -- past WITH
 873
 874             if Token = Tok_Type then
 875
 876                --  WITH TYPE is an obsolete GNAT specific extension
 877
 878                Error_Msg_SP
 879                  ("`WITH TYPE` is an obsolete 'G'N'A'T extension");
 880                Error_Msg_SP ("\use Ada 2005 `LIMITED WITH` clause instead");
 881
 882                Scan;  -- past TYPE
 883
 884                T_Is;
 885
 886                if Token = Tok_Tagged then
 887                   Scan;
 888
 889                elsif Token = Tok_Access then
 890                   Scan;
 891
 892                else
 893                   Error_Msg_SC ("expect tagged or access qualifier");
 894                end if;
 895
 896                TF_Semicolon;
 897
 898             else
 899                First_Flag := True;
 900
 901                --  Loop through names in one with clause, generating a separate
 902                --  N_With_Clause node for each name encountered.
 903
 904                loop
 905                   With_Node := New_Node (N_With_Clause, Token_Ptr);
 906                   Append (With_Node, Item_List);
 907
 908                   --  Note that we allow with'ing of child units, even in
 909                   --  Ada 83 mode, since presumably if this is not desired,
 910                   --  then the compilation of the child unit itself is the
 911                   --  place where such an "error" should be caught.
 912
 913                   Set_Name (With_Node, P_Qualified_Simple_Name);
 914                   Set_First_Name (With_Node, First_Flag);
 915                   Set_Limited_Present (With_Node, Has_Limited);
 916                   Set_Private_Present (With_Node, Has_Private);
 917                   First_Flag := False;
 918
 919                   --  All done if no comma
 920
 921                   exit when Token /= Tok_Comma;
 922
 923                   --  If comma is followed by compilation unit token
 924                   --  or by USE, or PRAGMA, then it should have been a
 925                   --  semicolon after all
 926
 927                   Save_Scan_State (Scan_State);
 928                   Scan; -- past comma
 929
 930                   if Token in Token_Class_Cunit
 931                     or else Token = Tok_Use
 932                     or else Token = Tok_Pragma
 933                   then
 934                      Restore_Scan_State (Scan_State);
 935                      exit;
 936                   end if;
 937                end loop;
 938
 939                Set_Last_Name (With_Node, True);
 940                TF_Semicolon;
 941             end if;
 942
 943          --  Processing for USE clause
 944
 945          elsif Token = Tok_Use then
 946             Append (P_Use_Clause, Item_List);
 947
 948          --  Anything else is end of context clause
 949
 950          else
 951             exit;
 952          end if;
 953       end loop;
 954
 955       return Item_List;
 956    end P_Context_Clause;
 957
 958    --------------------------
 959    -- 10.1.2  Context Item --
 960    --------------------------
 961
 962    --  Parsed by P_Context_Clause (10.1.2)
 963
 964    -------------------------
 965    -- 10.1.2  With Clause --
 966    -------------------------
 967
 968    --  Parsed by P_Context_Clause (10.1.2)
 969
 970    -----------------------
 971    -- 10.1.3  Body Stub --
 972    -----------------------
 973
 974    --  Subprogram stub parsed by P_Subprogram (6.1)
 975    --  Package stub parsed by P_Package (7.1)
 976    --  Task stub parsed by P_Task (9.1)
 977    --  Protected stub parsed by P_Protected (9.4)
 978
 979    ----------------------------------
 980    -- 10.1.3  Subprogram Body Stub --
 981    ----------------------------------
 982
 983    --  Parsed by P_Subprogram (6.1)
 984
 985    -------------------------------
 986    -- 10.1.3  Package Body Stub --
 987    -------------------------------
 988
 989    --  Parsed by P_Package (7.1)
 990
 991    ----------------------------
 992    -- 10.1.3  Task Body Stub --
 993    ----------------------------
 994
 995    --  Parsed by P_Task (9.1)
 996
 997    ---------------------------------
 998    -- 10.1.3  Protected Body Stub --
 999    ---------------------------------
1000
1001    --  Parsed by P_Protected (9.4)
1002
1003    ---------------------
1004    -- 10.1.3  Subunit --
1005    ---------------------
1006
1007    --  SUBUNIT ::= separate (PARENT_UNIT_NAME) PROPER_BODY
1008
1009    --  PARENT_UNIT_NAME ::= NAME
1010
1011    --  The caller has checked that the initial token is SEPARATE
1012
1013    --  Error recovery: cannot raise Error_Resync
1014
1015    function P_Subunit return Node_Id is
1016       Subunit_Node : Node_Id;
1017       Body_Node    : Node_Id;
1018
1019    begin
1020       Subunit_Node := New_Node (N_Subunit, Token_Ptr);
1021       Body_Node := Error; -- in case no good body found
1022       Scan; -- past SEPARATE;
1023
1024       U_Left_Paren;
1025       Set_Name (Subunit_Node, P_Qualified_Simple_Name);
1026       U_Right_Paren;
1027
1028       Ignore (Tok_Semicolon);
1029
1030       if Token = Tok_Function or else Token = Tok_Procedure then
1031          Body_Node := P_Subprogram (Pf_Pbod);
1032
1033       elsif Token = Tok_Package then
1034          Body_Node := P_Package (Pf_Pbod);
1035
1036       elsif Token = Tok_Protected then
1037          Scan; -- past PROTECTED
1038
1039          if Token = Tok_Body then
1040             Body_Node := P_Protected;
1041          else
1042             Error_Msg_AP ("BODY expected");
1043             return Error;
1044          end if;
1045
1046       elsif Token = Tok_Task then
1047          Scan; -- past TASK
1048
1049          if Token = Tok_Body then
1050             Body_Node := P_Task;
1051          else
1052             Error_Msg_AP ("BODY expected");
1053             return Error;
1054          end if;
1055
1056       else
1057          Error_Msg_SC ("proper body expected");
1058          return Error;
1059       end if;
1060
1061       Set_Proper_Body  (Subunit_Node, Body_Node);
1062       return Subunit_Node;
1063
1064    end P_Subunit;
1065
1066    ------------------
1067    -- Set_Location --
1068    ------------------
1069
1070    function Set_Location return Source_Ptr is
1071       Physical   : Boolean;
1072       Loc        : Source_Ptr;
1073       Scan_State : Saved_Scan_State;
1074
1075    begin
1076       --  A special check. If the first token is pragma, and this is a
1077       --  Source_Reference pragma, then do NOT eat previous comments, since
1078       --  the Source_Reference pragma is required to be the first line in
1079       --  the source file.
1080
1081       if Token = Tok_Pragma then
1082          Save_Scan_State (Scan_State);
1083          Scan; --  past Pragma
1084
1085          if Token = Tok_Identifier
1086            and then Token_Name = Name_Source_Reference
1087          then
1088             Restore_Scan_State (Scan_State);
1089             return Token_Ptr;
1090          end if;
1091
1092          Restore_Scan_State (Scan_State);
1093       end if;
1094
1095       --  Otherwise acquire previous comments and blank lines
1096
1097       if Prev_Token = No_Token then
1098          return Source_First (Current_Source_File);
1099
1100       else
1101          Loc := Prev_Token_Ptr;
1102          loop
1103             exit when Loc = Token_Ptr;
1104
1105             --  Should we worry about UTF_32 line terminators here
1106
1107             if Source (Loc) in Line_Terminator then
1108                Skip_Line_Terminators (Loc, Physical);
1109                exit when Physical;
1110             end if;
1111
1112             Loc := Loc + 1;
1113          end loop;
1114
1115          return Loc;
1116       end if;
1117    end Set_Location;
1118
1119    ------------------
1120    -- Unit_Display --
1121    ------------------
1122
1123    --  The format of the generated line, as expected by GNATCHOP is
1124
1125    --    Unit {unit} line {line}, file offset {offs} [, SR], file name {file}
1126
1127    --  where
1128
1129    --     {unit}     unit name with terminating (spec) or (body)
1130    --     {line}     starting line number
1131    --     {offs}     offset to start of text in file
1132    --     {file}     source file name
1133
1134    --  The SR parameter is present only if a source reference pragma was
1135    --  scanned for this unit. The significance is that gnatchop should not
1136    --  attempt to add another one.
1137
1138    procedure Unit_Display
1139      (Cunit      : Node_Id;
1140       Loc        : Source_Ptr;
1141       SR_Present : Boolean)
1142    is
1143       Unum : constant Unit_Number_Type    := Get_Cunit_Unit_Number (Cunit);
1144       Sind : constant Source_File_Index   := Source_Index (Unum);
1145       Unam : constant Unit_Name_Type      := Unit_Name (Unum);
1146
1147    begin
1148       if List_Units then
1149          Write_Str ("Unit ");
1150          Write_Unit_Name (Unit_Name (Unum));
1151          Unit_Location (Sind, Loc);
1152
1153          if SR_Present then
1154             Write_Str (", SR");
1155          end if;
1156
1157          Write_Str (", file name ");
1158          Write_Name (Get_File_Name (Unam, Nkind (Unit (Cunit)) = N_Subunit));
1159          Write_Eol;
1160       end if;
1161    end Unit_Display;
1162
1163    -------------------
1164    -- Unit_Location --
1165    -------------------
1166
1167    procedure Unit_Location (Sind : Source_File_Index; Loc : Source_Ptr) is
1168       Line : constant Logical_Line_Number := Get_Logical_Line_Number (Loc);
1169       --  Should the above be the physical line number ???
1170
1171    begin
1172       Write_Str (" line ");
1173       Write_Int (Int (Line));
1174
1175       Write_Str (", file offset ");
1176       Write_Int (Int (Loc) - Int (Source_First (Sind)));
1177    end Unit_Location;
1178
1179 end Ch10;