libquadmath/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal && autoconf && autoheader && automake
   3
   4 AC_INIT([GCC Quad-precision Math Library], 0.1,,[libquadmath])
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
   8 #
   9 # You will slowly go insane if you do not grok the following fact:  when
  10 # building this library, the top-level /target/ becomes the library's /host/.
  11 #
  12 # configure then causes --target to default to --host, exactly like any
  13 # other package using autoconf.  Therefore, 'target' and 'host' will
  14 # always be the same.  This makes sense both for native and cross compilers
  15 # just think about it for a little while.  :-)
  16 #
  17 # Also, if this library is being configured as part of a cross compiler, the
  18 # top-level configure script will pass the "real" host as $with_cross_host.
  19 #
  20 # Do not delete or change the following two lines.  For why, see
  21 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  22 AC_CANONICAL_SYSTEM
  23 ACX_NONCANONICAL_TARGET
  24
  25 AM_ENABLE_MULTILIB(, ..)
  26
  27 target_alias=${target_alias-$host_alias}
  28 AC_SUBST(target_alias)
  29
  30 AM_INIT_AUTOMAKE([1.9.0 foreign subdir-objects no-dist -Wall -Wno-override -Werror])
  31
  32 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  33 AC_ARG_ENABLE(version-specific-runtime-libs,
  34 AS_HELP_STRING([--enable-version-specific-runtime-libs],
  35  [specify that runtime libraries should be installed in a compiler-specific directory]),
  36 [case "$enableval" in
  37  yes) version_specific_libs=yes ;;
  38  no)  version_specific_libs=no ;;
  39  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  40  esac],
  41 [version_specific_libs=no])
  42 AC_MSG_RESULT($version_specific_libs)
  43
  44 GCC_NO_EXECUTABLES
  45
  46 AC_USE_SYSTEM_EXTENSIONS
  47
  48 # See if makeinfo has been installed and is modern enough
  49 # that we can use it.
  50 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
  51                    [GNU texinfo.* \([0-9][0-9.]*\)],
  52                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
  53 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
  54
  55 ACX_BUGURL([https://gcc.gnu.org/bugs/])
  56
  57 # Configure libtool
  58 AM_PROG_LIBTOOL
  59 ACX_LT_HOST_FLAGS
  60 AC_SUBST(enable_shared)
  61 AC_SUBST(enable_static)
  62
  63 AM_MAINTAINER_MODE
  64
  65 AC_LANG_C
  66 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  67 # We must force CC to /not/ be precious variables; otherwise
  68 # the wrong, non-multilib-adjusted value will be used in multilibs.
  69 # As a side effect, we have to subst CFLAGS ourselves.
  70
  71 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  72 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  73 AC_PROG_CC
  74 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  75
  76 AC_SUBST(CFLAGS)
  77
  78 AM_PROG_CC_C_O
  79
  80 if test "x$GCC" != "xyes"; then
  81   AC_MSG_ERROR([libquadmath must be built with GCC])
  82 fi
  83 AC_PROG_CPP
  84
  85 GCC_WITH_TOOLEXECLIBDIR
  86
  87 # Calculate toolexeclibdir
  88 # Also toolexecdir, though it's only used in toolexeclibdir
  89 case ${version_specific_libs} in
  90   yes)
  91     # Need the gcc compiler version to know where to install libraries
  92     # and header files if --enable-version-specific-runtime-libs option
  93     # is selected.
  94     toolexecdir='$(libdir)/gcc/$(target_alias)'
  95     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  96     ;;
  97   no)
  98     if test -n "$with_cross_host" &&
  99        test x"$with_cross_host" != x"no"; then
 100       # Install a library built with a cross compiler in tooldir, not libdir.
 101       toolexecdir='$(exec_prefix)/$(target_alias)'
 102       case ${with_toolexeclibdir} in
 103         no)
 104           toolexeclibdir='$(toolexecdir)/lib'
 105           ;;
 106         *)
 107           toolexeclibdir=${with_toolexeclibdir}
 108           ;;
 109       esac
 110     else
 111       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 112       toolexeclibdir='$(libdir)'
 113     fi
 114     multi_os_directory=`$CC -print-multi-os-directory`
 115     case $multi_os_directory in
 116       .) ;; # Avoid trailing /.
 117       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 118     esac
 119     ;;
 120 esac
 121 AC_SUBST(toolexecdir)
 122 AC_SUBST(toolexeclibdir)
 123
 124 AC_CHECK_HEADERS(fenv.h langinfo.h locale.h wchar.h wctype.h limits.h ctype.h printf.h errno.h)
 125 LIBQUAD_CHECK_MATH_H_SIGNGAM
 126
 127 # If available, sqrtl and cbrtl speed up the calculation -
 128 # but they are not required
 129 if test x$gcc_no_link != xyes; then
 130   AC_CHECK_LIB([m],[sqrtl],[AC_DEFINE([HAVE_SQRTL],[1],[libm includes sqrtl])])
 131   AC_CHECK_LIB([m],[cbrtl],[AC_DEFINE([HAVE_CBRTL],[1],[libm includes cbrtl])])
 132   AC_CHECK_LIB([m],[feholdexcept],[AC_DEFINE([HAVE_FEHOLDEXCEPT],[1],[libm includes feholdexcept])])
 133   AC_CHECK_LIB([m],[fesetround],[AC_DEFINE([HAVE_FESETROUND],[1],[libm includes fesetround])])
 134   AC_CHECK_LIB([m],[feupdateenv],[AC_DEFINE([HAVE_FEUPDATEENV],[1],[libm includes feupdateenv])])
 135   AC_CHECK_LIB([m],[fesetenv],[AC_DEFINE([HAVE_FESETENV],[1],[libm includes fesetenv])])
 136   AC_CHECK_LIB([m],[fetestexcept],[AC_DEFINE([HAVE_FETESTEXCEPT],[1],[libm includes fetestexcept])])
 137   AC_CHECK_FUNCS(strtoull)
 138 else
 139   if test "x$ac_cv_lib_m_sqrtl" = x""yes; then
 140     AC_DEFINE([HAVE_SQRTL],[1],[libm includes sqrtl])
 141   fi
 142   if test "x$ac_cv_lib_m_cbrtl" = x""yes; then
 143     AC_DEFINE([HAVE_CBRTL],[1],[libm includes cbrtl])
 144   fi
 145   if test "x$ac_cv_lib_m_feholdexcept" = x""yes; then
 146     AC_DEFINE([HAVE_FEHOLDEXCEPT],[1],[libm includes feholdexcept])
 147   fi
 148   if test "x$ac_cv_lib_m_fesetround" = x""yes; then
 149     AC_DEFINE([HAVE_FESETROUND],[1],[libm includes fesetround])
 150   fi
 151   if test "x$ac_cv_lib_m_feupdateenv" = x""yes; then
 152     AC_DEFINE([HAVE_FEUPDATEENV],[1],[libm includes feupdateenv])
 153   fi
 154   if test "x$ac_cv_lib_m_fesetenv" = x""yes; then
 155     AC_DEFINE([HAVE_FESETENV],[1],[libm includes fesetenv])
 156   fi
 157   if test "x$ac_cv_lib_m_fetestexcept" = x""yes; then
 158     AC_DEFINE([HAVE_FETESTEXCEPT],[1],[libm includes fetestexcept])
 159   fi
 160 fi
 161
 162 # Check for hidden visibility (copied from libssp).
 163 saved_CFLAGS="$CFLAGS"
 164 CFLAGS="$CFLAGS -Werror"
 165 AC_MSG_CHECKING([whether hidden visibility is supported])
 166 AC_TRY_COMPILE([
 167 void __attribute__((visibility ("hidden"))) bar (void) {}],,
 168 [quadmath_hidden=yes],[quadmath_hidden=no])
 169 AC_MSG_RESULT($quadmath_hidden)
 170 if test x$quadmath_hidden = xyes; then
 171   AC_DEFINE([HAVE_HIDDEN_VISIBILITY],[1],[__attribute__((visibility ("hidden"))) supported])
 172 fi
 173 CFLAGS="$saved_CFLAGS"
 174
 175 # Check for symbol versioning (copied from libssp).
 176 AC_MSG_CHECKING([whether symbol versioning is supported])
 177 AC_ARG_ENABLE(symvers,
 178 AS_HELP_STRING([--disable-symvers],
 179   [disable symbol versioning for libquadmath]),
 180 quadmath_use_symver=$enableval,
 181 quadmath_use_symver=yes)
 182 if test "x$quadmath_use_symver" != xno; then
 183   if test x$gcc_no_link = xyes; then
 184     # If we cannot link, we cannot build shared libraries, so do not use
 185     # symbol versioning.
 186     quadmath_use_symver=no
 187   else
 188     save_LDFLAGS="$LDFLAGS"
 189     LDFLAGS="$LDFLAGS -fPIC -shared -Wl,--version-script,./conftest.map"
 190     cat > conftest.map <<EOF
 191 FOO_1.0 {
 192   global: *foo*; bar; local: *;
 193 };
 194 EOF
 195     AC_TRY_LINK([int foo;],[],[quadmath_use_symver=gnu],[quadmath_use_symver=no])
 196     if test x$quadmath_use_symver = xno; then
 197       case "$target_os" in
 198         solaris2*)
 199           LDFLAGS="$save_LDFLAGS"
 200           LDFLAGS="$LDFLAGS -fPIC -shared -Wl,-M,./conftest.map"
 201           # Sun ld cannot handle wildcards and treats all entries as undefined.
 202           cat > conftest.map <<EOF
 203 FOO_1.0 {
 204   global: foo; local: *;
 205 };
 206 EOF
 207           AC_TRY_LINK([int foo;],[],[quadmath_use_symver=sun],[quadmath_use_symver=no])
 208           ;;
 209       esac
 210     fi
 211     LDFLAGS="$save_LDFLAGS"
 212   fi
 213 fi
 214 AC_MSG_RESULT($quadmath_use_symver)
 215 AM_CONDITIONAL(LIBQUAD_USE_SYMVER, [test "x$quadmath_use_symver" != xno])
 216 AM_CONDITIONAL(LIBQUAD_USE_SYMVER_GNU, [test "x$quadmath_use_symver" = xgnu])
 217 AM_CONDITIONAL(LIBQUAD_USE_SYMVER_SUN, [test "x$quadmath_use_symver" = xsun])
 218
 219 AC_CACHE_CHECK([whether __float128 is supported], [libquad_cv_have_float128],
 220   [GCC_TRY_COMPILE_OR_LINK([
 221     #if (!defined(_ARCH_PPC)) || defined(__LONG_DOUBLE_IEEE128__)
 222     typedef _Complex float __attribute__((mode(TC))) __complex128;
 223     #else
 224     typedef _Complex float __attribute__((mode(KC))) __complex128;
 225     #endif
 226
 227     __float128 foo (__float128 x)
 228     {
 229
 230      __complex128 z1, z2;
 231
 232      z1 = x;
 233      z2 = x / 7.Q;
 234      z2 /= z1;
 235
 236      return (__float128) z2;
 237     }
 238
 239     __float128 bar (__float128 x)
 240     {
 241       return x * __builtin_huge_valq ();
 242     }
 243   ],[
 244     foo (1.2Q);
 245     bar (1.2Q);
 246   ],[
 247     libquad_cv_have_float128=yes
 248   ],[
 249     libquad_cv_have_float128=no
 250 ])])
 251 AM_CONDITIONAL(BUILD_LIBQUADMATH, [test "x$libquad_cv_have_float128" = xyes])
 252
 253 # Check for printf hook support.
 254 AC_MSG_CHECKING([whether printf hooks are supported])
 255 AC_TRY_COMPILE([
 256 #include <printf.h>
 257 #include <stdarg.h>
 258 #include <stdlib.h>
 259 extern void flt128_va (void *, va_list *);
 260 extern int flt128_ais (const struct printf_info *, size_t, int *, int *);
 261 extern int flt128_printf_fp (FILE *, const struct printf_info *, const void *const *);
 262 ],[
 263 int pa_flt128 = register_printf_type (flt128_va);
 264 int mod_Q = register_printf_modifier (L"Q");
 265 int res = register_printf_specifier ('f', flt128_printf_fp, flt128_ais);
 266 struct printf_info info = { .user = -1 };
 267 ],
 268 [quadmath_printf_hooks=yes],[quadmath_printf_hooks=no])
 269 AC_MSG_RESULT($quadmath_printf_hooks)
 270 if test x$quadmath_printf_hooks = xyes; then
 271   AC_DEFINE([HAVE_PRINTF_HOOKS],[1],[GNU C Library stype printf hooks supported])
 272 fi
 273
 274 # Check for whether locale support for quadmath_snprintf or Q printf hooks
 275 # should be provided.
 276 AC_MSG_CHECKING([whether nl_langinfo should be used])
 277 AC_TRY_COMPILE([#include <langinfo.h>],[
 278 const char *s;
 279 s = nl_langinfo (DECIMAL_POINT);
 280 s = nl_langinfo (MON_DECIMAL_POINT);
 281 s = nl_langinfo (GROUPING);
 282 s = nl_langinfo (MON_GROUPING);
 283 s = nl_langinfo (THOUSANDS_SEP);
 284 s = nl_langinfo (MON_THOUSANDS_SEP);
 285 (void) s;
 286 ],
 287 [quadmath_use_nl_langinfo=yes],[quadmath_use_nl_langinfo=no])
 288 AC_MSG_RESULT($quadmath_use_nl_langinfo)
 289 if test x$quadmath_use_nl_langinfo = xyes; then
 290   AC_DEFINE([USE_NL_LANGINFO],[1],[whether nl_langinfo should be used])
 291 fi
 292
 293 AC_MSG_CHECKING([whether nl_langinfo should be used for wide char locale info])
 294 AC_TRY_COMPILE([#include <langinfo.h>],[
 295 const char *s;
 296 s = nl_langinfo (_NL_NUMERIC_DECIMAL_POINT_WC);
 297 s = nl_langinfo (_NL_MONETARY_DECIMAL_POINT_WC);
 298 s = nl_langinfo (_NL_NUMERIC_THOUSANDS_SEP_WC);
 299 s = nl_langinfo (_NL_MONETARY_THOUSANDS_SEP_WC);
 300 (void) s;
 301 ],
 302 [quadmath_use_nl_langinfo_wc=yes],[quadmath_use_nl_langinfo_wc=no])
 303 AC_MSG_RESULT($quadmath_use_nl_langinfo_wc)
 304 if test x$quadmath_use_nl_langinfo_wc = xyes; then
 305   AC_DEFINE([USE_NL_LANGINFO_WC],[1],[whether nl_langinfo should be used for wide char locale info])
 306 fi
 307
 308 AC_MSG_CHECKING([whether localeconv should be used])
 309 AC_TRY_COMPILE([#include <locale.h>],[
 310 const struct lconv *l = localeconv ();
 311 const char *s;
 312 s = l->decimal_point;
 313 s = l->mon_decimal_point;
 314 s = l->grouping;
 315 s = l->mon_grouping;
 316 s = l->thousands_sep;
 317 s = l->mon_thousands_sep;
 318 (void) s;
 319 ],
 320 [quadmath_use_localeconv=yes],[quadmath_use_localeconv=no])
 321 AC_MSG_RESULT($quadmath_use_localeconv)
 322 if test x$quadmath_use_localeconv = xyes; then
 323   AC_DEFINE([USE_LOCALECONV],[1],[whether localeconv should be used])
 324 fi
 325
 326 # Check for whether i18n number rewriting support for quadmath_snprintf
 327 # or Q printf hooks should be provided.
 328 AC_MSG_CHECKING([whether i18n number rewriting support for quadmath_snprintf should be added])
 329 AC_TRY_COMPILE([#include <langinfo.h>
 330 #include <limits.h>
 331 #include <string.h>
 332 #include <wchar.h>
 333 #include <wctype.h>],[
 334 const char *s;
 335 char decimal[MB_LEN_MAX];
 336 wctrans_t map = wctrans ("to_outpunct");
 337 wint_t wdecimal = towctrans (L'.', map);
 338 mbstate_t state;
 339 memset (&state, '\0', sizeof (state));
 340 wcrtomb (decimal, wdecimal, &state);
 341 s = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
 342 s = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
 343 s = nl_langinfo (_NL_CTYPE_MB_CUR_MAX);
 344 (void) s;
 345 ],
 346 [quadmath_use_i18n_number_h=yes],[quadmath_use_i18n_number_h=no])
 347 AC_MSG_RESULT($quadmath_use_i18n_number_h)
 348 if test x$quadmath_use_i18n_number_h = xyes; then
 349   AC_DEFINE([USE_I18N_NUMBER_H],[1],[whether i18n number rewriting can be supported])
 350 fi
 351
 352 # Add CET specific flags if CET is enabled
 353 GCC_CET_FLAGS(CET_FLAGS)
 354 XCFLAGS="$XCFLAGS $CET_FLAGS"
 355
 356 case x$target in
 357   xpowerpc64le*-linux*)
 358     AC_PREPROC_IFELSE(
 359       [AC_LANG_PROGRAM([[#if __SIZEOF_LONG_DOUBLE__ != 16
 360                          #error long double is double
 361                          #endif]],
 362                        [[(void) 0;]])],
 363       [XCFLAGS="$XCFLAGS -mno-gnu-attribute"])
 364     ;;
 365   *)
 366     ;;
 367 esac
 368 AC_SUBST(XCFLAGS)
 369
 370 AC_CACHE_SAVE
 371
 372 if test ${multilib} = yes; then
 373   multilib_arg="--enable-multilib"
 374 else
 375   multilib_arg=
 376 fi
 377
 378
 379 # We would like our source tree to be readonly. However when releases or
 380 # pre-releases are generated, the flex/bison generated files as well as the
 381 # various formats of manuals need to be included along with the rest of the
 382 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 383 # just that.
 384 AC_MSG_CHECKING(generated-files-in-srcdir)
 385 AC_ARG_ENABLE(generated-files-in-srcdir,
 386 AS_HELP_STRING([--enable-generated-files-in-srcdir],
 387  [put copies of generated files in source dir intended for creating source tarballs for users without texinfo bison or flex]),
 388 [case "$enableval" in
 389  yes) enable_generated_files_in_srcdir=yes ;;
 390  no)  enable_generated_files_in_srcdir=no ;;
 391  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 392  esac],
 393 [enable_generated_files_in_srcdir=no])
 394 AC_MSG_RESULT($enable_generated_files_in_srcdir)
 395 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
 396
 397 # Determine what GCC version number to use in filesystem paths.
 398 GCC_BASE_VER
 399
 400 AC_CONFIG_FILES(Makefile)
 401 AC_OUTPUT