gcc-4_9-mobile/configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32 m4_include([config/cloog.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_PREREQ(2.64)
  36 AC_DISABLE_OPTION_CHECKING
  37
  38 progname=$0
  39 # if PWD already has a value, it is probably wrong.
  40 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  41
  42 # Export original configure arguments for use by sub-configures.
  43 # Quote arguments with shell meta charatcers.
  44 TOPLEVEL_CONFIGURE_ARGUMENTS=
  45 set -- "$progname" "$@"
  46 for ac_arg
  47 do
  48   case "$ac_arg" in
  49   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  50     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  51     # if the argument is of the form -foo=baz, quote the baz part only
  52     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  53   *) ;;
  54   esac
  55   # Add the quoted argument to the list.
  56   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  57 done
  58 if test "$silent" = yes; then
  59   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  60 fi
  61 # Remove the initial space we just introduced and, as these will be
  62 # expanded by make, quote '$'.
  63 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  64 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  65
  66 # Find the build, host, and target systems.
  67 ACX_NONCANONICAL_BUILD
  68 ACX_NONCANONICAL_HOST
  69 ACX_NONCANONICAL_TARGET
  70
  71 dnl Autoconf 2.5x and later will set a default program prefix if
  72 dnl --target was used, even if it was the same as --host.  Disable
  73 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  74 dnl to take effect.
  75 test "$host_noncanonical" = "$target_noncanonical" &&
  76   test "$program_prefix$program_suffix$program_transform_name" = \
  77     NONENONEs,x,x, &&
  78   program_transform_name=s,y,y,
  79
  80 AC_CANONICAL_SYSTEM
  81 AC_ARG_PROGRAM
  82
  83 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  84 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  85
  86 # Get 'install' or 'install-sh' and its variants.
  87 AC_PROG_INSTALL
  88 ACX_PROG_LN
  89 AC_PROG_LN_S
  90 AC_PROG_SED
  91 AC_PROG_AWK
  92
  93 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  94
  95 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  96 # a relative path.
  97 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  98   INSTALL="${srcpwd}/install-sh -c"
  99 fi
 100
 101 # Set srcdir to "." if that's what it is.
 102 # This is important for multilib support.
 103 pwd=`${PWDCMD-pwd}`
 104 if test "${pwd}" = "${srcpwd}" ; then
 105   srcdir=.
 106 fi
 107
 108 topsrcdir=$srcpwd
 109
 110 extra_host_args=
 111
 112 ### To add a new directory to the tree, first choose whether it is a target
 113 ### or a host dependent tool.  Then put it into the appropriate list
 114 ### (library or tools, host or target), doing a dependency sort.
 115
 116 # Subdirs will be configured in the order listed in build_configdirs,
 117 # configdirs, or target_configdirs; see the serialization section below.
 118
 119 # Dependency sorting is only needed when *configuration* must be done in
 120 # a particular order.  In all cases a dependency should be specified in
 121 # the Makefile, whether or not it's implicitly specified here.
 122
 123 # Double entries in build_configdirs, configdirs, or target_configdirs may
 124 # cause circular dependencies and break everything horribly.
 125
 126 # these library is used by various programs built for the build
 127 # environment
 128 #
 129 build_libs="build-libiberty"
 130
 131 # these tools are built for the build environment
 132 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 133
 134 # these libraries are used by various programs built for the host environment
 135 #
 136 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl cloog libelf libiconv"
 137
 138 # these tools are built for the host environment
 139 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 140 # know that we are building the simulator.
 141 # binutils, gas and ld appear in that order because it makes sense to run
 142 # "make check" in that particular order.
 143 # If --enable-gold is used, "gold" may replace "ld".
 144 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 145
 146 # libgcj represents the runtime libraries only used by gcj.
 147 libgcj="target-libffi \
 148         target-zlib \
 149         target-libjava"
 150
 151 # these libraries are built for the target environment, and are built after
 152 # the host libraries and the host tools (which may be a cross compiler)
 153 # Note that libiberty is not a target library.
 154 target_libraries="target-libgcc \
 155                 target-libbacktrace \
 156                 target-libgloss \
 157                 target-newlib \
 158                 target-libgomp \
 159                 target-libcilkrts \
 160                 target-libatomic \
 161                 target-libitm \
 162                 target-libstdc++-v3 \
 163                 target-libsanitizer \
 164                 target-libvtv \
 165                 target-libssp \
 166                 target-libquadmath \
 167                 target-libgfortran \
 168                 target-boehm-gc \
 169                 ${libgcj} \
 170                 target-libobjc \
 171                 target-libada \
 172                 target-libgo"
 173
 174 # these tools are built using the target libraries, and are intended to
 175 # run only in the target environment
 176 #
 177 # note: any program that *uses* libraries that are in the "target_libraries"
 178 # list belongs in this list.
 179 #
 180 target_tools="target-rda"
 181
 182 ################################################################################
 183
 184 ## All tools belong in one of the four categories, and are assigned above
 185 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 186 ## is important because configure will choke if they ever get through.
 187 ## ${configdirs} is directories we build using the host tools.
 188 ## ${target_configdirs} is directories we build using the target tools.
 189 configdirs=`echo ${host_libs} ${host_tools}`
 190 target_configdirs=`echo ${target_libraries} ${target_tools}`
 191 build_configdirs=`echo ${build_libs} ${build_tools}`
 192
 193 m4_divert_text([PARSE_ARGS],
 194 [case $srcdir in
 195   *" "*)
 196 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 197     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 198 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 199     ;;
 200 esac
 201 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 202 ])
 203
 204 ################################################################################
 205
 206 srcname="gnu development package"
 207
 208 # This gets set non-empty for some net releases of packages.
 209 appdirs=""
 210
 211 # Define is_cross_compiler to save on calls to 'test'.
 212 is_cross_compiler=
 213 if test x"${host}" = x"${target}" ; then
 214   is_cross_compiler=no
 215 else
 216   is_cross_compiler=yes
 217 fi
 218
 219 # Find the build and target subdir names.
 220 GCC_TOPLEV_SUBDIRS
 221 # Be sure to cover against remnants of an in-tree build.
 222 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 223   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 224 Use a pristine source tree when building in a separate tree])
 225 fi
 226
 227 # Skipdirs are removed silently.
 228 skipdirs=
 229 # Noconfigdirs are removed loudly.
 230 noconfigdirs=""
 231
 232 use_gnu_ld=
 233 # Make sure we don't let GNU ld be added if we didn't want it.
 234 if test x$with_gnu_ld = xno ; then
 235   use_gnu_ld=no
 236   noconfigdirs="$noconfigdirs ld gold"
 237 fi
 238
 239 use_gnu_as=
 240 # Make sure we don't let GNU as be added if we didn't want it.
 241 if test x$with_gnu_as = xno ; then
 242   use_gnu_as=no
 243   noconfigdirs="$noconfigdirs gas"
 244 fi
 245
 246 use_included_zlib=
 247 # Make sure we don't let ZLIB be added if we didn't want it.
 248 if test x$with_system_zlib = xyes ; then
 249   use_included_zlib=no
 250   noconfigdirs="$noconfigdirs zlib"
 251 fi
 252
 253 # some tools are so dependent upon X11 that if we're not building with X,
 254 # it's not even worth trying to configure, much less build, that tool.
 255
 256 case ${with_x} in
 257   yes | "") ;; # the default value for this tree is that X11 is available
 258   no)
 259     skipdirs="${skipdirs} tk itcl libgui"
 260     # We won't be able to build gdbtk without X.
 261     enable_gdbtk=no
 262     ;;
 263   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 264 esac
 265
 266 # Some are only suitable for cross toolchains.
 267 # Remove these if host=target.
 268 cross_only="target-libgloss target-newlib target-opcodes"
 269
 270 case $is_cross_compiler in
 271   no) skipdirs="${skipdirs} ${cross_only}" ;;
 272 esac
 273
 274 # If both --with-headers and --with-libs are specified, default to
 275 # --without-newlib.
 276 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 277    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 278   if test x"${with_newlib}" = x ; then
 279     with_newlib=no
 280   fi
 281 fi
 282
 283 # Recognize --with-newlib/--without-newlib.
 284 case ${with_newlib} in
 285   no) skipdirs="${skipdirs} target-newlib" ;;
 286   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 287 esac
 288
 289 # Handle --enable-gold, --enable-ld.
 290 # --disable-gold [--enable-ld]
 291 #     Build only ld.  Default option.
 292 # --enable-gold [--enable-ld]
 293 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 294 #     as "ld.bfd" and "ld".
 295 # --enable-gold=default [--enable-ld]
 296 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 297 #     install ld as "ld.bfd".
 298 # --enable-gold[=default] --disable-ld
 299 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 300 # --enable-gold --enable-ld=default
 301 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 302 #     and ld.bfd).
 303 #     In other words, ld is default
 304 # --enable-gold=default --enable-ld=default
 305 #     Error.
 306
 307 default_ld=
 308 AC_ARG_ENABLE(gold,
 309 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 310                 [build gold @<:@ARG={default,yes,no}@:>@])],
 311 ENABLE_GOLD=$enableval,
 312 ENABLE_GOLD=no)
 313 case "${ENABLE_GOLD}" in
 314   yes|default)
 315     # Check for ELF target.
 316     is_elf=no
 317     case "${target}" in
 318       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 319       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 320       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 321       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 322         case "${target}" in
 323           *-*-linux*aout* | *-*-linux*oldld*)
 324             ;;
 325           *)
 326             is_elf=yes
 327             ;;
 328         esac
 329     esac
 330
 331     if test "$is_elf" = "yes"; then
 332       # Check for target supported by gold.
 333       case "${target}" in
 334         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* | tilegx*-*-*)
 335           configdirs="$configdirs gold"
 336           if test x${ENABLE_GOLD} = xdefault; then
 337             default_ld=gold
 338           fi
 339           ENABLE_GOLD=yes
 340           ;;
 341       esac
 342     fi
 343     ;;
 344   no)
 345     ;;
 346   *)
 347     AC_MSG_ERROR([invalid --enable-gold argument])
 348     ;;
 349 esac
 350
 351 AC_ARG_ENABLE(ld,
 352 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 353                 [build ld @<:@ARG={default,yes,no}@:>@])],
 354 ENABLE_LD=$enableval,
 355 ENABLE_LD=yes)
 356
 357 case "${ENABLE_LD}" in
 358   default)
 359     if test x${default_ld} != x; then
 360       AC_MSG_ERROR([either gold or ld can be the default ld])
 361     fi
 362     ;;
 363   yes)
 364     ;;
 365   no)
 366     if test x${ENABLE_GOLD} != xyes; then
 367       AC_MSG_WARN([neither ld nor gold are enabled])
 368     fi
 369     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 370     ;;
 371   *)
 372     AC_MSG_ERROR([invalid --enable-ld argument])
 373     ;;
 374 esac
 375
 376 # Configure extra directories which are host specific
 377
 378 case "${host}" in
 379   *-cygwin*)
 380     configdirs="$configdirs libtermcap" ;;
 381 esac
 382
 383 # A target can indicate whether a language isn't supported for some reason.
 384 # Only spaces may be used in this macro; not newlines or tabs.
 385 unsupported_languages=
 386
 387 # Remove more programs from consideration, based on the host or
 388 # target this usually means that a port of the program doesn't
 389 # exist yet.
 390
 391 case "${host}" in
 392   i[[3456789]]86-*-msdosdjgpp*)
 393     noconfigdirs="$noconfigdirs tcl tk itcl"
 394     ;;
 395 esac
 396
 397
 398 AC_ARG_ENABLE(libquadmath,
 399 AS_HELP_STRING([--disable-libquadmath],
 400   [do not build libquadmath directory]),
 401 ENABLE_LIBQUADMATH=$enableval,
 402 ENABLE_LIBQUADMATH=yes)
 403 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 404   noconfigdirs="$noconfigdirs target-libquadmath"
 405 fi
 406
 407
 408 AC_ARG_ENABLE(libquadmath-support,
 409 AS_HELP_STRING([--disable-libquadmath-support],
 410   [disable libquadmath support for Fortran]),
 411 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 412 ENABLE_LIBQUADMATH_SUPPORT=yes)
 413 enable_libquadmath_support=
 414 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 415   enable_libquadmath_support=no
 416 fi
 417
 418
 419 AC_ARG_ENABLE(libada,
 420 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 421 ENABLE_LIBADA=$enableval,
 422 ENABLE_LIBADA=yes)
 423 if test "${ENABLE_LIBADA}" != "yes" ; then
 424   noconfigdirs="$noconfigdirs gnattools"
 425 fi
 426
 427 AC_ARG_ENABLE(libssp,
 428 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 429 ENABLE_LIBSSP=$enableval,
 430 ENABLE_LIBSSP=yes)
 431
 432 AC_ARG_ENABLE(libstdcxx,
 433 AS_HELP_STRING([--disable-libstdcxx],
 434   [do not build libstdc++-v3 directory]),
 435 ENABLE_LIBSTDCXX=$enableval,
 436 ENABLE_LIBSTDCXX=default)
 437 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 438   noconfigdirs="$noconfigdirs libstdc++-v3"
 439 fi]
 440
 441 # Save it here so that, even in case of --enable-libgcj, if the Java
 442 # front-end isn't enabled, we still get libgcj disabled.
 443 libgcj_saved=$libgcj
 444 case $enable_libgcj in
 445 yes)
 446   # If we reset it here, it won't get added to noconfigdirs in the
 447   # target-specific build rules, so it will be forcibly enabled
 448   # (unless the Java language itself isn't enabled).
 449   libgcj=
 450   ;;
 451 no)
 452   # Make sure we get it printed in the list of not supported target libs.
 453   # Don't disable libffi, though, other languages use it.
 454   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 455   # Clear libgcj_saved so that even if java is enabled libffi won't be
 456   # built.
 457   libgcj_saved=
 458   ;;
 459 esac
 460
 461 AC_ARG_ENABLE(static-libjava,
 462 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 463                 [build static libjava @<:@default=no@:>@])],
 464 ENABLE_STATIC_LIBJAVA=$enableval,
 465 ENABLE_STATIC_LIBJAVA=no)
 466 enable_static_libjava=
 467 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 468   enable_static_libjava=yes
 469 fi
 470
 471 if test x$enable_static_libjava != xyes ; then
 472   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 473 fi
 474 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 475
 476 # Disable libgomp on non POSIX hosted systems.
 477 if test x$enable_libgomp = x ; then
 478     # Enable libgomp by default on hosted POSIX systems.
 479     case "${target}" in
 480     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 481         ;;
 482     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 483         ;;
 484     *-*-solaris2* | *-*-hpux11*)
 485         ;;
 486     *-*-darwin* | *-*-aix*)
 487         ;;
 488     *)
 489         noconfigdirs="$noconfigdirs target-libgomp"
 490         ;;
 491     esac
 492 fi
 493
 494 # Disable libatomic on unsupported systems.
 495 if test -d ${srcdir}/libatomic; then
 496     if test x$enable_libatomic = x; then
 497         AC_MSG_CHECKING([for libatomic support])
 498         if (srcdir=${srcdir}/libatomic; \
 499                 . ${srcdir}/configure.tgt; \
 500                 test -n "$UNSUPPORTED")
 501         then
 502             AC_MSG_RESULT([no])
 503             noconfigdirs="$noconfigdirs target-libatomic"
 504         else
 505             AC_MSG_RESULT([yes])
 506         fi
 507     fi
 508 fi
 509
 510 # Disable libcilkrts on unsupported systems.
 511 if test -d ${srcdir}/libcilkrts; then
 512     if test x$enable_libcilkrts = x; then
 513         AC_MSG_CHECKING([for libcilkrts support])
 514         if (srcdir=${srcdir}/libcilkrts; \
 515                 . ${srcdir}/configure.tgt; \
 516                 test -n "$UNSUPPORTED")
 517         then
 518             AC_MSG_RESULT([no])
 519             noconfigdirs="$noconfigdirs target-libcilkrts"
 520         else
 521             AC_MSG_RESULT([yes])
 522         fi
 523     fi
 524 fi
 525
 526 # Disable libitm on unsupported systems.
 527 if test -d ${srcdir}/libitm; then
 528     if test x$enable_libitm = x; then
 529         AC_MSG_CHECKING([for libitm support])
 530         if (srcdir=${srcdir}/libitm; \
 531                 . ${srcdir}/configure.tgt; \
 532                 test -n "$UNSUPPORTED")
 533         then
 534             AC_MSG_RESULT([no])
 535             noconfigdirs="$noconfigdirs target-libitm"
 536         else
 537             AC_MSG_RESULT([yes])
 538         fi
 539     fi
 540 fi
 541
 542 # Disable libsanitizer on unsupported systems.
 543 if test -d ${srcdir}/libsanitizer; then
 544     if test x$enable_libsanitizer = x; then
 545         AC_MSG_CHECKING([for libsanitizer support])
 546         if (srcdir=${srcdir}/libsanitizer; \
 547                 . ${srcdir}/configure.tgt; \
 548                 test -n "$UNSUPPORTED")
 549         then
 550             AC_MSG_RESULT([no])
 551             noconfigdirs="$noconfigdirs target-libsanitizer"
 552         else
 553             AC_MSG_RESULT([yes])
 554         fi
 555     fi
 556 fi
 557
 558 # Disable libvtv on unsupported systems.
 559 if test -d ${srcdir}/libvtv; then
 560     if test x$enable_libvtv = x; then
 561         AC_MSG_CHECKING([for libvtv support])
 562         if (srcdir=${srcdir}/libvtv; \
 563                 . ${srcdir}/configure.tgt; \
 564                 test "$VTV_SUPPORTED" != "yes")
 565         then
 566             AC_MSG_RESULT([no])
 567             noconfigdirs="$noconfigdirs target-libvtv"
 568         else
 569             AC_MSG_RESULT([yes])
 570         fi
 571     fi
 572 fi
 573
 574 # Disable libquadmath for some systems.
 575 case "${target}" in
 576   avr-*-*)
 577     noconfigdirs="$noconfigdirs target-libquadmath"
 578     ;;
 579   # libquadmath is unused on AIX and libquadmath build process use of
 580   # LD_LIBRARY_PATH can break AIX bootstrap.
 581   powerpc-*-aix* | rs6000-*-aix*)
 582     noconfigdirs="$noconfigdirs target-libquadmath"
 583     ;;
 584 esac
 585
 586 # Disable libssp for some systems.
 587 case "${target}" in
 588   avr-*-*)
 589     # No hosted I/O support.
 590     noconfigdirs="$noconfigdirs target-libssp"
 591     ;;
 592   powerpc-*-aix* | rs6000-*-aix*)
 593     noconfigdirs="$noconfigdirs target-libssp"
 594     ;;
 595   rl78-*-*)
 596     # libssp uses a misaligned load to trigger a fault, but the RL78
 597     # doesn't fault for those - instead, it gives a build-time error
 598     # for explicit misaligned loads.
 599     noconfigdirs="$noconfigdirs target-libssp"
 600     ;;
 601 esac
 602
 603 # Disable libstdc++-v3 for some systems.
 604 # Allow user to override this if they pass --enable-libstdc++-v3
 605 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 606   case "${target}" in
 607     *-*-vxworks*)
 608       # VxWorks uses the Dinkumware C++ library.
 609       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 610       ;;
 611     arm*-wince-pe*)
 612       # the C++ libraries don't build on top of CE's C libraries
 613       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 614       ;;
 615     avr-*-*)
 616       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 617       ;;
 618   esac
 619 fi
 620
 621 # Disable Fortran for some systems.
 622 case "${target}" in
 623   mmix-*-*)
 624     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 625     unsupported_languages="$unsupported_languages fortran"
 626     ;;
 627 esac
 628
 629 # Disable Java if libffi is not supported.
 630 case "${target}" in
 631   aarch64-*-*)
 632     ;;
 633   alpha*-*-*)
 634     ;;
 635   arm*-*-*)
 636     ;;
 637   cris-*-*)
 638     ;;
 639   frv-*-*)
 640     ;;
 641   hppa*-*-linux*)
 642     ;;
 643   hppa*-*-hpux*)
 644     ;;
 645   i?86-*-*)
 646     ;;
 647   ia64*-*-*)
 648     ;;
 649   m32r*-*-*)
 650     ;;
 651   m68k-*-*)
 652     ;;
 653   mips*-*-rtems*)
 654     ;;
 655   mips*-*-linux*)
 656     ;;
 657   powerpc*-*-linux*)
 658     ;;
 659   powerpc-*-darwin*)
 660     ;;
 661   powerpc-*-aix* | rs6000-*-aix*)
 662     ;;
 663   powerpc-*-freebsd*)
 664     ;;
 665   powerpc64-*-freebsd*)
 666     ;;
 667   powerpc*-*-rtems*)
 668     ;;
 669   s390-*-* | s390x-*-*)
 670     ;;
 671   sh-*-* | sh[[34]]*-*-*)
 672     ;;
 673   sh64-*-* | sh5*-*-*)
 674     ;;
 675   sparc*-*-*)
 676     ;;
 677   x86_64-*-*)
 678     ;;
 679   *-*-*)
 680     unsupported_languages="$unsupported_languages java"
 681     ;;
 682 esac
 683
 684 # Disable Java, libgcj or related libraries for some systems.
 685 case "${target}" in
 686   powerpc-*-darwin*)
 687     ;;
 688   i[[3456789]]86-*-darwin*)
 689     ;;
 690   x86_64-*-darwin[[912]]*)
 691     ;;
 692   *-*-darwin*)
 693     noconfigdirs="$noconfigdirs ${libgcj}"
 694     ;;
 695   *-*-netware*)
 696     noconfigdirs="$noconfigdirs ${libgcj}"
 697     ;;
 698   *-*-rtems*)
 699     noconfigdirs="$noconfigdirs ${libgcj}"
 700     ;;
 701   *-*-tpf*)
 702     noconfigdirs="$noconfigdirs ${libgcj}"
 703     ;;
 704   *-*-uclinux*)
 705     noconfigdirs="$noconfigdirs ${libgcj}"
 706     ;;
 707   *-*-vxworks*)
 708     noconfigdirs="$noconfigdirs ${libgcj}"
 709     ;;
 710   alpha*-*-*vms*)
 711     noconfigdirs="$noconfigdirs ${libgcj}"
 712     ;;
 713   arm-wince-pe)
 714     noconfigdirs="$noconfigdirs ${libgcj}"
 715     ;;
 716   arm*-*-symbianelf*)
 717     noconfigdirs="$noconfigdirs ${libgcj}"
 718     ;;
 719   bfin-*-*)
 720     noconfigdirs="$noconfigdirs target-boehm-gc"
 721     ;;
 722   cris-*-* | crisv32-*-*)
 723     unsupported_languages="$unsupported_languages java"
 724     case "${target}" in
 725       *-*-linux*)
 726         ;;
 727       *) # See PR46792 regarding target-libffi.
 728         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 729     esac
 730     ;;
 731   hppa*64*-*-linux*)
 732     # In this case, it's because the hppa64-linux target is for
 733     # the kernel only at this point and has no libc, and thus no
 734     # headers, crt*.o, etc., all of which are needed by these.
 735     unsupported_languages="$unsupported_languages java"
 736     ;;
 737   hppa*64*-*-hpux*)
 738     noconfigdirs="$noconfigdirs ${libgcj}"
 739     ;;
 740   hppa*-hp-hpux11*)
 741     ;;
 742   hppa*-*-hpux*)
 743     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 744     # build on HP-UX 10.20.
 745     noconfigdirs="$noconfigdirs ${libgcj}"
 746     ;;
 747   ia64*-*-*vms*)
 748     noconfigdirs="$noconfigdirs ${libgcj}"
 749     ;;
 750   i[[3456789]]86-w64-mingw*)
 751     noconfigdirs="$noconfigdirs ${libgcj}"
 752     ;;
 753   i[[3456789]]86-*-mingw*)
 754     noconfigdirs="$noconfigdirs ${libgcj}"
 755     ;;
 756   x86_64-*-mingw*)
 757     noconfigdirs="$noconfigdirs ${libgcj}"
 758     ;;
 759   mmix-*-*)
 760     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 761     ;;
 762   powerpc-*-aix*)
 763     # copied from rs6000-*-* entry
 764     noconfigdirs="$noconfigdirs ${libgcj}"
 765     ;;
 766   rs6000-*-aix*)
 767     noconfigdirs="$noconfigdirs ${libgcj}"
 768     ;;
 769   *-*-lynxos*)
 770     noconfigdirs="$noconfigdirs ${libgcj}"
 771     ;;
 772 esac
 773
 774 # Disable libgo for some systems where it is known to not work.
 775 # For testing, you can easily override this with --enable-libgo.
 776 if test x$enable_libgo = x; then
 777     case "${target}" in
 778     *-*-darwin*)
 779         # PR 46986
 780         noconfigdirs="$noconfigdirs target-libgo"
 781         ;;
 782     *-*-cygwin* | *-*-mingw*)
 783         noconfigdirs="$noconfigdirs target-libgo"
 784         ;;
 785     *-*-aix*)
 786         noconfigdirs="$noconfigdirs target-libgo"
 787         ;;
 788     esac
 789 fi
 790
 791 # Default libgloss CPU subdirectory.
 792 libgloss_dir="$target_cpu"
 793
 794 case "${target}" in
 795   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 796     libgloss_dir=wince
 797     ;;
 798   aarch64*-*-* )
 799     libgloss_dir=aarch64
 800     ;;
 801   arm*-*-*)
 802     libgloss_dir=arm
 803     ;;
 804   cris-*-* | crisv32-*-*)
 805     libgloss_dir=cris
 806     ;;
 807   hppa*-*-*)
 808     libgloss_dir=pa
 809     ;;
 810   i[[3456789]]86-*-*)
 811     libgloss_dir=i386
 812     ;;
 813   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 814     libgloss_dir=m68hc11
 815     ;;
 816   m68*-*-* | fido-*-*)
 817     libgloss_dir=m68k
 818     ;;
 819   mips*-*-*)
 820     libgloss_dir=mips
 821     ;;
 822   powerpc*-*-*)
 823     libgloss_dir=rs6000
 824     ;;
 825   sparc*-*-*)
 826     libgloss_dir=sparc
 827     ;;
 828 esac
 829
 830 # Disable newlib and libgloss for various target OSes.
 831 case "${target}" in
 832   alpha*-dec-osf*)
 833     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 834     ;;
 835   i[[3456789]]86-*-linux*)
 836     # This section makes it possible to build newlib natively on linux.
 837     # If we are using a cross compiler then don't configure newlib.
 838     if test x${is_cross_compiler} != xno ; then
 839       noconfigdirs="$noconfigdirs target-newlib"
 840     fi
 841     noconfigdirs="$noconfigdirs target-libgloss"
 842     # If we are not using a cross compiler, do configure newlib.
 843     # Note however, that newlib will only be configured in this situation
 844     # if the --with-newlib option has been given, because otherwise
 845     # 'target-newlib' will appear in skipdirs.
 846     ;;
 847   i[[3456789]]86-*-rdos*)
 848     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 849     ;;
 850   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 851     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 852     ;;
 853   sparc-*-sunos4*)
 854     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 855     ;;
 856   *-*-aix*)
 857     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 858     ;;
 859   *-*-beos*)
 860     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 861     ;;
 862   *-*-chorusos)
 863     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 864     ;;
 865   *-*-dragonfly*)
 866     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 867     ;;
 868   *-*-freebsd*)
 869     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 870     ;;
 871   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 872     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 873     ;;
 874   *-*-lynxos*)
 875     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 876     ;;
 877   *-*-mingw*)
 878     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 879     ;;
 880   *-*-netbsd*)
 881     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 882     ;;
 883   *-*-netware*)
 884     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 885     ;;
 886   *-*-tpf*)
 887     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 888     ;;
 889   *-*-uclinux*)
 890     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 891     ;;
 892   *-*-vxworks*)
 893     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 894     ;;
 895 esac
 896
 897 case "${target}" in
 898   *-*-chorusos)
 899     ;;
 900   powerpc-*-darwin*)
 901     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 902     noconfigdirs="$noconfigdirs sim target-rda"
 903     ;;
 904   i[[3456789]]86-*-darwin*)
 905     noconfigdirs="$noconfigdirs ld gprof"
 906     noconfigdirs="$noconfigdirs sim target-rda"
 907     ;;
 908   x86_64-*-darwin[[912]]*)
 909     noconfigdirs="$noconfigdirs ld gas gprof"
 910     noconfigdirs="$noconfigdirs sim target-rda"
 911     ;;
 912   *-*-darwin*)
 913     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 914     noconfigdirs="$noconfigdirs sim target-rda"
 915     ;;
 916   *-*-dragonfly*)
 917     ;;
 918   *-*-freebsd*)
 919     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 920         && test -f /usr/local/include/gmp.h; then
 921       with_gmp=/usr/local
 922     fi
 923     ;;
 924   *-*-kaos*)
 925     # Remove unsupported stuff on all kaOS configurations.
 926     noconfigdirs="$noconfigdirs target-libgloss"
 927     ;;
 928   *-*-netbsd*)
 929     ;;
 930   *-*-netware*)
 931     ;;
 932   *-*-rtems*)
 933     noconfigdirs="$noconfigdirs target-libgloss"
 934     ;;
 935     # The tpf target doesn't support gdb yet.
 936   *-*-tpf*)
 937     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 938     ;;
 939   *-*-uclinux*)
 940     noconfigdirs="$noconfigdirs target-rda"
 941     ;;
 942   *-*-vxworks*)
 943     ;;
 944   alpha*-dec-osf*)
 945     # ld works, but does not support shared libraries.
 946     # gas doesn't generate exception information.
 947     noconfigdirs="$noconfigdirs gas ld"
 948     ;;
 949   alpha*-*-*vms*)
 950     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 951     ;;
 952   alpha*-*-*)
 953     # newlib is not 64 bit ready
 954     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 955     ;;
 956   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 957     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 958     ;;
 959   arc-*-*|arceb-*-*)
 960     noconfigdirs="$noconfigdirs target-libgloss"
 961     ;;
 962   arm*-*-linux-androideabi)
 963     noconfigdirs="$noconfigdirs target-libiberty"
 964     ;;
 965   arm-*-pe*)
 966     noconfigdirs="$noconfigdirs target-libgloss"
 967     ;;
 968   arm-*-riscix*)
 969     noconfigdirs="$noconfigdirs ld target-libgloss"
 970     ;;
 971   avr-*-rtems*)
 972     ;;
 973   avr-*-*)
 974     if test x${with_avrlibc} != xno; then
 975       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 976     fi
 977     ;;
 978   c4x-*-* | tic4x-*-*)
 979     noconfigdirs="$noconfigdirs target-libgloss"
 980     ;;
 981   tic54x-*-*)
 982     noconfigdirs="$noconfigdirs target-libgloss gdb"
 983     ;;
 984   d10v-*-*)
 985     noconfigdirs="$noconfigdirs target-libgloss"
 986     ;;
 987   d30v-*-*)
 988     noconfigdirs="$noconfigdirs gdb"
 989     ;;
 990   fr30-*-elf*)
 991     noconfigdirs="$noconfigdirs gdb"
 992     ;;
 993   moxie-*-*)
 994     noconfigdirs="$noconfigdirs gprof"
 995     ;;
 996   h8300*-*-*)
 997     noconfigdirs="$noconfigdirs target-libgloss"
 998     ;;
 999   h8500-*-*)
1000     noconfigdirs="$noconfigdirs target-libgloss"
1001     ;;
1002   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1003     ;;
1004   hppa*64*-*-linux*)
1005     ;;
1006   hppa*-*-linux*)
1007     ;;
1008   hppa*-*-*elf* | \
1009   hppa*-*-lites* | \
1010   hppa*-*-openbsd* | \
1011   hppa*64*-*-*)
1012     ;;
1013   hppa*-hp-hpux11*)
1014     noconfigdirs="$noconfigdirs ld"
1015     ;;
1016   hppa*-*-pro*)
1017     ;;
1018   hppa*-*-*)
1019     noconfigdirs="$noconfigdirs ld"
1020     ;;
1021   i960-*-*)
1022     noconfigdirs="$noconfigdirs gdb"
1023     ;;
1024   ia64*-*-elf*)
1025     # No gdb support yet.
1026     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1027     ;;
1028   ia64*-**-hpux*)
1029     # No ld support yet.
1030     noconfigdirs="$noconfigdirs libgui itcl ld"
1031     ;;
1032   ia64*-*-*vms*)
1033     # No ld support yet.
1034     noconfigdirs="$noconfigdirs libgui itcl ld"
1035     ;;
1036   i[[3456789]]86-w64-mingw*)
1037     ;;
1038   i[[3456789]]86-*-mingw*)
1039     target_configdirs="$target_configdirs target-winsup"
1040     ;;
1041   *-*-cygwin*)
1042     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1043     noconfigdirs="$noconfigdirs target-libgloss"
1044     # always build newlib if winsup directory is present.
1045     if test -d "$srcdir/winsup/cygwin"; then
1046       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1047     elif test -d "$srcdir/newlib"; then
1048       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1049     fi
1050     ;;
1051   i[[3456789]]86-*-pe)
1052     noconfigdirs="$noconfigdirs target-libgloss"
1053     ;;
1054   i[[3456789]]86-*-sco3.2v5*)
1055     # The linker does not yet know about weak symbols in COFF,
1056     # and is not configured to handle mixed ELF and COFF.
1057     noconfigdirs="$noconfigdirs ld target-libgloss"
1058     ;;
1059   i[[3456789]]86-*-sco*)
1060     noconfigdirs="$noconfigdirs gprof target-libgloss"
1061     ;;
1062   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1063     noconfigdirs="$noconfigdirs target-libgloss"
1064     ;;
1065   i[[3456789]]86-*-sysv4*)
1066     noconfigdirs="$noconfigdirs target-libgloss"
1067     ;;
1068   i[[3456789]]86-*-beos*)
1069     noconfigdirs="$noconfigdirs gdb"
1070     ;;
1071   i[[3456789]]86-*-rdos*)
1072     noconfigdirs="$noconfigdirs gdb"
1073     ;;
1074   mmix-*-*)
1075     noconfigdirs="$noconfigdirs gdb"
1076     ;;
1077   mt-*-*)
1078     noconfigdirs="$noconfigdirs sim"
1079     ;;
1080   powerpc-*-aix*)
1081     # copied from rs6000-*-* entry
1082     noconfigdirs="$noconfigdirs gprof"
1083     ;;
1084   powerpc*-*-winnt* | powerpc*-*-pe*)
1085     target_configdirs="$target_configdirs target-winsup"
1086     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1087     # always build newlib.
1088     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1089     ;;
1090     # This is temporary until we can link against shared libraries
1091   powerpcle-*-solaris*)
1092     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1093     ;;
1094   powerpc-*-beos*)
1095     noconfigdirs="$noconfigdirs gdb"
1096     ;;
1097   rs6000-*-lynxos*)
1098     noconfigdirs="$noconfigdirs gprof"
1099     ;;
1100   rs6000-*-aix*)
1101     noconfigdirs="$noconfigdirs gprof"
1102     ;;
1103   rs6000-*-*)
1104     noconfigdirs="$noconfigdirs gprof"
1105     ;;
1106   m68k-apollo-*)
1107     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1108     ;;
1109   microblaze*)
1110     noconfigdirs="$noconfigdirs gprof"
1111     ;;
1112   mips*-sde-elf* | mips*-mti-elf*)
1113     if test x$with_newlib = xyes; then
1114       noconfigdirs="$noconfigdirs gprof"
1115     fi
1116     ;;
1117   mips*-*-irix5*)
1118     noconfigdirs="$noconfigdirs gprof target-libgloss"
1119     ;;
1120   mips*-*-irix6*)
1121     noconfigdirs="$noconfigdirs gprof target-libgloss"
1122     ;;
1123   mips*-*-bsd*)
1124     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1125     ;;
1126   mips*-*-linux*)
1127     ;;
1128   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1129   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1130     noconfigdirs="$noconfigdirs ld gas gprof"
1131     ;;
1132   mips*-*-*)
1133     noconfigdirs="$noconfigdirs gprof"
1134     ;;
1135   sh-*-* | sh64-*-*)
1136     case "${target}" in
1137       sh*-*-elf)
1138          ;;
1139       *)
1140          noconfigdirs="$noconfigdirs target-libgloss" ;;
1141     esac
1142     ;;
1143   sparc-*-sunos4*)
1144     if test x${is_cross_compiler} = xno ; then
1145            use_gnu_ld=no
1146     fi
1147     ;;
1148   tic6x-*-*)
1149     noconfigdirs="$noconfigdirs sim"
1150     ;;
1151   tilepro*-*-* | tilegx*-*-*)
1152     noconfigdirs="$noconfigdirs sim"
1153     ;;
1154   v810-*-*)
1155     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1156     ;;
1157   vax-*-*)
1158     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1159     ;;
1160 esac
1161
1162 # If we aren't building newlib, then don't build libgloss, since libgloss
1163 # depends upon some newlib header files.
1164 case "${noconfigdirs}" in
1165   *target-libgloss*) ;;
1166   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1167 esac
1168
1169 # Work in distributions that contain no compiler tools, like Autoconf.
1170 host_makefile_frag=/dev/null
1171 if test -d ${srcdir}/config ; then
1172 case "${host}" in
1173   i[[3456789]]86-*-msdosdjgpp*)
1174     host_makefile_frag="config/mh-djgpp"
1175     ;;
1176   *-cygwin*)
1177     ACX_CHECK_CYGWIN_CAT_WORKS
1178     host_makefile_frag="config/mh-cygwin"
1179     ;;
1180   *-mingw*)
1181     host_makefile_frag="config/mh-mingw"
1182     ;;
1183   alpha*-*-linux*)
1184     host_makefile_frag="config/mh-alpha-linux"
1185     ;;
1186   hppa*-hp-hpux10*)
1187     host_makefile_frag="config/mh-pa-hpux10"
1188     ;;
1189   hppa*-hp-hpux*)
1190     host_makefile_frag="config/mh-pa"
1191     ;;
1192   hppa*-*)
1193     host_makefile_frag="config/mh-pa"
1194     ;;
1195   *-*-darwin*)
1196     host_makefile_frag="config/mh-darwin"
1197     ;;
1198   powerpc-*-aix*)
1199     host_makefile_frag="config/mh-ppc-aix"
1200     ;;
1201   rs6000-*-aix*)
1202     host_makefile_frag="config/mh-ppc-aix"
1203     ;;
1204 esac
1205 fi
1206
1207 if test "${build}" != "${host}" ; then
1208   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1209   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1210   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1211   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1212   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1213   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1214   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1215   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1216   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1217   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1218   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1219   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1220   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1221 else
1222   AR_FOR_BUILD="\$(AR)"
1223   AS_FOR_BUILD="\$(AS)"
1224   CC_FOR_BUILD="\$(CC)"
1225   CXX_FOR_BUILD="\$(CXX)"
1226   GCJ_FOR_BUILD="\$(GCJ)"
1227   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1228   GOC_FOR_BUILD="\$(GOC)"
1229   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1230   LD_FOR_BUILD="\$(LD)"
1231   NM_FOR_BUILD="\$(NM)"
1232   RANLIB_FOR_BUILD="\$(RANLIB)"
1233   WINDRES_FOR_BUILD="\$(WINDRES)"
1234   WINDMC_FOR_BUILD="\$(WINDMC)"
1235 fi
1236
1237 AC_PROG_CC
1238 AC_PROG_CXX
1239
1240 # We must set the default linker to the linker used by gcc for the correct
1241 # operation of libtool.  If LD is not defined and we are using gcc, try to
1242 # set the LD default to the ld used by gcc.
1243 if test -z "$LD"; then
1244   if test "$GCC" = yes; then
1245     case $build in
1246     *-*-mingw*)
1247       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1248     *)
1249       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1250     esac
1251     case $gcc_prog_ld in
1252     # Accept absolute paths.
1253     [[\\/]* | [A-Za-z]:[\\/]*)]
1254       LD="$gcc_prog_ld" ;;
1255     esac
1256   fi
1257 fi
1258
1259 # Check whether -static-libstdc++ -static-libgcc is supported.
1260 have_static_libs=no
1261 if test "$GCC" = yes; then
1262   saved_LDFLAGS="$LDFLAGS"
1263
1264   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1265   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1266   AC_LANG_PUSH(C++)
1267   AC_LINK_IFELSE([
1268 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1269 #error -static-libstdc++ not implemented
1270 #endif
1271 int main() {}],
1272     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1273     [AC_MSG_RESULT([no])])
1274   AC_LANG_POP(C++)
1275
1276   LDFLAGS="$saved_LDFLAGS"
1277 fi
1278
1279 ACX_PROG_GNAT
1280 ACX_PROG_CMP_IGNORE_INITIAL
1281
1282 AC_ARG_ENABLE([bootstrap],
1283 [AS_HELP_STRING([--enable-bootstrap],
1284                 [enable bootstrapping @<:@yes if native build@:>@])],,
1285 enable_bootstrap=default)
1286
1287 # Issue errors and warnings for invalid/strange bootstrap combinations.
1288 if test -r $srcdir/gcc/configure; then
1289   have_compiler=yes
1290 else
1291   have_compiler=no
1292 fi
1293
1294 case "$have_compiler:$host:$target:$enable_bootstrap" in
1295   *:*:*:no) ;;
1296
1297   # Default behavior.  Enable bootstrap if we have a compiler
1298   # and we are in a native configuration.
1299   yes:$build:$build:default)
1300     enable_bootstrap=yes ;;
1301
1302   *:*:*:default)
1303     enable_bootstrap=no ;;
1304
1305   # We have a compiler and we are in a native configuration, bootstrap is ok
1306   yes:$build:$build:yes)
1307     ;;
1308
1309   # Other configurations, but we have a compiler.  Assume the user knows
1310   # what he's doing.
1311   yes:*:*:yes)
1312     AC_MSG_WARN([trying to bootstrap a cross compiler])
1313     ;;
1314
1315   # No compiler: if they passed --enable-bootstrap explicitly, fail
1316   no:*:*:yes)
1317     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1318
1319   # Fail if wrong command line
1320   *)
1321     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1322     ;;
1323 esac
1324
1325 # Used for setting $lt_cv_objdir
1326 _LT_CHECK_OBJDIR
1327
1328 # Check for GMP, MPFR and MPC
1329 gmplibs="-lmpc -lmpfr -lgmp"
1330 gmpinc=
1331 have_gmp=no
1332
1333 # Specify a location for mpc
1334 # check for this first so it ends up on the link line before mpfr.
1335 AC_ARG_WITH(mpc,
1336 [AS_HELP_STRING([--with-mpc=PATH],
1337                 [specify prefix directory for installed MPC package.
1338                  Equivalent to --with-mpc-include=PATH/include
1339                  plus --with-mpc-lib=PATH/lib])])
1340 AC_ARG_WITH(mpc-include,
1341 [AS_HELP_STRING([--with-mpc-include=PATH],
1342                 [specify directory for installed MPC include files])])
1343 AC_ARG_WITH(mpc-lib,
1344 [AS_HELP_STRING([--with-mpc-lib=PATH],
1345                 [specify directory for the installed MPC library])])
1346
1347 if test "x$with_mpc" != x; then
1348   gmplibs="-L$with_mpc/lib $gmplibs"
1349   gmpinc="-I$with_mpc/include $gmpinc"
1350 fi
1351 if test "x$with_mpc_include" != x; then
1352   gmpinc="-I$with_mpc_include $gmpinc"
1353 fi
1354 if test "x$with_mpc_lib" != x; then
1355   gmplibs="-L$with_mpc_lib $gmplibs"
1356 fi
1357 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1358   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1359   gmpinc='-I$$s/mpc/src '"$gmpinc"
1360   # Do not test the mpc version.  Assume that it is sufficient, since
1361   # it is in the source tree, and the library has not been built yet
1362   # but it would be included on the link line in the version check below
1363   # hence making the test fail.
1364   have_gmp=yes
1365 fi
1366
1367 # Specify a location for mpfr
1368 # check for this first so it ends up on the link line before gmp.
1369 AC_ARG_WITH(mpfr-dir,
1370 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1371 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1372 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1373
1374 AC_ARG_WITH(mpfr,
1375 [AS_HELP_STRING([--with-mpfr=PATH],
1376                 [specify prefix directory for installed MPFR package.
1377                  Equivalent to --with-mpfr-include=PATH/include
1378                  plus --with-mpfr-lib=PATH/lib])])
1379 AC_ARG_WITH(mpfr-include,
1380 [AS_HELP_STRING([--with-mpfr-include=PATH],
1381                 [specify directory for installed MPFR include files])])
1382 AC_ARG_WITH(mpfr-lib,
1383 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1384                 [specify directory for the installed MPFR library])])
1385
1386 if test "x$with_mpfr" != x; then
1387   gmplibs="-L$with_mpfr/lib $gmplibs"
1388   gmpinc="-I$with_mpfr/include $gmpinc"
1389 fi
1390 if test "x$with_mpfr_include" != x; then
1391   gmpinc="-I$with_mpfr_include $gmpinc"
1392 fi
1393 if test "x$with_mpfr_lib" != x; then
1394   gmplibs="-L$with_mpfr_lib $gmplibs"
1395 fi
1396 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1397   # MPFR v3.1.0 moved the sources into a src sub-directory.
1398   if test -d ${srcdir}/mpfr/src; then
1399     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1400     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1401     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1402   else
1403     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1404     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1405     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1406   fi
1407   # Do not test the mpfr version.  Assume that it is sufficient, since
1408   # it is in the source tree, and the library has not been built yet
1409   # but it would be included on the link line in the version check below
1410   # hence making the test fail.
1411   have_gmp=yes
1412 fi
1413
1414 # Specify a location for gmp
1415 AC_ARG_WITH(gmp-dir,
1416 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1417 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1418 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1419
1420 AC_ARG_WITH(gmp,
1421 [AS_HELP_STRING([--with-gmp=PATH],
1422                 [specify prefix directory for the installed GMP package.
1423                  Equivalent to --with-gmp-include=PATH/include
1424                  plus --with-gmp-lib=PATH/lib])])
1425 AC_ARG_WITH(gmp-include,
1426 [AS_HELP_STRING([--with-gmp-include=PATH],
1427                 [specify directory for installed GMP include files])])
1428 AC_ARG_WITH(gmp-lib,
1429 [AS_HELP_STRING([--with-gmp-lib=PATH],
1430                 [specify directory for the installed GMP library])])
1431
1432
1433 if test "x$with_gmp" != x; then
1434   gmplibs="-L$with_gmp/lib $gmplibs"
1435   gmpinc="-I$with_gmp/include $gmpinc"
1436 fi
1437 if test "x$with_gmp_include" != x; then
1438   gmpinc="-I$with_gmp_include $gmpinc"
1439 fi
1440 if test "x$with_gmp_lib" != x; then
1441   gmplibs="-L$with_gmp_lib $gmplibs"
1442 fi
1443 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1444   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1445   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1446   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1447   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1448   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1449   # Do not test the gmp version.  Assume that it is sufficient, since
1450   # it is in the source tree, and the library has not been built yet
1451   # but it would be included on the link line in the version check below
1452   # hence making the test fail.
1453   have_gmp=yes
1454 fi
1455
1456 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1457   have_gmp=yes
1458   saved_CFLAGS="$CFLAGS"
1459   CFLAGS="$CFLAGS $gmpinc"
1460   # Check for the recommended and required versions of GMP.
1461   AC_MSG_CHECKING([for the correct version of gmp.h])
1462   AC_TRY_COMPILE([#include "gmp.h"],[
1463   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1464   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1465   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1466   choke me
1467   #endif
1468   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1469   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1470   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1471   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1472   choke me
1473   #endif
1474   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1475    [AC_MSG_RESULT([no]); have_gmp=no])
1476
1477   # If we have GMP, check the MPFR version.
1478   if test x"$have_gmp" = xyes; then
1479     # Check for the recommended and required versions of MPFR.
1480     AC_MSG_CHECKING([for the correct version of mpfr.h])
1481     AC_TRY_COMPILE([#include <gmp.h>
1482     #include <mpfr.h>],[
1483     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1484     choke me
1485     #endif
1486     ], [AC_TRY_COMPILE([#include <gmp.h>
1487     #include <mpfr.h>],[
1488     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1489     choke me
1490     #endif
1491     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1492      [AC_MSG_RESULT([no]); have_gmp=no])
1493   fi
1494
1495   # Check for the MPC header version.
1496   if test x"$have_gmp" = xyes ; then
1497     # Check for the recommended and required versions of MPC.
1498     AC_MSG_CHECKING([for the correct version of mpc.h])
1499     AC_TRY_COMPILE([#include <mpc.h>],[
1500     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1501     choke me
1502     #endif
1503     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1504     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1505     choke me
1506     #endif
1507     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1508      [AC_MSG_RESULT([no]); have_gmp=no])
1509   fi
1510
1511   # Now check the MPFR library.
1512   if test x"$have_gmp" = xyes; then
1513     saved_LIBS="$LIBS"
1514     LIBS="$LIBS $gmplibs"
1515     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1516     AC_TRY_LINK([#include <mpc.h>],[
1517     mpfr_t n;
1518     mpfr_t x;
1519     mpc_t c;
1520     int t;
1521     mpfr_init (n);
1522     mpfr_init (x);
1523     mpfr_atan2 (n, n, x, GMP_RNDN);
1524     mpfr_erfc (n, x, GMP_RNDN);
1525     mpfr_subnormalize (x, t, GMP_RNDN);
1526     mpfr_clear(n);
1527     mpfr_clear(x);
1528     mpc_init2 (c, 53);
1529     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1530     mpc_cosh (c, c, MPC_RNDNN);
1531     mpc_pow (c, c, c, MPC_RNDNN);
1532     mpc_acosh (c, c, MPC_RNDNN);
1533     mpc_clear (c);
1534     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1535     LIBS="$saved_LIBS"
1536   fi
1537
1538   CFLAGS="$saved_CFLAGS"
1539
1540 # The library versions listed in the error message below should match
1541 # the HARD-minimums enforced above.
1542   if test x$have_gmp != xyes; then
1543     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1544 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1545 their locations.  Source code for these libraries can be found at
1546 their respective hosting sites as well as at
1547 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1548 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1549 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1550 make sure that you have installed both the libraries and the header
1551 files.  They may be located in separate packages.])
1552   fi
1553 fi
1554
1555 # Flags needed for both GMP, MPFR and/or MPC.
1556 AC_SUBST(gmplibs)
1557 AC_SUBST(gmpinc)
1558 AC_SUBST(extra_mpfr_configure_flags)
1559 AC_SUBST(extra_mpc_gmp_configure_flags)
1560 AC_SUBST(extra_mpc_mpfr_configure_flags)
1561 AC_SUBST(extra_isl_gmp_configure_flags)
1562
1563 # Allow host libstdc++ to be specified for static linking with PPL.
1564 AC_ARG_WITH(host-libstdcxx,
1565 [AS_HELP_STRING([--with-host-libstdcxx=L],
1566                 [use linker arguments L to link with libstdc++
1567                  when linking with PPL])])
1568
1569 case $with_host_libstdcxx in
1570   no|yes)
1571     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1572     ;;
1573 esac
1574
1575 # Libraries to use for stage1 or when not bootstrapping.
1576 AC_ARG_WITH(stage1-libs,
1577 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1578 [if test "$withval" = "no" -o "$withval" = "yes"; then
1579    stage1_libs=
1580  else
1581    stage1_libs=$withval
1582  fi],
1583 [stage1_libs=$with_host_libstdcxx])
1584 AC_SUBST(stage1_libs)
1585
1586 # Linker flags to use for stage1 or when not bootstrapping.
1587 AC_ARG_WITH(stage1-ldflags,
1588 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1589 [if test "$withval" = "no" -o "$withval" = "yes"; then
1590    stage1_ldflags=
1591  else
1592    stage1_ldflags=$withval
1593  fi],
1594 [stage1_ldflags=
1595  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1596  # if supported.  But if the user explicitly specified the libraries to use,
1597  # trust that they are doing what they want.
1598  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1599    stage1_ldflags="-static-libstdc++ -static-libgcc"
1600  fi])
1601 AC_SUBST(stage1_ldflags)
1602
1603 # Libraries to use for stage2 and later builds.  This defaults to the
1604 # argument passed to --with-host-libstdcxx.
1605 AC_ARG_WITH(boot-libs,
1606 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1607 [if test "$withval" = "no" -o "$withval" = "yes"; then
1608    poststage1_libs=
1609  else
1610    poststage1_libs=$withval
1611  fi],
1612 [poststage1_libs=$with_host_libstdcxx])
1613 AC_SUBST(poststage1_libs)
1614
1615 # Linker flags to use for stage2 and later builds.
1616 AC_ARG_WITH(boot-ldflags,
1617 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1618                 [linker flags for stage2 and later])],
1619 [if test "$withval" = "no" -o "$withval" = "yes"; then
1620    poststage1_ldflags=
1621  else
1622    poststage1_ldflags=$withval
1623  fi],
1624 [poststage1_ldflags=
1625  # In stages 2 and 3, default to linking libstdc++ and libgcc
1626  # statically.  But if the user explicitly specified the libraries to
1627  # use, trust that they are doing what they want.
1628  if test "$poststage1_libs" = ""; then
1629    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1630  fi])
1631 AC_SUBST(poststage1_ldflags)
1632
1633 # GCC GRAPHITE dependences, ISL and CLOOG which in turn requires ISL.
1634 # Basic setup is inlined here, actual checks are in config/cloog.m4 and
1635 # config/isl.m4
1636
1637 AC_ARG_WITH(cloog,
1638   [AS_HELP_STRING(
1639     [--with-cloog=PATH],
1640     [Specify prefix directory for the installed CLooG-ISL package.
1641      Equivalent to --with-cloog-include=PATH/include
1642      plus --with-cloog-lib=PATH/lib])])
1643 AC_ARG_WITH(isl,
1644   [AS_HELP_STRING(
1645    [--with-isl=PATH],
1646    [Specify prefix directory for the installed ISL package.
1647     Equivalent to --with-isl-include=PATH/include
1648     plus --with-isl-lib=PATH/lib])])
1649
1650 # Treat either --without-cloog or --without-isl as a request to disable
1651 # GRAPHITE support and skip all following checks.
1652 if test "x$with_isl" != "xno" &&
1653    test "x$with_cloog" != "xno"; then
1654   # Check for ISL
1655   dnl Provide configure switches and initialize islinc & isllibs
1656   dnl with user input.
1657   ISL_INIT_FLAGS
1658   dnl The versions of ISL that work for Graphite
1659   ISL_CHECK_VERSION(0,10)
1660   if test "${gcc_cv_isl}" = no ; then
1661     ISL_CHECK_VERSION(0,11)
1662     if test "${gcc_cv_isl}" = no ; then
1663       ISL_CHECK_VERSION(0,12)
1664       if test "${gcc_cv_isl}" = no ; then
1665         ISL_CHECK_VERSION(0,14)
1666       fi
1667     fi
1668   fi
1669   dnl Only execute fail-action, if ISL has been requested.
1670   ISL_IF_FAILED([
1671     AC_MSG_ERROR([Unable to find a usable ISL.  See config.log for details.])])
1672
1673   if test "x$gcc_cv_isl" != "xno"; then
1674     # Check for CLOOG
1675     dnl Provide configure switches and initialize clooginc & clooglibs
1676     dnl with user input.
1677     CLOOG_INIT_FLAGS
1678     dnl The versions of CLooG that work for Graphite.
1679     CLOOG_CHECK_VERSION(0,17,0)
1680     if test "${gcc_cv_cloog}" = no ; then
1681       CLOOG_CHECK_VERSION(0,18,0)
1682     fi
1683
1684     dnl Only execute fail-action, if CLooG has been requested.
1685     CLOOG_IF_FAILED([
1686       AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1687   fi
1688 fi
1689
1690 # If either the ISL or the CLooG check failed, disable builds of in-tree
1691 # variants of both
1692 if test "x$with_isl" = xno ||
1693    test "x$with_cloog" = xno ||
1694    test "x$gcc_cv_cloog" = xno ||
1695    test "x$gcc_cv_isl" = xno; then
1696   noconfigdirs="$noconfigdirs cloog isl"
1697   islinc=
1698   clooginc=
1699   clooglibs=
1700 fi
1701
1702 AC_SUBST(islinc)
1703 AC_SUBST(clooglibs)
1704 AC_SUBST(clooginc)
1705
1706
1707 # Check for LTO support.
1708 AC_ARG_ENABLE(lto,
1709 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1710 enable_lto=$enableval,
1711 enable_lto=yes; default_enable_lto=yes)
1712
1713 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1714   build_lto_plugin=yes
1715   # Allow ELF platforms to build the function_reordering_plugin always.
1716   build_function_reordering_plugin=yes
1717 ],[if test x"$default_enable_lto" = x"yes" ; then
1718     case $target in
1719       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1720       # On other non-ELF platforms, LTO has yet to be validated.
1721       *) enable_lto=no ;;
1722     esac
1723   else
1724   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1725   # It would also be nice to check the binutils support, but we don't
1726   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1727   # warn during gcc/ subconfigure; unless you're bootstrapping with
1728   # -flto it won't be needed until after installation anyway.
1729     case $target in
1730       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1731       *) if test x"$enable_lto" = x"yes"; then
1732         AC_MSG_ERROR([LTO support is not enabled for this target.])
1733         fi
1734       ;;
1735     esac
1736   fi
1737   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1738   # Build it unless LTO was explicitly disabled.
1739   case $target in
1740     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1741     *) ;;
1742   esac
1743 ])
1744
1745
1746 # By default, C and C++ are the only stage 1 languages.
1747 stage1_languages=,c,
1748
1749 # Target libraries that we bootstrap.
1750 bootstrap_target_libs=,target-libgcc,
1751
1752 # Figure out what language subdirectories are present.
1753 # Look if the user specified --enable-languages="..."; if not, use
1754 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1755 # go away some day.
1756 # NB:  embedded tabs in this IF block -- do not untabify
1757 if test -d ${srcdir}/gcc; then
1758   if test x"${enable_languages+set}" != xset; then
1759     if test x"${LANGUAGES+set}" = xset; then
1760       enable_languages="${LANGUAGES}"
1761         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1762     else
1763       enable_languages=all
1764     fi
1765   else
1766     if test x"${enable_languages}" = x ||
1767        test x"${enable_languages}" = xyes;
1768        then
1769       echo configure.in: --enable-languages needs at least one language argument 1>&2
1770       exit 1
1771     fi
1772   fi
1773   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1774
1775   # 'f95' is the old name for the 'fortran' language. We issue a warning
1776   # and make the substitution.
1777   case ,${enable_languages}, in
1778     *,f95,*)
1779       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1780       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1781       ;;
1782   esac
1783
1784   # If bootstrapping, C++ must be enabled.
1785   case ",$enable_languages,:$enable_bootstrap" in
1786     *,c++,*:*) ;;
1787     *:yes)
1788       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1789         enable_languages="${enable_languages},c++"
1790       else
1791         AC_MSG_ERROR([bootstrapping requires c++ sources])
1792       fi
1793       ;;
1794   esac
1795
1796   # First scan to see if an enabled language requires some other language.
1797   # We assume that a given config-lang.in will list all the language
1798   # front ends it requires, even if some are required indirectly.
1799   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1800     case ${lang_frag} in
1801       ..) ;;
1802       # The odd quoting in the next line works around
1803       # an apparent bug in bash 1.12 on linux.
1804       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1805       *)
1806         # From the config-lang.in, get $language, $lang_requires, and
1807         # $lang_requires_boot_languages.
1808         language=
1809         lang_requires=
1810         lang_requires_boot_languages=
1811         . ${lang_frag}
1812         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1813           case ,${enable_languages}, in
1814             *,$other,*) ;;
1815             *,all,*) ;;
1816             *,$language,*)
1817               echo " \`$other' language required by \`$language'; enabling" 1>&2
1818               enable_languages="${enable_languages},${other}"
1819               ;;
1820           esac
1821         done
1822         for other in ${lang_requires_boot_languages} ; do
1823           if test "$other" != "c"; then
1824             case ,${enable_stage1_languages}, in
1825               *,$other,*) ;;
1826               *,all,*) ;;
1827               *)
1828                 case ,${enable_languages}, in
1829                   *,$language,*)
1830                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1831                     enable_stage1_languages="$enable_stage1_languages,${other}"
1832                     ;;
1833                 esac
1834                 ;;
1835             esac
1836           fi
1837         done
1838         ;;
1839     esac
1840   done
1841
1842   new_enable_languages=,c,
1843
1844   # If LTO is enabled, add the LTO front end.
1845   extra_host_libiberty_configure_flags=
1846   if test "$enable_lto" = "yes" ; then
1847     case ,${enable_languages}, in
1848       *,lto,*) ;;
1849       *) enable_languages="${enable_languages},lto" ;;
1850     esac
1851     if test "${build_lto_plugin}" = "yes" ; then
1852       configdirs="$configdirs lto-plugin"
1853       extra_host_libiberty_configure_flags=--enable-shared
1854     fi
1855   fi
1856   if test "${build_function_reordering_plugin}" = "yes" ; then
1857     configdirs="$configdirs function_reordering_plugin"
1858     extra_host_libiberty_configure_flags=--enable-shared
1859   fi
1860
1861   AC_SUBST(extra_host_libiberty_configure_flags)
1862
1863   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1864   potential_languages=,c,
1865
1866   enabled_target_libs=
1867   disabled_target_libs=
1868
1869   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1870     case ${lang_frag} in
1871       ..) ;;
1872       # The odd quoting in the next line works around
1873       # an apparent bug in bash 1.12 on linux.
1874       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1875       *)
1876         # From the config-lang.in, get $language, $target_libs,
1877         # $lang_dirs, $boot_language, and $build_by_default
1878         language=
1879         target_libs=
1880         lang_dirs=
1881         subdir_requires=
1882         boot_language=no
1883         build_by_default=yes
1884         . ${lang_frag}
1885         if test x${language} = x; then
1886           echo "${lang_frag} doesn't set \$language." 1>&2
1887           exit 1
1888         fi
1889
1890         if test "$language" = "c++"; then
1891           boot_language=yes
1892         fi
1893
1894         add_this_lang=no
1895         case ,${enable_languages}, in
1896           *,${language},*)
1897             # Language was explicitly selected; include it
1898             # unless it is C, which is enabled by default.
1899             if test "$language" != "c"; then
1900               add_this_lang=yes
1901             fi
1902             ;;
1903           *,all,*)
1904             # 'all' was selected, select it if it is a default language
1905             if test "$language" != "c"; then
1906               add_this_lang=${build_by_default}
1907             fi
1908             ;;
1909         esac
1910
1911         # Disable languages that need other directories if these aren't available.
1912         for i in $subdir_requires; do
1913           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1914           case ,${enable_languages}, in
1915             *,${language},*)
1916               # Specifically requested language; tell them.
1917               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1918               ;;
1919             *)
1920               # Silently disable.
1921               add_this_lang=unsupported
1922               ;;
1923           esac
1924         done
1925
1926         # Disable Ada if no preexisting GNAT is available.
1927         case ,${enable_languages},:${language}:${have_gnat} in
1928           *,${language},*:ada:no)
1929             # Specifically requested language; tell them.
1930             AC_MSG_ERROR([GNAT is required to build $language])
1931             ;;
1932           *:ada:no)
1933             # Silently disable.
1934             add_this_lang=unsupported
1935             ;;
1936         esac
1937
1938         # Disable a language that is unsupported by the target.
1939         case " $unsupported_languages " in
1940           *" $language "*)
1941             add_this_lang=unsupported
1942             ;;
1943         esac
1944
1945         case $add_this_lang in
1946           unsupported)
1947             # Remove language-dependent dirs.
1948             disabled_target_libs="$disabled_target_libs $target_libs"
1949             noconfigdirs="$noconfigdirs $lang_dirs"
1950             ;;
1951           no)
1952             # Remove language-dependent dirs; still show language as supported.
1953             disabled_target_libs="$disabled_target_libs $target_libs"
1954             noconfigdirs="$noconfigdirs $lang_dirs"
1955             potential_languages="${potential_languages}${language},"
1956             ;;
1957           yes)
1958             new_enable_languages="${new_enable_languages}${language},"
1959             potential_languages="${potential_languages}${language},"
1960             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1961             enabled_target_libs="$enabled_target_libs $target_libs"
1962             case "${boot_language}:,$enable_stage1_languages," in
1963               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1964                 # Add to (comma-separated) list of stage 1 languages.
1965                 case ",$stage1_languages," in
1966                   *,$language,* | ,yes, | ,all,) ;;
1967                   *) stage1_languages="${stage1_languages}${language}," ;;
1968                 esac
1969                 # We need to bootstrap any supporting libraries.
1970                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1971                 ;;
1972             esac
1973             ;;
1974         esac
1975         ;;
1976     esac
1977   done
1978
1979   # Add target libraries which are only needed for disabled languages
1980   # to noconfigdirs.
1981   if test -n "$disabled_target_libs"; then
1982     for dir in $disabled_target_libs; do
1983       case " $enabled_target_libs " in
1984       *" ${dir} "*) ;;
1985       *) noconfigdirs="$noconfigdirs $dir" ;;
1986       esac
1987     done
1988   fi
1989
1990   AC_ARG_ENABLE(stage1-languages,
1991   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1992                   [choose additional languages to build during
1993                   stage1.  Mostly useful for compiler development])],
1994   [case ,${enable_stage1_languages}, in
1995     ,no,|,,)
1996       # Set it to something that will have no effect in the loop below
1997       enable_stage1_languages=c ;;
1998     ,yes,)
1999       enable_stage1_languages=`echo $new_enable_languages | \
2000         sed -e "s/^,//" -e "s/,$//" ` ;;
2001     *,all,*)
2002       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2003         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2004   esac
2005
2006   # Add "good" languages from enable_stage1_languages to stage1_languages,
2007   # while "bad" languages go in missing_languages.  Leave no duplicates.
2008   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2009     case $potential_languages in
2010       *,$i,*)
2011         case $stage1_languages in
2012           *,$i,*) ;;
2013           *) stage1_languages="$stage1_languages$i," ;;
2014         esac ;;
2015       *)
2016         case $missing_languages in
2017           *,$i,*) ;;
2018           *) missing_languages="$missing_languages$i," ;;
2019         esac ;;
2020      esac
2021   done])
2022
2023   # Remove leading/trailing commas that were added for simplicity
2024   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2025   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2026   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2027   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2028
2029   if test "x$missing_languages" != x; then
2030     AC_MSG_ERROR([
2031 The following requested languages could not be built: ${missing_languages}
2032 Supported languages are: ${potential_languages}])
2033   fi
2034   if test "x$new_enable_languages" != "x$enable_languages"; then
2035     echo The following languages will be built: ${new_enable_languages}
2036     enable_languages="$new_enable_languages"
2037   fi
2038
2039   AC_SUBST(stage1_languages)
2040   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2041 fi
2042
2043 # Handle --disable-<component> generically.
2044 for dir in $configdirs $build_configdirs $target_configdirs ; do
2045   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2046   varname=`echo $dirname | sed -e s/+/_/g`
2047   if eval test x\${enable_${varname}} "=" xno ; then
2048     noconfigdirs="$noconfigdirs $dir"
2049   fi
2050 done
2051
2052 # Check for Boehm's garbage collector
2053 AC_ARG_ENABLE(objc-gc,
2054 [AS_HELP_STRING([--enable-objc-gc],
2055                 [enable use of Boehm's garbage collector with the
2056                  GNU Objective-C runtime])],
2057 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
2058   *,objc,*:*:yes:*target-boehm-gc*)
2059     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
2060     ;;
2061 esac])
2062
2063 # Make sure we only build Boehm's garbage collector if required.
2064 case ,${enable_languages},:${enable_objc_gc} in
2065   *,objc,*:yes)
2066     # Keep target-boehm-gc if requested for Objective-C.
2067     ;;
2068   *)
2069     # Otherwise remove target-boehm-gc depending on target-libjava.
2070     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
2071       noconfigdirs="$noconfigdirs target-boehm-gc"
2072     fi
2073     ;;
2074 esac
2075
2076 # Disable libitm, libsanitizer, libvtv if we're not building C++
2077 case ,${enable_languages}, in
2078   *,c++,*) ;;
2079   *)
2080     noconfigdirs="$noconfigdirs target-libcilkrts target-libitm target-libsanitizer target-libvtv"
2081     ;;
2082 esac
2083
2084 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2085 # $build_configdirs and $target_configdirs.
2086 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2087
2088 notsupp=""
2089 for dir in . $skipdirs $noconfigdirs ; do
2090   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2091   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2092     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2093     if test -r $srcdir/$dirname/configure ; then
2094       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2095         true
2096       else
2097         notsupp="$notsupp $dir"
2098       fi
2099     fi
2100   fi
2101   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2102     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2103     if test -r $srcdir/$dirname/configure ; then
2104       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2105         true
2106       else
2107         notsupp="$notsupp $dir"
2108       fi
2109     fi
2110   fi
2111   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2112     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2113     if test -r $srcdir/$dirname/configure ; then
2114       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2115         true
2116       else
2117         notsupp="$notsupp $dir"
2118       fi
2119     fi
2120   fi
2121 done
2122
2123 # Quietly strip out all directories which aren't configurable in this tree.
2124 # This relies on all configurable subdirectories being autoconfiscated, which
2125 # is now the case.
2126 build_configdirs_all="$build_configdirs"
2127 build_configdirs=
2128 for i in ${build_configdirs_all} ; do
2129   j=`echo $i | sed -e s/build-//g`
2130   if test -f ${srcdir}/$j/configure ; then
2131     build_configdirs="${build_configdirs} $i"
2132   fi
2133 done
2134
2135 configdirs_all="$configdirs"
2136 configdirs=
2137 for i in ${configdirs_all} ; do
2138   if test -f ${srcdir}/$i/configure ; then
2139     configdirs="${configdirs} $i"
2140   fi
2141 done
2142
2143 target_configdirs_all="$target_configdirs"
2144 target_configdirs=
2145 for i in ${target_configdirs_all} ; do
2146   j=`echo $i | sed -e s/target-//g`
2147   if test -f ${srcdir}/$j/configure ; then
2148     target_configdirs="${target_configdirs} $i"
2149   fi
2150 done
2151
2152 # Produce a warning message for the subdirs we can't configure.
2153 # This isn't especially interesting in the Cygnus tree, but in the individual
2154 # FSF releases, it's important to let people know when their machine isn't
2155 # supported by the one or two programs in a package.
2156
2157 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2158   # If $appdirs is non-empty, at least one of those directories must still
2159   # be configured, or we error out.  (E.g., if the gas release supports a
2160   # specified target in some subdirs but not the gas subdir, we shouldn't
2161   # pretend that all is well.)
2162   if test -n "$appdirs" ; then
2163     for dir in $appdirs ; do
2164       if test -r $dir/Makefile.in ; then
2165         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2166           appdirs=""
2167           break
2168         fi
2169         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2170           appdirs=""
2171           break
2172         fi
2173       fi
2174     done
2175     if test -n "$appdirs" ; then
2176       echo "*** This configuration is not supported by this package." 1>&2
2177       exit 1
2178     fi
2179   fi
2180   # Okay, some application will build, or we don't care to check.  Still
2181   # notify of subdirs not getting built.
2182   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2183   echo "    ${notsupp}" 1>&2
2184   echo "    (Any other directories should still work fine.)" 1>&2
2185 fi
2186
2187 case "$host" in
2188   *msdosdjgpp*)
2189     enable_gdbtk=no ;;
2190 esac
2191
2192 # To find our prefix, in gcc_cv_tool_prefix.
2193 ACX_TOOL_DIRS
2194
2195 copy_dirs=
2196
2197 AC_ARG_WITH([build-sysroot],
2198   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2199                   [use sysroot as the system root during the build])],
2200   [if test x"$withval" != x ; then
2201      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2202    fi],
2203   [SYSROOT_CFLAGS_FOR_TARGET=])
2204 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2205
2206 AC_ARG_WITH([debug-prefix-map],
2207   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2208                   [map A to B, C to D ... in debug information])],
2209   [if test x"$withval" != x; then
2210      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2211      for debug_map in $withval; do
2212        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2213      done
2214    fi],
2215   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2216 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2217
2218 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2219 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2220 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2221 # We want to ensure that TARGET libraries (which we know are built with
2222 # gcc) are built with "-O2 -g", so include those options when setting
2223 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2224 if test "x$CFLAGS_FOR_TARGET" = x; then
2225   CFLAGS_FOR_TARGET=$CFLAGS
2226   case " $CFLAGS " in
2227     *" -O2 "*) ;;
2228     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2229   esac
2230   case " $CFLAGS " in
2231     *" -g "* | *" -g3 "*) ;;
2232     *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2233   esac
2234 fi
2235 AC_SUBST(CFLAGS_FOR_TARGET)
2236
2237 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2238   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2239   case " $CXXFLAGS " in
2240     *" -O2 "*) ;;
2241     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2242   esac
2243   case " $CXXFLAGS " in
2244     *" -g "* | *" -g3 "*) ;;
2245     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2246   esac
2247 fi
2248 AC_SUBST(CXXFLAGS_FOR_TARGET)
2249
2250 AC_SUBST(LDFLAGS_FOR_TARGET)
2251
2252 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2253 # the named directory are copied to $(tooldir)/sys-include.
2254 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2255   if test x${is_cross_compiler} = xno ; then
2256     echo 1>&2 '***' --with-headers is only supported when cross compiling
2257     exit 1
2258   fi
2259   if test x"${with_headers}" != xyes ; then
2260     x=${gcc_cv_tool_prefix}
2261     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2262   fi
2263 fi
2264
2265 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2266 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2267 # are permitted.
2268 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2269   if test x${is_cross_compiler} = xno ; then
2270     echo 1>&2 '***' --with-libs is only supported when cross compiling
2271     exit 1
2272   fi
2273   if test x"${with_libs}" != xyes ; then
2274     # Copy the libraries in reverse order, so that files in the first named
2275     # library override files in subsequent libraries.
2276     x=${gcc_cv_tool_prefix}
2277     for l in ${with_libs}; do
2278       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2279     done
2280   fi
2281 fi
2282
2283 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2284 #
2285 # This is done by determining whether or not the appropriate directory
2286 # is available, and by checking whether or not specific configurations
2287 # have requested that this magic not happen.
2288 #
2289 # The command line options always override the explicit settings in
2290 # configure.in, and the settings in configure.in override this magic.
2291 #
2292 # If the default for a toolchain is to use GNU as and ld, and you don't
2293 # want to do that, then you should use the --without-gnu-as and
2294 # --without-gnu-ld options for the configure script.  Similarly, if
2295 # the default is to use the included zlib and you don't want to do that,
2296 # you should use the --with-system-zlib option for the configure script.
2297
2298 if test x${use_gnu_as} = x &&
2299    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2300   with_gnu_as=yes
2301   extra_host_args="$extra_host_args --with-gnu-as"
2302 fi
2303
2304 if test x${use_gnu_ld} = x &&
2305    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2306   with_gnu_ld=yes
2307   extra_host_args="$extra_host_args --with-gnu-ld"
2308 fi
2309
2310 if test x${use_included_zlib} = x &&
2311    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2312   :
2313 else
2314   with_system_zlib=yes
2315   extra_host_args="$extra_host_args --with-system-zlib"
2316 fi
2317
2318 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2319 # can detect this case.
2320
2321 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2322   with_newlib=yes
2323   extra_host_args="$extra_host_args --with-newlib"
2324 fi
2325
2326 # Handle ${copy_dirs}
2327 set fnord ${copy_dirs}
2328 shift
2329 while test $# != 0 ; do
2330   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2331     :
2332   else
2333     echo Copying $1 to $2
2334
2335     # Use the install script to create the directory and all required
2336     # parent directories.
2337     if test -d $2 ; then
2338       :
2339     else
2340       echo >config.temp
2341       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2342     fi
2343
2344     # Copy the directory, assuming we have tar.
2345     # FIXME: Should we use B in the second tar?  Not all systems support it.
2346     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2347
2348     # It is the responsibility of the user to correctly adjust all
2349     # symlinks.  If somebody can figure out how to handle them correctly
2350     # here, feel free to add the code.
2351
2352     echo $1 > $2/COPIED
2353   fi
2354   shift; shift
2355 done
2356
2357 # Determine a target-dependent exec_prefix that the installed
2358 # gcc will search in.  Keep this list sorted by triplet, with
2359 # the *-*-osname triplets last.
2360 md_exec_prefix=
2361 case "${target}" in
2362   i[[34567]]86-pc-msdosdjgpp*)
2363     md_exec_prefix=/dev/env/DJDIR/bin
2364     ;;
2365   *-*-hpux* | \
2366   *-*-nto-qnx* | \
2367   *-*-solaris2*)
2368     md_exec_prefix=/usr/ccs/bin
2369     ;;
2370 esac
2371
2372 extra_arflags_for_target=
2373 extra_nmflags_for_target=
2374 extra_ranlibflags_for_target=
2375 target_makefile_frag=/dev/null
2376 case "${target}" in
2377   spu-*-*)
2378     target_makefile_frag="config/mt-spu"
2379     ;;
2380   mips*-sde-elf* | mips*-mti-elf*)
2381     target_makefile_frag="config/mt-sde"
2382     ;;
2383   mipsisa*-*-elfoabi*)
2384     target_makefile_frag="config/mt-mips-elfoabi"
2385     ;;
2386   mips*-*-*linux* | mips*-*-gnu*)
2387     target_makefile_frag="config/mt-mips-gnu"
2388     ;;
2389   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2390     target_makefile_frag="config/mt-gnu"
2391     ;;
2392   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2393     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2394     # commands to handle both 32-bit and 64-bit objects.  These flags are
2395     # harmless if we're using GNU nm or ar.
2396     extra_arflags_for_target=" -X32_64"
2397     extra_nmflags_for_target=" -B -X32_64"
2398     ;;
2399 esac
2400
2401 alphaieee_frag=/dev/null
2402 case $target in
2403   alpha*-*-*)
2404     # This just makes sure to use the -mieee option to build target libs.
2405     # This should probably be set individually by each library.
2406     alphaieee_frag="config/mt-alphaieee"
2407     ;;
2408 esac
2409
2410 # If --enable-target-optspace always use -Os instead of -O2 to build
2411 # the target libraries, similarly if it is not specified, use -Os
2412 # on selected platforms.
2413 ospace_frag=/dev/null
2414 case "${enable_target_optspace}:${target}" in
2415   yes:*)
2416     ospace_frag="config/mt-ospace"
2417     ;;
2418   :d30v-*)
2419     ospace_frag="config/mt-d30v"
2420     ;;
2421   :m32r-* | :d10v-* | :fr30-*)
2422     ospace_frag="config/mt-ospace"
2423     ;;
2424   no:* | :*)
2425     ;;
2426   *)
2427     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2428     ;;
2429 esac
2430
2431 # Some systems (e.g., one of the i386-aix systems the gas testers are
2432 # using) don't handle "\$" correctly, so don't use it here.
2433 tooldir='${exec_prefix}'/${target_noncanonical}
2434 build_tooldir=${tooldir}
2435
2436 # Create a .gdbinit file which runs the one in srcdir
2437 # and tells GDB to look there for source files.
2438
2439 if test -r ${srcdir}/.gdbinit ; then
2440   case ${srcdir} in
2441     .) ;;
2442     *) cat > ./.gdbinit <<EOF
2443 # ${NO_EDIT}
2444 dir ${srcdir}
2445 dir .
2446 source ${srcdir}/.gdbinit
2447 EOF
2448     ;;
2449   esac
2450 fi
2451
2452 # Make sure that the compiler is able to generate an executable.  If it
2453 # can't, we are probably in trouble.  We don't care whether we can run the
2454 # executable--we might be using a cross compiler--we only care whether it
2455 # can be created.  At this point the main configure script has set CC.
2456 we_are_ok=no
2457 echo "int main () { return 0; }" > conftest.c
2458 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2459 if test $? = 0 ; then
2460   if test -s conftest || test -s conftest.exe ; then
2461     we_are_ok=yes
2462   fi
2463 fi
2464 case $we_are_ok in
2465   no)
2466     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2467     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2468     rm -f conftest*
2469     exit 1
2470     ;;
2471 esac
2472 rm -f conftest*
2473
2474 # Decide which environment variable is used to find dynamic libraries.
2475 case "${host}" in
2476   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2477   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2478   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2479   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2480 esac
2481
2482 # On systems where the dynamic library environment variable is PATH,
2483 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2484 # built executables to PATH.
2485 if test "$RPATH_ENVVAR" = PATH; then
2486   GCC_SHLIB_SUBDIR=/shlib
2487 else
2488   GCC_SHLIB_SUBDIR=
2489 fi
2490
2491 # Adjust the toplevel makefile according to whether bootstrap was selected.
2492 case $enable_bootstrap in
2493   yes)
2494     bootstrap_suffix=bootstrap
2495     BUILD_CONFIG=bootstrap-debug
2496     ;;
2497   no)
2498     bootstrap_suffix=no-bootstrap
2499     BUILD_CONFIG=
2500     ;;
2501 esac
2502
2503 AC_MSG_CHECKING(for default BUILD_CONFIG)
2504
2505 AC_ARG_WITH([build-config],
2506   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2507                   [use config/NAME.mk build configuration])],
2508   [case $with_build_config in
2509    yes) with_build_config= ;;
2510    no) with_build_config= BUILD_CONFIG= ;;
2511    esac])
2512
2513 if test "x${with_build_config}" != x; then
2514   BUILD_CONFIG=$with_build_config
2515 else
2516   case $BUILD_CONFIG in
2517   bootstrap-debug)
2518     if echo "int f (void) { return 0; }" > conftest.c &&
2519        ${CC} -c conftest.c &&
2520        mv conftest.o conftest.o.g0 &&
2521        ${CC} -c -g conftest.c &&
2522        mv conftest.o conftest.o.g &&
2523        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2524       :
2525     else
2526       BUILD_CONFIG=
2527     fi
2528     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2529     ;;
2530   esac
2531 fi
2532 AC_MSG_RESULT($BUILD_CONFIG)
2533 AC_SUBST(BUILD_CONFIG)
2534
2535 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2536 AC_MSG_CHECKING([for --enable-vtable-verify])
2537 AC_ARG_ENABLE(vtable-verify,
2538 [  --enable-vtable-verify    Enable vtable verification feature ],
2539 [case "$enableval" in
2540  yes) enable_vtable_verify=yes ;;
2541  no)  enable_vtable_verify=no ;;
2542  *)   enable_vtable_verify=no;;
2543  esac],
2544 [enable_vtable_verify=no])
2545 AC_MSG_RESULT($enable_vtable_verify)
2546
2547 # Record target_configdirs and the configure arguments for target and
2548 # build configuration in Makefile.
2549 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2550 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2551 bootstrap_fixincludes=no
2552
2553 # If we are building libgomp, bootstrap it.
2554 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2555   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2556 fi
2557
2558 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2559 # or bootstrap-ubsan, bootstrap it.
2560 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2561   case "$BUILD_CONFIG" in
2562     *bootstrap-asan* | *bootstrap-ubsan* )
2563       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2564       bootstrap_fixincludes=yes
2565       ;;
2566   esac
2567 fi
2568
2569 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2570 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2571    test "$enable_vtable_verify" != no; then
2572   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2573 fi
2574
2575 # Determine whether gdb needs tk/tcl or not.
2576 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2577 # and in that case we want gdb to be built without tk.  Ugh!
2578 # In fact I believe gdb is the *only* package directly dependent on tk,
2579 # so we should be able to put the 'maybe's in unconditionally and
2580 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2581 # 100% sure that that's safe though.
2582
2583 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2584 case "$enable_gdbtk" in
2585   no)
2586     GDB_TK="" ;;
2587   yes)
2588     GDB_TK="${gdb_tk}" ;;
2589   *)
2590     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2591     # distro.  Eventually someone will fix this and move Insight, nee
2592     # gdbtk to a separate directory.
2593     if test -d ${srcdir}/gdb/gdbtk ; then
2594       GDB_TK="${gdb_tk}"
2595     else
2596       GDB_TK=""
2597     fi
2598     ;;
2599 esac
2600 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2601 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2602
2603 # Strip out unwanted targets.
2604
2605 # While at that, we remove Makefiles if we were started for recursive
2606 # configuration, so that the top-level Makefile reconfigures them,
2607 # like we used to do when configure itself was recursive.
2608
2609 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2610 # but now we're fixing up the Makefile ourselves with the additional
2611 # commands passed to AC_CONFIG_FILES.  Use separate variables
2612 # extrasub-{build,host,target} not because there is any reason to split
2613 # the substitutions up that way, but only to remain below the limit of
2614 # 99 commands in a script, for HP-UX sed.
2615 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2616
2617 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2618   yes:yes:*\ gold\ *:*,c++,*) ;;
2619   yes:yes:*\ gold\ *:*)
2620     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2621     ;;
2622 esac
2623
2624 extrasub_build=
2625 for module in ${build_configdirs} ; do
2626   if test -z "${no_recursion}" \
2627      && test -f ${build_subdir}/${module}/Makefile; then
2628     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2629     rm -f ${build_subdir}/${module}/Makefile
2630   fi
2631   extrasub_build="$extrasub_build
2632 /^@if build-$module\$/d
2633 /^@endif build-$module\$/d
2634 /^@if build-$module-$bootstrap_suffix\$/d
2635 /^@endif build-$module-$bootstrap_suffix\$/d"
2636 done
2637 extrasub_host=
2638 for module in ${configdirs} ; do
2639   if test -z "${no_recursion}"; then
2640     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2641       if test -f ${file}; then
2642         echo 1>&2 "*** removing ${file} to force reconfigure"
2643         rm -f ${file}
2644       fi
2645     done
2646   fi
2647   case ${module},${bootstrap_fixincludes} in
2648     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2649     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2650   esac
2651   extrasub_host="$extrasub_host
2652 /^@if $module\$/d
2653 /^@endif $module\$/d
2654 /^@if $module-$host_bootstrap_suffix\$/d
2655 /^@endif $module-$host_bootstrap_suffix\$/d"
2656 done
2657 extrasub_target=
2658 for module in ${target_configdirs} ; do
2659   if test -z "${no_recursion}" \
2660      && test -f ${target_subdir}/${module}/Makefile; then
2661     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2662     rm -f ${target_subdir}/${module}/Makefile
2663   fi
2664
2665   # We only bootstrap target libraries listed in bootstrap_target_libs.
2666   case $bootstrap_target_libs in
2667     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2668     *) target_bootstrap_suffix=no-bootstrap ;;
2669   esac
2670
2671   extrasub_target="$extrasub_target
2672 /^@if target-$module\$/d
2673 /^@endif target-$module\$/d
2674 /^@if target-$module-$target_bootstrap_suffix\$/d
2675 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2676 done
2677
2678 # Do the final fixup along with target modules.
2679 extrasub_target="$extrasub_target
2680 /^@if /,/^@endif /d"
2681
2682 # Create the serialization dependencies.  This uses a temporary file.
2683
2684 AC_ARG_ENABLE([serial-configure],
2685 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2686                 [force sequential configuration of
2687                  sub-packages for the host, target or build
2688                  machine, or all sub-packages])])
2689
2690 case ${enable_serial_configure} in
2691   yes)
2692     enable_serial_build_configure=yes
2693     enable_serial_host_configure=yes
2694     enable_serial_target_configure=yes
2695     ;;
2696 esac
2697
2698 # These force 'configure's to be done one at a time, to avoid problems
2699 # with contention over a shared config.cache.
2700 rm -f serdep.tmp
2701 echo '# serdep.tmp' > serdep.tmp
2702 olditem=
2703 test "x${enable_serial_build_configure}" = xyes &&
2704 for item in ${build_configdirs} ; do
2705   case ${olditem} in
2706     "") ;;
2707     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2708   esac
2709   olditem=${item}
2710 done
2711 olditem=
2712 test "x${enable_serial_host_configure}" = xyes &&
2713 for item in ${configdirs} ; do
2714   case ${olditem} in
2715     "") ;;
2716     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2717   esac
2718   olditem=${item}
2719 done
2720 olditem=
2721 test "x${enable_serial_target_configure}" = xyes &&
2722 for item in ${target_configdirs} ; do
2723   case ${olditem} in
2724     "") ;;
2725     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2726   esac
2727   olditem=${item}
2728 done
2729 serialization_dependencies=serdep.tmp
2730 AC_SUBST_FILE(serialization_dependencies)
2731
2732 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2733 # target, nonopt, and variable assignments.  These are the ones we
2734 # might not want to pass down to subconfigures.  The exception being
2735 # --cache-file=/dev/null, which is used to turn off the use of cache
2736 # files altogether, and which should be passed on to subconfigures.
2737 # Also strip program-prefix, program-suffix, and program-transform-name,
2738 # so that we can pass down a consistent program-transform-name.
2739 baseargs=
2740 tbaseargs=
2741 keep_next=no
2742 skip_next=no
2743 eval "set -- $ac_configure_args"
2744 for ac_arg
2745 do
2746   if test X"$skip_next" = X"yes"; then
2747     skip_next=no
2748     continue
2749   fi
2750   if test X"$keep_next" = X"yes"; then
2751     case $ac_arg in
2752       *\'*)
2753         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2754     esac
2755     baseargs="$baseargs '$ac_arg'"
2756     tbaseargs="$tbaseargs '$ac_arg'"
2757     keep_next=no
2758     continue
2759   fi
2760
2761   # Handle separated arguments.  Based on the logic generated by
2762   # autoconf 2.59.
2763   case $ac_arg in
2764     *=* | --config-cache | -C | -disable-* | --disable-* \
2765       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2766       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2767       | -with-* | --with-* | -without-* | --without-* | --x)
2768       separate_arg=no
2769       ;;
2770     -*)
2771       separate_arg=yes
2772       ;;
2773     *)
2774       separate_arg=no
2775       ;;
2776   esac
2777
2778   skip_targ=no
2779   case $ac_arg in
2780 changequote(,)
2781   --with-* | --without-*)
2782     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2783
2784     case $libopt in
2785     *[-_]include)
2786       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2787       ;;
2788     *[-_]lib)
2789       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2790       ;;
2791     *)
2792       lib=$libopt
2793       ;;
2794     esac
2795 changequote([,])
2796
2797     case $lib in
2798     mpc | mpfr | gmp | cloog)
2799       # If we're processing --with-$lib, --with-$lib-include or
2800       # --with-$lib-lib, for one of the libs above, and target is
2801       # different from host, don't pass the current argument to any
2802       # target library's configure.
2803       if test x$is_cross_compiler = xyes; then
2804         skip_targ=yes
2805       fi
2806       ;;
2807     esac
2808     ;;
2809   esac
2810
2811   case "$ac_arg" in
2812     --cache-file=/dev/null | \
2813     -cache-file=/dev/null )
2814       # Handled here to avoid the test to skip args below.
2815       baseargs="$baseargs '$ac_arg'"
2816       tbaseargs="$tbaseargs '$ac_arg'"
2817       # Assert: $separate_arg should always be no.
2818       keep_next=$separate_arg
2819       ;;
2820     --no*)
2821       continue
2822       ;;
2823     --c* | \
2824     --sr* | \
2825     --ho* | \
2826     --bu* | \
2827     --t* | \
2828     --program-* | \
2829     -cache_file* | \
2830     -srcdir* | \
2831     -host* | \
2832     -build* | \
2833     -target* | \
2834     -program-prefix* | \
2835     -program-suffix* | \
2836     -program-transform-name* )
2837       skip_next=$separate_arg
2838       continue
2839       ;;
2840     -*)
2841       # An option.  Add it.
2842       case $ac_arg in
2843         *\'*)
2844           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2845       esac
2846       baseargs="$baseargs '$ac_arg'"
2847       if test X"$skip_targ" = Xno; then
2848         tbaseargs="$tbaseargs '$ac_arg'"
2849       fi
2850       keep_next=$separate_arg
2851       ;;
2852     *)
2853       # Either a variable assignment, or a nonopt (triplet).  Don't
2854       # pass it down; let the Makefile handle this.
2855       continue
2856       ;;
2857   esac
2858 done
2859 # Remove the initial space we just introduced and, as these will be
2860 # expanded by make, quote '$'.
2861 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2862
2863 # Add in --program-transform-name, after --program-prefix and
2864 # --program-suffix have been applied to it.  Autoconf has already
2865 # doubled dollar signs and backslashes in program_transform_name; we want
2866 # the backslashes un-doubled, and then the entire thing wrapped in single
2867 # quotes, because this will be expanded first by make and then by the shell.
2868 # Also, because we want to override the logic in subdir configure scripts to
2869 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2870 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2871 ${program_transform_name}
2872 EOF_SED
2873 gcc_transform_name=`cat conftestsed.out`
2874 rm -f conftestsed.out
2875 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2876 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2877 if test "$silent" = yes; then
2878   baseargs="$baseargs --silent"
2879   tbaseargs="$tbaseargs --silent"
2880 fi
2881 baseargs="$baseargs --disable-option-checking"
2882 tbaseargs="$tbaseargs --disable-option-checking"
2883
2884 # Record and document user additions to sub configure arguments.
2885 AC_ARG_VAR([build_configargs],
2886            [additional configure arguments for build directories])
2887 AC_ARG_VAR([host_configargs],
2888            [additional configure arguments for host directories])
2889 AC_ARG_VAR([target_configargs],
2890            [additional configure arguments for target directories])
2891
2892 # For the build-side libraries, we just need to pretend we're native,
2893 # and not use the same cache file.  Multilibs are neither needed nor
2894 # desired.
2895 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2896
2897 # For host modules, accept cache file option, or specification as blank.
2898 case "${cache_file}" in
2899 "") # empty
2900   cache_file_option="" ;;
2901 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2902   cache_file_option="--cache-file=${cache_file}" ;;
2903 *) # relative path
2904   cache_file_option="--cache-file=../${cache_file}" ;;
2905 esac
2906
2907 # Host dirs don't like to share a cache file either, horribly enough.
2908 # This seems to be due to autoconf 2.5x stupidity.
2909 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2910
2911 target_configargs="$target_configargs ${tbaseargs}"
2912
2913 # Passing a --with-cross-host argument lets the target libraries know
2914 # whether they are being built with a cross-compiler or being built
2915 # native.  However, it would be better to use other mechanisms to make the
2916 # sorts of decisions they want to make on this basis.  Please consider
2917 # this option to be deprecated.  FIXME.
2918 if test x${is_cross_compiler} = xyes ; then
2919   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2920 fi
2921
2922 # Special user-friendly check for native x86_64-linux build, if
2923 # multilib is not explicitly enabled.
2924 case "$target:$have_compiler:$host:$target:$enable_multilib" in
2925   x86_64-*linux*:yes:$build:$build:)
2926     # Make sure we have a developement environment that handles 32-bit
2927     dev64=no
2928     echo "int main () { return 0; }" > conftest.c
2929     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2930     if test $? = 0 ; then
2931       if test -s conftest || test -s conftest.exe ; then
2932         dev64=yes
2933       fi
2934     fi
2935     rm -f conftest*
2936     if test x${dev64} != xyes ; then
2937       AC_MSG_ERROR([I suspect your system does not have 32-bit developement libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
2938     fi
2939     ;;
2940 esac
2941
2942 # Default to --enable-multilib.
2943 if test x${enable_multilib} = x ; then
2944   target_configargs="--enable-multilib ${target_configargs}"
2945 fi
2946
2947 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2948 # changed from the earlier setting of with_newlib.
2949 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2950   target_configargs="--with-newlib ${target_configargs}"
2951 fi
2952
2953 # Different target subdirs use different values of certain variables
2954 # (notably CXX).  Worse, multilibs use *lots* of different values.
2955 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2956 # it doesn't automatically accept command-line overrides of them.
2957 # This means it's not safe for target subdirs to share a cache file,
2958 # which is disgusting, but there you have it.  Hopefully this can be
2959 # fixed in future.  It's still worthwhile to use a cache file for each
2960 # directory.  I think.
2961
2962 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2963 # We need to pass --target, as newer autoconf's requires consistency
2964 # for target_alias and gcc doesn't manage it consistently.
2965 target_configargs="--cache-file=./config.cache ${target_configargs}"
2966
2967 FLAGS_FOR_TARGET=
2968 case " $target_configdirs " in
2969  *" newlib "*)
2970   case " $target_configargs " in
2971   *" --with-newlib "*)
2972    case "$target" in
2973     *-cygwin*)
2974       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
2975       ;;
2976    esac
2977
2978    # If we're not building GCC, don't discard standard headers.
2979    if test -d ${srcdir}/gcc; then
2980      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2981
2982      if test "${build}" != "${host}"; then
2983        # On Canadian crosses, CC_FOR_TARGET will have already been set
2984        # by `configure', so we won't have an opportunity to add -Bgcc/
2985        # to it.  This is right: we don't want to search that directory
2986        # for binaries, but we want the header files in there, so add
2987        # them explicitly.
2988        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2989
2990        # Someone might think of using the pre-installed headers on
2991        # Canadian crosses, in case the installed compiler is not fully
2992        # compatible with the compiler being built.  In this case, it
2993        # would be better to flag an error than risking having
2994        # incompatible object files being constructed.  We can't
2995        # guarantee that an error will be flagged, but let's hope the
2996        # compiler will do it, when presented with incompatible header
2997        # files.
2998      fi
2999    fi
3000
3001    case "${target}-${is_cross_compiler}" in
3002    i[[3456789]]86-*-linux*-no)
3003       # Here host == target, so we don't need to build gcc,
3004       # so we don't want to discard standard headers.
3005       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3006       ;;
3007    *)
3008       # If we're building newlib, use its generic headers last, but search
3009       # for any libc-related directories first (so make it the last -B
3010       # switch).
3011       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3012
3013       # If we're building libgloss, find the startup file, simulator library
3014       # and linker script.
3015       case " $target_configdirs " in
3016         *" libgloss "*)
3017         # Look for startup file, simulator library and maybe linker script.
3018         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3019         # Look for libnosys.a in case the target needs it.
3020         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3021         # Most targets have the linker script in the source directory.
3022         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3023         ;;
3024       esac
3025       ;;
3026    esac
3027    ;;
3028   esac
3029   ;;
3030 esac
3031
3032 case "$target" in
3033   x86_64-*mingw* | *-w64-mingw*)
3034   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3035   # however, use a symlink named 'mingw' in ${prefix} .
3036     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3037     ;;
3038   *-mingw*)
3039   # MinGW can't be handled as Cygwin above since it does not use newlib.
3040     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3041     ;;
3042 esac
3043
3044 # Allow the user to override the flags for
3045 # our build compiler if desired.
3046 if test x"${build}" = x"${host}" ; then
3047   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3048   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3049   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3050 fi
3051
3052 # On Canadian crosses, we'll be searching the right directories for
3053 # the previously-installed cross compiler, so don't bother to add
3054 # flags for directories within the install tree of the compiler
3055 # being built; programs in there won't even run.
3056 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3057   # Search for pre-installed headers if nothing else fits.
3058   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3059 fi
3060
3061 if test "x${use_gnu_ld}" = x &&
3062    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3063   # Arrange for us to find uninstalled linker scripts.
3064   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3065 fi
3066
3067 # Search for other target-specific linker scripts and such.
3068 case "${target}" in
3069   mep*)
3070     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3071     ;;
3072 esac
3073
3074 # Makefile fragments.
3075 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3076 do
3077   eval fragval=\$$frag
3078   if test $fragval != /dev/null; then
3079     eval $frag=${srcdir}/$fragval
3080   fi
3081 done
3082 AC_SUBST_FILE(host_makefile_frag)
3083 AC_SUBST_FILE(target_makefile_frag)
3084 AC_SUBST_FILE(alphaieee_frag)
3085 AC_SUBST_FILE(ospace_frag)
3086
3087 # Miscellanea: directories, flags, etc.
3088 AC_SUBST(RPATH_ENVVAR)
3089 AC_SUBST(GCC_SHLIB_SUBDIR)
3090 AC_SUBST(tooldir)
3091 AC_SUBST(build_tooldir)
3092 AC_SUBST(CONFIGURE_GDB_TK)
3093 AC_SUBST(GDB_TK)
3094 AC_SUBST(INSTALL_GDB_TK)
3095
3096 # Build module lists & subconfigure args.
3097 AC_SUBST(build_configargs)
3098 AC_SUBST(build_configdirs)
3099
3100 # Host module lists & subconfigure args.
3101 AC_SUBST(host_configargs)
3102 AC_SUBST(configdirs)
3103 AC_SUBST(target_configdirs)
3104
3105 # Target module lists & subconfigure args.
3106 AC_SUBST(target_configargs)
3107
3108
3109 # Build tools.
3110 AC_SUBST(AR_FOR_BUILD)
3111 AC_SUBST(AS_FOR_BUILD)
3112 AC_SUBST(CC_FOR_BUILD)
3113 AC_SUBST(CFLAGS_FOR_BUILD)
3114 AC_SUBST(CXXFLAGS_FOR_BUILD)
3115 AC_SUBST(CXX_FOR_BUILD)
3116 AC_SUBST(DLLTOOL_FOR_BUILD)
3117 AC_SUBST(GCJ_FOR_BUILD)
3118 AC_SUBST(GFORTRAN_FOR_BUILD)
3119 AC_SUBST(GOC_FOR_BUILD)
3120 AC_SUBST(LDFLAGS_FOR_BUILD)
3121 AC_SUBST(LD_FOR_BUILD)
3122 AC_SUBST(NM_FOR_BUILD)
3123 AC_SUBST(RANLIB_FOR_BUILD)
3124 AC_SUBST(WINDMC_FOR_BUILD)
3125 AC_SUBST(WINDRES_FOR_BUILD)
3126
3127 # Generate default definitions for YACC, M4, LEX and other programs that run
3128 # on the build machine.  These are used if the Makefile can't locate these
3129 # programs in objdir.
3130 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3131
3132 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3133 case " $build_configdirs " in
3134   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3135 esac
3136
3137 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3138 case " $build_configdirs " in
3139   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3140 esac
3141
3142 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3143 case " $build_configdirs " in
3144   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3145 esac
3146
3147 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3148 case " $build_configdirs " in
3149   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3150   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3151 esac
3152
3153 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3154 case " $build_configdirs " in
3155   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3156 esac
3157
3158 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3159 case " $build_configdirs " in
3160   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3161   *)
3162 changequote(,)
3163     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3164     # higher, else we use the "missing" dummy.
3165     if ${MAKEINFO} --version \
3166        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3167       :
3168     else
3169       MAKEINFO="$MISSING makeinfo"
3170     fi
3171     ;;
3172 changequote([,])
3173 esac
3174
3175 # FIXME: expect and dejagnu may become build tools?
3176
3177 AC_CHECK_PROGS(EXPECT, expect, expect)
3178 case " $configdirs " in
3179   *" expect "*)
3180     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3181     ;;
3182 esac
3183
3184 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3185 case " $configdirs " in
3186   *" dejagnu "*)
3187     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3188     ;;
3189 esac
3190
3191
3192 # Host tools.
3193 NCN_STRICT_CHECK_TOOLS(AR, ar)
3194 NCN_STRICT_CHECK_TOOLS(AS, as)
3195 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3196 NCN_STRICT_CHECK_TOOLS(LD, ld)
3197 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3198 NCN_STRICT_CHECK_TOOLS(NM, nm)
3199 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3200 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3201 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3202 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3203 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3204 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3205 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3206 AC_SUBST(CC)
3207 AC_SUBST(CXX)
3208 AC_SUBST(CFLAGS)
3209 AC_SUBST(CXXFLAGS)
3210
3211 # Target tools.
3212 AC_ARG_WITH([build-time-tools],
3213   [AS_HELP_STRING([--with-build-time-tools=PATH],
3214                   [use given path to find target tools during the build])],
3215   [case x"$withval" in
3216      x/*) ;;
3217      *)
3218        with_build_time_tools=
3219        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3220        ;;
3221    esac],
3222   [with_build_time_tools=])
3223
3224 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3225 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3226 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3227 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3228 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3229 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3230
3231 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3232 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3233 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3234 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3235 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3236 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3237 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3238 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3239 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3240 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3241 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3242 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3243
3244 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3245
3246 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3247 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3248 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3249 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3250 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3251                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3252                 c++)
3253 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3254                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3255                 c++)
3256 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3257 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3258 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3259                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3260 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3261                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3262 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3263                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3264 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3265 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3266 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3267 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3268 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3269 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3270 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3271 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3272 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3273
3274 AC_SUBST(FLAGS_FOR_TARGET)
3275 AC_SUBST(RAW_CXX_FOR_TARGET)
3276
3277 # Certain tools may need extra flags.
3278 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3279 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3280 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3281
3282 # When building target libraries, except in a Canadian cross, we use
3283 # the same toolchain as the compiler we just built.
3284 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3285 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3286 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3287 if test $host = $build; then
3288   case " $configdirs " in
3289     *" gcc "*)
3290       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3291       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3292       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3293       ;;
3294   esac
3295 fi
3296
3297 AC_SUBST(COMPILER_AS_FOR_TARGET)
3298 AC_SUBST(COMPILER_LD_FOR_TARGET)
3299 AC_SUBST(COMPILER_NM_FOR_TARGET)
3300
3301 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3302 AC_ARG_ENABLE(maintainer-mode,
3303 [AS_HELP_STRING([--enable-maintainer-mode],
3304                 [enable make rules and dependencies not useful
3305                  (and sometimes confusing) to the casual installer])],
3306       USE_MAINTAINER_MODE=$enableval,
3307       USE_MAINTAINER_MODE=no)
3308 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3309 AC_SUBST(MAINTAINER_MODE_TRUE)
3310 AC_SUBST(MAINTAINER_MODE_FALSE)
3311 if test "$USE_MAINTAINER_MODE" = yes; then
3312   MAINTAINER_MODE_TRUE=
3313   MAINTAINER_MODE_FALSE='#'
3314 else
3315   MAINTAINER_MODE_TRUE='#'
3316   MAINTAINER_MODE_FALSE=
3317 fi
3318 MAINT=$MAINTAINER_MODE_TRUE
3319 AC_SUBST(MAINT)dnl
3320
3321 # ---------------------
3322 # GCC bootstrap support
3323 # ---------------------
3324
3325 # Stage specific cflags for build.
3326 stage1_cflags="-g"
3327 case $build in
3328   vax-*-*)
3329     case ${GCC} in
3330       yes) stage1_cflags="-g -Wa,-J" ;;
3331       *) stage1_cflags="-g -J" ;;
3332     esac ;;
3333 esac
3334
3335 AC_SUBST(stage1_cflags)
3336
3337 # Enable --enable-checking in stage1 of the compiler.
3338 AC_ARG_ENABLE(stage1-checking,
3339 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3340                 [choose additional checking for stage1 of the compiler])],
3341 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3342 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3343   stage1_checking=--enable-checking=yes,types
3344 else
3345   stage1_checking=--enable-checking=$enable_checking,types
3346 fi])
3347 AC_SUBST(stage1_checking)
3348
3349 # Enable -Werror in bootstrap stage2 and later.
3350 AC_ARG_ENABLE(werror,
3351 [AS_HELP_STRING([--enable-werror],
3352                 [enable -Werror in bootstrap stage2 and later])], [],
3353 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3354   enable_werror=yes
3355 else
3356   enable_werror=no
3357 fi])
3358 case ${enable_werror} in
3359   yes) stage2_werror_flag="--enable-werror-always" ;;
3360   *) stage2_werror_flag="" ;;
3361 esac
3362 AC_SUBST(stage2_werror_flag)
3363
3364 # Enable --enable-host-shared.
3365 AC_ARG_ENABLE(host-shared,
3366 [AS_HELP_STRING([--enable-host-shared],
3367                 [build host code as shared libraries])],
3368 [host_shared=$enableval], [host_shared=no])
3369 AC_SUBST(host_shared)
3370
3371 # Specify what files to not compare during bootstrap.
3372
3373 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3374 case "$target" in
3375   hppa*64*-*-hpux*) ;;
3376   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3377   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3378 esac
3379 AC_SUBST(compare_exclusions)
3380
3381 AC_CONFIG_FILES([Makefile],
3382   [sed "$extrasub_build" Makefile |
3383    sed "$extrasub_host" |
3384    sed "$extrasub_target" > mf$$
3385    mv -f mf$$ Makefile],
3386   [extrasub_build="$extrasub_build"
3387    extrasub_host="$extrasub_host"
3388    extrasub_target="$extrasub_target"])
3389 AC_OUTPUT