libgfortran/m4/specific.m4

   1 include(head.m4)
   2 define(atype_code,regexp(file,`_\([ircl][0-9]+\).[fF]90',`\1'))dnl
   3 define(atype_letter,substr(atype_code, 0, 1))dnl
   4 define(atype_kind,substr(atype_code, 1))dnl
   5 define(get_typename2, `$1 (kind=$2)')dnl
   6 define(get_typename, `get_typename2(ifelse($1,i,integer,ifelse($1,r,real,ifelse($1,l,logical,ifelse($1,c,complex,unknown)))),`$2')')dnl
   7 define(atype_name, get_typename(atype_letter,atype_kind))dnl
   8 define(name, regexp(regexp(file, `[^/]*$', `\&'), `^_\([^_]*\)_', `\1'))dnl
   9 define(function_name,`specific__'name`_'atype_code)dnl
  10
  11 define(type,ifelse(atype_letter,l,LOGICAL,ifelse(atype_letter,i,INTEGER,ifelse(atype_letter,r,REAL,ifelse(atype_letter,c,COMPLEX,UNKNOW)))))dnl
  12 define(Q,ifelse(atype_kind,4,F,ifelse(atype_kind,8,`',ifelse(atype_kind,10,L,ifelse(atype_kind,16,L,`_'atype_kind)))))dnl
  13
  14 dnl A few specifics require a function other than their name, or
  15 dnl nothing. The list is currently:
  16 dnl    - integer and logical specifics require no libm function
  17 dnl    - AINT requires the trunc() family functions
  18 dnl    - ANINT requires round()
  19 dnl    - CONJG, DIM, SIGN require no libm function
  20 define(needed,ifelse(atype_letter,i,`none',ifelse(atype_letter,l,`none',ifelse(name,aint,trunc,ifelse(name,anint,round,ifelse(name,conjg,none,ifelse(name,dim,none,ifelse(name,sign,none,ifelse(name,abs,fabs,name)))))))))dnl
  21 define(prefix,ifelse(atype_letter,c,C,`'))dnl
  22
  23 dnl Special case for fabs, for which the corresponding complex function
  24 dnl is not cfabs but cabs.
  25 define(NEEDED,translit(ifelse(prefix`'needed,`Cfabs',`abs',needed),`a-z',`A-Z'))dnl
  26
  27 #include "config.h"
  28 #include "kinds.inc"
  29 #include "c99_protos.inc"
  30
  31 `#if defined (HAVE_GFC_'type`_'atype_kind`)'
  32 ifelse(NEEDED,NONE,`',`#ifdef HAVE_'prefix`'NEEDED`'Q)
  33
  34 elemental function function_name (parm)
  35    atype_name, intent (in) :: parm
  36    atype_name :: function_name
  37
  38    function_name = name (parm)
  39 end function
  40
  41 ifelse(NEEDED,NONE,`',`#endif')
  42 #endif