libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([xmalloc.c])
   5
   6 # This works around the fact that libtool configuration may change LD
   7 # for this particular configuration, but some shells, instead of
   8 # keeping the changes in LD private, export them just because LD is
   9 # exported.  We don't use libtool yet, but some day we might, so...
  10 ORIGINAL_LD_FOR_MULTILIBS=$LD
  11
  12 dnl We use these options to decide which functions to include.
  13 AC_ARG_WITH(target-subdir,
  14 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  15 AC_ARG_WITH(build-subdir,
  16 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  17 AC_ARG_WITH(cross-host,
  18 [  --with-cross-host=HOST           Configuring with a cross compiler])
  19 AC_ARG_WITH(newlib,
  20 [  --with-newlib                    Configuring with newlib])
  21
  22 if test "${srcdir}" = "."; then
  23   if test -n "${with_build_subdir}"; then
  24     libiberty_topdir="${srcdir}/../.."
  25     with_target_subdir=
  26   elif test -z "${with_target_subdir}"; then
  27     libiberty_topdir="${srcdir}/.."
  28   else
  29     if test "${with_target_subdir}" != "."; then
  30       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  31     else
  32       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  33     fi
  34   fi
  35 else
  36   libiberty_topdir="${srcdir}/.."
  37 fi
  38 AC_SUBST(libiberty_topdir)
  39 AC_CONFIG_AUX_DIR($libiberty_topdir)
  40
  41 dnl Very limited version of automake's enable-maintainer-mode
  42
  43 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  44   dnl maintainer-mode is disabled by default
  45   AC_ARG_ENABLE(maintainer-mode,
  46 [  --enable-maintainer-mode
  47                           enable make rules and dependencies not useful
  48                           (and sometimes confusing) to the casual installer],
  49       maintainer_mode=$enableval,
  50       maintainer_mode=no)
  51
  52 AC_MSG_RESULT($maintainer_mode)
  53
  54 if test "$maintainer_mode" = "yes"; then
  55   MAINT=''
  56   NOTMAINT='#'
  57 else
  58   MAINT='#'
  59   NOTMAINT=''
  60 fi
  61 AC_SUBST(MAINT)dnl
  62 AC_SUBST(NOTMAINT)dnl
  63
  64 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  65 # rely on it - libiberty is built before texinfo.
  66 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  67 if test "x$MAKEINFO" = "x"; then
  68     MAKEINFO="@echo makeinfo missing; true"
  69     BUILD_INFO=
  70 else
  71     BUILD_INFO=info
  72     case "$MAKEINFO" in
  73       */missing\ makeinfo*)
  74         BUILD_INFO=
  75         AC_MSG_WARN([
  76 *** Makeinfo is missing. Info documentation will not be built.])
  77         ;;
  78       *)
  79         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  80           x*\ [[1-3]].* )
  81             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  82             BUILD_INFO=
  83             AC_MSG_WARN([
  84 *** Makeinfo is too old. Info documentation will not be built.])
  85           ;;
  86         esac
  87         ;;
  88     esac
  89 fi
  90 AC_SUBST(MAKEINFO)
  91 AC_SUBST(BUILD_INFO)
  92
  93 AC_CHECK_PROG(PERL, perl, perl, )
  94 if test x"$PERL" = x""; then
  95   HAVE_PERL='#'
  96 else
  97   HAVE_PERL=''
  98 fi
  99 AC_SUBST(HAVE_PERL)
 100
 101 AC_CANONICAL_HOST
 102
 103 dnl When we start using automake:
 104 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 105
 106 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 107 dnl to call AC_CHECK_PROG.
 108 AC_CHECK_TOOL(AR, ar)
 109 AC_CHECK_TOOL(RANLIB, ranlib, :)
 110
 111 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 112 # Add --enable-multilib to configure.
 113 # Default to --enable-multilib
 114 AC_ARG_ENABLE(multilib,
 115 [  --enable-multilib       build many library versions (default)],
 116 [case "$enableval" in
 117   yes) multilib=yes ;;
 118   no)  multilib=no ;;
 119   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 120  esac],
 121               [multilib=yes])
 122
 123 # Even if the default multilib is not a cross compilation,
 124 # it may be that some of the other multilibs are.
 125 if test $cross_compiling = no && test $multilib = yes \
 126    && test "x${with_multisubdir}" != x ; then
 127    cross_compiling=maybe
 128 fi
 129
 130 # We may wish to install the target headers somewhere.
 131 AC_MSG_CHECKING([whether to install libiberty headers and static library])
 132 dnl install-libiberty is disabled by default
 133
 134 AC_ARG_ENABLE(install-libiberty,
 135 [  --enable-install-libiberty       Install headers and library for end users],
 136 enable_install_libiberty=$enableval,
 137 enable_install_libiberty=no)dnl
 138
 139 # Option parsed, now set things appropriately.
 140 case x"$enable_install_libiberty" in
 141   xyes|x)
 142     target_header_dir=libiberty
 143     ;;
 144   xno)
 145     target_header_dir=
 146     ;;
 147   *)
 148     # This could be sanity-checked in various ways...
 149     target_header_dir="${enable_install_libiberty}"
 150     ;;
 151 esac
 152 AC_MSG_RESULT($enable_install_libiberty)
 153 AC_MSG_NOTICE([target_header_dir = $target_header_dir])
 154
 155 GCC_NO_EXECUTABLES
 156 AC_PROG_CC
 157 AC_GNU_SOURCE
 158 AC_SYS_LARGEFILE
 159 AC_PROG_CPP_WERROR
 160
 161 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 162                           -Wstrict-prototypes \
 163                           -Wshadow=local], [ac_libiberty_warn_cflags])
 164 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 165
 166 AC_PROG_CC_C_O
 167 # autoconf is lame and doesn't give us any substitution variable for this.
 168 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 169   NO_MINUS_C_MINUS_O=yes
 170 else
 171   OUTPUT_OPTION='-o $@'
 172 fi
 173 AC_SUBST(NO_MINUS_C_MINUS_O)
 174 AC_SUBST(OUTPUT_OPTION)
 175
 176 AC_C_CONST
 177 AC_C_INLINE
 178 AC_C_BIGENDIAN
 179
 180 dnl When we start using libtool:
 181 dnl Default to a non shared library.  This may be overridden by the
 182 dnl configure option --enable-shared.
 183 dnl AM_DISABLE_SHARED
 184
 185 dnl When we start using libtool:
 186 dnl AM_PROG_LIBTOOL
 187
 188 dnl When we start using automake:
 189 dnl AM_CONFIG_HEADER(config.h:config.in)
 190 AC_CONFIG_HEADER(config.h:config.in)
 191
 192 dnl When we start using automake:
 193 dnl AM_MAINTAINER_MODE
 194 dnl AC_EXEEXT
 195
 196 dnl When we start using automake:
 197 dnl AM_PROG_INSTALL
 198 AC_PROG_INSTALL
 199
 200 # Don't build the shared library for build.
 201 if [[ -n "${with_build_subdir}" ]]; then
 202   enable_shared=no
 203 fi
 204
 205 frag=
 206 case "${host}" in
 207   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 208                         frag=mh-aix ;;
 209   *-*-cxux7*)           frag=mh-cxux7 ;;
 210   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 211   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 212   i370-*-opened*)       frag=mh-openedition ;;
 213   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 214 esac
 215
 216 if [[ -n "${frag}" ]]; then
 217   frag=${libiberty_topdir}/libiberty/config/$frag
 218 fi
 219
 220 GCC_PICFLAG
 221
 222 # If they didn't specify --enable-shared, don't generate shared libs.
 223 case "${enable_shared}" in
 224   yes) shared=yes ;;
 225   no) shared=no ;;
 226   "") shared=no ;;
 227   *) shared=yes ;;
 228 esac
 229
 230 # ...unless --enable-host-shared was passed from top-level config:
 231 if [[ "${enable_host_shared}" = "yes" ]]; then
 232   shared=yes
 233 fi
 234
 235 if [[ "${shared}" != "yes" ]]; then
 236   PICFLAG=
 237 fi
 238 AC_SUBST(PICFLAG)
 239
 240 NOASANFLAG=
 241 case " ${CFLAGS} " in
 242   *\ -fsanitize=address\ *) NOASANFLAG=-fno-sanitize=address ;;
 243 esac
 244 AC_SUBST(NOASANFLAG)
 245
 246 GCC_CET_HOST_FLAGS(CET_HOST_FLAGS)
 247 AC_SUBST(CET_HOST_FLAGS)
 248
 249 echo "# Warning: this fragment is automatically generated" > temp-frag
 250
 251 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 252   echo "Appending ${frag} to xhost-mkfrag"
 253   echo "# Following fragment copied from ${frag}" >> temp-frag
 254   cat ${frag} >> temp-frag
 255 fi
 256
 257 # record if we want to build shared libs.
 258 if [[ "${shared}" = "yes" ]]; then
 259   echo enable_shared = yes >> temp-frag
 260 else
 261   echo enable_shared = no >> temp-frag
 262 fi
 263
 264 frag=xhost-mkfrag
 265 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 266
 267 host_makefile_frag=${frag}
 268 AC_SUBST_FILE(host_makefile_frag)
 269
 270 # It's OK to check for header files.  Although the compiler may not be
 271 # able to link anything, it had better be able to at least compile
 272 # something.
 273 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 274 AC_HEADER_SYS_WAIT
 275 AC_HEADER_TIME
 276
 277 libiberty_AC_DECLARE_ERRNO
 278
 279 # Determine sizes of some types.
 280 AC_CHECK_SIZEOF([int])
 281 AC_CHECK_SIZEOF([long])
 282 AC_CHECK_SIZEOF([size_t])
 283
 284 # Check for presense of long long
 285 AC_CHECK_TYPE([long long],
 286   [AC_DEFINE(HAVE_LONG_LONG, 1, [Define if you have the `long long' type.]) AC_CHECK_SIZEOF([long long])],
 287   [])
 288
 289 # Look for a 64-bit type.
 290 AC_MSG_CHECKING([for a 64-bit type])
 291 AC_CACHE_VAL(liberty_cv_uint64,
 292 [AC_TRY_COMPILE(
 293 [#ifdef HAVE_STDINT_H
 294 #include <stdint.h>
 295 #endif],
 296 [extern uint64_t foo;],
 297 liberty_cv_uint64=uint64_t,
 298 [AC_TRY_COMPILE(
 299 [#ifdef HAVE_LIMITS_H
 300 #include <limits.h>
 301 #endif
 302 #ifndef CHAR_BIT
 303 #define CHAR_BIT 8
 304 #endif],
 305 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 306 liberty_cv_uint64="unsigned long",
 307 [AC_TRY_COMPILE(
 308 [#ifdef HAVE_LIMITS_H
 309 #include <limits.h>
 310 #endif
 311 #ifndef CHAR_BIT
 312 #define CHAR_BIT 8
 313 #endif],
 314 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 315 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 316 AC_MSG_RESULT($liberty_cv_uint64)
 317 if test "$liberty_cv_uint64" != none; then
 318   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 319                      [Define to an unsigned 64-bit type available in the compiler.])
 320 fi
 321
 322 AC_TYPE_INTPTR_T
 323 AC_TYPE_UINTPTR_T
 324 AC_TYPE_SSIZE_T
 325
 326 # Given the above check, we always have uintptr_t or a fallback
 327 # definition.  So define HAVE_UINTPTR_T in case any imported code
 328 # relies on it.
 329 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 330
 331 AC_TYPE_PID_T
 332
 333 # This is the list of functions which libiberty will provide if they
 334 # are not available on the host.
 335
 336 funcs="asprintf"
 337 funcs="$funcs atexit"
 338 funcs="$funcs basename"
 339 funcs="$funcs bcmp"
 340 funcs="$funcs bcopy"
 341 funcs="$funcs bsearch"
 342 funcs="$funcs bzero"
 343 funcs="$funcs calloc"
 344 funcs="$funcs clock"
 345 funcs="$funcs ffs"
 346 funcs="$funcs getcwd"
 347 funcs="$funcs getpagesize"
 348 funcs="$funcs gettimeofday"
 349 funcs="$funcs index"
 350 funcs="$funcs insque"
 351 funcs="$funcs memchr"
 352 funcs="$funcs memcmp"
 353 funcs="$funcs memcpy"
 354 funcs="$funcs memmem"
 355 funcs="$funcs memmove"
 356 funcs="$funcs mempcpy"
 357 funcs="$funcs memset"
 358 funcs="$funcs mkstemps"
 359 funcs="$funcs putenv"
 360 funcs="$funcs random"
 361 funcs="$funcs rename"
 362 funcs="$funcs rindex"
 363 funcs="$funcs setenv"
 364 funcs="$funcs snprintf"
 365 funcs="$funcs sigsetmask"
 366 funcs="$funcs stpcpy"
 367 funcs="$funcs stpncpy"
 368 funcs="$funcs strcasecmp"
 369 funcs="$funcs strchr"
 370 funcs="$funcs strdup"
 371 funcs="$funcs strncasecmp"
 372 funcs="$funcs strndup"
 373 funcs="$funcs strnlen"
 374 funcs="$funcs strrchr"
 375 funcs="$funcs strstr"
 376 funcs="$funcs strtod"
 377 funcs="$funcs strtol"
 378 funcs="$funcs strtoul"
 379 funcs="$funcs strtoll"
 380 funcs="$funcs strtoull"
 381 funcs="$funcs strverscmp"
 382 funcs="$funcs tmpnam"
 383 funcs="$funcs vasprintf"
 384 funcs="$funcs vfprintf"
 385 funcs="$funcs vprintf"
 386 funcs="$funcs vsnprintf"
 387 funcs="$funcs vsprintf"
 388 funcs="$funcs waitpid"
 389 funcs="$funcs setproctitle"
 390
 391 # Also in the old function.def file: alloca, vfork, getopt.
 392
 393 vars="sys_errlist sys_nerr sys_siglist"
 394
 395 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 396  getsysinfo gettimeofday on_exit pipe2 psignal pstat_getdynamic pstat_getstatic \
 397  realpath setrlimit sbrk spawnve spawnvpe strerror strsignal sysconf sysctl \
 398  sysmp table times wait3 wait4"
 399
 400 # These are neither executed nor required, but they help keep
 401 # autoheader happy without adding a bunch of text to acconfig.h.
 402 if test "x" = "y"; then
 403   AC_CHECK_FUNCS(asprintf atexit \
 404     basename bcmp bcopy bsearch bzero \
 405     calloc canonicalize_file_name clock \
 406     dup3 \
 407     ffs __fsetlocking \
 408     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 409     index insque \
 410     memchr memcmp memcpy memmem memmove memset mkstemps \
 411     on_exit \
 412     pipe2 psignal pstat_getdynamic pstat_getstatic putenv \
 413     random realpath rename rindex \
 414     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 415      stpcpy stpncpy strcasecmp strchr strdup \
 416      strerror strncasecmp strndup strnlen strrchr strsignal strstr strtod \
 417      strtol strtoul strtoll strtoull strverscmp sysconf sysctl sysmp \
 418     table times tmpnam \
 419     vasprintf vfprintf vprintf vsprintf \
 420     wait3 wait4 waitpid)
 421   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf, strtol, strtoul, strtoll, strtoull, strnlen])
 422   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 423   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 424   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 425 fi
 426
 427 # For each of these functions, if the host does not provide the
 428 # function we want to put FN.o in LIBOBJS, and if the host does
 429 # provide the function, we want to define HAVE_FN in config.h.
 430
 431 setobjs=
 432 CHECK=
 433 if test -n "${with_target_subdir}"; then
 434
 435   # We are being configured as a target library.  AC_REPLACE_FUNCS
 436   # may not work correctly, because the compiler may not be able to
 437   # link executables.  Note that we may still be being configured
 438   # native.
 439
 440   # If we are being configured for newlib, we know which functions
 441   # newlib provide and which ones we will be expected to provide.
 442
 443   if test "x${with_newlib}" = "xyes"; then
 444     AC_LIBOBJ([asprintf])
 445     AC_LIBOBJ([basename])
 446     AC_LIBOBJ([insque])
 447     AC_LIBOBJ([random])
 448     AC_LIBOBJ([strdup])
 449     AC_LIBOBJ([vasprintf])
 450
 451     for f in $funcs; do
 452       case "$f" in
 453         asprintf | basename | insque | random | strdup | vasprintf)
 454           ;;
 455         *)
 456           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 457           AC_DEFINE_UNQUOTED($n)
 458           ;;
 459       esac
 460     done
 461
 462     # newlib doesnt provide any of the variables in $vars, so we
 463     # dont have to check them here.
 464
 465     # Of the functions in $checkfuncs, newlib only has strerror.
 466     AC_DEFINE(HAVE_STRERROR)
 467
 468     setobjs=yes
 469
 470   fi
 471
 472   # If we are being configured for Mingw, we know which functions
 473   # Mingw provides and which ones we will be expected to provide.
 474
 475   case "${host}" in
 476   *-*-mingw*)
 477     AC_LIBOBJ([asprintf])
 478     AC_LIBOBJ([basename])
 479     AC_LIBOBJ([bcmp])
 480     AC_LIBOBJ([bcopy])
 481     AC_LIBOBJ([bzero])
 482     AC_LIBOBJ([clock])
 483     AC_LIBOBJ([ffs])
 484     AC_LIBOBJ([getpagesize])
 485     AC_LIBOBJ([index])
 486     AC_LIBOBJ([insque])
 487     AC_LIBOBJ([mempcpy])
 488     AC_LIBOBJ([mkstemps])
 489     AC_LIBOBJ([random])
 490     AC_LIBOBJ([rindex])
 491     AC_LIBOBJ([sigsetmask])
 492     AC_LIBOBJ([stpcpy])
 493     AC_LIBOBJ([stpncpy])
 494     AC_LIBOBJ([strndup])
 495     AC_LIBOBJ([strnlen])
 496     AC_LIBOBJ([strverscmp])
 497     AC_LIBOBJ([vasprintf])
 498     AC_LIBOBJ([waitpid])
 499
 500     for f in $funcs; do
 501       case "$f" in
 502         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strnlen | strverscmp | vasprintf | waitpid)
 503           ;;
 504         *)
 505           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 506           AC_DEFINE_UNQUOTED($n)
 507           ;;
 508       esac
 509     done
 510
 511     # Mingw doesnt provide any of the variables in $vars, so we
 512     # dont have to check them here.
 513
 514     # Of the functions in $checkfuncs, Mingw only has strerror.
 515     AC_DEFINE(HAVE_STRERROR)
 516
 517     setobjs=yes
 518     ;;
 519
 520   *-*-msdosdjgpp)
 521     AC_LIBOBJ([vasprintf])
 522     AC_LIBOBJ([vsnprintf])
 523     AC_LIBOBJ([snprintf])
 524     AC_LIBOBJ([asprintf])
 525
 526     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 527              getcwd getpagesize getrusage gettimeofday \
 528              index insque memchr memcmp memcpy memmove memset psignal \
 529              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 530              strchr strdup strerror strncasecmp strrchr strstr strtod \
 531              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 532              vsprintf waitpid
 533     do
 534       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 535       AC_DEFINE_UNQUOTED($n)
 536     done
 537
 538
 539     setobjs=yes
 540     ;;
 541
 542   esac
 543
 544 else
 545
 546    # Not a target library, so we set things up to run the test suite.
 547    CHECK=really-check
 548
 549 fi
 550
 551 AC_SUBST(CHECK)
 552 AC_SUBST(target_header_dir)
 553
 554 case "${host}" in
 555   *-*-cygwin* | *-*-mingw*)
 556     AC_DEFINE(HAVE_SYS_ERRLIST)
 557     AC_DEFINE(HAVE_SYS_NERR)
 558     ;;
 559 esac
 560
 561 if test -z "${setobjs}"; then
 562   case "${host}" in
 563
 564   *-*-vxworks*)
 565     # Handle VxWorks configuration specially, since on VxWorks the
 566     # libraries are actually on the target board, not in the file
 567     # system.
 568     AC_LIBOBJ([basename])
 569     AC_LIBOBJ([getpagesize])
 570     AC_LIBOBJ([insque])
 571     AC_LIBOBJ([random])
 572     AC_LIBOBJ([strcasecmp])
 573     AC_LIBOBJ([strncasecmp])
 574     AC_LIBOBJ([strdup])
 575     AC_LIBOBJ([vfork])
 576     AC_LIBOBJ([waitpid])
 577     AC_LIBOBJ([vasprintf])
 578     for f in $funcs; do
 579       case "$f" in
 580         basename | getpagesize | insque | random | strcasecmp)
 581           ;;
 582         strncasecmp | strdup | vfork | waitpid | vasprintf)
 583           ;;
 584         *)
 585           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 586           AC_DEFINE_UNQUOTED($n)
 587           ;;
 588       esac
 589     done
 590
 591     # VxWorks doesn't provide any of the variables in $vars, so we
 592     # don't have to check them here.
 593
 594     # Of the functions in $checkfuncs, VxWorks only has strerror.
 595     AC_DEFINE(HAVE_STRERROR)
 596
 597     setobjs=yes
 598     ;;
 599
 600   esac
 601 fi
 602
 603 if test -z "${setobjs}"; then
 604
 605   case "${host}" in
 606
 607   *-*-android*)
 608     # On android, getpagesize is defined in unistd.h as a static inline
 609     # function, which AC_CHECK_FUNCS does not handle properly.
 610     ac_cv_func_getpagesize=yes
 611     ;;
 612
 613   *-*-mingw32*)
 614     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 615     # macros, so the test below won't find them.
 616     libiberty_cv_var_sys_nerr=yes
 617     libiberty_cv_var_sys_errlist=yes
 618     ;;
 619
 620   *-*-msdosdjgpp*)
 621     # vfork and fork are stubs.
 622     ac_cv_func_vfork_works=no
 623     ;;
 624
 625   *-*-uwin*)
 626     # Under some versions of uwin, vfork is notoriously buggy and the test
 627     # can hang configure; on other versions, vfork exists just as a stub.
 628     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 629     ac_cv_func_vfork_works=no
 630     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 631     # macros (actually, these are imported from a DLL, but the end effect
 632     # is the same), so the test below won't find them.
 633     libiberty_cv_var_sys_nerr=yes
 634     libiberty_cv_var_sys_errlist=yes
 635     ;;
 636
 637   *-*-*vms*)
 638     # Under VMS, vfork works very different than on Unix. The standard test
 639     # won't work, and it isn't easily adaptable. It makes more sense to
 640     # just force it.
 641     ac_cv_func_vfork_works=yes
 642     ;;
 643
 644   esac
 645
 646   # We haven't set the list of objects yet.  Use the standard autoconf
 647   # tests.  This will only work if the compiler works.
 648   AC_ISC_POSIX
 649   AC_REPLACE_FUNCS($funcs)
 650   libiberty_AC_FUNC_C_ALLOCA
 651   AC_FUNC_FORK
 652   if test $ac_cv_func_vfork_works = no; then
 653     AC_LIBOBJ([vfork])
 654   fi
 655   # We only need _doprnt if we might use it to implement v*printf.
 656   if test $ac_cv_func_vprintf != yes \
 657      || test $ac_cv_func_vfprintf != yes \
 658      || test $ac_cv_func_vsprintf != yes; then
 659     AC_REPLACE_FUNCS(_doprnt)
 660   else
 661     AC_CHECK_FUNCS(_doprnt)
 662   fi
 663
 664   for v in $vars; do
 665     AC_MSG_CHECKING([for $v])
 666     AC_CACHE_VAL(libiberty_cv_var_$v,
 667       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 668                       [eval "libiberty_cv_var_$v=yes"],
 669                       [eval "libiberty_cv_var_$v=no"])])
 670     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 671       AC_MSG_RESULT(yes)
 672       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 673       AC_DEFINE_UNQUOTED($n)
 674     else
 675       AC_MSG_RESULT(no)
 676     fi
 677   done
 678
 679   # special check for _system_configuration because AIX <4.3.2 do not
 680   # contain the `physmem' member.
 681   AC_MSG_CHECKING([for external symbol _system_configuration])
 682   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 683                         [[double x = _system_configuration.physmem;]])],
 684     [AC_MSG_RESULT([yes])
 685     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 686               [Define if you have the _system_configuration variable.])],
 687     [AC_MSG_RESULT([no])])
 688
 689   AC_CHECK_FUNCS($checkfuncs)
 690   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 691   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 692   AC_CHECK_DECLS([strtol, strtoul, strtoll, strtoull])
 693   AC_CHECK_DECLS([strverscmp])
 694   AC_CHECK_DECLS([strnlen])
 695   libiberty_NEED_DECLARATION(canonicalize_file_name)
 696 fi
 697
 698 # Figure out which version of pexecute to use.
 699 case "${host}" in
 700      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 701      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 702      *-*-msdos*)                pexecute=pex-msdos  ;;
 703      *)                         pexecute=pex-unix   ;;
 704 esac
 705 AC_SUBST(pexecute)
 706
 707 libiberty_AC_FUNC_STRNCMP
 708
 709 # Install a library built with a cross compiler in $(tooldir) rather
 710 # than $(libdir).
 711 if test -z "${with_cross_host}"; then
 712   INSTALL_DEST=libdir
 713 else
 714   INSTALL_DEST=tooldir
 715 fi
 716 AC_SUBST(INSTALL_DEST)
 717
 718 m4_pattern_allow(LIBOBJS)
 719 L=""
 720 for l in x $LIBOBJS; do
 721   case $l in
 722     x) ;;
 723     *) L="$L ./$l" ;;
 724   esac
 725 done
 726 LIBOBJS="$L"
 727
 728 dnl Required by html and install-html
 729 AC_SUBST(datarootdir)
 730 AC_SUBST(docdir)
 731 AC_SUBST(htmldir)
 732
 733 # We need multilib support, but only if configuring for the target.
 734 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 735 AC_CONFIG_COMMANDS([default],
 736   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 737 if test -n "$CONFIG_FILES"; then
 738   if test -n "${with_target_subdir}"; then
 739     # FIXME: We shouldn't need to set ac_file
 740     ac_file=Makefile
 741     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 742     . ${libiberty_topdir}/config-ml.in
 743   fi
 744 fi]],
 745 [[srcdir=${srcdir}
 746 host=${host}
 747 target=${target}
 748 with_target_subdir=${with_target_subdir}
 749 with_multisubdir=${with_multisubdir}
 750 ac_configure_args="--enable-multilib ${ac_configure_args}"
 751 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 752 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 753 libiberty_topdir=${libiberty_topdir}
 754 ]])
 755 AC_OUTPUT