libcpp/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT(cpplib, [ ], gcc-bugs@gcc.gnu.org, cpplib)
   6 AC_CONFIG_SRCDIR(ucnid.h)
   7 AC_CANONICAL_SYSTEM
   8 AM_INIT_AUTOMAKE(foreign)
   9 AM_MAINTAINER_MODE
  10
  11 # Checks for programs.
  12 AC_PROG_CC
  13 AC_PROG_RANLIB
  14
  15 # Checks for header files.
  16 AC_HEADER_TIME
  17 ACX_HEADER_STRING
  18 AC_CHECK_HEADERS(iconv.h locale.h fcntl.h limits.h stddef.h \
  19         stdlib.h strings.h string.h sys/file.h unistd.h)
  20
  21 # Checks for typedefs, structures, and compiler characteristics.
  22 AC_C_CONST
  23 AC_C_INLINE
  24 AC_FUNC_OBSTACK
  25 AC_TYPE_OFF_T
  26 AC_TYPE_SIZE_T
  27 AC_STRUCT_TM
  28 AC_CHECK_SIZEOF(int)
  29 AC_CHECK_SIZEOF(long)
  30 AC_CHECK_FUNCS(putc_unlocked fputc_unlocked fputs_unlocked \
  31         fwrite_unlocked fprintf_unlocked)
  32 AC_CHECK_DECLS([abort, errno, putc_unlocked, fputc_unlocked,
  33         fputs_unlocked, fwrite_unlocked, fprintf_unlocked])
  34
  35 # Checks for library functions.
  36 AC_FUNC_ALLOCA
  37 AC_HEADER_STDC
  38 AM_LANGINFO_CODESET
  39 ZW_GNU_GETTEXT_SISTER_DIR
  40
  41 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
  42 [AC_TRY_COMPILE([
  43 #include "ansidecl.h"
  44 #include "system.h"
  45 ],
  46 [if ((uchar *)0) return 0;
  47  if (sizeof(uchar)) return 0;],
  48 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
  49 if test $ac_cv_type_uchar = yes; then
  50   AC_DEFINE(HAVE_UCHAR, 1,
  51   [Define if <sys/types.h> defines \`uchar'.])
  52 fi
  53
  54 AM_ICONV
  55 AM_CONDITIONAL(ENABLE_NLS, [test "x$enable_nls" != xno])
  56 AC_ARG_ENABLE(checking,
  57 [  --enable-checking      enable expensive run-time checks],,
  58 enable_checking=no)
  59
  60 if test $enable_checking != no ; then
  61   AC_DEFINE(ENABLE_CHECKING, 1,
  62 [Define if you want more run-time sanity checks.])
  63 fi
  64
  65 m4_changequote(,)
  66 case $target in
  67         alpha*-*-* | \
  68         x86_64-*-* | \
  69         ia64-*-* | \
  70         hppa*64*-*-* | parisc*64*-*-* | \
  71         mips*-*-* | \
  72         mmix-*-* | \
  73         powerpc*-*-* | \
  74         rs6000*-*-* | \
  75         s390*-*-* | \
  76         sparc64*-*-* | ultrasparc-*-freebsd* | \
  77         sparcv9-*-solaris2* | \
  78         sparc-*-solaris2.[789] | sparc-*-solaris2.1[0-9] | \
  79         sh[123456789l]*-*-*)
  80                 need_64bit_hwint=yes ;;
  81         *)
  82                 need_64bit_hwint=no ;;
  83 esac
  84
  85 case $need_64bit_hwint:$ac_cv_sizeof_long in
  86         *:8 | no:*) host_wide_int=long ;;
  87         *) host_wide_int='long long' ;;
  88 esac
  89 m4_changequote([,])
  90
  91 AC_DEFINE_UNQUOTED(HOST_WIDE_INT, $host_wide_int,
  92 [Define to the widest efficient host integer type at least
  93    as wide as the target's size_t type.])
  94
  95 AC_CONFIG_HEADERS(config.h:config.in)
  96 AC_CONFIG_FILES(Makefile)
  97 AC_OUTPUT