libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 # This works around the fact that libtool configuration may change LD
   5 # for this particular configuration, but some shells, instead of
   6 # keeping the changes in LD private, export them just because LD is
   7 # exported.
   8 ORIGINAL_LD_FOR_MULTILIBS=$LD
   9
  10 AC_PROG_LN_S
  11
  12 dnl We use these options to decide which functions to include.
  13 AC_ARG_WITH(target-subdir,
  14 [  --with-target-subdir=SUBDIR
  15                            configuring in a subdirectory])
  16 AC_ARG_WITH(cross-host,
  17 [  --with-cross-host=HOST  configuring with a cross compiler])
  18
  19 AC_ARG_WITH(newlib,
  20 [  --with-newlib           Configuring with newlib])
  21
  22 LIBGCJ_CONFIGURE(.)
  23
  24 AM_CONFIG_HEADER(include/config.h gcj/libgcj-config.h)
  25
  26 # Only use libltdl for native builds.
  27 if test -z "${with_cross_host}"; then
  28    AC_LIBLTDL_CONVENIENCE
  29    AC_LIBTOOL_DLOPEN
  30    DIRLTDL=libltdl
  31    AC_DEFINE(USE_LTDL)
  32    # Sigh.  Libtool's macro doesn't do the right thing.
  33    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  34    # FIXME: this is a hack.
  35    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
  36    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
  37 fi
  38 AC_SUBST(INCLTDL)
  39 AC_SUBST(LIBLTDL)
  40 AC_SUBST(DIRLTDL)
  41 AM_PROG_LIBTOOL
  42 AC_CONFIG_SUBDIRS($DIRLTDL)
  43
  44 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  45    COMPPATH=.
  46 else
  47    COMPPATH=..
  48 fi
  49 AC_SUBST(COMPPATH)
  50
  51 dnl The -no-testsuite modules omit the test subdir.
  52 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  53
  54 dnl Should the runtime set system properties by examining the
  55 dnl environment variable GCJ_PROPERTIES?
  56 AC_ARG_ENABLE(getenv-properties,
  57 [  --disable-getenv-properties
  58                           don't set system properties from GCJ_PROPERTIES])
  59
  60 dnl Whether GCJ_PROPERTIES is used depends on the target.
  61 if test -z "$enable_getenv_properties"; then
  62    enable_getenv_properties=${enable_getenv_properties_default-yes}
  63 fi
  64 if test "$enable_getenv_properties" = no; then
  65    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  66 fi
  67
  68 dnl Whether we should use arguments to main()
  69 if test -z "$enable_main_args"; then
  70    enable_main_args=${enable_main_args_default-yes}
  71 fi
  72 if test "$enable_main_args" = no; then
  73    AC_DEFINE(DISABLE_MAIN_ARGS)
  74 fi
  75
  76
  77 dnl Should we use hashtable-based synchronization?
  78 dnl Currently works only for Linux X86/ia64
  79 dnl Typically faster and more space-efficient
  80 AC_ARG_ENABLE(hash-synchronization,
  81 [  --enable-hash-synchronization
  82                           Use global hash table for monitor locks])
  83
  84 if test -z "$enable_hash_synchronization"; then
  85    enable_hash_synchronization=$enable_hash_synchronization_default
  86 fi
  87
  88 dnl configure.host sets slow_pthread_self if the synchronization code should
  89 dnl try to avoid pthread_self calls by caching thread IDs in a hashtable.
  90 if test "${slow_pthread_self}" = "yes"; then
  91   AC_DEFINE(SLOW_PTHREAD_SELF)
  92 fi
  93
  94
  95 dnl See if the user has requested runtime debugging.
  96 LIBGCJDEBUG="false"
  97 AC_SUBST(LIBGCJDEBUG)
  98 AC_ARG_ENABLE(libgcj-debug,
  99 [  --enable-libgcj-debug   enable runtime debugging code],
 100   if test "$enable_libgcj_debug" = yes; then
 101     AC_DEFINE(DEBUG)
 102     LIBGCJDEBUG="true"
 103   fi)
 104
 105 dnl See if the user has the interpreter included.
 106 AC_ARG_ENABLE(interpreter,
 107 [  --enable-interpreter    enable interpreter],
 108   if test "$enable_interpreter" = yes; then
 109     # This can also be set in configure.host.
 110     libgcj_interpreter=yes
 111   elif test "$enable_interpreter" = no; then
 112     libgcj_interpreter=no
 113   fi)
 114
 115 if test "$libgcj_interpreter" = yes; then
 116    AC_DEFINE(INTERPRETER)
 117 fi
 118 INTERPRETER="$libgcj_interpreter"
 119 AC_SUBST(INTERPRETER)
 120
 121 AC_MSG_CHECKING([for exception model to use])
 122 AC_LANG_SAVE
 123 AC_LANG_CPLUSPLUS
 124 AC_ARG_ENABLE(sjlj-exceptions,
 125 [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
 126 [:],
 127 [dnl Botheration.  Now we've got to detect the exception model.
 128 dnl Link tests against libgcc.a are problematic since -- at least
 129 dnl as of this writing -- we've not been given proper -L bits for
 130 dnl single-tree newlib and libgloss.
 131 dnl
 132 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 133 dnl conftest files before we got a change to grep them first.
 134 cat > conftest.$ac_ext << EOF
 135 [#]line __oline__ "configure"
 136 struct S { ~S(); };
 137 void bar();
 138 void foo()
 139 {
 140   S s;
 141   bar();
 142 }
 143 EOF
 144 old_CXXFLAGS="$CXXFLAGS"
 145 CXXFLAGS=-S
 146 if AC_TRY_EVAL(ac_compile); then
 147   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 148     enable_sjlj_exceptions=yes
 149   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 150     enable_sjlj_exceptions=no
 151   fi
 152 fi
 153 CXXFLAGS="$old_CXXFLAGS"
 154 rm -f conftest*])
 155 if test x$enable_sjlj_exceptions = xyes; then
 156   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 157         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 158   ac_exception_model_name=sjlj
 159 elif test x$enable_sjlj_exceptions = xno; then
 160   ac_exception_model_name="call frame"
 161 else
 162   AC_MSG_ERROR([unable to detect exception model])
 163 fi
 164 AC_LANG_RESTORE
 165 AC_MSG_RESULT($ac_exception_model_name)
 166
 167 # If we are non using SJLJ exceptions, and this host does not have support
 168 # for unwinding from a signal handler, enable checked dereferences and divides.
 169 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 170   CHECKREFSPEC=-fcheck-references
 171   DIVIDESPEC=-fuse-divide-subroutine
 172   EXCEPTIONSPEC=
 173 fi
 174
 175 dnl See if the user wants to disable java.net.  This is the mildly
 176 dnl ugly way that we admit that target-side configuration sucks.
 177 AC_ARG_ENABLE(java-net,
 178 [  --disable-java-net      disable java.net])
 179
 180 dnl Whether java.net is built by default can depend on the target.
 181 if test -z "$enable_java_net"; then
 182    enable_java_net=${enable_java_net_default-yes}
 183 fi
 184 if test "$enable_java_net" = no; then
 185    AC_DEFINE(DISABLE_JAVA_NET)
 186 fi
 187
 188 dnl See if the user wants to configure without libffi.  Some
 189 dnl architectures don't support it, and default values are set in
 190 dnl configure.host.
 191 AC_ARG_WITH(libffi,
 192 [  --without-libffi        don't use libffi],,with_libffi=${with_libffi_default-yes})
 193
 194 LIBFFI=
 195 LIBFFIINCS=
 196 if test "$with_libffi" != no; then
 197    AC_DEFINE(USE_LIBFFI)
 198    LIBFFI=../libffi/libffi_convenience.la
 199    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 200 fi
 201 AC_SUBST(LIBFFI)
 202 AC_SUBST(LIBFFIINCS)
 203
 204 dnl See if the user wants to disable JVMPI support.
 205 AC_ARG_ENABLE(jvmpi,
 206 [  --disable-jvmpi         disable JVMPI support])
 207
 208 if test "$enable_jvmpi" != no; then
 209     AC_DEFINE(ENABLE_JVMPI)
 210 fi
 211
 212 dnl If the target is an eCos system, use the appropriate eCos
 213 dnl I/O routines.
 214 dnl FIXME: this should not be a local option but a global target
 215 dnl system; at present there is no eCos target.
 216 TARGET_ECOS=${PROCESS-"no"}
 217 AC_ARG_WITH(ecos,
 218 [  --with-ecos             enable runtime eCos target support],
 219 TARGET_ECOS="$with_ecos"
 220 )
 221
 222 PLATFORMOBJS=
 223 case "$TARGET_ECOS" in
 224    no) case "$host" in
 225       *mingw*)
 226             PLATFORM=Win32
 227             PLATFORMOBJS=win32.lo
 228             PLATFORMH=win32.h
 229       ;;
 230       *)
 231             PLATFORM=Posix
 232             PLATFORMOBJS=posix.lo
 233             PLATFORMH=posix.h
 234       ;;
 235       esac
 236       ;;
 237    *)
 238       PLATFORM=Ecos
 239       AC_DEFINE(ECOS)
 240       PLATFORMOBJS=posix.lo
 241       PLATFORMH=posix.h
 242       ;;
 243 esac
 244 AC_SUBST(PLATFORMOBJS)
 245 AC_LINK_FILES(include/$PLATFORMH, include/platform.h)
 246
 247 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 248 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 249 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 250 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 251
 252
 253 dnl These may not be defined in a non-ANS conformant embedded system.
 254 dnl FIXME: Should these case a runtime exception in that case?
 255 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 256 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 257
 258 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 259 dnl to create the link will fail.
 260 test -d java || mkdir java
 261 test -d java/io || mkdir java/io
 262 test -d gnu || mkdir gnu
 263 AC_LINK_FILES(java/io/natFile${FILE-${PLATFORM}}.cc, java/io/natFile.cc)
 264 AC_LINK_FILES(java/io/natFileDescriptor${FILE-${PLATFORM}}.cc, java/io/natFileDescriptor.cc)
 265
 266 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 267 test -d java/lang || mkdir java/lang
 268 AC_LINK_FILES(java/lang/${PLATFORM}Process.java, java/lang/ConcreteProcess.java)
 269 AC_LINK_FILES(java/lang/nat${PLATFORM}Process.cc, java/lang/natConcreteProcess.cc)
 270
 271 case "${host}" in
 272     *mingw*)
 273       SYSTEMSPEC="-lgdi32 -lwsock32 -lws2_32"
 274     ;;
 275     *)
 276       SYSTEMSPEC=
 277     ;;
 278 esac
 279 AC_SUBST(SYSTEMSPEC)
 280
 281 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 282 AC_SUBST(LIBGCJTESTSPEC)
 283
 284 AC_ARG_WITH(system-zlib,
 285 [  --with-system-zlib      use installed libz])
 286 ZLIBSPEC=
 287 AC_SUBST(ZLIBSPEC)
 288 ZLIBTESTSPEC=
 289 AC_SUBST(ZLIBTESTSPEC)
 290
 291 dnl FIXME: this should be _libs on some hosts.
 292 libsubdir=.libs
 293
 294 dnl Allow the GC to be disabled.  Can be useful when debugging.
 295 AC_MSG_CHECKING([for garbage collector to use])
 296 AC_ARG_ENABLE(java-gc,
 297 changequote(<<,>>)dnl
 298 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 299 changequote([,])
 300   GC=$enableval,
 301   GC=boehm)
 302 GCLIBS=
 303 GCINCS=
 304 GCDEPS=
 305 GCOBJS=
 306 GCSPEC=
 307 JC1GCSPEC=
 308 GCTESTSPEC=
 309 case "$GC" in
 310  boehm)
 311     AC_MSG_RESULT(boehm)
 312     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 313     GCINCS='-I$(top_srcdir)/../boehm-gc/include'
 314     JC1GCSPEC='-fuse-boehm-gc'
 315     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 316
 317     dnl We also want to pick up some cpp flags required when including
 318     dnl boehm-config.h.  Yuck.
 319     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 320     GCOBJS=boehm.lo
 321     GCHDR=boehm-gc.h
 322     dnl The POSIX thread support needs to know this.
 323     AC_DEFINE(HAVE_BOEHM_GC)
 324     ;;
 325  no)
 326     AC_MSG_RESULT(none)
 327     GCOBJS=nogc.lo
 328     GCHDR=no-gc.h
 329     ;;
 330  *)
 331     AC_MSG_ERROR(unrecognized collector \"$GC\")
 332     ;;
 333 esac
 334 AC_SUBST(GCLIBS)
 335 AC_SUBST(GCINCS)
 336 AC_SUBST(GCDEPS)
 337 AC_SUBST(GCOBJS)
 338 AC_SUBST(GCSPEC)
 339 AC_SUBST(JC1GCSPEC)
 340 AC_SUBST(GCTESTSPEC)
 341 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 342
 343
 344 AC_MSG_CHECKING([for thread model used by GCC])
 345 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 346 AC_MSG_RESULT([$THREADS])
 347
 348 case "$THREADS" in
 349  no | none | single)
 350     THREADS=none
 351     ;;
 352  posix | pthreads)
 353     THREADS=posix
 354     case "$host" in
 355      *-*-linux*)
 356         AC_DEFINE(LINUX_THREADS)
 357         ;;
 358     esac
 359     ;;
 360  win32)
 361     ;;
 362  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 363     AC_MSG_ERROR(thread package $THREADS not yet supported)
 364     ;;
 365  *)
 366     AC_MSG_ERROR($THREADS is an unknown thread package)
 367     ;;
 368 esac
 369
 370 THREADLDFLAGS=
 371 THREADLIBS=
 372 THREADINCS=
 373 THREADDEPS=
 374 THREADOBJS=
 375 THREADH=
 376 THREADSPEC=
 377 case "$THREADS" in
 378  posix)
 379     case "$host" in
 380      *-*-cygwin*)
 381         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 382         ;;
 383 changequote(<<,>>)
 384      *-*-freebsd[1234]*)
 385 changequote([,])
 386         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 387         # merely adds pthread_* functions) but it does have a -pthread switch
 388         # which is required at link-time to select -lc_r *instead* of -lc.
 389         THREADLDFLAGS=-pthread
 390         # Don't set THREADSPEC here as might be expected since -pthread is
 391         # not processed when found within a spec file, it must come from
 392         # the command line.  For now, the user must provide the -pthread
 393         # switch to link code compiled with gcj.  In future, consider adding
 394         # support for weak references to pthread_* functions ala gthr.h API.
 395         THREADSPEC='%{!pthread: %eUnder this configuration, the user must provide -pthread when linking.}'
 396         ;;
 397      *-*-freebsd*)
 398         # FreeBSD 5 implements a model much closer to other modern UNIX
 399         # which support threads.  However, it still does not support
 400         # -lpthread.
 401         THREADLDFLAGS=-pthread
 402         THREADSPEC=-lc_r
 403         ;;
 404      *)
 405         THREADLIBS=-lpthread
 406         THREADSPEC=-lpthread
 407         ;;
 408     esac
 409     THREADOBJS=posix-threads.lo
 410     THREADH=posix-threads.h
 411     # MIT pthreads doesn't seem to have the mutexattr functions.
 412     # But for now we don't check for it.  We just assume you aren't
 413     # using MIT pthreads.
 414     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 415
 416     # If we're using the Boehm GC, then we happen to know that it
 417     # defines _REENTRANT, so we don't bother.  Eww.
 418     if test "$GC" != boehm; then
 419        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 420     fi
 421     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 422     ;;
 423
 424  win32)
 425     THREADOBJS=win32-threads.lo
 426     THREADH=win32-threads.h
 427     ;;
 428
 429  none)
 430     THREADOBJS=no-threads.lo
 431     THREADH=no-threads.h
 432     ;;
 433 esac
 434 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 435 AC_SUBST(THREADLIBS)
 436 AC_SUBST(THREADINCS)
 437 AC_SUBST(THREADDEPS)
 438 AC_SUBST(THREADOBJS)
 439 AC_SUBST(THREADSPEC)
 440 AC_SUBST(THREADLDFLAGS)
 441
 442 if test -d sysdep; then true; else mkdir sysdep; fi
 443 AC_LINK_FILES(sysdep/$sysdeps_dir/locks.h, sysdep/locks.h)
 444
 445 HASH_SYNC_SPEC=
 446 # Hash synchronization is only useful with posix threads right now.
 447 if test "$enable_hash_synchronization" = yes && test "$THREADS" = "posix"; then
 448    HASH_SYNC_SPEC=-fhash-synchronization
 449    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 450 fi
 451 AC_SUBST(HASH_SYNC_SPEC)
 452
 453
 454 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 455
 456 CANADIAN=no
 457 NULL_TARGET=no
 458 NATIVE=yes
 459
 460 # We're in the tree with gcc, and need to include some of its headers.
 461 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 462
 463 # Figure out where generated headers like libgcj-config.h get installed.
 464 changequote(,)dnl
 465 gcc_version_trigger=${libgcj_basedir}/../gcc/version.c
 466 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 467 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 468 tool_include_dir='$(libdir)/gcc-lib/$(target_alias)/'${gcc_version}/include
 469 changequote([,])dnl
 470 AC_SUBST(tool_include_dir)
 471 AC_SUBST(gcc_version)
 472
 473 if test "x${with_newlib}" = "xyes"; then
 474    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 475    # may not work correctly, because the compiler may not be able to
 476    # link executables.
 477
 478    # We assume newlib.  This lets us hard-code the functions we know
 479    # we'll have.
 480    AC_DEFINE(HAVE_MEMMOVE)
 481    AC_DEFINE(HAVE_MEMCPY)
 482    AC_DEFINE(HAVE_STRERROR)
 483    AC_DEFINE(HAVE_TIME)
 484    AC_DEFINE(HAVE_GMTIME_R)
 485    AC_DEFINE(HAVE_LOCALTIME_R)
 486    dnl This is only for POSIX threads.
 487    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 488    dnl We also assume we are using gcc, which provides alloca.
 489    AC_DEFINE(HAVE_ALLOCA)
 490
 491    dnl Assume we do not have getuid and friends.
 492    AC_DEFINE(NO_GETUID)
 493
 494    # If Canadian cross, then don't pick up tools from the build
 495    # directory.
 496    if test x"$build" != x"$with_cross_host" \
 497         && test x"$build" != x"$target"; then
 498       CANADIAN=yes
 499       GCC_UNWIND_INCLUDE=
 500       GCJ="${target_alias}-gcj"
 501    fi
 502    NATIVE=no
 503 else
 504    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep opendir)
 505    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 506    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 507    AC_CHECK_FUNCS(nl_langinfo setlocale)
 508    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 509    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 510    AC_CHECK_FUNCS(fork execvp pipe sigaction)
 511    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 512    AC_CHECK_FUNC(backtrace, [
 513      case "$host" in
 514        ia64-*-linux*)
 515          # Has broken backtrace()
 516          ;;
 517        s390*-*-linux*)
 518          # Has broken backtrace()
 519          ;;
 520        *)
 521          AC_DEFINE(HAVE_BACKTRACE)
 522          ;;
 523      esac
 524    ])
 525
 526    AC_CHECK_LIB(dl, dladdr, [
 527      AC_DEFINE(HAVE_DLADDR)])
 528    if test x"$build" = x"$host"; then
 529      AC_CHECK_FILES(/proc/self/exe, [
 530        AC_DEFINE(HAVE_PROC_SELF_EXE)])
 531    else
 532      case $host in
 533      *-linux*)
 534        AC_DEFINE(HAVE_PROC_SELF_EXE)
 535        ;;
 536      esac
 537    fi
 538
 539    AM_ICONV
 540    AM_LC_MESSAGES
 541    AC_STRUCT_TIMEZONE
 542
 543    AC_CHECK_FUNCS(gethostbyname_r, [
 544      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 545      # There are two different kinds of gethostbyname_r.
 546      # We look for the one that returns `int'.
 547      # Hopefully this check is robust enough.
 548      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 549        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 550
 551      case " $GCINCS " in
 552      *" -D_REENTRANT "*) ;;
 553      *)
 554         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 555         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 556         [libjava_cv_gethostbyname_r_needs_reentrant],
 557         [ AC_LANG_SAVE
 558           AC_LANG_CPLUSPLUS
 559           AC_TRY_COMPILE([#include <netdb.h>],
 560             [gethostbyname_r("", 0, 0);],
 561             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 562                 CPPFLAGS_SAVE="$CPPFLAGS"
 563                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 564                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 565                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 566                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 567                 CPPFLAGS="$CPPFLAGS_SAVE"
 568           ])
 569           AC_LANG_RESTORE
 570         ])
 571         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 572           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 573         fi
 574      ;;
 575      esac
 576
 577      AC_CACHE_CHECK([for struct hostent_data],
 578         [libjava_cv_struct_hostent_data], [dnl
 579         AC_TRY_COMPILE([
 580 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 581 # define _REENTRANT 1
 582 #endif
 583 #include <netdb.h>], [struct hostent_data data;],
 584           [libjava_cv_struct_hostent_data=yes],
 585           [libjava_cv_struct_hostent_data=no])])
 586      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 587        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 588          [Define if struct hostent_data is defined in netdb.h])
 589      fi
 590    ])
 591
 592    # FIXME: libjava source code expects to find a prototype for
 593    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 594    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 595    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 596    # linkage check is enough, yet C++ code requires proper prototypes.)
 597    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 598    AC_CHECK_FUNCS(gethostbyaddr_r, [
 599      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 600      # There are two different kinds of gethostbyaddr_r.
 601      # We look for the one that returns `int'.
 602      # Hopefully this check is robust enough.
 603      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 604        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])])
 605
 606    AC_CHECK_FUNCS(gethostname, [
 607      AC_DEFINE(HAVE_GETHOSTNAME)
 608      AC_EGREP_HEADER(gethostname, unistd.h, [
 609        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 610
 611    # Look for these functions in the thread library, but only bother
 612    # if using POSIX threads.
 613    if test "$THREADS" = posix; then
 614       save_LIBS="$LIBS"
 615       LIBS="$LIBS $THREADLIBS"
 616       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 617       # E.g., Solaris.
 618       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 619
 620       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 621       # Solaris 7 the name librt is preferred.
 622       AC_CHECK_FUNCS(sched_yield, , [
 623         AC_CHECK_LIB(rt, sched_yield, [
 624           AC_DEFINE(HAVE_SCHED_YIELD)
 625           THREADLIBS="$THREADLIBS -lrt"
 626           THREADSPEC="$THREADSPEC -lrt"], [
 627           AC_CHECK_LIB(posix4, sched_yield, [
 628             AC_DEFINE(HAVE_SCHED_YIELD)
 629             THREADLIBS="$THREADLIBS -lposix4"
 630             THREADSPEC="$THREADSPEC -lposix4"])])])
 631       LIBS="$save_LIBS"
 632
 633       # We can save a little space at runtime if the mutex has m_count
 634       # or __m_count.  This is a nice hack for Linux.
 635       AC_TRY_COMPILE([#include <pthread.h>], [
 636           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 637         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 638         AC_TRY_COMPILE([#include <pthread.h>], [
 639             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 640           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 641    fi
 642
 643    # We require a way to get the time.
 644    time_found=no
 645    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 646    if test "$time_found" = no; then
 647       AC_MSG_ERROR([no function found to get the time])
 648    fi
 649
 650    AC_CHECK_FUNCS(memmove)
 651
 652    # We require memcpy.
 653    memcpy_found=no
 654    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 655    if test "$memcpy_found" = no; then
 656       AC_MSG_ERROR([memcpy is required])
 657    fi
 658
 659    AC_CHECK_LIB(dl, dlopen, [
 660        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
 661
 662    # Some library-finding code we stole from Tcl.
 663    #--------------------------------------------------------------------
 664    #    Check for the existence of the -lsocket and -lnsl libraries.
 665    #    The order here is important, so that they end up in the right
 666    #    order in the command line generated by make.  Here are some
 667    #    special considerations:
 668    #    1. Use "connect" and "accept" to check for -lsocket, and
 669    #       "gethostbyname" to check for -lnsl.
 670    #    2. Use each function name only once:  can't redo a check because
 671    #       autoconf caches the results of the last check and won't redo it.
 672    #    3. Use -lnsl and -lsocket only if they supply procedures that
 673    #       aren't already present in the normal libraries.  This is because
 674    #       IRIX 5.2 has libraries, but they aren't needed and they're
 675    #       bogus:  they goof up name resolution if used.
 676    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 677    #       To get around this problem, check for both libraries together
 678    #       if -lsocket doesn't work by itself.
 679    #--------------------------------------------------------------------
 680
 681    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 682     [gcj_cv_lib_sockets=
 683      gcj_checkBoth=0
 684      unset ac_cv_func_connect
 685      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 686      if test "$gcj_checkSocket" = 1; then
 687          unset ac_cv_func_connect
 688          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 689                       gcj_checkBoth=1)
 690      fi
 691      if test "$gcj_checkBoth" = 1; then
 692          gcj_oldLibs=$LIBS
 693          LIBS="$LIBS -lsocket -lnsl"
 694          unset ac_cv_func_accept
 695          AC_CHECK_FUNC(accept,
 696                        [gcj_checkNsl=0
 697                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 698          unset ac_cv_func_accept
 699          LIBS=$gcj_oldLibs
 700      fi
 701      unset ac_cv_func_gethostbyname
 702      gcj_oldLibs=$LIBS
 703      LIBS="$LIBS $gcj_cv_lib_sockets"
 704      AC_CHECK_FUNC(gethostbyname, ,
 705                    [AC_CHECK_LIB(nsl, main,
 706                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 707      unset ac_cv_func_gethostbyname
 708      LIBS=$gcj_oldLIBS
 709    ])
 710    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 711
 712    if test "$with_system_zlib" = yes; then
 713       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
 714    fi
 715
 716    # On Solaris, and maybe other architectures, the Boehm collector
 717    # requires -ldl.
 718    if test "$GC" = boehm; then
 719       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 720    fi
 721
 722    if test -z "${with_multisubdir}"; then
 723       builddotdot=.
 724    else
 725 changequote(<<,>>)
 726       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 727 changequote([,])
 728    fi
 729    if test -x "${builddotdot}/../../gcc/gcj"; then
 730       dir="`cd ${builddotdot}/../../gcc && ${PWDCMD-pwd}`"
 731       GCJ="$dir/gcj -B`${PWDCMD-pwd}`/ -B$dir/"
 732    else
 733       CANADIAN=yes
 734       NULL_TARGET=yes
 735       GCJ="gcj -B`${PWDCMD-pwd}`/"
 736    fi
 737 fi
 738
 739 # Create it, so that compile/link tests don't fail
 740 test -f libgcj.spec || touch libgcj.spec
 741
 742 # We must search the source tree for java.lang, since we still don't
 743 # have libgcj.jar nor java/lang/*.class
 744 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
 745 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
 746
 747 # Since some classes depend on this one, we need its source available
 748 # before we can do any GCJ compilation test :-(
 749 if test ! -f gnu/classpath/Configuration.java; then
 750   test -d gnu || mkdir gnu
 751   test -d gnu/classpath || mkdir gnu/classpath
 752   sed 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
 753         < $srcdir/gnu/classpath/Configuration.java.in \
 754         > gnu/classpath/Configuration.java
 755   # We do not want to redirect the output of the grep below to /dev/null,
 756   # but we add /dev/null to the input list so that grep will print the
 757   # filename of Configuration.java in case it finds any matches.
 758   if grep @ gnu/classpath/Configuration.java /dev/null; then
 759     AC_MSG_ERROR([configure.in is missing the substitutions above])
 760   fi
 761 fi
 762
 763 LT_AC_PROG_GCJ
 764
 765 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
 766
 767 AC_COMPILE_CHECK_SIZEOF(void *)
 768
 769 ZLIBS=
 770 SYS_ZLIBS=
 771 ZINCS=
 772
 773 if test -z "$ZLIBSPEC"; then
 774    # Use zlib from the GCC tree.
 775    ZINCS='-I$(top_srcdir)/../zlib'
 776    ZLIBS=../zlib/libzgcj_convenience.la
 777 else
 778    # System's zlib.
 779    SYS_ZLIBS="$ZLIBSPEC"
 780 fi
 781 AC_SUBST(ZLIBS)
 782 AC_SUBST(SYS_ZLIBS)
 783 AC_SUBST(ZINCS)
 784 AC_SUBST(DIVIDESPEC)
 785 AC_SUBST(CHECKREFSPEC)
 786 AC_SUBST(EXCEPTIONSPEC)
 787
 788 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 789 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 790 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 791 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 792 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 793 AC_SUBST(GCC_UNWIND_INCLUDE)
 794
 795 # Determine gcj version number.
 796 changequote(<<,>>)
 797 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`
 798 changequote([,])
 799 GCJVERSION=$gcjversion
 800 AC_SUBST(GCJVERSION)
 801 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
 802
 803 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 804 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 805 save_CFLAGS="$CFLAGS"
 806 CFLAGS="-x c++ -O2 -ffloat-store"
 807 AC_TRY_COMPILE([#include <math.h>], ,
 808   [AC_MSG_RESULT(no)],
 809   [AC_DEFINE(__NO_MATH_INLINES)
 810    AC_MSG_RESULT(yes)])
 811 CFLAGS="$save_CFLAGS"
 812
 813 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 814 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 815 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 816 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h stdint.h langinfo.h locale.h)
 817 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 818 dnl for now.  If you change this, you also must update natFile.cc.
 819 AC_CHECK_HEADERS(dirent.h)
 820 AC_CHECK_HEADERS(inttypes.h, [
 821     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
 822     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
 823 ])
 824 AC_HEADER_SYS_WAIT
 825
 826 AC_CHECK_TYPE([ssize_t], [int])
 827
 828 AC_MSG_CHECKING([for in_addr_t])
 829 AC_TRY_COMPILE([#include <sys/types.h>
 830 #if STDC_HEADERS
 831 #include <stdlib.h>
 832 #include <stddef.h>
 833 #endif
 834 #if HAVE_NETINET_IN_H
 835 #include <netinet/in.h>
 836 #endif], [in_addr_t foo;],
 837   [AC_DEFINE([HAVE_IN_ADDR_T])
 838    AC_MSG_RESULT(yes)],
 839   [AC_MSG_RESULT(no)])
 840
 841 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 842 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 843   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 844    AC_MSG_RESULT(yes)],
 845   [AC_MSG_RESULT(no)])
 846
 847 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
 848 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ipv6_mreq mreq6;],
 849   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ)
 850    AC_MSG_RESULT(yes)],
 851   [AC_MSG_RESULT(no)])
 852
 853 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 854 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 855   [AC_DEFINE(HAVE_INET6)
 856    AC_MSG_RESULT(yes)],
 857   [AC_MSG_RESULT(no)])
 858
 859 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 860 AC_TRY_COMPILE([#define _POSIX_PII_SOCKET
 861 #include <sys/types.h>
 862 #include <sys/socket.h>], [socklen_t x = 5;],
 863   [AC_DEFINE(HAVE_SOCKLEN_T)
 864    AC_MSG_RESULT(yes)],
 865   [AC_MSG_RESULT(no)])
 866
 867 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 868 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 869   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 870    AC_MSG_RESULT(yes)],
 871   [AC_MSG_RESULT(no)
 872    AC_MSG_CHECKING([for global timezone variable])
 873    dnl FIXME: we don't want a link check here because that won't work
 874    dnl when cross-compiling.  So instead we make an assumption that
 875    dnl the header file will mention timezone if it exists.
 876    dnl Don't find the win32 function timezone
 877    AC_TRY_COMPILE([#include <time.h>], [void i(){long z2 = 2*timezone;}],
 878      [AC_DEFINE(HAVE_TIMEZONE)
 879       AC_MSG_RESULT(yes)],
 880      [AC_MSG_RESULT(no)
 881        AC_MSG_CHECKING([for global _timezone variable])
 882        dnl FIXME: As above, don't want link check
 883        AC_TRY_COMPILE([#include <time.h>], [long z2 = _timezone;],
 884          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE)
 885           AC_MSG_RESULT(yes)],
 886           [AC_MSG_RESULT(no)])])])
 887
 888 AC_FUNC_ALLOCA
 889
 890 AC_CHECK_PROGS(PERL, perl, false)
 891
 892 SYSDEP_SOURCES=
 893
 894 case "${host}" in
 895  i?86-*-linux*)
 896     SIGNAL_HANDLER=include/i386-signal.h
 897     ;;
 898  sparc*-sun-solaris*)
 899     SIGNAL_HANDLER=include/sparc-signal.h
 900     ;;
 901 # ia64-*)
 902 #    SYSDEP_SOURCES=sysdep/ia64.c
 903 #    test -d sysdep || mkdir sysdep
 904 #    ;;
 905  ia64-*-linux*)
 906     SIGNAL_HANDLER=include/dwarf2-signal.h
 907     ;;
 908  powerpc-*-linux*)
 909     SIGNAL_HANDLER=include/dwarf2-signal.h
 910     ;;
 911  alpha*-*-linux*)
 912     SIGNAL_HANDLER=include/dwarf2-signal.h
 913     ;;
 914  s390*-*-linux*)
 915     SIGNAL_HANDLER=include/s390-signal.h
 916     ;;
 917  x86_64*-*-linux*)
 918     SIGNAL_HANDLER=include/dwarf2-signal.h
 919     ;;
 920  sparc*-*-linux*)
 921     SIGNAL_HANDLER=include/dwarf2-signal.h
 922     ;;
 923  *mingw*)
 924     SIGNAL_HANDLER=include/win32-signal.h
 925     ;;
 926  *)
 927     SIGNAL_HANDLER=include/default-signal.h
 928     ;;
 929 esac
 930
 931 # If we're using sjlj exceptions, forget what we just learned.
 932 if test "$enable_sjlj_exceptions" = yes; then
 933    SIGNAL_HANDLER=include/default-signal.h
 934 fi
 935
 936 AC_SUBST(SYSDEP_SOURCES)
 937
 938 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 939
 940 if test "${multilib}" = "yes"; then
 941   multilib_arg="--enable-multilib"
 942 else
 943   multilib_arg=
 944 fi
 945
 946 AC_PATH_XTRA
 947
 948 dnl Determine which AWT peer libraries to build
 949 AC_ARG_ENABLE(java-awt,
 950 [  --enable-java-awt       list of AWT peer implementations to be built])
 951
 952 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 953 use_xlib_awt=""
 954 use_gtk_awt=""
 955
 956 for peer in $peerlibs ; do
 957   case $peer in
 958     xlib)
 959       if [test "$no_x" = yes]; then
 960         echo "*** xlib peers requested but no X library available" 1>&2
 961         exit 1
 962       else
 963         use_xlib_awt="yes"
 964       fi
 965       ;;
 966     gtk)
 967       # Nothing, yet...
 968       ;;
 969     no)
 970       use_xlib_awt=
 971       use_gtk_awt=
 972       break
 973       ;;
 974     *)
 975       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 976       exit 1
 977   esac
 978 done
 979
 980 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 981 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 982
 983
 984 here=`${PWDCMD-pwd}`
 985 AC_SUBST(here)
 986
 987 # We get this from the environment.
 988 AC_SUBST(GCJFLAGS)
 989
 990 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gnu/classpath/Configuration.java gcj/Makefile include/Makefile testsuite/Makefile,
 991 [# Only add multilib support code if we just rebuilt top-level Makefile.
 992 case " $CONFIG_FILES " in
 993  *" Makefile "*)
 994    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 995    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 996    ;;
 997 esac
 998
 999 # Make subdirectories and `.d' files.  Look in both srcdir and
1000 # builddir for the .java files.
1001 h=`${PWDCMD-pwd}`
1002 : > deps.mk
1003 ( (cd $srcdir && find . \( -name '*.java' -o -name '*.cc' \) -print) ;
1004   find . \( -name '*.java' -o -name '*.cc' \) -print) | \
1005    fgrep -v testsuite | \
1006    sed -e 's/\.java/.d/'\;'s/\.cc/.d/' | \
1007    while read f; do
1008       echo "include $f" >> deps.mk
1009       test -f $f || {
1010 changequote(<<,>>)
1011          d=`echo $f | sed -e 's,/[^/]*$,,'`
1012 changequote([,])
1013          if test ! -d $d; then
1014            $libgcj_basedir/../mkinstalldirs $d
1015          fi;
1016          echo > $f
1017       }
1018    done
1019 ],
1020 srcdir=${srcdir}
1021 host=${host}
1022 target=${target}
1023 with_multisubdir=${with_multisubdir}
1024 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1025 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1026 libgcj_basedir=${libgcj_basedir}
1027 CC="${CC}"
1028 CXX="${CXX}"
1029 )