libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_INIT(package-unused, version-unused,, libstdc++)
   4 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  Only used at the end of this file.
  11 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 # Find the rest of the source tree framework.
  14 AM_ENABLE_MULTILIB(, ..)
  15
  16 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  17 #
  18 # You will slowly go insane if you do not grok the following fact:  when
  19 # building v3 as part of the compiler, the top-level /target/ becomes the
  20 # library's /host/.  configure then causes --target to default to --host,
  21 # exactly like any other package using autoconf.  Therefore, 'target' and
  22 # 'host' will always be the same.  This makes sense both for native and
  23 # cross compilers, just think about it for a little while.  :-)
  24 #
  25 # Also, if v3 is being configured as part of a cross compiler, the top-level
  26 # configure script will pass the "real" host as $with_cross_host.
  27 #
  28 # Do not delete or change the following two lines.  For why, see
  29 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  30 AC_CANONICAL_SYSTEM
  31 target_alias=${target_alias-$host_alias}
  32
  33 # Handy for debugging:
  34 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  35
  36 if test "$build" != "$host"; then
  37   # We are being configured with some form of cross compiler.
  38   GLIBCXX_IS_NATIVE=false
  39   case "$host","$target" in
  40     # Darwin crosses can use the host system's libraries and headers,
  41     # because of the fat library support.  Of course, it must be the
  42     # same version of Darwin on both sides.  Allow the user to
  43     # just say --target=foo-darwin without a version number to mean
  44     # "the version on this system".
  45       *-*-darwin*,*-*-darwin*)
  46         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  47         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  48         if test $hostos = $targetos -o $targetos = darwin ; then
  49           GLIBCXX_IS_NATIVE=true
  50         fi
  51         ;;
  52
  53       *)
  54         GCC_NO_EXECUTABLES
  55         ;;
  56   esac
  57 else
  58   GLIBCXX_IS_NATIVE=true
  59 fi
  60
  61 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  62 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  63 #  1.x:  minimum required version
  64 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  65 #              of other PACKAGE_* variables will, however, and there's nothing
  66 #              we can do about that; they come from AC_INIT).
  67 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  68 #            file in the top srcdir, etc, etc), so stop complaining.
  69 #  no-dependencies:  turns off auto dependency generation (just for now)
  70 #  no-dist:  we don't want 'dist' and related rules.
  71 #  -Wall:  turns on all automake warnings...
  72 #  -Wno-portability:  ...except this one, since GNU make is now required.
  73 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  74 AH_TEMPLATE(PACKAGE, [Name of package])
  75 AH_TEMPLATE(VERSION, [Version number of package])
  76
  77 # -fno-builtin must be present here so that a non-conflicting form of
  78 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  79
  80 save_CXXFLAGS="$CXXFLAGS"
  81 CXXFLAGS="$CXXFLAGS -fno-builtin"
  82 AC_PROG_CC
  83 AC_PROG_CXX
  84 CXXFLAGS="$save_CXXFLAGS"
  85
  86 AC_SYS_LARGEFILE
  87
  88 # Runs configure.host, and assorted other critical bits.  Sets
  89 # up critical shell variables.
  90 GLIBCXX_CONFIGURE
  91
  92 # Libtool setup.
  93 if test "x${with_newlib}" != "xyes" &&
  94     test "x${with_avrlibc}" != "xyes" &&
  95     test "x$with_headers" != "xno"; then
  96   AC_LIBTOOL_DLOPEN
  97 fi
  98 AM_PROG_LIBTOOL
  99 ACX_LT_HOST_FLAGS
 100 AC_SUBST(enable_shared)
 101 AC_SUBST(enable_static)
 102
 103 if test "$enable_vtable_verify" = yes; then
 104   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 105   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 106 fi
 107
 108
 109 # libtool variables for C++ shared and position-independent compiles.
 110 #
 111 # Use glibcxx_lt_pic_flag to designate the automake variable
 112 # used to encapsulate the default libtool approach to creating objects
 113 # with position-independent code. Default: -prefer-pic.
 114 #
 115 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 116 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 117 #
 118 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 119 # creating position-independent objects. This varies with the target
 120 # hardware and operating system, but is often: -DPIC -fPIC.
 121 if test "$enable_shared" = yes; then
 122   glibcxx_lt_pic_flag="-prefer-pic"
 123   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 124   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 125
 126 else
 127   glibcxx_lt_pic_flag=
 128   glibcxx_compiler_pic_flag=
 129   glibcxx_compiler_shared_flag=
 130 fi
 131 AC_SUBST(glibcxx_lt_pic_flag)
 132 AC_SUBST(glibcxx_compiler_pic_flag)
 133 AC_SUBST(glibcxx_compiler_shared_flag)
 134
 135 # Override the libtool's pic_flag and pic_mode.
 136 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 137 # NB: this impacts --with-pic and --without-pic.
 138 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 139 pic_mode='default'
 140
 141 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 142 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 143
 144 # Possibly disable most of the library.
 145 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 146 ## than just ignoring the results.  Faster /and/ more correct, win win.
 147 GLIBCXX_ENABLE_HOSTED
 148
 149 # Enable descriptive messages to standard output on termination.
 150 GLIBCXX_ENABLE_VERBOSE
 151
 152 # Enable compiler support that doesn't require linking.
 153 GLIBCXX_ENABLE_PCH($is_hosted)
 154 GLIBCXX_ENABLE_THREADS
 155 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 156 GLIBCXX_ENABLE_LOCK_POLICY
 157 GLIBCXX_ENABLE_DECIMAL_FLOAT
 158 GLIBCXX_ENABLE_FLOAT128
 159 if test "$enable_float128" = yes; then
 160   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 161 fi
 162
 163 # Checks for compiler support that doesn't require linking.
 164 GLIBCXX_CHECK_COMPILER_FEATURES
 165
 166 # Enable all the variable C++ runtime options that don't require linking.
 167 GLIBCXX_ENABLE_CSTDIO
 168 GLIBCXX_ENABLE_CLOCALE
 169 GLIBCXX_ENABLE_ALLOCATOR
 170 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 171 GLIBCXX_ENABLE_LONG_LONG([yes])
 172 GLIBCXX_ENABLE_WCHAR_T([yes])
 173 GLIBCXX_ENABLE_C99([yes])
 174 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 175 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0 -D_GLIBCXX_ASSERTIONS"])
 176 GLIBCXX_ENABLE_DEBUG([no])
 177 GLIBCXX_ENABLE_PARALLEL([yes])
 178 GLIBCXX_ENABLE_CXX_FLAGS
 179 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 180 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 181 GLIBCXX_ENABLE_PYTHON
 182 GLIBCXX_ENABLE_WERROR([no])
 183 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 184
 185 # Checks for operating systems support that doesn't require linking.
 186 GLIBCXX_CHECK_STDIO_PROTO
 187 GLIBCXX_CHECK_MATH11_PROTO
 188 GLIBCXX_CHECK_UCHAR_H
 189
 190 # For LFS support.
 191 GLIBCXX_CHECK_LFS
 192
 193 # For showmanyc_helper().
 194 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 195 GLIBCXX_CHECK_POLL
 196 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 197
 198 # For xsputn_2().
 199 AC_CHECK_HEADERS(sys/uio.h)
 200 GLIBCXX_CHECK_WRITEV
 201
 202 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 203 # so that the check is done with the C compiler (not C++).
 204 # Checking with C++ can break a canadian cross build if either
 205 # file does not exist in C but does in C++.
 206 AC_CHECK_HEADERS(fenv.h complex.h)
 207
 208 # For C99 support to TR1.
 209 GLIBCXX_CHECK_C99_TR1
 210
 211 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 212 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 213
 214 # For gettimeofday support.
 215 GLIBCXX_CHECK_GETTIMEOFDAY
 216
 217 # For clock_gettime, nanosleep and sched_yield support.
 218 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 219
 220 # Check for tmpnam which is obsolescent in POSIX.1-2008
 221 GLIBCXX_CHECK_TMPNAM
 222
 223 # For pthread_cond_clockwait
 224 GLIBCXX_CHECK_PTHREAD_COND_CLOCKWAIT
 225
 226 # For pthread_mutex_clocklock
 227 GLIBCXX_CHECK_PTHREAD_MUTEX_CLOCKLOCK
 228
 229 # For pthread_rwlock_clockrdlock and pthread_rwlock_clockwrlock
 230 GLIBCXX_CHECK_PTHREAD_RWLOCK_CLOCKLOCK
 231
 232 AC_LC_MESSAGES
 233
 234 # For hardware_concurrency
 235 AC_CHECK_HEADERS(sys/sysinfo.h)
 236 GLIBCXX_CHECK_GET_NPROCS
 237 AC_CHECK_HEADERS(unistd.h)
 238 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 239 GLIBCXX_CHECK_SC_NPROC_ONLN
 240 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 241 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 242 GLIBCXX_CHECK_SDT_H
 243
 244 # Check for available headers.
 245 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 246 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 247 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 248 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 249 wchar.h wctype.h linux/types.h])
 250
 251 AC_CHECK_HEADERS([linux/random.h], [], [],
 252 [[#ifdef HAVE_LINUX_TYPES_H
 253 # include <linux/types.h>
 254 #endif
 255 ]])
 256
 257 AC_CHECK_HEADERS([xlocale.h])
 258
 259 # Only do link tests if native. Else, hardcode.
 260 if $GLIBCXX_IS_NATIVE; then
 261
 262   # We can do more elaborate tests that assume a working linker.
 263   CANADIAN=no
 264
 265   GLIBCXX_CHECK_LINKER_FEATURES
 266   GLIBCXX_CHECK_MATH_SUPPORT
 267   GLIBCXX_CHECK_STDLIB_SUPPORT
 268
 269   # For /dev/random and /dev/urandom for std::random_device.
 270   GLIBCXX_CHECK_DEV_RANDOM
 271
 272   # For TLS support.
 273   GCC_CHECK_TLS
 274
 275   AC_CHECK_FUNCS(__cxa_thread_atexit_impl __cxa_thread_atexit)
 276   AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 277   AC_CHECK_FUNCS(_wfopen)
 278   AC_CHECK_FUNCS(secure_getenv)
 279
 280   # C11 functions for C++17 library
 281   AC_CHECK_FUNCS(timespec_get)
 282
 283   # For Networking TS.
 284   AC_CHECK_FUNCS(sockatmark)
 285
 286   # Non-standard functions used by C++17 std::from_chars
 287   AC_CHECK_FUNCS(uselocale)
 288
 289   # For iconv support.
 290   AM_ICONV
 291
 292 else
 293
 294   # This lets us hard-code the functionality we know we'll have in the cross
 295   # target environment.  "Let" is a sugar-coated word placed on an especially
 296   # dull and tedious hack, actually.
 297   #
 298   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 299   # that involve linking, can't be used:
 300   #    "cannot open sim-crt0.o"
 301   #    "cannot open crt0.o"
 302   # etc.  All this is because there currently exists no unified, consistent
 303   # way for top level CC information to be passed down to target directories:
 304   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 305   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 306   # crosses can be removed.
 307
 308   # If Canadian cross, then don't pick up tools from the build directory.
 309   # Used only in GLIBCXX_EXPORT_INCLUDES.
 310   if test -n "$with_cross_host" &&
 311      test x"$build_alias" != x"$with_cross_host" &&
 312      test x"$build" != x"$target";
 313   then
 314     CANADIAN=yes
 315   else
 316     CANADIAN=no
 317   fi
 318
 319   # Construct crosses by hand, eliminating bits that need ld...
 320   # GLIBCXX_CHECK_MATH_SUPPORT
 321
 322   # First, test for "known" system libraries.  We may be using newlib even
 323   # on a hosted environment.
 324   if test "x${with_newlib}" = "xyes"; then
 325     os_include_dir="os/newlib"
 326     AC_DEFINE(HAVE_HYPOT)
 327
 328     # GLIBCXX_CHECK_STDLIB_SUPPORT
 329     AC_DEFINE(HAVE_STRTOF)
 330
 331     AC_DEFINE(HAVE_ACOSF)
 332     AC_DEFINE(HAVE_ASINF)
 333     AC_DEFINE(HAVE_ATAN2F)
 334     AC_DEFINE(HAVE_ATANF)
 335     AC_DEFINE(HAVE_CEILF)
 336     AC_DEFINE(HAVE_COSF)
 337     AC_DEFINE(HAVE_COSHF)
 338     AC_DEFINE(HAVE_EXPF)
 339     AC_DEFINE(HAVE_FABSF)
 340     AC_DEFINE(HAVE_FLOORF)
 341     AC_DEFINE(HAVE_FMODF)
 342     AC_DEFINE(HAVE_FREXPF)
 343     AC_DEFINE(HAVE_LDEXPF)
 344     AC_DEFINE(HAVE_LOG10F)
 345     AC_DEFINE(HAVE_LOGF)
 346     AC_DEFINE(HAVE_MODFF)
 347     AC_DEFINE(HAVE_POWF)
 348     AC_DEFINE(HAVE_SINF)
 349     AC_DEFINE(HAVE_SINHF)
 350     AC_DEFINE(HAVE_SQRTF)
 351     AC_DEFINE(HAVE_TANF)
 352     AC_DEFINE(HAVE_TANHF)
 353
 354     AC_DEFINE(HAVE_ICONV)
 355     AC_DEFINE(HAVE_MEMALIGN)
 356
 357     case "${target}" in
 358       *-rtems*)
 359         case "${target}" in
 360           bfin* | lm32* | mips* | moxie* | or1k* | v850*)
 361             ;;
 362           *)
 363             AC_DEFINE(HAVE_TLS)
 364             ;;
 365         esac
 366         AC_DEFINE(HAVE_ALIGNED_ALLOC)
 367         AC_DEFINE(HAVE_AT_QUICK_EXIT)
 368         AC_DEFINE(HAVE_LINK)
 369         AC_DEFINE(HAVE_QUICK_EXIT)
 370         AC_DEFINE(HAVE_READLINK)
 371         AC_DEFINE(HAVE_SETENV)
 372         AC_DEFINE(HAVE_SLEEP)
 373         AC_DEFINE(HAVE_SOCKATMARK)
 374         AC_DEFINE(HAVE_STRERROR_L)
 375         AC_DEFINE(HAVE_SYMLINK)
 376         AC_DEFINE(HAVE_TRUNCATE)
 377         AC_DEFINE(HAVE_USLEEP)
 378         ;;
 379     esac
 380   elif test "x$with_headers" != "xno"; then
 381     GLIBCXX_CROSSCONFIG
 382   fi
 383
 384   # At some point, we should differentiate between architectures
 385   # like x86, which have long double versions, and alpha/powerpc/etc.,
 386   # which don't. For the time being, punt.
 387   if test x"long_double_math_on_this_cpu" = x"yes"; then
 388     AC_DEFINE(HAVE_ACOSL)
 389     AC_DEFINE(HAVE_ASINL)
 390     AC_DEFINE(HAVE_ATAN2L)
 391     AC_DEFINE(HAVE_ATANL)
 392     AC_DEFINE(HAVE_CEILL)
 393     AC_DEFINE(HAVE_COSL)
 394     AC_DEFINE(HAVE_COSHL)
 395     AC_DEFINE(HAVE_EXPL)
 396     AC_DEFINE(HAVE_FABSL)
 397     AC_DEFINE(HAVE_FLOORL)
 398     AC_DEFINE(HAVE_FMODL)
 399     AC_DEFINE(HAVE_FREXPL)
 400     AC_DEFINE(HAVE_LDEXPL)
 401     AC_DEFINE(HAVE_LOG10L)
 402     AC_DEFINE(HAVE_LOGL)
 403     AC_DEFINE(HAVE_MODFL)
 404     AC_DEFINE(HAVE_POWL)
 405     AC_DEFINE(HAVE_SINCOSL)
 406     AC_DEFINE(HAVE_SINL)
 407     AC_DEFINE(HAVE_SINHL)
 408     AC_DEFINE(HAVE_SQRTL)
 409     AC_DEFINE(HAVE_TANL)
 410     AC_DEFINE(HAVE_TANHL)
 411   fi
 412 fi
 413
 414 # Check for _Unwind_GetIPInfo.
 415 GCC_CHECK_UNWIND_GETIPINFO
 416
 417 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 418
 419 if test "$is_hosted" = yes; then
 420 # TODO: remove this and change src/c++11/compatibility-atomic-c++0x.cc to
 421 # use <stdint.h> instead of <gstdint.h>.
 422 GCC_HEADER_STDINT(include/gstdint.h)
 423 fi
 424
 425 GLIBCXX_ENABLE_SYMVERS([yes])
 426 AC_SUBST(libtool_VERSION)
 427
 428 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 429
 430 GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
 431 GLIBCXX_DEFAULT_ABI
 432
 433 ac_ldbl_compat=no
 434 ac_ldbl_alt128_compat=no
 435 ac_ldbl_ieee128_default=no
 436 LONG_DOUBLE_COMPAT_FLAGS="-mlong-double-64"
 437 LONG_DOUBLE_128_FLAGS=
 438 LONG_DOUBLE_ALT128_COMPAT_FLAGS=
 439 case "$target" in
 440   powerpc*-*-linux* | \
 441   sparc*-*-linux* | \
 442   s390*-*-linux* | \
 443   alpha*-*-linux*)
 444   AC_TRY_COMPILE(, [
 445 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 446 #error no need for long double compatibility
 447 #endif
 448   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 449   if test "$ac_ldbl_compat" = yes; then
 450     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 451               [Define if compatibility should be provided for -mlong-double-64.])
 452     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 453     case "$target" in
 454       powerpc*-*-linux*)
 455         LONG_DOUBLE_COMPAT_FLAGS="$LONG_DOUBLE_COMPAT_FLAGS -mno-gnu-attribute"
 456         # Check for IEEE128 support in libm:
 457         AC_CHECK_LIB(m, __frexpieee128,
 458                      [ac_ldbl_ieee128_in_libc=yes],
 459                      [ac_ldbl_ieee128_in_libc=no])
 460         if test $ac_ldbl_ieee128_in_libc = yes; then
 461           # Determine which long double format is the compiler's default:
 462           AC_TRY_COMPILE(, [
 463             #ifndef __LONG_DOUBLE_IEEE128__
 464             #error compiler defaults to ibm128
 465             #endif
 466           ], [ac_ldbl_ieee128_default=yes], [ac_ldbl_ieee128_default=no])
 467           # Library objects should use default long double format.
 468           if test "$ac_ldbl_ieee128_default" = yes; then
 469             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 470             # Except for the ones that explicitly use these flags:
 471             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ibmlongdouble -mno-gnu-attribute -Wno-psabi"
 472           else
 473             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 474             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ieeelongdouble -mno-gnu-attribute -Wno-psabi"
 475           fi
 476           AC_DEFINE([_GLIBCXX_LONG_DOUBLE_ALT128_COMPAT],1,
 477                 [Define if compatibility should be provided for alternative 128-bit long double formats.])
 478           port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/os/gnu-linux/ldbl-ieee128-extra.ver"
 479           ac_ldbl_alt128_compat=yes
 480         else
 481           ac_ldbl_alt128_compat=no
 482         fi
 483         ;;
 484     esac
 485   fi
 486 esac
 487 AC_SUBST(LONG_DOUBLE_COMPAT_FLAGS)
 488 AC_SUBST(LONG_DOUBLE_128_FLAGS)
 489 AC_SUBST(LONG_DOUBLE_ALT128_COMPAT_FLAGS)
 490 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 491 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_ALT128_COMPAT, test $ac_ldbl_alt128_compat = yes)
 492
 493 # Check if assembler supports disabling hardware capability support.
 494 GCC_CHECK_ASSEMBLER_HWCAP
 495
 496 # Check if assembler supports rdrand opcode.
 497 GLIBCXX_CHECK_X86_RDRAND
 498 # Check if assembler supports rdseed opcode.
 499 GLIBCXX_CHECK_X86_RDSEED
 500
 501 # Check for other random number APIs
 502 GLIBCXX_CHECK_GETENTROPY
 503 GLIBCXX_CHECK_ARC4RANDOM
 504
 505 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 506 GLIBCXX_CONFIGURE_TESTSUITE
 507
 508 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 509 GLIBCXX_CHECK_GTHREADS
 510
 511 # For Filesystem TS.
 512 AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
 513 GLIBCXX_ENABLE_FILESYSTEM_TS
 514 GLIBCXX_CHECK_FILESYSTEM_DEPS
 515
 516 GLIBCXX_ENABLE_BACKTRACE
 517
 518 # For Networking TS.
 519 AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/socket.h sys/uio.h poll.h netdb.h arpa/inet.h netinet/in.h netinet/tcp.h])
 520 AC_CHECK_DECL(F_GETFL,,,[#include <fcntl.h>])
 521 AC_CHECK_DECL(F_SETFL,,,[#include <fcntl.h>])
 522 if test "$ac_cv_have_decl_F_GETFL$ac_cv_have_decl_F_SETFL" = yesyes ; then
 523   AC_CHECK_DECL(O_NONBLOCK,,,[#include <fcntl.h>])
 524 fi
 525
 526 # For Transactional Memory TS
 527 GLIBCXX_CHECK_SIZE_T_MANGLING
 528
 529 # Check which release added std::exception_ptr for the target
 530 GLIBCXX_CHECK_EXCEPTION_PTR_SYMVER
 531
 532 # Define documentation rules conditionally.
 533
 534 # See if makeinfo has been installed and is modern enough
 535 # that we can use it.
 536 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 537                    [GNU texinfo.* \([0-9][0-9.]*\)],
 538                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 539 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 540
 541 # Check for doxygen
 542 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 543 AC_CHECK_PROG([DOT], dot, yes, no)
 544
 545 # Check for docbook
 546 AC_CHECK_PROG([XMLCATALOG], xmlcatalog, yes, no)
 547 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 548 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 549 GLIBCXX_CONFIGURE_DOCBOOK
 550
 551 # Check for xml/html dependencies.
 552 AM_CONDITIONAL(BUILD_XML,
 553                test $ac_cv_prog_DOXYGEN = "yes" &&
 554                test $ac_cv_prog_DOT = "yes" &&
 555                test $ac_cv_prog_XSLTPROC = "yes" &&
 556                test $ac_cv_prog_XMLLINT = "yes" &&
 557                test $glibcxx_stylesheets = "yes")
 558
 559 AM_CONDITIONAL(BUILD_HTML,
 560                test $ac_cv_prog_DOXYGEN = "yes" &&
 561                test $ac_cv_prog_DOT = "yes" &&
 562                test $ac_cv_prog_XSLTPROC = "yes" &&
 563                test $ac_cv_prog_XMLLINT = "yes" &&
 564                test $glibcxx_stylesheets = "yes")
 565
 566 # Check for man dependencies.
 567 AM_CONDITIONAL(BUILD_MAN,
 568                test $ac_cv_prog_DOXYGEN = "yes" &&
 569                test $ac_cv_prog_DOT = "yes")
 570
 571 # Check for pdf dependencies.
 572 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 573 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 574 AM_CONDITIONAL(BUILD_PDF,
 575                test $ac_cv_prog_DOXYGEN = "yes" &&
 576                test $ac_cv_prog_DOT = "yes" &&
 577                test $ac_cv_prog_XSLTPROC = "yes" &&
 578                test $ac_cv_prog_XMLLINT = "yes" &&
 579                test $ac_cv_prog_DBLATEX = "yes" &&
 580                test $ac_cv_prog_PDFLATEX = "yes")
 581
 582 case "$build" in
 583  *-*-darwin* ) glibcxx_include_dir_notparallel=yes ;;
 584  * ) glibcxx_include_dir_notparallel=no ;;
 585 esac
 586 AM_CONDITIONAL(INCLUDE_DIR_NOTPARALLEL,
 587                test $glibcxx_include_dir_notparallel = "yes")
 588
 589 # Propagate the target-specific source directories through the build chain.
 590 ATOMICITY_SRCDIR=config/${atomicity_dir}
 591 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 592 ATOMIC_FLAGS=${atomic_flags}
 593 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 594 OS_INC_SRCDIR=config/${os_include_dir}
 595 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 596 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 597 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 598 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 599 AC_SUBST(ATOMICITY_SRCDIR)
 600 AC_SUBST(ATOMIC_WORD_SRCDIR)
 601 AC_SUBST(ATOMIC_FLAGS)
 602 AC_SUBST(CPU_DEFINES_SRCDIR)
 603 AC_SUBST(ABI_TWEAKS_SRCDIR)
 604 AC_SUBST(OS_INC_SRCDIR)
 605 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 606 AC_SUBST(CPU_OPT_EXT_RANDOM)
 607 AC_SUBST(CPU_OPT_BITS_RANDOM)
 608
 609 # Conditionalize the makefile for this target machine.
 610 tmake_file_=
 611 for f in ${tmake_file}
 612 do
 613         if test -f ${srcdir}/config/$f
 614         then
 615                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 616         fi
 617 done
 618 tmake_file="${tmake_file_}"
 619 AC_SUBST(tmake_file)
 620
 621 # Add CET specific flags if Intel CET is enabled.
 622 GCC_CET_FLAGS(CET_FLAGS)
 623 EXTRA_CXX_FLAGS="$EXTRA_CXX_FLAGS $CET_FLAGS"
 624 EXTRA_CFLAGS="$EXTRA_CFLAGS $CET_FLAGS"
 625 AC_SUBST(EXTRA_CFLAGS)
 626 AC_SUBST(EXTRA_CXX_FLAGS)
 627
 628 # Determine cross-compile flags and AM_CONDITIONALs.
 629 #AC_SUBST(GLIBCXX_IS_NATIVE)
 630 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 631 GLIBCXX_EVALUATE_CONDITIONALS
 632
 633 AC_CACHE_SAVE
 634
 635 if test ${multilib} = yes; then
 636   multilib_arg="--enable-multilib"
 637 else
 638   multilib_arg=
 639 fi
 640
 641 # Export all the install information.
 642 GLIBCXX_EXPORT_INSTALL_INFO
 643
 644 # Export all the include and flag information to Makefiles.
 645 GLIBCXX_EXPORT_INCLUDES
 646 GLIBCXX_EXPORT_FLAGS
 647
 648 # Determine what GCC version number to use in filesystem paths.
 649 GCC_BASE_VER
 650
 651 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 652 dnl which can all be called multiple times as needed, plus one (different)
 653 dnl AC_OUTPUT macro.  This one lists the files to be created:
 654 AC_CONFIG_FILES(Makefile)
 655 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 656 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 657 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 658 AC_CONFIG_FILES([src/libbacktrace/backtrace-supported.h])
 659
 660 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 661 # that multilib installs will end up installed in the correct place.
 662 # The testsuite needs it for multilib-aware ABI baseline files.
 663 # To work around this not being passed down from config-ml.in ->
 664 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 665 # append it here.  Only modify Makefiles that have just been created.
 666 #
 667 # Also, get rid of this simulated-VPATH thing that automake does.
 668 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 669   [cat > vpsed$$ << \_EOF
 670 s!`test -f '$<' || echo '$(srcdir)/'`!!
 671 _EOF
 672    sed -f vpsed$$ $ac_file > tmp$$
 673    mv tmp$$ $ac_file
 674    rm vpsed$$
 675    echo 'MULTISUBDIR =' >> $ac_file
 676    ml_norecursion=yes
 677    . ${multi_basedir}/config-ml.in
 678    AS_UNSET([ml_norecursion])
 679 ])
 680
 681 AC_CONFIG_COMMANDS([generate-headers],
 682   [(cd include && ${MAKE-make} pch_build= )])
 683
 684 dnl And this actually makes things happen:
 685 AC_OUTPUT