gcc/ada/s-memory.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                         S Y S T E M . M E M O R Y                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.2 $
  10 --                                                                          --
  11 --             Copyright (C) 2001 Free Software Foundation, Inc.            --
  12 --                                                                          --
  13 -- This specification is derived from the Ada Reference Manual for use with --
  14 -- GNAT. The copyright notice above, and the license provisions that follow --
  15 -- apply solely to the  contents of the part following the private keyword. --
  16 --                                                                          --
  17 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  18 -- terms of the  GNU General Public License as published  by the Free Soft- --
  19 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  20 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  21 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  22 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  23 -- for  more details.  You should have  received  a copy of the GNU General --
  24 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  25 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  26 -- MA 02111-1307, USA.                                                      --
  27 --                                                                          --
  28 -- As a special exception,  if other files  instantiate  generics from this --
  29 -- unit, or you link  this unit with other files  to produce an executable, --
  30 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  31 -- covered  by the  GNU  General  Public  License.  This exception does not --
  32 -- however invalidate  any other reasons why  the executable file  might be --
  33 -- covered by the  GNU Public License.                                      --
  34 --                                                                          --
  35 -- GNAT was originally developed  by the GNAT team at  New York University. --
  36 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  37 --                                                                          --
  38 ------------------------------------------------------------------------------
  39
  40 --  This is the default implementation of this package.
  41
  42 --  This implementation assumes that the underlying malloc/free/realloc
  43 --  implementation is thread safe, and thus, no additional lock is required.
  44 --  Note that we still need to defer abortion because on most systems,
  45 --  an asynchronous signal (as used for implementing asynchronous abortion
  46 --  of task) cannot safely be handled while malloc is executing.
  47
  48 --  If you are not using Ada constructs containing the "abort" keyword,
  49 --  then you can remove the calls to Abort_Defer.all and Abort_Undefer.all
  50 --  from this unit.
  51
  52 with Ada.Exceptions;
  53 with System.Soft_Links;
  54
  55 package body System.Memory is
  56
  57    use Ada.Exceptions;
  58    use System.Soft_Links;
  59
  60    function c_malloc (Size : size_t) return System.Address;
  61    pragma Import (C, c_malloc, "malloc");
  62
  63    procedure c_free (Ptr : System.Address);
  64    pragma Import (C, c_free, "free");
  65
  66    function c_realloc
  67      (Ptr : System.Address; Size : size_t) return System.Address;
  68    pragma Import (C, c_realloc, "realloc");
  69
  70    -----------
  71    -- Alloc --
  72    -----------
  73
  74    function Alloc (Size : size_t) return System.Address is
  75       Result      : System.Address;
  76       Actual_Size : size_t := Size;
  77
  78    begin
  79       if Size = size_t'Last then
  80          Raise_Exception (Storage_Error'Identity, "object too large");
  81       end if;
  82
  83       --  Change size from zero to non-zero. We still want a proper pointer
  84       --  for the zero case because pointers to zero length objects have to
  85       --  be distinct, but we can't just go ahead and allocate zero bytes,
  86       --  since some malloc's return zero for a zero argument.
  87
  88       if Size = 0 then
  89          Actual_Size := 1;
  90       end if;
  91
  92       Abort_Defer.all;
  93       Result := c_malloc (Actual_Size);
  94       Abort_Undefer.all;
  95
  96       if Result = System.Null_Address then
  97          Raise_Exception (Storage_Error'Identity, "heap exhausted");
  98       end if;
  99
 100       return Result;
 101    end Alloc;
 102
 103    ----------
 104    -- Free --
 105    ----------
 106
 107    procedure Free (Ptr : System.Address) is
 108    begin
 109       Abort_Defer.all;
 110       c_free (Ptr);
 111       Abort_Undefer.all;
 112    end Free;
 113
 114    -------------
 115    -- Realloc --
 116    -------------
 117
 118    function Realloc
 119      (Ptr  : System.Address;
 120       Size : size_t)
 121       return System.Address
 122    is
 123       Result      : System.Address;
 124       Actual_Size : size_t := Size;
 125
 126    begin
 127       if Size = size_t'Last then
 128          Raise_Exception (Storage_Error'Identity, "object too large");
 129       end if;
 130
 131       Abort_Defer.all;
 132       Result := c_realloc (Ptr, Actual_Size);
 133       Abort_Undefer.all;
 134
 135       if Result = System.Null_Address then
 136          Raise_Exception (Storage_Error'Identity, "heap exhausted");
 137       end if;
 138
 139       return Result;
 140    end Realloc;
 141
 142 end System.Memory;