gcc/ada/ali.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                  A L I                                   --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2014, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package defines the internal data structures used for representation
  27 --  of Ada Library Information (ALI) acquired from the ALI files generated by
  28 --  the front end.
  29
  30 with Casing;  use Casing;
  31 with Gnatvsn; use Gnatvsn;
  32 with Namet;   use Namet;
  33 with Rident;  use Rident;
  34 with Table;
  35 with Types;   use Types;
  36
  37 with GNAT.HTable; use GNAT.HTable;
  38
  39 package ALI is
  40
  41    --------------
  42    -- Id Types --
  43    --------------
  44
  45    --  The various entries are stored in tables with distinct subscript ranges.
  46    --  The following type definitions show the ranges used for the subscripts
  47    --  (Id values) for the various tables.
  48
  49    type ALI_Id is range 0 .. 999_999;
  50    --  Id values used for ALIs table entries
  51
  52    type Unit_Id is range 1_000_000 .. 1_999_999;
  53    --  Id values used for Unit table entries
  54
  55    type With_Id is range 2_000_000 .. 2_999_999;
  56    --  Id values used for Withs table entries
  57
  58    type Arg_Id is range 3_000_000 .. 3_999_999;
  59    --  Id values used for argument table entries
  60
  61    type Sdep_Id is range 4_000_000 .. 4_999_999;
  62    --  Id values used for Sdep table entries
  63
  64    type Source_Id is range 5_000_000 .. 5_999_999;
  65    --  Id values used for Source table entries
  66
  67    type Interrupt_State_Id is range 6_000_000 .. 6_999_999;
  68    --  Id values used for Interrupt_State table entries
  69
  70    type Priority_Specific_Dispatching_Id is range 7_000_000 .. 7_999_999;
  71    --  Id values used for Priority_Specific_Dispatching table entries
  72
  73    --------------------
  74    -- ALI File Table --
  75    --------------------
  76
  77    --  Each ALI file read generates an entry in the ALIs table
  78
  79    No_ALI_Id : constant ALI_Id := ALI_Id'First;
  80    --  Special value indicating no ALI entry
  81
  82    First_ALI_Entry : constant ALI_Id := No_ALI_Id + 1;
  83    --  Id of first actual entry in table
  84
  85    type Main_Program_Type is (None, Proc, Func);
  86    --  Indicator of whether unit can be used as main program
  87
  88    type ALIs_Record is record
  89
  90       Afile : File_Name_Type;
  91       --  Name of ALI file
  92
  93       Ofile_Full_Name : File_Name_Type;
  94       --  Full name of object file corresponding to the ALI file
  95
  96       Sfile : File_Name_Type;
  97       --  Name of source file that generates this ALI file (which is equal
  98       --  to the name of the source file in the first unit table entry for
  99       --  this ALI file, since the body if present is always first).
 100
 101       Ver : String (1 .. Ver_Len_Max);
 102       --  Value of library version (V line in ALI file). Not set if
 103       --  V lines are ignored as a result of the Ignore_Lines parameter.
 104
 105       Ver_Len : Natural;
 106       --  Length of characters stored in Ver. Not set if V lines are ignored as
 107       --  a result of the Ignore_Lines parameter.
 108
 109       SAL_Interface : Boolean;
 110       --  Set True when this is an interface to a standalone library
 111
 112       First_Unit : Unit_Id;
 113       --  Id of first Unit table entry for this file
 114
 115       Last_Unit : Unit_Id;
 116       --  Id of last Unit table entry for this file
 117
 118       First_Sdep : Sdep_Id;
 119       --  Id of first Sdep table entry for this file
 120
 121       Last_Sdep : Sdep_Id;
 122       --  Id of last Sdep table entry for this file
 123
 124       Main_Program : Main_Program_Type;
 125       --  Indicator of whether first unit can be used as main program. Not set
 126       --  if 'M' appears in Ignore_Lines.
 127
 128       Main_Priority : Int;
 129       --  Indicates priority value if Main_Program field indicates that this
 130       --  can be a main program. A value of -1 (No_Main_Priority) indicates
 131       --  that no parameter was found, or no M line was present. Not set if
 132       --  'M' appears in Ignore_Lines.
 133
 134       Main_CPU : Int;
 135       --  Indicates processor if Main_Program field indicates that this can
 136       --  be a main program. A value of -1 (No_Main_CPU) indicates that no C
 137       --  parameter was found, or no M line was present. Not set if 'M' appears
 138       --  in Ignore_Lines.
 139
 140       Time_Slice_Value : Int;
 141       --  Indicates value of time slice parameter from T=xxx on main program
 142       --  line. A value of -1 indicates that no T=xxx parameter was found, or
 143       --  no M line was present. Not set if 'M' appears in Ignore_Lines.
 144
 145       WC_Encoding : Character;
 146       --  Wide character encoding if main procedure. Otherwise not relevant.
 147       --  Not set if 'M' appears in Ignore_Lines.
 148
 149       Locking_Policy : Character;
 150       --  Indicates locking policy for units in this file. Space means tasking
 151       --  was not used, or that no Locking_Policy pragma was present or that
 152       --  this is a language defined unit. Otherwise set to first character
 153       --  (upper case) of policy name. Not set if 'P' appears in Ignore_Lines.
 154
 155       Partition_Elaboration_Policy : Character;
 156       --  Indicates partition elaboration policy for units in this file. Space
 157       --  means that no Partition_Elaboration_Policy pragma was present or that
 158       --  this is a language defined unit. Otherwise set to first character
 159       --  (upper case) of policy name. Not set if 'P' appears in Ignore_Lines.
 160
 161       Queuing_Policy : Character;
 162       --  Indicates queuing policy for units in this file. Space means tasking
 163       --  was not used, or that no Queuing_Policy pragma was present or that
 164       --  this is a language defined unit. Otherwise set to first character
 165       --  (upper case) of policy name. Not set if 'P' appears in Ignore_Lines.
 166
 167       Task_Dispatching_Policy : Character;
 168       --  Indicates task dispatching policy for units in this file. Space means
 169       --  tasking was not used, or that no Task_Dispatching_Policy pragma was
 170       --  present or that this is a language defined unit. Otherwise set to
 171       --  first character (upper case) of policy name. Not set if 'P' appears
 172       --  in Ignore_Lines.
 173
 174       Compile_Errors : Boolean;
 175       --  Set to True if compile errors for unit. Note that No_Object will
 176       --  always be set as well in this case. Not set if 'P' appears in
 177       --  Ignore_Lines.
 178
 179       GNATprove_Mode : Boolean;
 180       --  Set to True if ALI and object file produced in GNATprove_Mode as
 181       --  signalled by GP appearing on the P line. Not set if 'P' appears in
 182       --  Ignore_Lines.
 183
 184       No_Object : Boolean;
 185       --  Set to True if no object file generated. Not set if 'P' appears in
 186       --  Ignore_Lines.
 187
 188       Normalize_Scalars : Boolean;
 189       --  Set to True if file was compiled with Normalize_Scalars. Not set if
 190       --  'P' appears in Ignore_Lines.
 191
 192       SSO_Default : Character;
 193       --  Set to 'H' or 'L' if file was compiled with a configuration pragma
 194       --  file containing Default_Scalar_Storage_Order (High/Low_Order_First).
 195       --  Set to ' ' if neither pragma was present. Not set if 'P' appears in
 196       --  Ignore_Lines.
 197
 198       Unit_Exception_Table : Boolean;
 199       --  Set to True if unit exception table pointer generated. Not set if 'P'
 200       --  appears in Ignore_Lines.
 201
 202       Zero_Cost_Exceptions : Boolean;
 203       --  Set to True if file was compiled with zero cost exceptions. Not set
 204       --  if 'P' appears in Ignore_Lines.
 205
 206       Restrictions : Restrictions_Info;
 207       --  Restrictions information reconstructed from R lines
 208
 209       First_Interrupt_State : Interrupt_State_Id;
 210       Last_Interrupt_State  : Interrupt_State_Id'Base;
 211       --  These point to the first and last entries in the interrupt state
 212       --  table for this unit. If no entries, then Last_Interrupt_State =
 213       --  First_Interrupt_State - 1 (that's why the 'Base reference is there,
 214       --  it can be one less than the lower bound of the subtype). Not set if
 215       --  'I' appears in Ignore_Lines
 216
 217       First_Specific_Dispatching : Priority_Specific_Dispatching_Id;
 218       Last_Specific_Dispatching  : Priority_Specific_Dispatching_Id'Base;
 219       --  These point to the first and last entries in the priority specific
 220       --  dispatching table for this unit. If there are no entries, then
 221       --  Last_Specific_Dispatching = First_Specific_Dispatching - 1. That
 222       --  is why the 'Base reference is there, it can be one less than the
 223       --  lower bound of the subtype. Not set if 'S' appears in Ignore_Lines.
 224
 225    end record;
 226
 227    No_Main_Priority : constant Int := -1;
 228    --  Code for no main priority set
 229
 230    No_Main_CPU : constant Int := -1;
 231    --  Code for no main cpu set
 232
 233    package ALIs is new Table.Table (
 234      Table_Component_Type => ALIs_Record,
 235      Table_Index_Type     => ALI_Id,
 236      Table_Low_Bound      => First_ALI_Entry,
 237      Table_Initial        => 500,
 238      Table_Increment      => 200,
 239      Table_Name           => "ALIs");
 240
 241    ----------------
 242    -- Unit Table --
 243    ----------------
 244
 245    --  Each unit within an ALI file generates an entry in the unit table
 246
 247    No_Unit_Id : constant Unit_Id := Unit_Id'First;
 248    --  Special value indicating no unit table entry
 249
 250    First_Unit_Entry : constant Unit_Id := No_Unit_Id + 1;
 251    --  Id of first actual entry in table
 252
 253    type Unit_Type is (Is_Spec, Is_Body, Is_Spec_Only, Is_Body_Only);
 254    --  Indicates type of entry, if both body and spec appear in the ALI file,
 255    --  then the first unit is marked Is_Body, and the second is marked Is_Spec.
 256    --  If only a spec appears, then it is marked as Is_Spec_Only, and if only
 257    --  a body appears, then it is marked Is_Body_Only).
 258
 259    subtype Version_String is String (1 .. 8);
 260    --  Version string, taken from unit record
 261
 262    type Unit_Record is record
 263
 264       My_ALI : ALI_Id;
 265       --  Corresponding ALI entry
 266
 267       Uname : Unit_Name_Type;
 268       --  Name of Unit
 269
 270       Sfile : File_Name_Type;
 271       --  Name of source file
 272
 273       Preelab : Boolean;
 274       --  Indicates presence of PR parameter for a preelaborated package
 275
 276       No_Elab : Boolean;
 277       --  Indicates presence of NE parameter for a unit that has does not
 278       --  have an elaboration routine (since it has no elaboration code).
 279
 280       Pure : Boolean;
 281       --  Indicates presence of PU parameter for a package having pragma Pure
 282
 283       Dynamic_Elab : Boolean;
 284       --  Set to True if the unit was compiled with dynamic elaboration checks
 285       --  (i.e. either -gnatE or pragma Elaboration_Checks (RM) was used to
 286       --  compile the unit).
 287
 288       Elaborate_Body : Boolean;
 289       --  Indicates presence of EB parameter for a package which has a pragma
 290       --  Elaborate_Body, and also for generic package instantiations.
 291
 292       Set_Elab_Entity : Boolean;
 293       --  Indicates presence of EE parameter for a unit which has an
 294       --  elaboration entity which must be set true as part of the
 295       --  elaboration of the unit.
 296
 297       Has_RACW : Boolean;
 298       --  Indicates presence of RA parameter for a package that declares at
 299       --  least one Remote Access to Class_Wide (RACW) object.
 300
 301       Remote_Types : Boolean;
 302       --  Indicates presence of RT parameter for a package which has a
 303       --  pragma Remote_Types.
 304
 305       Shared_Passive : Boolean;
 306       --  Indicates presence of SP parameter for a package which has a pragma
 307       --  Shared_Passive.
 308
 309       RCI : Boolean;
 310       --  Indicates presence of RC parameter for a package which has a pragma
 311       --  Remote_Call_Interface.
 312
 313       Predefined : Boolean;
 314       --  Indicates if unit is language predefined (or a child of such a unit)
 315
 316       Internal : Boolean;
 317       --  Indicates if unit is an internal unit (or a child of such a unit)
 318
 319       First_With : With_Id;
 320       --  Id of first withs table entry for this file
 321
 322       Last_With : With_Id;
 323       --  Id of last withs table entry for this file
 324
 325       First_Arg : Arg_Id;
 326       --  Id of first args table entry for this file
 327
 328       Last_Arg : Arg_Id;
 329       --  Id of last args table entry for this file
 330
 331       Utype : Unit_Type;
 332       --  Type of entry
 333
 334       Is_Generic : Boolean;
 335       --  True for generic unit (i.e. a generic declaration, or a generic
 336       --  body). False for a non-generic unit.
 337
 338       Unit_Kind : Character;
 339       --  Indicates the nature of the unit. 'p' for Packages and 's' for
 340       --  subprograms.
 341
 342       Version : Version_String;
 343       --  Version of unit
 344
 345       Icasing : Casing_Type;
 346       --  Indicates casing of identifiers in source file for this unit. This
 347       --  is used for informational output, and also for constructing the main
 348       --  unit if it is being built in Ada.
 349
 350       Kcasing : Casing_Type;
 351       --  Indicates casing of keywords in source file for this unit. This is
 352       --  used for informational output, and also for constructing the main
 353       --  unit if it is being built in Ada.
 354
 355       Elab_Position : aliased Natural;
 356       --  Initialized to zero. Set non-zero when a unit is chosen and
 357       --  placed in the elaboration order. The value represents the
 358       --  ordinal position in the elaboration order.
 359
 360       Init_Scalars : Boolean;
 361       --  Set True if IS qualifier appears in ALI file, indicating that
 362       --  an Initialize_Scalars pragma applies to the unit.
 363
 364       SAL_Interface : Boolean;
 365       --  Set True when this is an interface to a standalone library
 366
 367       Directly_Scanned : Boolean;
 368       --  True iff it is a unit from an ALI file specified to gnatbind
 369
 370       Body_Needed_For_SAL : Boolean;
 371       --  Indicates that the source for the body of the unit (subprogram,
 372       --  package, or generic unit) must be included in a standalone library.
 373
 374       Elaborate_Body_Desirable : Boolean;
 375       --  Indicates that the front end elaboration circuitry decided that it
 376       --  would be a good idea if this package had Elaborate_Body. The binder
 377       --  will attempt, but does not promise, to place the elaboration call
 378       --  for the body right after the call for the spec, or at least as close
 379       --  together as possible.
 380
 381       Optimize_Alignment : Character;
 382       --  Optimize_Alignment setting. Set to L/S/T/O for OL/OS/OT/OO present
 383
 384       Has_Finalizer : Boolean;
 385       --  Indicates whether a package body or a spec has a library-level
 386       --  finalization routine.
 387    end record;
 388
 389    package Units is new Table.Table (
 390      Table_Component_Type => Unit_Record,
 391      Table_Index_Type     => Unit_Id,
 392      Table_Low_Bound      => First_Unit_Entry,
 393      Table_Initial        => 100,
 394      Table_Increment      => 200,
 395      Table_Name           => "Unit");
 396
 397    ---------------------------
 398    -- Interrupt State Table --
 399    ---------------------------
 400
 401    --  An entry is made in this table for each I (interrupt state) line
 402    --  encountered in the input ALI file. The First/Last_Interrupt_Id
 403    --  fields of the ALI file entry show the range of entries defined
 404    --  within a particular ALI file.
 405
 406    type Interrupt_State_Record is record
 407       Interrupt_Id : Nat;
 408       --  Id from interrupt state entry
 409
 410       Interrupt_State : Character;
 411       --  State from interrupt state entry ('u'/'r'/'s')
 412
 413       IS_Pragma_Line : Nat;
 414       --  Line number of Interrupt_State pragma
 415    end record;
 416
 417    package Interrupt_States is new Table.Table (
 418      Table_Component_Type => Interrupt_State_Record,
 419      Table_Index_Type     => Interrupt_State_Id'Base,
 420      Table_Low_Bound      => Interrupt_State_Id'First,
 421      Table_Initial        => 100,
 422      Table_Increment      => 200,
 423      Table_Name           => "Interrupt_States");
 424
 425    -----------------------------------------
 426    -- Priority Specific Dispatching Table --
 427    -----------------------------------------
 428
 429    --  An entry is made in this table for each S (priority specific
 430    --  dispatching) line encountered in the input ALI file. The
 431    --  First/Last_Specific_Dispatching_Id fields of the ALI file
 432    --  entry show the range of entries defined within a particular
 433    --  ALI file.
 434
 435    type Specific_Dispatching_Record is record
 436       Dispatching_Policy : Character;
 437       --  First character (upper case) of the corresponding policy name
 438
 439       First_Priority     : Nat;
 440       --  Lower bound of the priority range to which the specified dispatching
 441       --  policy applies.
 442
 443       Last_Priority      : Nat;
 444       --  Upper bound of the priority range to which the specified dispatching
 445       --  policy applies.
 446
 447       PSD_Pragma_Line : Nat;
 448       --  Line number of Priority_Specific_Dispatching pragma
 449    end record;
 450
 451    package Specific_Dispatching is new Table.Table (
 452      Table_Component_Type => Specific_Dispatching_Record,
 453      Table_Index_Type     => Priority_Specific_Dispatching_Id'Base,
 454      Table_Low_Bound      => Priority_Specific_Dispatching_Id'First,
 455      Table_Initial        => 100,
 456      Table_Increment      => 200,
 457      Table_Name           => "Priority_Specific_Dispatching");
 458
 459    --------------
 460    -- Switches --
 461    --------------
 462
 463    --  These switches record status information about ali files that
 464    --  have been read, for quick reference without searching tables.
 465
 466    --  Note: a switch will be left set at its default value if the line
 467    --  which might otherwise set it is ignored (from Ignore_Lines).
 468
 469    Dynamic_Elaboration_Checks_Specified : Boolean := False;
 470    --  Set to False by Initialize_ALI. Set to True if Scan_ALI reads
 471    --  a unit for which dynamic elaboration checking is enabled.
 472
 473    GNATprove_Mode_Specified : Boolean := False;
 474    --  Set to True if an ali file was produced in GNATprove mode.
 475
 476    Initialize_Scalars_Used : Boolean := False;
 477    --  Set True if an ali file contains the Initialize_Scalars flag
 478
 479    Locking_Policy_Specified : Character := ' ';
 480    --  Set to blank by Initialize_ALI. Set to the appropriate locking policy
 481    --  character if an ali file contains a P line setting the locking policy.
 482
 483    No_Normalize_Scalars_Specified : Boolean := False;
 484    --  Set to False by Initialize_ALI. Set to True if an ali file indicates
 485    --  that the file was compiled without normalize scalars.
 486
 487    No_Object_Specified : Boolean := False;
 488    --  Set to False by Initialize_ALI. Set to True if an ali file contains
 489    --  the No_Object flag.
 490
 491    Normalize_Scalars_Specified : Boolean := False;
 492    --  Set to False by Initialize_ALI. Set to True if an ali file indicates
 493    --  that the file was compiled in Normalize_Scalars mode.
 494
 495    Partition_Elaboration_Policy_Specified : Character := ' ';
 496    --  Set to blank by Initialize_ALI. Set to the appropriate partition
 497    --  elaboration policy character if an ali file contains a P line setting
 498    --  the policy.
 499
 500    Queuing_Policy_Specified : Character := ' ';
 501    --  Set to blank by Initialize_ALI. Set to the appropriate queuing policy
 502    --  character if an ali file contains a P line setting the queuing policy.
 503
 504    Cumulative_Restrictions : Restrictions_Info := No_Restrictions;
 505    --  This variable records the cumulative contributions of R lines in all
 506    --  ali files, showing whether a restriction pragma exists anywhere, and
 507    --  accumulating the aggregate knowledge of violations.
 508
 509    SSO_Default_Specified : Boolean := False;
 510    --  Set to True if at least one ALI file contains an OH/OL flag indicating
 511    --  that it was compiled with a configuration pragmas file containing the
 512    --  pragma Default_Scalar_Storage_Order (OH/OL present in ALI file P line).
 513
 514    Stack_Check_Switch_Set : Boolean := False;
 515    --  Set to True if at least one ALI file contains '-fstack-check' in its
 516    --  argument list.
 517
 518    Static_Elaboration_Model_Used : Boolean := False;
 519    --  Set to False by Initialize_ALI. Set to True if any ALI file for a
 520    --  non-internal unit compiled with the static elaboration model is
 521    --  encountered.
 522
 523    Task_Dispatching_Policy_Specified : Character := ' ';
 524    --  Set to blank by Initialize_ALI. Set to the appropriate task dispatching
 525    --  policy character if an ali file contains a P line setting the
 526    --  task dispatching policy.
 527
 528    Unreserve_All_Interrupts_Specified : Boolean := False;
 529    --  Set to False by Initialize_ALI. Set to True if an ali file is read that
 530    --  has  P line specifying unreserve all interrupts mode.
 531
 532    Zero_Cost_Exceptions_Specified : Boolean := False;
 533    --  Set to False by Initialize_ALI. Set to True if an ali file is read that
 534    --  has a P line specifying the generation of zero cost exceptions.
 535
 536    -----------------
 537    -- Withs Table --
 538    -----------------
 539
 540    --  Each With line (W line) in an ALI file generates a Withs table entry
 541
 542    --  Note: there will be no entries in this table if 'W' lines are ignored
 543
 544    No_With_Id : constant With_Id := With_Id'First;
 545    --  Special value indicating no withs table entry
 546
 547    First_With_Entry : constant With_Id := No_With_Id + 1;
 548    --  Id of first actual entry in table
 549
 550    type With_Record is record
 551
 552       Uname : Unit_Name_Type;
 553       --  Name of Unit
 554
 555       Sfile : File_Name_Type;
 556       --  Name of source file, set to No_File in generic case
 557
 558       Afile : File_Name_Type;
 559       --  Name of ALI file, set to No_File in generic case
 560
 561       Elaborate : Boolean;
 562       --  Indicates presence of E parameter
 563
 564       Elaborate_All : Boolean;
 565       --  Indicates presence of EA parameter
 566
 567       Elab_All_Desirable : Boolean;
 568       --  Indicates presence of AD parameter
 569
 570       Elab_Desirable     : Boolean;
 571       --  Indicates presence of ED parameter
 572
 573       SAL_Interface : Boolean := False;
 574       --  True if the Unit is an Interface of a Stand-Alone Library
 575
 576       Limited_With : Boolean := False;
 577       --  True if unit is named in a limited_with_clause
 578
 579       Implicit_With_From_Instantiation : Boolean := False;
 580       --  True if this is an implicit with from a generic instantiation
 581    end record;
 582
 583    package Withs is new Table.Table (
 584      Table_Component_Type => With_Record,
 585      Table_Index_Type     => With_Id,
 586      Table_Low_Bound      => First_With_Entry,
 587      Table_Initial        => 5000,
 588      Table_Increment      => 200,
 589      Table_Name           => "Withs");
 590
 591    ---------------------
 592    -- Arguments Table --
 593    ---------------------
 594
 595    --  Each Arg line (A line) in an ALI file generates an Args table entry
 596
 597    --  Note: there will be no entries in this table if 'A' lines are ignored
 598
 599    No_Arg_Id : constant Arg_Id := Arg_Id'First;
 600    --  Special value indicating no args table entry
 601
 602    First_Arg_Entry : constant Arg_Id := No_Arg_Id + 1;
 603    --  Id of first actual entry in table
 604
 605    package Args is new Table.Table (
 606      Table_Component_Type => String_Ptr,
 607      Table_Index_Type     => Arg_Id,
 608      Table_Low_Bound      => First_Arg_Entry,
 609      Table_Initial        => 1000,
 610      Table_Increment      => 100,
 611      Table_Name           => "Args");
 612
 613    --------------------------
 614    -- Linker_Options Table --
 615    --------------------------
 616
 617    --  If an ALI file has one of more Linker_Options lines, then a single
 618    --  entry is made in this table. If more than one Linker_Options lines
 619    --  appears in a given ALI file, then the arguments are concatenated
 620    --  to form the entry in this table, using a NUL character as the
 621    --  separator, and a final NUL character is appended to the end.
 622
 623    --  Note: there will be no entries in this table if 'L' lines are ignored
 624
 625    type Linker_Option_Record is record
 626       Name : Name_Id;
 627       --  Name entry containing concatenated list of Linker_Options
 628       --  arguments separated by NUL and ended by NUL as described above.
 629
 630       Unit : Unit_Id;
 631       --  Unit_Id for the entry
 632
 633       Internal_File : Boolean;
 634       --  Set True if the linker options are from an internal file. This is
 635       --  used to insert certain standard entries after all the user entries
 636       --  but before the entries from the run-time.
 637
 638       Original_Pos : Positive;
 639       --  Keep track of original position in the linker options table. This
 640       --  is used to implement a stable sort when we sort the linker options
 641       --  table.
 642    end record;
 643
 644    --  The indexes of active entries in this table range from 1 to the
 645    --  value of Linker_Options.Last. The zero'th element is for sort call.
 646
 647    package Linker_Options is new Table.Table (
 648      Table_Component_Type => Linker_Option_Record,
 649      Table_Index_Type     => Integer,
 650      Table_Low_Bound      => 0,
 651      Table_Initial        => 200,
 652      Table_Increment      => 400,
 653      Table_Name           => "Linker_Options");
 654
 655    -----------------
 656    -- Notes Table --
 657    -----------------
 658
 659    --  The notes table records entries from N lines
 660
 661    type Notes_Record is record
 662       Pragma_Type : Character;
 663       --  'A', 'C', 'I', 'S', 'T' for Annotate/Comment/Ident/Subtitle/Title
 664
 665       Pragma_Line : Nat;
 666       --  Line number of pragma
 667
 668       Pragma_Col : Nat;
 669       --  Column number of pragma
 670
 671       Pragma_Source_File : File_Name_Type;
 672       --  Source file of pragma
 673
 674       Pragma_Args : Name_Id;
 675       --  Pragma arguments. No_Name if no arguments, otherwise a single
 676       --  name table entry consisting of all the characters on the notes
 677       --  line from the first non-blank character following the source
 678       --  location to the last character on the line.
 679    end record;
 680
 681    --  The indexes of active entries in this table range from 1 to the
 682    --  value of Linker_Options.Last. The zero'th element is for convenience
 683    --  if the table needs to be sorted.
 684
 685    package Notes is new Table.Table (
 686      Table_Component_Type => Notes_Record,
 687      Table_Index_Type     => Integer,
 688      Table_Low_Bound      => 0,
 689      Table_Initial        => 200,
 690      Table_Increment      => 400,
 691      Table_Name           => "Notes");
 692
 693    -------------------------------------------
 694    -- External Version Reference Hash Table --
 695    -------------------------------------------
 696
 697    --  This hash table keeps track of external version reference strings
 698    --  as read from E lines in the ali file. The stored values do not
 699    --  include the terminating quote characters.
 700
 701    --  Note: there will be no entries in this table if 'E' lines are ignored
 702
 703    type Vindex is range 0 .. 98;
 704    --  Type to define range of headers
 705
 706    function SHash (S : String_Ptr) return Vindex;
 707    --  Hash function for this table
 708
 709    function SEq (F1, F2 : String_Ptr) return Boolean;
 710    --  Equality function for this table
 711
 712    package Version_Ref is new Simple_HTable (
 713      Header_Num => Vindex,
 714      Element    => Boolean,
 715      No_Element => False,
 716      Key        => String_Ptr,
 717      Hash       => SHash,
 718      Equal      => SEq);
 719
 720    -------------------------
 721    -- No_Dependency Table --
 722    -------------------------
 723
 724    --  Each R line for a No_Dependency Restriction generates an entry in
 725    --  this No_Dependency table.
 726
 727    type No_Dep_Record is record
 728       ALI_File : ALI_Id;
 729       --  ALI File containing the entry
 730
 731       No_Dep_Unit : Name_Id;
 732       --  Id for names table entry including entire name, including periods
 733    end record;
 734
 735    package No_Deps is new Table.Table (
 736      Table_Component_Type => No_Dep_Record,
 737      Table_Index_Type     => Integer,
 738      Table_Low_Bound      => 0,
 739      Table_Initial        => 200,
 740      Table_Increment      => 400,
 741      Table_Name           => "No_Deps");
 742
 743    ------------------------------------
 744    -- Sdep (Source Dependency) Table --
 745    ------------------------------------
 746
 747    --  Each source dependency (D line) in an ALI file generates an entry in the
 748    --  Sdep table.
 749
 750    --  Note: there will be no entries in this table if 'D' lines are ignored
 751
 752    No_Sdep_Id : constant Sdep_Id := Sdep_Id'First;
 753    --  Special value indicating no Sdep table entry
 754
 755    First_Sdep_Entry : Sdep_Id := No_Sdep_Id + 1;
 756    --  Id of first Sdep entry for current ali file. This is initialized to the
 757    --  first Sdep entry in the table, and then incremented appropriately as
 758    --  successive ALI files are scanned.
 759
 760    type Sdep_Record is record
 761
 762       Sfile : File_Name_Type;
 763       --  Name of source file
 764
 765       Stamp : Time_Stamp_Type;
 766       --  Time stamp value. Note that this will be all zero characters for the
 767       --  dummy entries for missing or non-dependent files.
 768
 769       Checksum : Word;
 770       --  Checksum value. Note that this will be all zero characters for the
 771       --  dummy entries for missing or non-dependent files
 772
 773       Dummy_Entry : Boolean;
 774       --  Set True for dummy entries that correspond to missing files or files
 775       --  where no dependency relationship exists.
 776
 777       Subunit_Name : Name_Id;
 778       --  Name_Id for subunit name if present, else No_Name
 779
 780       Unit_Name : Name_Id;
 781       --  Name_Id for the unit name if not a subunit (No_Name for a subunit)
 782       Rfile : File_Name_Type;
 783       --  Reference file name. Same as Sfile unless a Source_Reference pragma
 784       --  was used, in which case it reflects the name used in the pragma.
 785
 786       Start_Line : Nat;
 787       --  Starting line number in file. Always 1, unless a Source_Reference
 788       --  pragma was used, in which case it reflects the line number value
 789       --  given in the pragma.
 790
 791    end record;
 792
 793    package Sdep is new Table.Table (
 794      Table_Component_Type => Sdep_Record,
 795      Table_Index_Type     => Sdep_Id,
 796      Table_Low_Bound      => First_Sdep_Entry,
 797      Table_Initial        => 5000,
 798      Table_Increment      => 200,
 799      Table_Name           => "Sdep");
 800
 801    ----------------------------
 802    -- Use of Name Table Info --
 803    ----------------------------
 804
 805    --  All unit names and file names are entered into the Names table. The Info
 806    --  fields of these entries are used as follows:
 807
 808    --    Unit name           Info field has Unit_Id of unit table entry
 809    --    ALI file name       Info field has ALI_Id of ALI table entry
 810    --    Source file name    Info field has Source_Id of source table entry
 811
 812    --------------------------
 813    -- Cross-Reference Data --
 814    --------------------------
 815
 816    --  The following table records cross-reference sections, there is one entry
 817    --  for each X header line in the ALI file for an xref section.
 818
 819    --  Note: there will be no entries in this table if 'X' lines are ignored
 820
 821    type Xref_Section_Record is record
 822       File_Num : Sdep_Id;
 823       --  Dependency number for file (entry in Sdep.Table)
 824
 825       File_Name : File_Name_Type;
 826       --  Name of file
 827
 828       First_Entity : Nat;
 829       --  First entry in Xref_Entity table
 830
 831       Last_Entity : Nat;
 832       --  Last entry in Xref_Entity table
 833    end record;
 834
 835    package Xref_Section is new Table.Table (
 836      Table_Component_Type => Xref_Section_Record,
 837      Table_Index_Type     => Nat,
 838      Table_Low_Bound      => 1,
 839      Table_Initial        => 50,
 840      Table_Increment      => 300,
 841      Table_Name           => "Xref_Section");
 842
 843    --  The following is used to indicate whether a typeref field is present
 844    --  for the entity, and if so what kind of typeref field.
 845
 846    type Tref_Kind is (
 847      Tref_None,    --  No typeref present
 848      Tref_Access,  --  Access type typeref (points to designated type)
 849      Tref_Derived, --  Derived type typeref (points to parent type)
 850      Tref_Type);   --  All other cases
 851
 852    type Visibility_Kind is
 853      (Global, --  Library level entity
 854       Static, --  Static C/C++ entity
 855       Other); --  Local and other entity
 856
 857    --  The following table records entities for which xrefs are recorded
 858
 859    type Xref_Entity_Record is record
 860       Line : Pos;
 861       --  Line number of definition
 862
 863       Etype : Character;
 864       --  Set to the identification character for the entity. See section
 865       --  "Cross-Reference Entity Identifiers" in lib-xref.ads for details.
 866
 867       Col : Pos;
 868       --  Column number of definition
 869
 870       Visibility : Visibility_Kind;
 871       --  Visibility of entity
 872
 873       Entity : Name_Id;
 874       --  Name of entity
 875
 876       Iref_File_Num : Sdep_Id;
 877       --  This field is set to the dependency reference for the file containing
 878       --  the generic entity that this one instantiates, or to No_Sdep_Id if
 879       --  the current entity is not an instantiation
 880
 881       Iref_Line : Nat;
 882       --  This field is set to the line number in Iref_File_Num of the generic
 883       --  entity that this one instantiates, or to zero if the current entity
 884       --  is not an instantiation.
 885
 886       Rref_Line : Nat;
 887       --  This field is set to the line number of a renaming reference if
 888       --  one is present, or to zero if no renaming reference is present
 889
 890       Rref_Col : Nat;
 891       --  This field is set to the column number of a renaming reference
 892       --  if one is present, or to zero if no renaming reference is present.
 893
 894       Tref : Tref_Kind;
 895       --  Indicates if a typeref is present, and if so what kind. Set to
 896       --  Tref_None if no typeref field is present.
 897
 898       Tref_File_Num : Sdep_Id;
 899       --  This field is set to No_Sdep_Id if no typeref is present, or
 900       --  if the typeref refers to an entity in standard. Otherwise it
 901       --  it is the dependency reference for the file containing the
 902       --  declaration of the typeref entity.
 903
 904       Tref_Line : Nat;
 905       --  This field is set to zero if no typeref is present, or if the
 906       --  typeref refers to an entity in standard. Otherwise it contains
 907       --  the line number of the declaration of the typeref entity.
 908
 909       Tref_Type : Character;
 910       --  This field is set to blank if no typeref is present, or if the
 911       --  typeref refers to an entity in standard. Otherwise it contains
 912       --  the identification character for the typeref entity. See section
 913       --  "Cross-Reference Entity Identifiers" in lib-xref.ads for details.
 914
 915       Tref_Col : Nat;
 916       --  This field is set to zero if no typeref is present, or if the
 917       --  typeref refers to an entity in standard. Otherwise it contains
 918       --  the column number of the declaration of the parent type.
 919
 920       Tref_Standard_Entity : Name_Id;
 921       --  This field is set to No_Name if no typeref is present or if the
 922       --  typeref refers to a declared entity rather than an entity in
 923       --  package Standard. If there is a typeref that references an
 924       --  entity in package Standard, then this field is a Name_Id
 925       --  reference for the entity name.
 926
 927       Oref_File_Num : Sdep_Id;
 928       --  This field is set to No_Sdep_Id if the entity doesn't override any
 929       --  other entity, or to the dependency reference for the overridden
 930       --  entity.
 931
 932       Oref_Line : Nat;
 933       Oref_Col  : Nat;
 934       --  These two fields are set to the line and column of the overridden
 935       --  entity.
 936
 937       First_Xref : Nat;
 938       --  Index into Xref table of first cross-reference
 939
 940       Last_Xref : Nat;
 941       --  Index into Xref table of last cross-reference. The value in
 942       --  Last_Xref can be less than the First_Xref value to indicate
 943       --  that no entries are present in the Xref Table.
 944    end record;
 945
 946    package Xref_Entity is new Table.Table (
 947      Table_Component_Type => Xref_Entity_Record,
 948      Table_Index_Type     => Nat,
 949      Table_Low_Bound      => 1,
 950      Table_Initial        => 500,
 951      Table_Increment      => 300,
 952      Table_Name           => "Xref_Entity");
 953
 954    Array_Index_Reference : constant Character := '*';
 955    Interface_Reference   : constant Character := 'I';
 956    --  Some special types of references. In the ALI file itself, these
 957    --  are output as attributes of the entity, not as references, but
 958    --  there is no provision in Xref_Entity_Record for storing multiple
 959    --  such references.
 960
 961    --  The following table records actual cross-references
 962
 963    type Xref_Record is record
 964       File_Num : Sdep_Id;
 965       --  Set to the file dependency number for the cross-reference. Note
 966       --  that if no file entry is present explicitly, this is just a copy
 967       --  of the reference for the current cross-reference section.
 968
 969       Line : Nat;
 970       --  Line number for the reference. This is zero when referencing a
 971       --  predefined entity, but in this case Name is set.
 972
 973       Rtype : Character;
 974       --  Indicates type of reference, using code used in ALI file:
 975       --    r = reference
 976       --    m = modification
 977       --    b = body entity
 978       --    c = completion of private or incomplete type
 979       --    x = type extension
 980       --    i = implicit reference
 981       --    Array_Index_Reference = reference to the index of an array
 982       --    Interface_Reference   = reference to an interface implemented
 983       --                            by the type
 984       --  See description in lib-xref.ads for further details
 985
 986       Col : Nat;
 987       --  Column number for the reference
 988
 989       Name : Name_Id := No_Name;
 990       --  This is only used when referencing a predefined entity. Currently,
 991       --  this only occurs for array indexes.
 992
 993       --  Note: for instantiation references, Rtype is set to ' ', and Col is
 994       --  set to zero. One or more such entries can follow any other reference.
 995       --  When there is more than one such entry, this is to be read as:
 996       --     e.g. ref1  ref2  ref3
 997       --     ref1 is a reference to an entity that was instantied at ref2.
 998       --     ref2 itself is also the result of an instantiation, that took
 999       --     place at ref3
1000
1001       Imported_Lang : Name_Id := No_Name;
1002       Imported_Name : Name_Id := No_Name;
1003       --  Language and name of imported entity reference
1004    end record;
1005
1006    package Xref is new Table.Table (
1007      Table_Component_Type => Xref_Record,
1008      Table_Index_Type     => Nat,
1009      Table_Low_Bound      => 1,
1010      Table_Initial        => 2000,
1011      Table_Increment      => 300,
1012      Table_Name           => "Xref");
1013
1014    --------------------------------------
1015    -- Subprograms for Reading ALI File --
1016    --------------------------------------
1017
1018    procedure Initialize_ALI;
1019    --  Initialize the ALI tables. Also resets all switch values to defaults
1020
1021    function Scan_ALI
1022      (F                : File_Name_Type;
1023       T                : Text_Buffer_Ptr;
1024       Ignore_ED        : Boolean;
1025       Err              : Boolean;
1026       Read_Xref        : Boolean := False;
1027       Read_Lines       : String  := "";
1028       Ignore_Lines     : String  := "X";
1029       Ignore_Errors    : Boolean := False;
1030       Directly_Scanned : Boolean := False) return ALI_Id;
1031    --  Given the text, T, of an ALI file, F, scan and store the information
1032    --  from the file, and return the Id of the resulting entry in the ALI
1033    --  table. Switch settings may be modified as described above in the
1034    --  switch description settings.
1035    --
1036    --    Ignore_ED is normally False. If set to True, it indicates that
1037    --    all AD/ED (elaboration desirable) indications in the ALI file are
1038    --    to be ignored. This parameter is obsolete now that the -f switch
1039    --    is removed from gnatbind, and should be removed ???
1040    --
1041    --    Err determines the action taken on an incorrectly formatted file.
1042    --    If Err is False, then an error message is output, and the program
1043    --    is terminated. If Err is True, then no error message is output,
1044    --    and No_ALI_Id is returned.
1045    --
1046    --    Ignore_Lines requests that Scan_ALI ignore any lines that start
1047    --    with any given key character. The default value of X causes all
1048    --    Xref lines to be ignored. The corresponding data in the ALI
1049    --    tables will not be filled in this case. It is not possible
1050    --    to ignore U (unit) lines, they are always read.
1051    --
1052    --    Read_Lines requests that Scan_ALI process only lines that start
1053    --    with one of the given characters. The corresponding data in the
1054    --    ALI file for any characters not given in the list will not be
1055    --    set. The default value of the null string indicates that all
1056    --    lines should be read (unless Ignore_Lines is specified). U
1057    --    (unit) lines are always read regardless of the value of this
1058    --    parameter.
1059    --
1060    --    Note: either Ignore_Lines or Read_Lines should be non-null, but not
1061    --    both. If both are provided then only the Read_Lines value is used,
1062    --    and the Ignore_Lines parameter is ignored.
1063    --
1064    --    Read_XREF is set True to read and acquire the cross-reference
1065    --    information. If Read_XREF is set to True, then the effect is to ignore
1066    --    all lines other than U, W, D and X lines and the Ignore_Lines and
1067    --    Read_Lines parameters are ignored (i.e. the use of True for Read_XREF
1068    --    is equivalent to specifying an argument of "UWDX" for Read_Lines.
1069    --
1070    --    Ignore_Errors is normally False. If it is set True, then Scan_ALI
1071    --    will do its best to scan through a file and extract all information
1072    --    it can, even if there are errors. In this case Err is only set if
1073    --    Scan_ALI was completely unable to process the file (e.g. it did not
1074    --    look like an ALI file at all). Ignore_Errors is intended to improve
1075    --    the downward compatibility of new compilers with old tools.
1076    --
1077    --    Directly_Scanned is normally False. If it is set to True, then the
1078    --    units (spec and/or body) corresponding to the ALI file are marked as
1079    --    such. It is used to decide for what units gnatbind should generate
1080    --    the symbols corresponding to 'Version or 'Body_Version in
1081    --    Stand-Alone Libraries.
1082
1083 end ALI;