gcc/gengtype-lex.l

   1 /* -*- indented-text -*- */
   2 /* Process source files and output type information.
   3    Copyright (C) 2002, 2003, 2004, 2005, 2007, 2008, 2009, 2010, 2012
   4    Free Software Foundation, Inc.
   5
   6 This file is part of GCC.
   7
   8 GCC is free software; you can redistribute it and/or modify it under
   9 the terms of the GNU General Public License as published by the Free
  10 Software Foundation; either version 3, or (at your option) any later
  11 version.
  12
  13 GCC is distributed in the hope that it will be useful, but WITHOUT ANY
  14 WARRANTY; without even the implied warranty of MERCHANTABILITY or
  15 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  16 for more details.
  17
  18 You should have received a copy of the GNU General Public License
  19 along with GCC; see the file COPYING3.  If not see
  20 <http://www.gnu.org/licenses/>.  */
  21
  22 %option noinput
  23
  24 %{
  25 #ifdef GENERATOR_FILE
  26 #include "bconfig.h"
  27 #else
  28 #include "config.h"
  29 #endif
  30 #include "system.h"
  31
  32 #define malloc xmalloc
  33 #define realloc xrealloc
  34
  35 #include "gengtype.h"
  36
  37 #define YY_DECL int yylex (const char **yylval)
  38 #define yyterminate() return EOF_TOKEN
  39
  40 struct fileloc lexer_line;
  41 int lexer_toplevel_done;
  42
  43 static void
  44 update_lineno (const char *l, size_t len)
  45 {
  46   while (len-- > 0)
  47     if (*l++ == '\n')
  48       lexer_line.line++;
  49 }
  50
  51 %}
  52
  53 ID      [[:alpha:]_][[:alnum:]_]*
  54 WS      [[:space:]]+
  55 HWS     [ \t\r\v\f]*
  56 IWORD   short|long|(un)?signed|char|int|HOST_WIDE_INT|HOST_WIDEST_INT|bool|size_t|BOOL_BITFIELD|CPPCHAR_SIGNED_T|ino_t|dev_t|HARD_REG_SET
  57 ITYPE   {IWORD}({WS}{IWORD})*
  58 EOID    [^[:alnum:]_]
  59
  60 %x in_struct in_struct_comment in_comment
  61 %option warn noyywrap nounput nodefault perf-report
  62 %option 8bit never-interactive
  63 %%
  64   /* Do this on entry to yylex():  */
  65   *yylval = 0;
  66   if (lexer_toplevel_done)
  67     {
  68       BEGIN(INITIAL);
  69       lexer_toplevel_done = 0;
  70     }
  71
  72   /* Things we look for in skipping mode: */
  73 <INITIAL>{
  74 ^{HWS}typedef/{EOID} {
  75   BEGIN(in_struct);
  76   return TYPEDEF;
  77 }
  78 ^{HWS}struct/{EOID} {
  79   BEGIN(in_struct);
  80   return STRUCT;
  81 }
  82 ^{HWS}union/{EOID} {
  83   BEGIN(in_struct);
  84   return UNION;
  85 }
  86 ^{HWS}extern/{EOID} {
  87   BEGIN(in_struct);
  88   return EXTERN;
  89 }
  90 ^{HWS}static/{EOID} {
  91   BEGIN(in_struct);
  92   return STATIC;
  93 }
  94 }
  95
  96 <in_struct>{
  97
  98 "/*"                            { BEGIN(in_struct_comment); }
  99
 100 {WS}                            { update_lineno (yytext, yyleng); }
 101 \\\n                            { lexer_line.line++; }
 102
 103 "const"/{EOID}                  /* don't care */
 104 "GTY"/{EOID}                    { return GTY_TOKEN; }
 105 "VEC"/{EOID}                    { return VEC_TOKEN; }
 106 "union"/{EOID}                  { return UNION; }
 107 "struct"/{EOID}                 { return STRUCT; }
 108 "enum"/{EOID}                   { return ENUM; }
 109 "ptr_alias"/{EOID}              { return PTR_ALIAS; }
 110 "nested_ptr"/{EOID}             { return NESTED_PTR; }
 111 "user"/{EOID}                   { return USER_GTY; }
 112 [0-9]+                          { return NUM; }
 113 "param"[0-9]*"_is"/{EOID}               {
 114   *yylval = XDUPVAR (const char, yytext, yyleng, yyleng+1);
 115   return PARAM_IS;
 116 }
 117
 118 {IWORD}({WS}{IWORD})*/{EOID}            |
 119 "ENUM_BITFIELD"{WS}?"("{WS}?{ID}{WS}?")"        {
 120   size_t len;
 121
 122   for (len = yyleng; ISSPACE (yytext[len-1]); len--)
 123     ;
 124
 125   *yylval = XDUPVAR (const char, yytext, len, len+1);
 126   update_lineno (yytext, yyleng);
 127   return SCALAR;
 128 }
 129
 130
 131 {ID}/{EOID}                     {
 132   *yylval = XDUPVAR (const char, yytext, yyleng, yyleng+1);
 133   return ID;
 134 }
 135
 136 \"([^"\\]|\\.)*\"               {
 137   *yylval = XDUPVAR (const char, yytext+1, yyleng-2, yyleng-1);
 138   return STRING;
 139 }
 140   /* This "terminal" avoids having to parse integer constant expressions.  */
 141 "["[^\[\]]*"]"                  {
 142   *yylval = XDUPVAR (const char, yytext+1, yyleng-2, yyleng-1);
 143   return ARRAY;
 144 }
 145 "'"("\\".|[^\\])"'"             {
 146   *yylval = XDUPVAR (const char, yytext+1, yyleng-2, yyleng);
 147   return CHAR;
 148 }
 149
 150 "..."                           { return ELLIPSIS; }
 151 [(){},*:<>;=%|-]                { return yytext[0]; }
 152
 153    /* ignore pp-directives */
 154 ^{HWS}"#"{HWS}[a-z_]+[^\n]*\n   {lexer_line.line++;}
 155
 156 .                               {
 157   error_at_line (&lexer_line, "unexpected character `%s'", yytext);
 158 }
 159 }
 160
 161 "/*"                    { BEGIN(in_comment); }
 162 \n                      { lexer_line.line++; }
 163 {ID}                    |
 164 "'"("\\".|[^\\])"'"     |
 165 [^"/\n]                 /* do nothing */
 166 \"([^"\\]|\\.|\\\n)*\"  { update_lineno (yytext, yyleng); }
 167 "/"/[^*]                /* do nothing */
 168
 169 <in_comment,in_struct_comment>{
 170 \n              { lexer_line.line++; }
 171 [^*\n]{16}      |
 172 [^*\n]          /* do nothing */
 173 "*"/[^/]        /* do nothing */
 174 }
 175 <in_comment>"*/"        { BEGIN(INITIAL); }
 176 <in_struct_comment>"*/" { BEGIN(in_struct); }
 177
 178 ["/]                    |
 179 <in_struct_comment,in_comment>"*"       {
 180   error_at_line (&lexer_line,
 181                  "unterminated comment or string; unexpected EOF");
 182 }
 183
 184 ^{HWS}"#"{HWS}"define"{WS}"GTY(" /* do nothing */
 185
 186 %%
 187
 188 void
 189 yybegin (const char *fname)
 190 {
 191   yyin = fopen (fname, "r");
 192   if (yyin == NULL)
 193     {
 194       perror (fname);
 195       exit (1);
 196     }
 197   lexer_line.file = input_file_by_name (fname);
 198   lexer_line.line = 1;
 199 }
 200
 201 void
 202 yyend (void)
 203 {
 204   fclose (yyin);
 205 }