libstdc++-v3/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT(package-unused, version-unused,, libstdc++)
   6 AC_CONFIG_SRCDIR(src/ios.cc)
   7 AC_CONFIG_HEADER(config.h)
   8
   9 # This works around the fact that libtool configuration may change LD
  10 # for this particular configuration, but some shells, instead of
  11 # keeping the changes in LD private, export them just because LD is
  12 # exported.  Only used at the end of this file.
  13 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  14
  15 # For libtool versioning info, format is CURRENT:REVISION:AGE
  16 libtool_VERSION=6:2:0
  17 AC_SUBST(libtool_VERSION)
  18
  19 # Find the rest of the source tree framework.
  20 AM_ENABLE_MULTILIB(, ..)
  21
  22 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  23 #
  24 # You will slowly go insane if you do not grok the following fact:  when
  25 # building v3 as part of the compiler, the top-level /target/ becomes the
  26 # library's /host/.  configure then causes --target to default to --host,
  27 # exactly like any other package using autoconf.  Therefore, 'target' and
  28 # 'host' will always be the same.  This makes sense both for native and
  29 # cross compilers, just think about it for a little while.  :-)
  30 #
  31 # Also, if v3 is being configured as part of a cross compiler, the top-level
  32 # configure script will pass the "real" host as $with_cross_host.
  33 #
  34 # Do not delete or change the following two lines.  For why, see
  35 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  36 AC_CANONICAL_SYSTEM
  37 target_alias=${target_alias-$host_alias}
  38
  39 # Handy for debugging:
  40 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  41
  42 if test "$build" != "$host"; then
  43   # We are being configured with some form of cross compiler.
  44   GLIBCXX_IS_NATIVE=false
  45   GCC_NO_EXECUTABLES
  46 else
  47   GLIBCXX_IS_NATIVE=true
  48 fi
  49
  50 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  51 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  52 #  1.x:  minimum required version
  53 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  54 #              of other PACKAGE_* variables will, however, and there's nothing
  55 #              we can do about that; they come from AC_INIT).
  56 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  57 #            file in the top srcdir, etc, etc), so stop complaining.
  58 #  no-dependencies:  turns off auto dependency generation (just for now)
  59 #  -Wall:  turns on all automake warnings...
  60 #  -Wno-portability:  ...except this one, since GNU make is now required.
  61 AM_INIT_AUTOMAKE([1.7.6 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  62
  63 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  64 # up critical shell variables.
  65 GLIBCXX_CONFIGURE
  66
  67 #AC_MSG_NOTICE([====== Starting libtool configuration])
  68 AC_LIBTOOL_DLOPEN
  69 AM_PROG_LIBTOOL
  70 AC_SUBST(enable_shared)
  71 AC_SUBST(enable_static)
  72 #AC_MSG_NOTICE([====== Finished libtool configuration]) ; sleep 10
  73
  74 # Possibly disable most of the library.
  75 ## XXX Consider skipping unncessary tests altogether in this case, rather
  76 ## than just ignoring the results.  Faster /and/ more correct, win win.
  77 GLIBCXX_ENABLE_HOSTED
  78
  79 # Check for support bits and g++ features that don't require linking.
  80 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  81 GLIBCXX_ENABLE_PCH($is_hosted)
  82
  83 # Enable all the variable C++ runtime options.
  84 # NB: C_MBCHAR must come early.
  85 GLIBCXX_ENABLE_CSTDIO
  86 GLIBCXX_ENABLE_CLOCALE
  87 GLIBCXX_ENABLE_ALLOCATOR
  88 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
  89 GLIBCXX_ENABLE_C_MBCHAR([yes])
  90 GLIBCXX_ENABLE_C99([yes])
  91 GLIBCXX_ENABLE_LONG_LONG([yes])
  92 GLIBCXX_ENABLE_THREADS
  93 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
  94 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
  95 GLIBCXX_ENABLE_DEBUG([no])
  96 GLIBCXX_ENABLE_CXX_FLAGS
  97
  98 # No surprises, no surprises...
  99 if test $atomicity_dir = cpu/generic ; then
 100   AC_MSG_WARN([No native atomic operations are provided for this platform.])
 101   if test $target_thread_file = single; then
 102     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
 103     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
 104   else
 105     AC_MSG_WARN([They will be faked using a mutex.])
 106     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
 107   fi
 108 fi
 109
 110
 111 if $GLIBCXX_IS_NATIVE; then
 112
 113   # We can do more elaborate tests that assume a working linker.
 114   CANADIAN=no
 115
 116   # Check for available headers.
 117   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 118   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 119   sys/types.h])
 120
 121   GLIBCXX_CHECK_COMPILER_FEATURES
 122   GLIBCXX_CHECK_LINKER_FEATURES
 123   GLIBCXX_CHECK_MATH_SUPPORT
 124   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 125   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 126   GLIBCXX_CHECK_WCHAR_T_SUPPORT
 127   GLIBCXX_CHECK_STDLIB_SUPPORT
 128
 129   # For showmanyc_helper().
 130   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 131   GLIBCXX_CHECK_POLL
 132   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 133
 134   # For xsputn_2().
 135   AC_CHECK_HEADERS(sys/uio.h)
 136   GLIBCXX_CHECK_WRITEV
 137
 138   # For the __streamoff_base_type typedef.
 139   GLIBCXX_CHECK_INT64_T
 140
 141   # For LFS support.
 142   GLIBCXX_CHECK_LFS
 143
 144   AC_LC_MESSAGES
 145
 146   AC_TRY_COMPILE(
 147     [#include <setjmp.h>],
 148     [sigjmp_buf env;
 149      while (! sigsetjmp (env, 1))
 150        siglongjmp (env, 1);
 151     ],
 152     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 153
 154   AC_FUNC_MMAP
 155
 156 else
 157
 158   # This lets us hard-code the functionality we know we'll have in the cross
 159   # target environment.  "Let" is a sugar-coated word placed on an especially
 160   # dull and tedious hack, actually.
 161   #
 162   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 163   # that involve linking, can't be used:
 164   #    "cannot open sim-crt0.o"
 165   #    "cannot open crt0.o"
 166   # etc.  All this is because there currently exists no unified, consistent
 167   # way for top level CC information to be passed down to target directories:
 168   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 169   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 170   # crosses can be removed.
 171
 172   # If Canadian cross, then don't pick up tools from the build directory.
 173   # Used only in GLIBCXX_EXPORT_INCLUDES.
 174   if test -n "$with_cross_host" &&
 175      test x"$build_alias" != x"$with_cross_host" &&
 176      test x"$build" != x"$target";
 177   then
 178     CANADIAN=yes
 179   else
 180     CANADIAN=no
 181   fi
 182
 183   # Construct crosses by hand, eliminating bits that need ld...
 184   # GLIBCXX_CHECK_COMPILER_FEATURES
 185   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 186   # GLIBCXX_CHECK_MATH_SUPPORT
 187
 188   # First, test for "known" system libraries.  We may be using newlib even
 189   # on a hosted environment.
 190   if test "x${with_newlib}" = "xyes"; then
 191     os_include_dir="os/newlib"
 192     AC_DEFINE(HAVE_HYPOT)
 193
 194     # GLIBCXX_CHECK_STDLIB_SUPPORT
 195     AC_DEFINE(HAVE_STRTOF)
 196     AC_DEFINE(HAVE_STRTOLD)
 197     # AC_FUNC_MMAP
 198     AC_DEFINE(HAVE_MMAP)
 199
 200     AC_DEFINE(HAVE_ACOSF)
 201     AC_DEFINE(HAVE_ASINF)
 202     AC_DEFINE(HAVE_ATAN2F)
 203     AC_DEFINE(HAVE_ATANF)
 204     AC_DEFINE(HAVE_CEILF)
 205     AC_DEFINE(HAVE_COPYSIGN)
 206     AC_DEFINE(HAVE_COPYSIGNF)
 207     AC_DEFINE(HAVE_COSF)
 208     AC_DEFINE(HAVE_COSHF)
 209     AC_DEFINE(HAVE_EXPF)
 210     AC_DEFINE(HAVE_FABSF)
 211     AC_DEFINE(HAVE_FLOORF)
 212     AC_DEFINE(HAVE_FMODF)
 213     AC_DEFINE(HAVE_FREXPF)
 214     AC_DEFINE(HAVE_LDEXPF)
 215     AC_DEFINE(HAVE_LOG10F)
 216     AC_DEFINE(HAVE_LOGF)
 217     AC_DEFINE(HAVE_MODFF)
 218     AC_DEFINE(HAVE_POWF)
 219     AC_DEFINE(HAVE_SINF)
 220     AC_DEFINE(HAVE_SINHF)
 221     AC_DEFINE(HAVE_SQRTF)
 222     AC_DEFINE(HAVE_TANF)
 223     AC_DEFINE(HAVE_TANHF)
 224
 225     AC_DEFINE(HAVE_S_ISREG)
 226     AC_DEFINE(HAVE_S_IFREG)
 227   else
 228     m4_include([crossconfig.m4])
 229   fi
 230
 231   # At some point, we should differentiate between architectures
 232   # like x86, which have long double versions, and alpha/powerpc/etc.,
 233   # which don't. For the time being, punt.
 234   if test x"long_double_math_on_this_cpu" = x"yes"; then
 235     AC_DEFINE(HAVE_ACOSL)
 236     AC_DEFINE(HAVE_ASINL)
 237     AC_DEFINE(HAVE_ATAN2L)
 238     AC_DEFINE(HAVE_ATANL)
 239     AC_DEFINE(HAVE_CEILL)
 240     AC_DEFINE(HAVE_COPYSIGNL)
 241     AC_DEFINE(HAVE_COSL)
 242     AC_DEFINE(HAVE_COSHL)
 243     AC_DEFINE(HAVE_EXPL)
 244     AC_DEFINE(HAVE_FABSL)
 245     AC_DEFINE(HAVE_FLOORL)
 246     AC_DEFINE(HAVE_FMODL)
 247     AC_DEFINE(HAVE_FREXPL)
 248     AC_DEFINE(HAVE_LDEXPL)
 249     AC_DEFINE(HAVE_LOG10L)
 250     AC_DEFINE(HAVE_LOGL)
 251     AC_DEFINE(HAVE_MODFL)
 252     AC_DEFINE(HAVE_POWL)
 253     AC_DEFINE(HAVE_SINCOSL)
 254     AC_DEFINE(HAVE_SINL)
 255     AC_DEFINE(HAVE_SINHL)
 256     AC_DEFINE(HAVE_SQRTL)
 257     AC_DEFINE(HAVE_TANL)
 258     AC_DEFINE(HAVE_TANHL)
 259   fi
 260
 261 fi
 262
 263 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 264 GLIBCXX_ENABLE_SYMVERS([yes])
 265
 266 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 267 GLIBCXX_CONFIGURE_TESTSUITE
 268
 269 # Propagate the target-specific source directories through the build chain.
 270 ATOMICITY_SRCDIR=config/${atomicity_dir}
 271 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 272 OS_INC_SRCDIR=config/${os_include_dir}
 273 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 274 AC_SUBST(ATOMICITY_SRCDIR)
 275 AC_SUBST(ATOMIC_WORD_SRCDIR)
 276 AC_SUBST(ABI_TWEAKS_SRCDIR)
 277 AC_SUBST(OS_INC_SRCDIR)
 278
 279 # Determine cross-compile flags and AM_CONDITIONALs.
 280 #AC_SUBST(GLIBCXX_IS_NATIVE)
 281 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 282 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 283 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 284 GLIBCXX_EVALUATE_CONDITIONALS
 285
 286 AC_CACHE_SAVE
 287
 288 if test ${multilib} = yes; then
 289   multilib_arg="--enable-multilib"
 290 else
 291   multilib_arg=
 292 fi
 293
 294 # Export all the install information.
 295 GLIBCXX_EXPORT_INSTALL_INFO
 296
 297 # Export all the include and flag information to Makefiles.
 298 GLIBCXX_EXPORT_INCLUDES
 299 GLIBCXX_EXPORT_FLAGS
 300
 301 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
 302    grep "enable shared" > /dev/null;
 303 then
 304   LIBSUPCXX_PICFLAGS=-prefer-pic
 305 else
 306   LIBSUPCXX_PICFLAGS=
 307 fi
 308 AC_SUBST(LIBSUPCXX_PICFLAGS)
 309
 310 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 311 dnl which can all be called multiple times as needed, plus one (different)
 312 dnl AC_OUTPUT macro.  This one lists the files to be created:
 313 AC_CONFIG_FILES( \
 314   Makefile \
 315   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 316   )
 317 AC_CONFIG_FILES([scripts/check_survey],[chmod +x scripts/check_survey])
 318 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 319
 320 dnl These commands are run at the end of config.status:
 321 AC_CONFIG_COMMANDS([default],
 322 [if test -n "$CONFIG_FILES"; then
 323    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 324    # that multilib installs will end up installed in the correct place.
 325    # The testsuite needs it for multilib-aware ABI baseline files.
 326    # To work around this not being passed down from config-ml.in ->
 327    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 328    # append it here.  Only modify Makefiles that have just been created.
 329    #
 330    # Also, get rid of this simulated-VPATH thing that automake does.
 331    cat > vpsed << \_EOF
 332 s!`test -f '$<' || echo '$(srcdir)/'`!!
 333 _EOF
 334    for i in $SUBDIRS; do
 335     case $CONFIG_FILES in
 336      *${i}/Makefile*)
 337        #echo "Adding MULTISUBDIR to $i/Makefile"
 338        sed -f vpsed $i/Makefile > tmp
 339        grep '^MULTISUBDIR =' Makefile >> tmp
 340        mv tmp $i/Makefile
 341        ;;
 342     esac
 343    done
 344    rm vpsed
 345  fi
 346  (cd include && ${MAKE-make})
 347 ],
 348 [
 349 # Variables needed in config.status (file generation) which aren't already
 350 # passed by autoconf.
 351 SUBDIRS="$SUBDIRS"
 352 ])
 353
 354 dnl And this actually makes things happen:
 355 AC_OUTPUT