libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12 sinclude(../config/gthr.m4)
  13 sinclude(../config/sjlj.m4)
  14 sinclude(../config/cet.m4)
  15
  16 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  17 AC_CONFIG_SRCDIR([static-object.mk])
  18
  19 # The libgcc should not depend on any header files
  20 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  21   [m4_divert_text([DEFAULTS],
  22     [ac_includes_default='/* none */'])])
  23
  24 AC_ARG_WITH(target-subdir,
  25 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  26 AC_ARG_WITH(cross-host,
  27 [  --with-cross-host=HOST           Configuring with a cross compiler])
  28 AC_ARG_WITH(ld,
  29 [  --with-ld               arrange to use the specified ld (full pathname)])
  30
  31 if test "${srcdir}" = "."; then
  32   if test -n "${with_build_subdir}"; then
  33     libgcc_topdir="${srcdir}/../.."
  34     with_target_subdir=
  35   elif test -z "${with_target_subdir}"; then
  36     libgcc_topdir="${srcdir}/.."
  37   else
  38     if test "${with_target_subdir}" != "."; then
  39       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  40     else
  41       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  42     fi
  43   fi
  44 else
  45   libgcc_topdir="${srcdir}/.."
  46 fi
  47 AC_SUBST(libgcc_topdir)
  48 AC_CONFIG_AUX_DIR($libgcc_topdir)
  49 AC_CONFIG_HEADER(auto-target.h:config.in)
  50
  51 AC_ARG_ENABLE(shared,
  52 [  --disable-shared        don't provide a shared libgcc],
  53 [
  54   case $enable_shared in
  55   yes | no) ;;
  56   *)
  57     enable_shared=no
  58     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  59     for pkg in $enableval; do
  60       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  61         enable_shared=yes
  62       fi
  63     done
  64     IFS="$ac_save_ifs"
  65     ;;
  66   esac
  67 ], [enable_shared=yes])
  68 AC_SUBST(enable_shared)
  69
  70 AC_ARG_ENABLE(gcov,
  71 [  --disable-gcov          don't provide libgcov and related host tools],
  72 [], [enable_gcov=yes])
  73 AC_SUBST(enable_gcov)
  74
  75 AC_ARG_ENABLE(vtable-verify,
  76 [  --enable-vtable-verify    Enable vtable verification feature ],
  77 [case "$enableval" in
  78  yes) enable_vtable_verify=yes ;;
  79  no)  enable_vtable_verify=no ;;
  80  *)   enable_vtable_verify=no;;
  81  esac],
  82 [enable_vtable_verify=no])
  83 AC_SUBST(enable_vtable_verify)
  84
  85 AC_ARG_WITH(aix-soname,
  86 [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
  87     [shared library versioning (aka "SONAME") variant to provide on AIX])],
  88 [case "${host}:${enable_shared}" in
  89  power*-*-aix[[5-9]]*:yes)
  90    AC_MSG_CHECKING([which variant of shared library versioning to provide for shared libgcc])
  91    case ${withval} in
  92      aix|svr4|both) ;;
  93      *) AC_MSG_ERROR([Unknown argument to --with-aix-soname]);;
  94    esac
  95    AC_MSG_RESULT($withval)
  96    ;;
  97  *) with_aix_soname=aix ;;
  98  esac
  99 ], [with_aix_soname=aix])
 100 AC_SUBST(with_aix_soname)
 101
 102 GCC_PICFLAG
 103 AC_SUBST(PICFLAG)
 104
 105 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 106 AC_ARG_ENABLE(version-specific-runtime-libs,
 107 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
 108 [case "$enableval" in
 109  yes) version_specific_libs=yes ;;
 110  no)  version_specific_libs=no ;;
 111  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 112  esac],
 113 [version_specific_libs=no])
 114 AC_MSG_RESULT($version_specific_libs)
 115
 116 AC_ARG_WITH(slibdir,
 117 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
 118 slibdir="$with_slibdir",
 119 if test "${version_specific_libs}" = yes; then
 120   slibdir='$(libsubdir)'
 121 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
 122   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 123 else
 124   slibdir='$(libdir)'
 125 fi)
 126 AC_SUBST(slibdir)
 127
 128 # Command-line options.
 129 # Very limited version of AC_MAINTAINER_MODE.
 130 AC_ARG_ENABLE([maintainer-mode],
 131   [AC_HELP_STRING([--enable-maintainer-mode],
 132                  [enable make rules and dependencies not useful (and
 133                   sometimes confusing) to the casual installer])],
 134   [case ${enable_maintainer_mode} in
 135      yes) MAINT='' ;;
 136      no) MAINT='#' ;;
 137      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 138    esac
 139    maintainer_mode=${enableval}],
 140   [MAINT='#'])
 141 AC_SUBST([MAINT])dnl
 142
 143 AC_PROG_INSTALL
 144
 145 AC_PROG_AWK
 146 # We need awk; bail out if it's missing.
 147 case ${AWK} in
 148   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 149 esac
 150
 151 AC_CANONICAL_HOST
 152 ACX_NONCANONICAL_HOST
 153 ACX_NONCANONICAL_TARGET
 154 GCC_TOPLEV_SUBDIRS
 155
 156 # Calculate toolexeclibdir
 157 # Also toolexecdir, though it's only used in toolexeclibdir
 158 case ${version_specific_libs} in
 159   yes)
 160     # Need the gcc compiler version to know where to install libraries
 161     # and header files if --enable-version-specific-runtime-libs option
 162     # is selected.
 163     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 164     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 165     ;;
 166   no)
 167     if test -n "$with_cross_host" &&
 168        test x"$with_cross_host" != x"no"; then
 169       # Install a library built with a cross compiler in tooldir, not libdir.
 170       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 171       toolexeclibdir='$(toolexecdir)/lib'
 172     else
 173       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 174       toolexeclibdir='$(libdir)'
 175     fi
 176     multi_os_directory=`$CC -print-multi-os-directory`
 177     case $multi_os_directory in
 178       .) ;; # Avoid trailing /.
 179       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 180     esac
 181     ;;
 182 esac
 183 AC_SUBST(toolexecdir)
 184 AC_SUBST(toolexeclibdir)
 185
 186 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 187 dnl to call AC_CHECK_PROG.
 188 AC_CHECK_TOOL(AR, ar)
 189 AC_CHECK_TOOL(LIPO, lipo, :)
 190 AC_CHECK_TOOL(NM, nm)
 191 AC_CHECK_TOOL(RANLIB, ranlib, :)
 192 AC_CHECK_TOOL(STRIP, strip, :)
 193 AC_PROG_LN_S
 194
 195 GCC_NO_EXECUTABLES
 196 AC_PROG_CC
 197 AC_PROG_CPP_WERROR
 198
 199 AC_SYS_LARGEFILE
 200
 201 AC_CHECK_SIZEOF([double])
 202 AC_CHECK_SIZEOF([long double])
 203 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 204 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 205 AC_SUBST(double_type_size)
 206 AC_SUBST(long_double_type_size)
 207
 208 AC_CHECK_HEADERS(inttypes.h stdint.h stdlib.h ftw.h \
 209         unistd.h sys/stat.h sys/types.h \
 210         string.h strings.h memory.h sys/auxv.h)
 211 AC_HEADER_STDC
 212
 213 # Check for decimal float support.
 214 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 215                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 216 #include <fenv.h>
 217 ]], [[
 218 _Decimal32 x;
 219 int fe_except =
 220   FE_INVALID|FE_DIVBYZERO|FE_OVERFLOW|FE_UNDERFLOW|FE_INEXACT;
 221 ]])],
 222                                   [libgcc_cv_dfp=yes],
 223                                   [libgcc_cv_dfp=no])])
 224 decimal_float=$libgcc_cv_dfp
 225 AC_SUBST(decimal_float)
 226
 227 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 228
 229 # Check for fixed-point support.
 230 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 231                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Sat _Fract x;])],
 232                                   [libgcc_cv_fixed_point=yes],
 233                                   [libgcc_cv_fixed_point=no])])
 234 fixed_point=$libgcc_cv_fixed_point
 235 AC_SUBST(fixed_point)
 236
 237 # For platforms with the unwind ABI which includes an unwind library,
 238 # libunwind, we can choose to use the system libunwind.
 239 # config.gcc also contains tests of with_system_libunwind.
 240 GCC_CHECK_UNWIND_GETIPINFO
 241
 242 # Check if the compiler is configured for setjmp/longjmp exceptions.
 243 GCC_CHECK_SJLJ_EXCEPTIONS
 244
 245 GCC_CET_FLAGS(CET_FLAGS)
 246 AC_SUBST(CET_FLAGS)
 247
 248 AC_ARG_ENABLE([explicit-exception-frame-registration],
 249   [AC_HELP_STRING([--enable-explicit-exception-frame-registration],
 250      [register exception tables explicitly at module start, for use
 251       e.g. for compatibility with installations without PT_GNU_EH_FRAME support])],
 252 [
 253 force_explicit_eh_registry=
 254 if test "$enable_explicit_exception_frame_registration" = yes; then
 255   if test $ac_cv_sjlj_exceptions = yes; then
 256     AC_MSG_ERROR([Can't --enable-explicit-exception-frame-registration
 257                   with setjmp/longjmp exceptions])
 258   fi
 259   force_explicit_eh_registry=-DUSE_EH_FRAME_REGISTRY_ALWAYS
 260 fi
 261 ])
 262 AC_SUBST([force_explicit_eh_registry])
 263
 264 AC_ARG_ENABLE([tm-clone-registry],
 265 [  --disable-tm-clone-registry    disable TM clone registry],
 266 [
 267 use_tm_clone_registry=
 268 if test "$enable_tm_clone_registry" = no; then
 269   use_tm_clone_registry=-DUSE_TM_CLONE_REGISTRY=0
 270 fi
 271 ])
 272 AC_SUBST([use_tm_clone_registry])
 273
 274 AC_LIB_PROG_LD_GNU
 275
 276 AC_MSG_CHECKING([for thread model used by GCC])
 277 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 278 AC_MSG_RESULT([$target_thread_file])
 279
 280 # Check for assembler CFI support.
 281 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 282                [AC_COMPILE_IFELSE(
 283 [AC_LANG_SOURCE([asm("\n\
 284         .text\n\
 285         .cfi_startproc\n\
 286         .cfi_personality 0, symbol\n\
 287         .cfi_endproc");])],
 288   [libgcc_cv_cfi=yes],
 289   [libgcc_cv_cfi=no])])
 290
 291 # Check 32bit or 64bit.  In the case of MIPS, this really determines the
 292 # word size rather than the address size.
 293 cat > conftest.c <<EOF
 294 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__)) \
 295     || defined(__mips64)
 296 host_address=64
 297 #else
 298 host_address=32
 299 #endif
 300 EOF
 301 eval `${CC-cc} -E conftest.c | grep host_address=`
 302 rm -f conftest.c
 303
 304 case ${host} in
 305 mips*-*-*)
 306   AC_CACHE_CHECK([whether the target is hard-float],
 307                  [libgcc_cv_mips_hard_float],
 308                  [AC_COMPILE_IFELSE(
 309     [AC_LANG_SOURCE([#ifndef __mips_hard_float
 310      #error FOO
 311      #endif
 312     ])],
 313     [libgcc_cv_mips_hard_float=yes],
 314     [libgcc_cv_mips_hard_float=no])])
 315 esac
 316
 317 case ${host} in
 318 *-*-solaris2*)
 319   # Check for system-provided CRTs on Solaris 11.4.
 320   AC_CACHE_CHECK([system-provided CRTs on Solaris],
 321                  [libgcc_cv_solaris_crts],
 322     [libgcc_cv_solaris_crts=no
 323      libgcc_sysroot="`${CC} -print-sysroot`"
 324      libgcc_libdir="$libgcc_sysroot/usr/lib"
 325      # At the time they were added, gcrt1.o became a symlink for backwards
 326      # compatibility on x86, while crt1.o was added on sparc, so check for that.
 327      case ${host} in
 328        i?86-*-solaris2* | x86_64-*-solaris2*)
 329          if test -h "$libgcc_libdir/gcrt1.o"; then libgcc_cv_solaris_crts=yes; fi
 330          ;;
 331        sparc*-*-solaris2*)
 332          if test -f "$libgcc_libdir/crt1.o"; then libgcc_cv_solaris_crts=yes; fi
 333          ;;
 334      esac])
 335   if test $libgcc_cv_solaris_crts = yes; then
 336     AC_DEFINE(HAVE_SOLARIS_CRTS, 1,
 337       [Define if the system-provided CRTs are present on Solaris.])
 338   fi
 339   ;;
 340 esac
 341
 342 # Determine the version of glibc, if any, used on the target.
 343 AC_MSG_CHECKING([for target glibc version])
 344 AC_ARG_WITH([glibc-version],
 345   [AS_HELP_STRING([--with-glibc-version=M.N],
 346     [assume GCC used with glibc version M.N or later])], [
 347 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
 348   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
 349   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
 350 else
 351   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
 352 fi], [
 353 AC_COMPUTE_INT([glibc_version_major], [__GLIBC__],
 354                                       [#include <features.h>],
 355                                       [glibc_version_major=0])
 356 AC_COMPUTE_INT([glibc_version_minor], [__GLIBC_MINOR__],
 357                                       [#include <features.h>],
 358                                       [glibc_version_minor=0])])
 359 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
 360
 361 # Determine floating-point type for powerpc*-*-linux*.
 362 # Single-precision-only FPRs are not a supported configuration for
 363 # this target, so are not allowed for in this test.
 364 case ${host} in
 365 powerpc*-*-linux*)
 366   cat > conftest.c <<EOF
 367 #ifdef __powerpc64__
 368 ppc_fp_type=64
 369 #elif defined _SOFT_FLOAT
 370 ppc_fp_type=soft
 371 #elif defined _SOFT_DOUBLE
 372 ppc_fp_type=e500v1
 373 #elif defined __NO_FPRS__
 374 ppc_fp_type=e500v2
 375 #else
 376 ppc_fp_type=hard
 377 #endif
 378 EOF
 379 eval `${CC-cc} -E conftest.c | grep ppc_fp_type=`
 380 rm -f conftest.c
 381 # glibc 2.19 and later provide all the soft-fp functions, with proper
 382 # interactions with <fenv.h> exception and rounding mode handling, so
 383 # make libgcc's versions into compat symbols if a recent enough glibc
 384 # version is being used.
 385 ppc_fp_compat=
 386 case ${ppc_fp_type} in
 387 soft|e500v1|e500v2)
 388   if test $glibc_version_major -gt 2 \
 389     || ( test $glibc_version_major -eq 2 \
 390         && test $glibc_version_minor -ge 19 ); then
 391     ppc_fp_compat="t-softfp-compat"
 392   fi
 393   ;;
 394 esac
 395 ;;
 396 esac
 397
 398 case ${host} in
 399 # At present, we cannot turn -mfloat128 on via #pragma GCC target, so just
 400 # check if we have VSX (ISA 2.06) support to build the software libraries, and
 401 # whether the assembler can handle xsaddqp for hardware support.  Also check if
 402 # a new glibc is being used so that __builtin_cpu_supports can be used.
 403 powerpc*-*-linux*)
 404   saved_CFLAGS="$CFLAGS"
 405   CFLAGS="$CFLAGS -mabi=altivec -mvsx -mfloat128"
 406   AC_CACHE_CHECK([for PowerPC ISA 2.06 to build __float128 libraries],
 407                  [libgcc_cv_powerpc_float128],
 408                  [AC_COMPILE_IFELSE(
 409     [AC_LANG_SOURCE([vector double dadd (vector double a, vector double b) { return a + b; }])],
 410     [libgcc_cv_powerpc_float128=yes],
 411     [libgcc_cv_powerpc_float128=no])])
 412
 413   CFLAGS="$CFLAGS -mpower9-vector -mfloat128-hardware"
 414   AC_CACHE_CHECK([for PowerPC ISA 3.0 to build hardware __float128 libraries],
 415                  [libgcc_cv_powerpc_float128_hw],
 416                  [AC_COMPILE_IFELSE(
 417     [AC_LANG_SOURCE([#include <sys/auxv.h>
 418      #ifndef AT_PLATFORM
 419      #error "AT_PLATFORM is not defined"
 420      #endif
 421      #ifndef __BUILTIN_CPU_SUPPORTS__
 422      #error "__builtin_cpu_supports is not available"
 423      #endif
 424      vector unsigned char add (vector unsigned char a, vector unsigned char b)
 425      {
 426        vector unsigned char ret;
 427        __asm__ ("xsaddqp %0,%1,%2" : "=v" (ret) : "v" (a), "v" (b));
 428        return ret;
 429      }
 430      void *add_resolver (void) { return (void *) add; }
 431      __float128 add_ifunc (__float128, __float128)
 432         __attribute__ ((__ifunc__ ("add_resolver")));])],
 433     [libgcc_cv_powerpc_float128_hw=yes],
 434     [libgcc_cv_powerpc_float128_hw=no])])
 435   CFLAGS="$saved_CFLAGS"
 436 esac
 437
 438 # Collect host-machine-specific information.
 439 . ${srcdir}/config.host
 440
 441 # Used for constructing correct paths for offload compilers.
 442 accel_dir_suffix=
 443 real_host_noncanonical=${host_noncanonical}
 444 if test x"$enable_as_accelerator_for" != x; then
 445   accel_dir_suffix=/accel/${target_noncanonical}
 446   real_host_noncanonical=${enable_as_accelerator_for}
 447 fi
 448 AC_SUBST(accel_dir_suffix)
 449 AC_SUBST(real_host_noncanonical)
 450
 451 if test x"$enable_offload_targets" != x; then
 452   extra_parts="${extra_parts} crtoffloadbegin.o crtoffloadend.o crtoffloadtable.o"
 453 fi
 454
 455 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 456 # This is after config.host so we can augment tmake_file.
 457 # Link with -nostartfiles -nodefaultlibs since neither are present while
 458 # building libgcc.
 459 case ${host} in
 460 i?86-*-solaris2* | x86_64-*-solaris2*)
 461   cat > conftest.s <<EOF
 462         .section        .eh_frame,"a",@unwind
 463         .zero   4
 464         .section        .jcr,"aw",@progbits
 465         .zero   8
 466 EOF
 467   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 468       tmake_file="${tmake_file} i386/t-crtstuff"
 469   fi
 470   ;;
 471 esac
 472
 473 # Check if Solaris linker support v2 linker mapfile syntax.
 474 # Link with -nostartfiles -nodefaultlibs since neither are present while
 475 # building libgcc.
 476 case ${host} in
 477 *-*-solaris2*)
 478   solaris_ld_v2_maps=no
 479   echo 'int main(void) {return 0;}' > conftest.c
 480   echo '$mapfile_version 2' > conftest.map
 481   if AC_TRY_COMMAND([${CC-cc} -nostartfiles -nodefaultlibs -Wl,-M,conftest.map -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
 482       solaris_ld_v2_maps=yes
 483   fi
 484   ;;
 485 esac
 486 AC_SUBST(solaris_ld_v2_maps)
 487
 488 # Check if xtensa target is configured for windowed ABI and thus needs to use
 489 # custom unwind code.
 490 # This is after config.host so we can augment tmake_file.
 491 case ${host} in
 492 xtensa*-*)
 493   cat > conftest.c <<EOF
 494         #ifdef __XTENSA_CALL0_ABI__
 495         #error
 496         #endif
 497 EOF
 498   if AC_TRY_COMMAND(${CC-cc} -E -o conftest.i conftest.c 1>&AS_MESSAGE_LOG_FD); then
 499       tmake_file="${tmake_file} xtensa/t-windowed"
 500   fi
 501   ;;
 502 esac
 503
 504 # Check for visibility support.  This is after config.host so that
 505 # we can check for asm_hidden_op.
 506 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 507     libgcc_cv_hidden_visibility_attribute, [
 508         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 509         libgcc_cv_hidden_visibility_attribute=no
 510         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 511             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 512                 libgcc_cv_hidden_visibility_attribute=yes
 513             fi
 514         fi
 515         rm -f conftest.*
 516     ])
 517
 518 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 519     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 520     AC_DEFINE_UNQUOTED(AS_HIDDEN_DIRECTIVE, $asm_hidden_op, [Define to the .hidden-like directive if it exists.])
 521 else
 522     vis_hide=
 523 fi
 524 AC_SUBST(vis_hide)
 525
 526 # Check for .cfi_sections .debug_frame support.
 527 AC_CACHE_CHECK([for .cfi_sections .debug_frame],
 528     libgcc_cv_cfi_sections_directive, [
 529         echo 'int foo (int, char *);' > conftest.c
 530         echo 'int bar (int x) { char *y = __builtin_alloca (x); return foo (x + 1, y) + 1; }' >> conftest.c
 531         libgcc_cv_cfi_sections_directive=no
 532         if AC_TRY_COMMAND(${CC-cc} -Werror -g -fno-asynchronous-unwind-tables -fno-unwind-tables -fno-exceptions -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 533             if grep "\\.cfi_sections.*\\.debug_frame" conftest.s >/dev/null; then
 534                 libgcc_cv_cfi_sections_directive=yes
 535             fi
 536         fi
 537         rm -f conftest.*
 538     ])
 539 if test $libgcc_cv_cfi_sections_directive = yes; then
 540     AC_DEFINE(HAVE_AS_CFI_SECTIONS, 1, [Define to 1 if the assembler supports .cfi_sections .debug_frame directive.])
 541 fi
 542
 543 # See if we have thread-local storage.  We can only test assembler
 544 # since link-time and run-time tests require the newly built
 545 # gcc, which can't be used to build executable due to that libgcc
 546 # is yet to be built here.
 547 GCC_CHECK_CC_TLS
 548 set_have_cc_tls=
 549 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 550   set_have_cc_tls="-DHAVE_CC_TLS"
 551 fi
 552 AC_SUBST(set_have_cc_tls)
 553
 554 # See if we have emulated thread-local storage.
 555 GCC_CHECK_EMUTLS
 556 set_use_emutls=
 557 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 558   set_use_emutls="-DUSE_EMUTLS"
 559 fi
 560 AC_SUBST(set_use_emutls)
 561
 562 dnl Check if as supports AVX instructions.
 563 AC_DEFUN([LIBGCC_CHECK_AS_AVX], [
 564 case "${target}" in
 565 i[[34567]]86-*-* | x86_64-*-*)
 566   AC_CACHE_CHECK([if the assembler supports AVX], libgcc_cv_as_avx, [
 567     AC_TRY_COMPILE([], [asm("vzeroupper");],
 568                    [libgcc_cv_as_avx=yes], [libgcc_cv_as_avx=no])
 569   ])
 570   if test x$libgcc_cv_as_avx = xyes; then
 571     AC_DEFINE(HAVE_AS_AVX, 1, [Define to 1 if the assembler supports AVX.])
 572   fi
 573   ;;
 574 esac])
 575 LIBGCC_CHECK_AS_AVX
 576
 577 dnl Check if as supports RTM instructions.
 578 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 579 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 580   [[void ip (void) __attribute__ ((constructor (1)));]])],
 581   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 582 if test $libgcc_cv_init_priority = yes; then
 583   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 584   [Define if the compiler supports init priority.])
 585 fi
 586
 587 # Conditionalize the sfp-machine.h header for this target machine.
 588 if test -z "${sfp_machine_header}"; then
 589         sfp_machine_header=$cpu_type/sfp-machine.h
 590         if test -f ${srcdir}/config/${sfp_machine_header}; then
 591                 :
 592         else
 593                 sfp_machine_header=no-sfp-machine.h
 594         fi
 595 fi
 596 AC_SUBST(sfp_machine_header)
 597
 598 # Conditionalize the makefile for this target machine.
 599 tmake_file_=
 600 for f in ${tmake_file}
 601 do
 602         if test -f ${srcdir}/config/$f
 603         then
 604                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 605         fi
 606 done
 607 tmake_file="${tmake_file_}"
 608 AC_SUBST(tmake_file)
 609
 610 # Likewise export definitions for libgcc_tm.h
 611 tm_file_=
 612 for f in ${tm_file}
 613 do
 614         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 615 done
 616 tm_file="${tm_file_}"
 617 AC_SUBST(tm_file)
 618 AC_SUBST(tm_defines)
 619
 620 # Map from thread model to thread header.
 621 GCC_AC_THREAD_HEADER([$target_thread_file])
 622
 623 # Determine what GCC version number to use in filesystem paths.
 624 GCC_BASE_VER
 625
 626 # Substitute configuration variables
 627 AC_SUBST(cpu_type)
 628 AC_SUBST(extra_parts)
 629 AC_SUBST(asm_hidden_op)
 630 AC_SUBST(enable_execute_stack)
 631 AC_SUBST(unwind_header)
 632 AC_SUBST(md_unwind_header)
 633 AC_SUBST(sfp_machine_header)
 634 AC_SUBST(thread_header)
 635
 636 # We need multilib support.
 637 AC_CONFIG_FILES([Makefile])
 638 AC_CONFIG_COMMANDS([default],
 639   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 640 if test -n "$CONFIG_FILES"; then
 641   # FIXME: We shouldn't need to set ac_file
 642   ac_file=Makefile
 643   . ${libgcc_topdir}/config-ml.in
 644 fi]],
 645 [[srcdir=${srcdir}
 646 host=${host}
 647 with_target_subdir=${with_target_subdir}
 648 with_multisubdir=${with_multisubdir}
 649 ac_configure_args="--enable-multilib ${ac_configure_args}"
 650 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 651 libgcc_topdir=${libgcc_topdir}
 652 CC="${CC}"
 653 ]])
 654 AC_OUTPUT