gcc/ada/a-coorse.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --           A D A . C O N T A I N E R S . O R D E R E D _ S E T S          --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- This unit was originally developed by Matthew J Heaney.                  --
  34 ------------------------------------------------------------------------------
  35
  36 private with Ada.Containers.Red_Black_Trees;
  37 private with Ada.Finalization;
  38 private with Ada.Streams;
  39
  40 generic
  41    type Element_Type is private;
  42
  43    with function "<" (Left, Right : Element_Type) return Boolean is <>;
  44    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  45
  46 package Ada.Containers.Ordered_Sets is
  47    pragma Preelaborate;
  48    pragma Remote_Types;
  49
  50    function Equivalent_Elements (Left, Right : Element_Type) return Boolean;
  51
  52    type Set is tagged private;
  53    pragma Preelaborable_Initialization (Set);
  54
  55    type Cursor is private;
  56    pragma Preelaborable_Initialization (Cursor);
  57
  58    Empty_Set : constant Set;
  59
  60    No_Element : constant Cursor;
  61
  62    function "=" (Left, Right : Set) return Boolean;
  63
  64    function Equivalent_Sets (Left, Right : Set) return Boolean;
  65
  66    function To_Set (New_Item : Element_Type) return Set;
  67
  68    function Length (Container : Set) return Count_Type;
  69
  70    function Is_Empty (Container : Set) return Boolean;
  71
  72    procedure Clear (Container : in out Set);
  73
  74    function Element (Position : Cursor) return Element_Type;
  75
  76    procedure Replace_Element
  77      (Container : in out Set;
  78       Position  : Cursor;
  79       New_Item  : Element_Type);
  80
  81    procedure Query_Element
  82      (Position : Cursor;
  83       Process  : not null access procedure (Element : Element_Type));
  84
  85    procedure Move (Target : in out Set; Source : in out Set);
  86
  87    procedure Insert
  88      (Container : in out Set;
  89       New_Item  : Element_Type;
  90       Position  : out Cursor;
  91       Inserted  : out Boolean);
  92
  93    procedure Insert
  94      (Container : in out Set;
  95       New_Item  : Element_Type);
  96
  97    procedure Include
  98      (Container : in out Set;
  99       New_Item  : Element_Type);
 100
 101    procedure Replace
 102      (Container : in out Set;
 103       New_Item  : Element_Type);
 104
 105    procedure Exclude
 106      (Container : in out Set;
 107       Item      : Element_Type);
 108
 109    procedure Delete
 110      (Container : in out Set;
 111       Item      : Element_Type);
 112
 113    procedure Delete
 114      (Container : in out Set;
 115       Position  : in out Cursor);
 116
 117    procedure Delete_First (Container : in out Set);
 118
 119    procedure Delete_Last (Container : in out Set);
 120
 121    procedure Union (Target : in out Set; Source : Set);
 122
 123    function Union (Left, Right : Set) return Set;
 124
 125    function "or" (Left, Right : Set) return Set renames Union;
 126
 127    procedure Intersection (Target : in out Set; Source : Set);
 128
 129    function Intersection (Left, Right : Set) return Set;
 130
 131    function "and" (Left, Right : Set) return Set renames Intersection;
 132
 133    procedure Difference (Target : in out Set; Source : Set);
 134
 135    function Difference (Left, Right : Set) return Set;
 136
 137    function "-" (Left, Right : Set) return Set renames Difference;
 138
 139    procedure Symmetric_Difference (Target : in out Set; Source : Set);
 140
 141    function Symmetric_Difference (Left, Right : Set) return Set;
 142
 143    function "xor" (Left, Right : Set) return Set renames Symmetric_Difference;
 144
 145    function Overlap (Left, Right : Set) return Boolean;
 146
 147    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean;
 148
 149    function First (Container : Set) return Cursor;
 150
 151    function First_Element (Container : Set) return Element_Type;
 152
 153    function Last (Container : Set) return Cursor;
 154
 155    function Last_Element (Container : Set) return Element_Type;
 156
 157    function Next (Position : Cursor) return Cursor;
 158
 159    procedure Next (Position : in out Cursor);
 160
 161    function Previous (Position : Cursor) return Cursor;
 162
 163    procedure Previous (Position : in out Cursor);
 164
 165    function Find (Container : Set; Item : Element_Type) return Cursor;
 166
 167    function Floor (Container : Set; Item : Element_Type) return Cursor;
 168
 169    function Ceiling (Container : Set; Item : Element_Type) return Cursor;
 170
 171    function Contains (Container : Set; Item : Element_Type) return Boolean;
 172
 173    function Has_Element (Position : Cursor) return Boolean;
 174
 175    function "<" (Left, Right : Cursor) return Boolean;
 176
 177    function ">" (Left, Right : Cursor) return Boolean;
 178
 179    function "<" (Left : Cursor; Right : Element_Type) return Boolean;
 180
 181    function ">" (Left : Cursor; Right : Element_Type) return Boolean;
 182
 183    function "<" (Left : Element_Type; Right : Cursor) return Boolean;
 184
 185    function ">" (Left : Element_Type; Right : Cursor) return Boolean;
 186
 187    procedure Iterate
 188      (Container : Set;
 189       Process   : not null access procedure (Position : Cursor));
 190
 191    procedure Reverse_Iterate
 192      (Container : Set;
 193       Process   : not null access procedure (Position : Cursor));
 194
 195    generic
 196       type Key_Type (<>) is private;
 197
 198       with function Key (Element : Element_Type) return Key_Type;
 199
 200       with function "<" (Left, Right : Key_Type) return Boolean is <>;
 201
 202    package Generic_Keys is
 203
 204       function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
 205
 206       function Key (Position : Cursor) return Key_Type;
 207
 208       function Element (Container : Set; Key : Key_Type) return Element_Type;
 209
 210       procedure Replace
 211         (Container : in out Set;
 212          Key       : Key_Type;
 213          New_Item  : Element_Type);
 214
 215       procedure Exclude (Container : in out Set; Key : Key_Type);
 216
 217       procedure Delete (Container : in out Set; Key : Key_Type);
 218
 219       function Find (Container : Set; Key : Key_Type) return Cursor;
 220
 221       function Floor (Container : Set; Key : Key_Type) return Cursor;
 222
 223       function Ceiling (Container : Set; Key : Key_Type) return Cursor;
 224
 225       function Contains (Container : Set; Key : Key_Type) return Boolean;
 226
 227       procedure Update_Element_Preserving_Key
 228         (Container : in out Set;
 229          Position  : Cursor;
 230          Process   : not null access
 231                        procedure (Element : in out Element_Type));
 232
 233    end Generic_Keys;
 234
 235 private
 236
 237    pragma Inline (Next);
 238    pragma Inline (Previous);
 239
 240    type Node_Type;
 241    type Node_Access is access Node_Type;
 242
 243    type Node_Type is limited record
 244       Parent  : Node_Access;
 245       Left    : Node_Access;
 246       Right   : Node_Access;
 247       Color   : Red_Black_Trees.Color_Type := Red_Black_Trees.Red;
 248       Element : Element_Type;
 249    end record;
 250
 251    package Tree_Types is new Red_Black_Trees.Generic_Tree_Types
 252      (Node_Type,
 253       Node_Access);
 254
 255    type Set is new Ada.Finalization.Controlled with record
 256       Tree : Tree_Types.Tree_Type;
 257    end record;
 258
 259    overriding
 260    procedure Adjust (Container : in out Set);
 261
 262    overriding
 263    procedure Finalize (Container : in out Set) renames Clear;
 264
 265    use Red_Black_Trees;
 266    use Tree_Types;
 267    use Ada.Finalization;
 268    use Ada.Streams;
 269
 270    type Set_Access is access all Set;
 271    for Set_Access'Storage_Size use 0;
 272
 273    type Cursor is record
 274       Container : Set_Access;
 275       Node      : Node_Access;
 276    end record;
 277
 278    procedure Write
 279      (Stream : not null access Root_Stream_Type'Class;
 280       Item   : Cursor);
 281
 282    for Cursor'Write use Write;
 283
 284    procedure Read
 285      (Stream : not null access Root_Stream_Type'Class;
 286       Item   : out Cursor);
 287
 288    for Cursor'Read use Read;
 289
 290    No_Element : constant Cursor := Cursor'(null, null);
 291
 292    procedure Write
 293      (Stream    : not null access Root_Stream_Type'Class;
 294       Container : Set);
 295
 296    for Set'Write use Write;
 297
 298    procedure Read
 299      (Stream    : not null access Root_Stream_Type'Class;
 300       Container : out Set);
 301
 302    for Set'Read use Read;
 303
 304    Empty_Set : constant Set :=
 305                  (Controlled with Tree => (First  => null,
 306                                            Last   => null,
 307                                            Root   => null,
 308                                            Length => 0,
 309                                            Busy   => 0,
 310                                            Lock   => 0));
 311
 312 end Ada.Containers.Ordered_Sets;