gcc/ada/s-valuns.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                       S Y S T E M . V A L _ U N S                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --          Copyright (C) 1992-1997 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 with System.Unsigned_Types; use System.Unsigned_Types;
  36 with System.Val_Util;       use System.Val_Util;
  37
  38 package body System.Val_Uns is
  39
  40    -------------------
  41    -- Scan_Unsigned --
  42    -------------------
  43
  44    function Scan_Unsigned
  45      (Str  : String;
  46       Ptr  : access Integer;
  47       Max  : Integer)
  48       return Unsigned
  49    is
  50       P : Integer;
  51       --  Local copy of the pointer
  52
  53       Uval : Unsigned;
  54       --  Accumulated unsigned integer result
  55
  56       Expon : Integer;
  57       --  Exponent value
  58
  59       Minus : Boolean := False;
  60       --  Set to True if minus sign is present, otherwise to False. Note that
  61       --  a minus sign is permissible for the singular case of -0, and in any
  62       --  case the pointer is left pointing past a negative integer literal.
  63
  64       Overflow : Boolean := False;
  65       --  Set True if overflow is detected at any point
  66
  67       Start : Positive;
  68       --  Save location of first non-blank character
  69
  70       Base_Char : Character;
  71       --  Base character (# or :) in based case
  72
  73       Base : Unsigned := 10;
  74       --  Base value (reset in based case)
  75
  76       Digit : Unsigned;
  77       --  Digit value
  78
  79    begin
  80       Scan_Sign (Str, Ptr, Max, Minus, Start);
  81
  82       if Str (Ptr.all) not in '0' .. '9' then
  83          Ptr.all := Start;
  84          raise Constraint_Error;
  85       end if;
  86
  87       P := Ptr.all;
  88       Uval := Character'Pos (Str (P)) - Character'Pos ('0');
  89       P := P + 1;
  90
  91       --  Scan out digits of what is either the number or the base.
  92       --  In either case, we are definitely scanning out in base 10.
  93
  94       declare
  95          Umax : constant := (Unsigned'Last - 9) / 10;
  96          --  Max value which cannot overflow on accumulating next digit
  97
  98          Umax10 : constant := Unsigned'Last / 10;
  99          --  Numbers bigger than Umax10 overflow if multiplied by 10
 100
 101       begin
 102          --  Loop through decimal digits
 103          loop
 104             exit when P > Max;
 105
 106             Digit := Character'Pos (Str (P)) - Character'Pos ('0');
 107
 108             --  Non-digit encountered
 109
 110             if Digit > 9 then
 111                if Str (P) = '_' then
 112                   Scan_Underscore (Str, P, Ptr, Max, False);
 113                else
 114                   exit;
 115                end if;
 116
 117             --  Accumulate result, checking for overflow
 118
 119             else
 120                if Uval <= Umax then
 121                   Uval := 10 * Uval + Digit;
 122
 123                elsif Uval > Umax10 then
 124                   Overflow := True;
 125
 126                else
 127                   Uval := 10 * Uval + Digit;
 128
 129                   if Uval < Umax10 then
 130                      Overflow := True;
 131                   end if;
 132                end if;
 133
 134                P := P + 1;
 135             end if;
 136          end loop;
 137       end;
 138
 139       Ptr.all := P;
 140
 141       --  Deal with based case
 142
 143       if P < Max and then (Str (P) = ':' or else Str (P) = '#') then
 144          Base_Char := Str (P);
 145          P := P + 1;
 146          Base := Uval;
 147          Uval := 0;
 148
 149          --  Check base value. Overflow is set True if we find a bad base, or
 150          --  a digit that is out of range of the base. That way, we scan out
 151          --  the numeral that is still syntactically correct, though illegal.
 152          --  We use a safe base of 16 for this scan, to avoid zero divide.
 153
 154          if Base not in 2 .. 16 then
 155             Overflow := True;
 156             Base :=  16;
 157          end if;
 158
 159          --  Scan out based integer
 160
 161          declare
 162             Umax : constant Unsigned := (Unsigned'Last - Base + 1) / Base;
 163             --  Max value which cannot overflow on accumulating next digit
 164
 165             UmaxB : constant Unsigned := Unsigned'Last / Base;
 166             --  Numbers bigger than UmaxB overflow if multiplied by base
 167
 168          begin
 169             --  Loop to scan out based integer value
 170
 171             loop
 172                --  We require a digit at this stage
 173
 174                if Str (P) in '0' .. '9' then
 175                   Digit := Character'Pos (Str (P)) - Character'Pos ('0');
 176
 177                elsif Str (P) in 'A' .. 'F' then
 178                   Digit :=
 179                     Character'Pos (Str (P)) - (Character'Pos ('A') - 10);
 180
 181                elsif Str (P) in 'a' .. 'f' then
 182                   Digit :=
 183                     Character'Pos (Str (P)) - (Character'Pos ('a') - 10);
 184
 185                --  If we don't have a digit, then this is not a based number
 186                --  after all, so we use the value we scanned out as the base
 187                --  (now in Base), and the pointer to the base character was
 188                --  already stored in Ptr.all.
 189
 190                else
 191                   Uval := Base;
 192                   exit;
 193                end if;
 194
 195                --  If digit is too large, just signal overflow and continue.
 196                --  The idea here is to keep scanning as long as the input is
 197                --  syntactically valid, even if we have detected overflow
 198
 199                if Digit >= Base then
 200                   Overflow := True;
 201
 202                --  Here we accumulate the value, checking overflow
 203
 204                elsif Uval <= Umax then
 205                   Uval := Base * Uval + Digit;
 206
 207                elsif Uval > UmaxB then
 208                   Overflow := True;
 209
 210                else
 211                   Uval := Base * Uval + Digit;
 212
 213                   if Uval < UmaxB then
 214                      Overflow := True;
 215                   end if;
 216                end if;
 217
 218                --  If at end of string with no base char, not a based number
 219                --  but we signal Constraint_Error and set the pointer past
 220                --  the end of the field, since this is what the ACVC tests
 221                --  seem to require, see CE3704N, line 204.
 222
 223                P := P + 1;
 224
 225                if P > Max then
 226                   Ptr.all := P;
 227                   raise Constraint_Error;
 228                end if;
 229
 230                --  If terminating base character, we are done with loop
 231
 232                if Str (P) = Base_Char then
 233                   Ptr.all := P + 1;
 234                   exit;
 235
 236                --  Deal with underscore
 237
 238                elsif Str (P) = '_' then
 239                   Scan_Underscore (Str, P, Ptr, Max, True);
 240                end if;
 241
 242             end loop;
 243          end;
 244       end if;
 245
 246       --  Come here with scanned unsigned value in Uval. The only remaining
 247       --  required step is to deal with exponent if one is present.
 248
 249       Expon := Scan_Exponent (Str, Ptr, Max);
 250
 251       if Expon /= 0 and then Uval /= 0 then
 252
 253          --  For non-zero value, scale by exponent value. No need to do this
 254          --  efficiently, since use of exponent in integer literals is rare,
 255          --  and in any case the exponent cannot be very large.
 256
 257          declare
 258             UmaxB : constant Unsigned := Unsigned'Last / Base;
 259             --  Numbers bigger than UmaxB overflow if multiplied by base
 260
 261          begin
 262             for J in 1 .. Expon loop
 263                if Uval > UmaxB then
 264                   Overflow := True;
 265                   exit;
 266                end if;
 267
 268                Uval := Uval * Base;
 269             end loop;
 270          end;
 271       end if;
 272
 273       --  Return result, dealing with sign and overflow
 274
 275       if Overflow or else (Minus and then Uval /= 0) then
 276          raise Constraint_Error;
 277       else
 278          return Uval;
 279       end if;
 280    end Scan_Unsigned;
 281
 282    --------------------
 283    -- Value_Unsigned --
 284    --------------------
 285
 286    function Value_Unsigned (Str : String) return Unsigned is
 287       V : Unsigned;
 288       P : aliased Integer := Str'First;
 289
 290    begin
 291       V := Scan_Unsigned (Str, P'Access, Str'Last);
 292       Scan_Trailing_Blanks (Str, P);
 293       return V;
 294
 295    end Value_Unsigned;
 296
 297 end System.Val_Uns;