gcc/ada/exp_ch13.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P _ C H 1 3                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2014, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Exp_Ch3;  use Exp_Ch3;
  30 with Exp_Ch6;  use Exp_Ch6;
  31 with Exp_Imgv; use Exp_Imgv;
  32 with Exp_Tss;  use Exp_Tss;
  33 with Exp_Util; use Exp_Util;
  34 with Freeze;   use Freeze;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Restrict; use Restrict;
  40 with Rident;   use Rident;
  41 with Rtsfind;  use Rtsfind;
  42 with Sem;      use Sem;
  43 with Sem_Aux;  use Sem_Aux;
  44 with Sem_Ch7;  use Sem_Ch7;
  45 with Sem_Ch8;  use Sem_Ch8;
  46 with Sem_Eval; use Sem_Eval;
  47 with Sem_Util; use Sem_Util;
  48 with Sinfo;    use Sinfo;
  49 with Snames;   use Snames;
  50 with Targparm; use Targparm;
  51 with Tbuild;   use Tbuild;
  52 with Uintp;    use Uintp;
  53 with Validsw;  use Validsw;
  54
  55 package body Exp_Ch13 is
  56
  57    ------------------------------------------
  58    -- Expand_N_Attribute_Definition_Clause --
  59    ------------------------------------------
  60
  61    --  Expansion action depends on attribute involved
  62
  63    procedure Expand_N_Attribute_Definition_Clause (N : Node_Id) is
  64       Loc : constant Source_Ptr := Sloc (N);
  65       Exp : constant Node_Id    := Expression (N);
  66       Ent : Entity_Id;
  67       V   : Node_Id;
  68
  69    begin
  70       Ent := Entity (Name (N));
  71
  72       if Is_Type (Ent) then
  73          Ent := Underlying_Type (Ent);
  74       end if;
  75
  76       case Get_Attribute_Id (Chars (N)) is
  77
  78          -------------
  79          -- Address --
  80          -------------
  81
  82          when Attribute_Address =>
  83
  84             --  If there is an initialization which did not come from the
  85             --  source program, then it is an artifact of our expansion, and we
  86             --  suppress it. The case we are most concerned about here is the
  87             --  initialization of a packed array to all false, which seems
  88             --  inappropriate for variable to which an address clause is
  89             --  applied. The expression may itself have been rewritten if the
  90             --  type is packed array, so we need to examine whether the
  91             --  original node is in the source. An exception though is the case
  92             --  of an access variable which is default initialized to null, and
  93             --  such initialization is retained.
  94
  95             --  Furthermore, if the initialization is the equivalent aggregate
  96             --  of the type initialization procedure, it replaces an implicit
  97             --  call to the init proc, and must be respected. Note that for
  98             --  packed types we do not build equivalent aggregates.
  99
 100             --  Also, if Init_Or_Norm_Scalars applies, then we need to retain
 101             --  any default initialization for objects of scalar types and
 102             --  types with scalar components. Normally a composite type will
 103             --  have an init_proc in the presence of Init_Or_Norm_Scalars,
 104             --  so when that flag is set we have just have to do a test for
 105             --  scalar and string types (the predefined string types such as
 106             --  String and Wide_String don't have an init_proc).
 107
 108             declare
 109                Decl : constant Node_Id := Declaration_Node (Ent);
 110                Typ  : constant Entity_Id := Etype (Ent);
 111
 112             begin
 113                if Nkind (Decl) = N_Object_Declaration
 114                   and then Present (Expression (Decl))
 115                   and then Nkind (Expression (Decl)) /= N_Null
 116                   and then
 117                    not Comes_From_Source (Original_Node (Expression (Decl)))
 118                then
 119                   if Present (Base_Init_Proc (Typ))
 120                     and then
 121                       Present (Static_Initialization (Base_Init_Proc (Typ)))
 122                   then
 123                      null;
 124
 125                   elsif Init_Or_Norm_Scalars
 126                     and then
 127                       (Is_Scalar_Type (Typ) or else Is_String_Type (Typ))
 128                   then
 129                      null;
 130
 131                   else
 132                      Set_Expression (Decl, Empty);
 133                   end if;
 134
 135                --  An object declaration to which an address clause applies
 136                --  has a delayed freeze, but the address expression itself
 137                --  must be elaborated at the point it appears. If the object
 138                --  is controlled, additional checks apply elsewhere.
 139
 140                elsif Nkind (Decl) = N_Object_Declaration
 141                  and then not Needs_Constant_Address (Decl, Typ)
 142                then
 143                   Remove_Side_Effects (Exp);
 144                end if;
 145             end;
 146
 147          ---------------
 148          -- Alignment --
 149          ---------------
 150
 151          when Attribute_Alignment =>
 152
 153             --  As required by Gigi, we guarantee that the operand is an
 154             --  integer literal (this simplifies things in Gigi).
 155
 156             if Nkind (Exp) /= N_Integer_Literal then
 157                Rewrite
 158                  (Exp, Make_Integer_Literal (Loc, Expr_Value (Exp)));
 159             end if;
 160
 161             --  A complex case arises if the alignment clause applies to an
 162             --  unconstrained object initialized with a function call. The
 163             --  result of the call is placed on the secondary stack, and the
 164             --  declaration is rewritten as a renaming of a dereference, which
 165             --  fails expansion. We must introduce a temporary and assign its
 166             --  value to the existing entity.
 167
 168             if Nkind (Parent (Ent)) = N_Object_Renaming_Declaration
 169               and then not Is_Entity_Name (Renamed_Object (Ent))
 170             then
 171                declare
 172                   Loc      : constant Source_Ptr := Sloc (N);
 173                   Decl     : constant Node_Id    := Parent (Ent);
 174                   Temp     : constant Entity_Id  := Make_Temporary (Loc, 'T');
 175                   New_Decl : Node_Id;
 176
 177                begin
 178                   --  Replace entity with temporary and reanalyze
 179
 180                   Set_Defining_Identifier (Decl, Temp);
 181                   Set_Analyzed (Decl, False);
 182                   Analyze (Decl);
 183
 184                   --  Introduce new declaration for entity but do not reanalyze
 185                   --  because entity is already in scope. Type and expression
 186                   --  are already resolved.
 187
 188                   New_Decl :=
 189                     Make_Object_Declaration (Loc,
 190                       Defining_Identifier => Ent,
 191                       Object_Definition   =>
 192                         New_Occurrence_Of (Etype (Ent), Loc),
 193                       Expression          => New_Occurrence_Of (Temp, Loc));
 194
 195                   Set_Renamed_Object (Ent, Empty);
 196                   Insert_After (Decl, New_Decl);
 197                   Set_Analyzed (Decl);
 198                end;
 199             end if;
 200
 201          ------------------
 202          -- Storage_Size --
 203          ------------------
 204
 205          when Attribute_Storage_Size =>
 206
 207             --  If the type is a task type, then assign the value of the
 208             --  storage size to the Size variable associated with the task.
 209             --  Insert the assignment right after the declaration of the Size
 210             --  variable.
 211
 212             --  Generate:
 213
 214             --  task_typeZ := expression
 215
 216             if Ekind (Ent) = E_Task_Type then
 217                declare
 218                   Assign : Node_Id;
 219
 220                begin
 221                   Assign :=
 222                     Make_Assignment_Statement (Loc,
 223                       Name =>
 224                         New_Occurrence_Of (Storage_Size_Variable (Ent), Loc),
 225                       Expression =>
 226                         Convert_To (RTE (RE_Size_Type), Expression (N)));
 227
 228                   --  If the clause is not generated by an aspect, insert
 229                   --  the assignment here.  Freezing rules ensure that this
 230                   --  is safe, or clause will have been rejected already.
 231
 232                   if Is_List_Member (N) then
 233                      Insert_After (N, Assign);
 234
 235                   --  Otherwise, insert assignment after task declaration.
 236
 237                   else
 238                      Insert_After
 239                        (Parent (Storage_Size_Variable (Entity (N))), Assign);
 240                   end if;
 241
 242                   Analyze (Assign);
 243                end;
 244
 245             --  For Storage_Size for an access type, create a variable to hold
 246             --  the value of the specified size with name typeV and expand an
 247             --  assignment statement to initialize this value.
 248
 249             elsif Is_Access_Type (Ent) then
 250
 251                --  We don't need the variable for a storage size of zero
 252
 253                if not No_Pool_Assigned (Ent) then
 254                   V :=
 255                     Make_Defining_Identifier (Loc,
 256                       Chars => New_External_Name (Chars (Ent), 'V'));
 257
 258                   --  Insert the declaration of the object
 259
 260                   Insert_Action (N,
 261                     Make_Object_Declaration (Loc,
 262                       Defining_Identifier => V,
 263                       Object_Definition  =>
 264                         New_Occurrence_Of (RTE (RE_Storage_Offset), Loc),
 265                       Expression =>
 266                         Convert_To (RTE (RE_Storage_Offset), Expression (N))));
 267
 268                   Set_Storage_Size_Variable (Ent, Entity_Id (V));
 269                end if;
 270             end if;
 271
 272          --  Other attributes require no expansion
 273
 274          when others =>
 275             null;
 276
 277       end case;
 278    end Expand_N_Attribute_Definition_Clause;
 279
 280    -----------------------------
 281    -- Expand_N_Free_Statement --
 282    -----------------------------
 283
 284    procedure Expand_N_Free_Statement (N : Node_Id) is
 285       Expr : constant Node_Id := Expression (N);
 286       Typ  : Entity_Id;
 287
 288    begin
 289       --  Certain run-time configurations and targets do not provide support
 290       --  for controlled types.
 291
 292       if Restriction_Active (No_Finalization) then
 293          return;
 294
 295       --  Do not create a specialized Deallocate since .NET/JVM compilers do
 296       --  not support pools and address arithmetic.
 297
 298       elsif VM_Target /= No_VM then
 299          return;
 300       end if;
 301
 302       --  Use the base type to perform the check for finalization master
 303
 304       Typ := Etype (Expr);
 305
 306       if Ekind (Typ) = E_Access_Subtype then
 307          Typ := Etype (Typ);
 308       end if;
 309
 310       --  Handle private access types
 311
 312       if Is_Private_Type (Typ)
 313         and then Present (Full_View (Typ))
 314       then
 315          Typ := Full_View (Typ);
 316       end if;
 317
 318       --  Do not create a custom Deallocate when freeing an object with
 319       --  suppressed finalization. In such cases the object is never attached
 320       --  to a master, so it does not need to be detached. Use a regular free
 321       --  statement instead.
 322
 323       if No (Finalization_Master (Typ)) then
 324          return;
 325       end if;
 326
 327       --  Use a temporary to store the result of a complex expression. Perform
 328       --  the following transformation:
 329       --
 330       --     Free (Complex_Expression);
 331       --
 332       --     Temp : constant Type_Of_Expression := Complex_Expression;
 333       --     Free (Temp);
 334
 335       if Nkind (Expr) /= N_Identifier then
 336          declare
 337             Expr_Typ : constant Entity_Id  := Etype (Expr);
 338             Loc      : constant Source_Ptr := Sloc (N);
 339             New_Expr : Node_Id;
 340             Temp_Id  : Entity_Id;
 341
 342          begin
 343             Temp_Id := Make_Temporary (Loc, 'T');
 344             Insert_Action (N,
 345               Make_Object_Declaration (Loc,
 346                 Defining_Identifier => Temp_Id,
 347                 Object_Definition =>
 348                   New_Occurrence_Of (Expr_Typ, Loc),
 349                 Expression =>
 350                   Relocate_Node (Expr)));
 351
 352             New_Expr := New_Occurrence_Of (Temp_Id, Loc);
 353             Set_Etype (New_Expr, Expr_Typ);
 354
 355             Set_Expression (N, New_Expr);
 356          end;
 357       end if;
 358
 359       --  Create a custom Deallocate for a controlled object. This routine
 360       --  ensures that the hidden list header will be deallocated along with
 361       --  the actual object.
 362
 363       Build_Allocate_Deallocate_Proc (N, Is_Allocate => False);
 364    end Expand_N_Free_Statement;
 365
 366    ----------------------------
 367    -- Expand_N_Freeze_Entity --
 368    ----------------------------
 369
 370    procedure Expand_N_Freeze_Entity (N : Node_Id) is
 371       E              : constant Entity_Id := Entity (N);
 372       E_Scope        : Entity_Id;
 373       In_Other_Scope : Boolean;
 374       In_Outer_Scope : Boolean;
 375       Decl           : Node_Id;
 376       Delete         : Boolean := False;
 377
 378    begin
 379       --  If there are delayed aspect specifications, we insert them just
 380       --  before the freeze node. They are already analyzed so we don't need
 381       --  to reanalyze them (they were analyzed before the type was frozen),
 382       --  but we want them in the tree for the back end, and so that the
 383       --  listing from sprint is clearer on where these occur logically.
 384
 385       if Has_Delayed_Aspects (E) then
 386          declare
 387             Aitem : Node_Id;
 388             Ritem : Node_Id;
 389
 390          begin
 391             --  Look for aspect specs for this entity
 392
 393             Ritem := First_Rep_Item (E);
 394             while Present (Ritem) loop
 395                if Nkind (Ritem) = N_Aspect_Specification
 396                  and then Entity (Ritem) = E
 397                then
 398                   Aitem := Aspect_Rep_Item (Ritem);
 399
 400                   --  Skip this for aspects (e.g. Current_Value) for which
 401                   --  there is no corresponding pragma or attribute.
 402
 403                   if Present (Aitem) then
 404                      pragma Assert (Is_Delayed_Aspect (Aitem));
 405                      Insert_Before (N, Aitem);
 406                   end if;
 407                end if;
 408
 409                Next_Rep_Item (Ritem);
 410             end loop;
 411          end;
 412       end if;
 413
 414       --  Processing for objects
 415
 416       if Is_Object (E) then
 417          if Present (Address_Clause (E)) then
 418             Apply_Address_Clause_Check (E, N);
 419          end if;
 420
 421          --  If initialization statements have been captured in a compound
 422          --  statement, insert them back into the tree now.
 423
 424          Explode_Initialization_Compound_Statement (E);
 425
 426          return;
 427
 428       --  Only other items requiring any front end action are types and
 429       --  subprograms.
 430
 431       elsif not Is_Type (E) and then not Is_Subprogram (E) then
 432          return;
 433       end if;
 434
 435       --  Here E is a type or a subprogram
 436
 437       E_Scope := Scope (E);
 438
 439       --  This is an error protection against previous errors
 440
 441       if No (E_Scope) then
 442          Check_Error_Detected;
 443          return;
 444       end if;
 445
 446       --  The entity may be a subtype declared for a constrained record
 447       --  component, in which case the relevant scope is the scope of
 448       --  the record. This happens for class-wide subtypes created for
 449       --  a constrained type extension with inherited discriminants.
 450
 451       if Is_Type (E_Scope)
 452         and then Ekind (E_Scope) not in Concurrent_Kind
 453       then
 454          E_Scope := Scope (E_Scope);
 455       end if;
 456
 457       --  Remember that we are processing a freezing entity and its freezing
 458       --  nodes. This flag (non-zero = set) is used to avoid the need of
 459       --  climbing through the tree while processing the freezing actions (ie.
 460       --  to avoid generating spurious warnings or to avoid killing constant
 461       --  indications while processing the code associated with freezing
 462       --  actions). We use a counter to deal with nesting.
 463
 464       Inside_Freezing_Actions := Inside_Freezing_Actions + 1;
 465
 466       --  If we are freezing entities defined in protected types, they belong
 467       --  in the enclosing scope, given that the original type has been
 468       --  expanded away. The same is true for entities in task types, in
 469       --  particular the parameter records of entries (Entities in bodies are
 470       --  all frozen within the body). If we are in the task body, this is a
 471       --  proper scope. If we are within a subprogram body, the proper scope
 472       --  is the corresponding spec. This may happen for itypes generated in
 473       --  the bodies of protected operations.
 474
 475       if Ekind (E_Scope) = E_Protected_Type
 476         or else (Ekind (E_Scope) = E_Task_Type
 477                   and then not Has_Completion (E_Scope))
 478       then
 479          E_Scope := Scope (E_Scope);
 480
 481       elsif Ekind (E_Scope) = E_Subprogram_Body then
 482          E_Scope := Corresponding_Spec (Unit_Declaration_Node (E_Scope));
 483       end if;
 484
 485       --  If the scope of the entity is in open scopes, it is the current one
 486       --  or an enclosing one, including a loop, a block, or a subprogram.
 487
 488       if In_Open_Scopes (E_Scope) then
 489          In_Other_Scope := False;
 490          In_Outer_Scope := E_Scope /= Current_Scope;
 491
 492       --  Otherwise it is a local package or a different compilation unit
 493
 494       else
 495          In_Other_Scope := True;
 496          In_Outer_Scope := False;
 497       end if;
 498
 499       --  If the entity being frozen is defined in a scope that is not
 500       --  currently on the scope stack, we must establish the proper
 501       --  visibility before freezing the entity and related subprograms.
 502
 503       if In_Other_Scope then
 504          Push_Scope (E_Scope);
 505
 506          --  Finalizers are little odd in terms of freezing. The spec of the
 507          --  procedure appears in the declarations while the body appears in
 508          --  the statement part of a single construct. Since the finalizer must
 509          --  be called by the At_End handler of the construct, the spec is
 510          --  manually frozen right after its declaration. The only side effect
 511          --  of this action appears in contexts where the construct is not in
 512          --  its final resting place. These contexts are:
 513
 514          --    * Entry bodies - The declarations and statements are moved to
 515          --      the procedure equivalen of the entry.
 516          --    * Protected subprograms - The declarations and statements are
 517          --      moved to the non-protected version of the subprogram.
 518          --    * Task bodies - The declarations and statements are moved to the
 519          --      task body procedure.
 520
 521          --  Visible declarations do not need to be installed in these three
 522          --  cases since it does not make semantic sense to do so. All entities
 523          --  referenced by a finalizer are visible and already resolved, plus
 524          --  the enclosing scope may not have visible declarations at all.
 525
 526          if Ekind (E) = E_Procedure
 527            and then Is_Finalizer (E)
 528            and then
 529              (Is_Entry (E_Scope)
 530                 or else (Is_Subprogram (E_Scope)
 531                           and then Is_Protected_Type (Scope (E_Scope)))
 532                 or else Is_Task_Type (E_Scope))
 533          then
 534             null;
 535          else
 536             Install_Visible_Declarations (E_Scope);
 537          end if;
 538
 539          if Is_Package_Or_Generic_Package (E_Scope) or else
 540             Is_Protected_Type (E_Scope)             or else
 541             Is_Task_Type (E_Scope)
 542          then
 543             Install_Private_Declarations (E_Scope);
 544          end if;
 545
 546       --  If the entity is in an outer scope, then that scope needs to
 547       --  temporarily become the current scope so that operations created
 548       --  during type freezing will be declared in the right scope and
 549       --  can properly override any corresponding inherited operations.
 550
 551       elsif In_Outer_Scope then
 552          Push_Scope (E_Scope);
 553       end if;
 554
 555       --  If type, freeze the type
 556
 557       if Is_Type (E) then
 558          Delete := Freeze_Type (N);
 559
 560          --  And for enumeration type, build the enumeration tables
 561
 562          if Is_Enumeration_Type (E) then
 563             Build_Enumeration_Image_Tables (E, N);
 564          end if;
 565
 566       --  If subprogram, freeze the subprogram
 567
 568       elsif Is_Subprogram (E) then
 569          Freeze_Subprogram (N);
 570
 571          --  Ada 2005 (AI-251): Remove the freezing node associated with the
 572          --  entities internally used by the frontend to register primitives
 573          --  covering abstract interfaces. The call to Freeze_Subprogram has
 574          --  already expanded the code that fills the corresponding entry in
 575          --  its secondary dispatch table and therefore the code generator
 576          --  has nothing else to do with this freezing node.
 577
 578          Delete := Present (Interface_Alias (E));
 579       end if;
 580
 581       --  Analyze actions generated by freezing. The init_proc contains source
 582       --  expressions that may raise Constraint_Error, and the assignment
 583       --  procedure for complex types needs checks on individual component
 584       --  assignments, but all other freezing actions should be compiled with
 585       --  all checks off.
 586
 587       if Present (Actions (N)) then
 588          Decl := First (Actions (N));
 589          while Present (Decl) loop
 590             if Nkind (Decl) = N_Subprogram_Body
 591               and then (Is_Init_Proc (Defining_Entity (Decl))
 592                           or else
 593                             Chars (Defining_Entity (Decl)) = Name_uAssign)
 594             then
 595                Analyze (Decl);
 596
 597             --  A subprogram body created for a renaming_as_body completes
 598             --  a previous declaration, which may be in a different scope.
 599             --  Establish the proper scope before analysis.
 600
 601             elsif Nkind (Decl) = N_Subprogram_Body
 602               and then Present (Corresponding_Spec (Decl))
 603               and then Scope (Corresponding_Spec (Decl)) /= Current_Scope
 604             then
 605                Push_Scope (Scope (Corresponding_Spec (Decl)));
 606                Analyze (Decl, Suppress => All_Checks);
 607                Pop_Scope;
 608
 609             --  We treat generated equality specially, if validity checks are
 610             --  enabled, in order to detect components default-initialized
 611             --  with invalid values.
 612
 613             elsif Nkind (Decl) = N_Subprogram_Body
 614               and then Chars (Defining_Entity (Decl)) = Name_Op_Eq
 615               and then Validity_Checks_On
 616               and then Initialize_Scalars
 617             then
 618                declare
 619                   Save_Force : constant Boolean := Force_Validity_Checks;
 620                begin
 621                   Force_Validity_Checks := True;
 622                   Analyze (Decl);
 623                   Force_Validity_Checks := Save_Force;
 624                end;
 625
 626             --  All other freezing actions
 627
 628             else
 629                Analyze (Decl, Suppress => All_Checks);
 630             end if;
 631
 632             Next (Decl);
 633          end loop;
 634       end if;
 635
 636       --  If we are to delete this N_Freeze_Entity, do so by rewriting so that
 637       --  a loop on all nodes being inserted will work propertly.
 638
 639       if Delete then
 640          Rewrite (N, Make_Null_Statement (Sloc (N)));
 641       end if;
 642
 643       --  Pop scope if we installed one for the analysis
 644
 645       if In_Other_Scope then
 646          if Ekind (Current_Scope) = E_Package then
 647             End_Package_Scope (E_Scope);
 648          else
 649             End_Scope;
 650          end if;
 651
 652       elsif In_Outer_Scope then
 653          Pop_Scope;
 654       end if;
 655
 656       --  Restore previous value of the nesting-level counter that records
 657       --  whether we are inside a (possibly nested) call to this procedure.
 658
 659       Inside_Freezing_Actions := Inside_Freezing_Actions - 1;
 660    end Expand_N_Freeze_Entity;
 661
 662    -------------------------------------------
 663    -- Expand_N_Record_Representation_Clause --
 664    -------------------------------------------
 665
 666    --  The only expansion required is for the case of a mod clause present,
 667    --  which is removed, and translated into an alignment representation
 668    --  clause inserted immediately after the record rep clause with any
 669    --  initial pragmas inserted at the start of the component clause list.
 670
 671    procedure Expand_N_Record_Representation_Clause (N : Node_Id) is
 672       Loc     : constant Source_Ptr := Sloc (N);
 673       Rectype : constant Entity_Id  := Entity (Identifier (N));
 674       Mod_Val : Uint;
 675       Citems  : List_Id;
 676       Repitem : Node_Id;
 677       AtM_Nod : Node_Id;
 678
 679    begin
 680       if Present (Mod_Clause (N)) and then not Ignore_Rep_Clauses then
 681          Mod_Val := Expr_Value (Expression (Mod_Clause (N)));
 682          Citems  := Pragmas_Before (Mod_Clause (N));
 683
 684          if Present (Citems) then
 685             Append_List_To (Citems, Component_Clauses (N));
 686             Set_Component_Clauses (N, Citems);
 687          end if;
 688
 689          AtM_Nod :=
 690            Make_Attribute_Definition_Clause (Loc,
 691              Name       => New_Occurrence_Of (Base_Type (Rectype), Loc),
 692              Chars      => Name_Alignment,
 693              Expression => Make_Integer_Literal (Loc, Mod_Val));
 694
 695          Set_From_At_Mod (AtM_Nod);
 696          Insert_After (N, AtM_Nod);
 697          Set_Mod_Clause (N, Empty);
 698       end if;
 699
 700       --  If the record representation clause has no components, then
 701       --  completely remove it.  Note that we also have to remove
 702       --  ourself from the Rep Item list.
 703
 704       if Is_Empty_List (Component_Clauses (N)) then
 705          if First_Rep_Item (Rectype) = N then
 706             Set_First_Rep_Item (Rectype, Next_Rep_Item (N));
 707          else
 708             Repitem := First_Rep_Item (Rectype);
 709             while Present (Next_Rep_Item (Repitem)) loop
 710                if Next_Rep_Item (Repitem) = N then
 711                   Set_Next_Rep_Item (Repitem, Next_Rep_Item (N));
 712                   exit;
 713                end if;
 714
 715                Next_Rep_Item (Repitem);
 716             end loop;
 717          end if;
 718
 719          Rewrite (N,
 720            Make_Null_Statement (Loc));
 721       end if;
 722    end Expand_N_Record_Representation_Clause;
 723
 724 end Exp_Ch13;