gcc/ada/a-ztcoio.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --      A D A . W I D E _ W I D E _ T E X T _ IO . C O M P L E X _ I O      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Wide_Wide_Text_IO.Complex_Aux;
  35
  36 with System.WCh_Con; use System.WCh_Con;
  37 with System.WCh_WtS; use System.WCh_WtS;
  38
  39 with Ada.Unchecked_Conversion;
  40
  41 package body Ada.Wide_Wide_Text_IO.Complex_IO is
  42
  43    package Aux renames Ada.Wide_Wide_Text_IO.Complex_Aux;
  44
  45    subtype LLF is Long_Long_Float;
  46    --  Type used for calls to routines in Aux
  47
  48    function TFT is new
  49      Ada.Unchecked_Conversion (File_Type, Ada.Wide_Wide_Text_IO.File_Type);
  50    --  This unchecked conversion is to get around a visibility bug in
  51    --  GNAT version 2.04w. It should be possible to simply use the
  52    --  subtype declared above and do normal checked conversions.
  53
  54    ---------
  55    -- Get --
  56    ---------
  57
  58    procedure Get
  59      (File  : File_Type;
  60       Item  : out Complex;
  61       Width : Field := 0)
  62    is
  63       Real_Item : Real'Base;
  64       Imag_Item : Real'Base;
  65
  66    begin
  67       Aux.Get (TFT (File), LLF (Real_Item), LLF (Imag_Item), Width);
  68       Item := (Real_Item, Imag_Item);
  69
  70    exception
  71       when Constraint_Error => raise Data_Error;
  72    end Get;
  73
  74    ---------
  75    -- Get --
  76    ---------
  77
  78    procedure Get
  79      (Item  : out Complex;
  80       Width : Field := 0)
  81    is
  82    begin
  83       Get (Current_Input, Item, Width);
  84    end Get;
  85
  86    ---------
  87    -- Get --
  88    ---------
  89
  90    procedure Get
  91      (From : Wide_Wide_String;
  92       Item : out Complex;
  93       Last : out Positive)
  94    is
  95       Real_Item : Real'Base;
  96       Imag_Item : Real'Base;
  97
  98       S : constant String := Wide_Wide_String_To_String (From, WCEM_Upper);
  99       --  String on which we do the actual conversion. Note that the method
 100       --  used for wide character encoding is irrelevant, since if there is
 101       --  a character outside the Standard.Character range then the call to
 102       --  Aux.Gets will raise Data_Error in any case.
 103
 104    begin
 105       Aux.Gets (S, LLF (Real_Item), LLF (Imag_Item), Last);
 106       Item := (Real_Item, Imag_Item);
 107
 108    exception
 109       when Data_Error => raise Constraint_Error;
 110    end Get;
 111
 112    ---------
 113    -- Put --
 114    ---------
 115
 116    procedure Put
 117      (File : File_Type;
 118       Item : Complex;
 119       Fore : Field := Default_Fore;
 120       Aft  : Field := Default_Aft;
 121       Exp  : Field := Default_Exp)
 122    is
 123    begin
 124       Aux.Put (TFT (File), LLF (Re (Item)), LLF (Im (Item)), Fore, Aft, Exp);
 125    end Put;
 126
 127    ---------
 128    -- Put --
 129    ---------
 130
 131    procedure Put
 132      (Item : Complex;
 133       Fore : Field := Default_Fore;
 134       Aft  : Field := Default_Aft;
 135       Exp  : Field := Default_Exp)
 136    is
 137    begin
 138       Put (Current_Output, Item, Fore, Aft, Exp);
 139    end Put;
 140
 141    ---------
 142    -- Put --
 143    ---------
 144
 145    procedure Put
 146      (To   : out Wide_Wide_String;
 147       Item : Complex;
 148       Aft  : Field := Default_Aft;
 149       Exp  : Field := Default_Exp)
 150    is
 151       S : String (To'First .. To'Last);
 152
 153    begin
 154       Aux.Puts (S, LLF (Re (Item)), LLF (Im (Item)), Aft, Exp);
 155
 156       for J in S'Range loop
 157          To (J) := Wide_Wide_Character'Val (Character'Pos (S (J)));
 158       end loop;
 159    end Put;
 160
 161 end Ada.Wide_Wide_Text_IO.Complex_IO;