gcc/ada/a-cihase.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                  ADA.CONTAINERS.INDEFINITE_HASHED_SETS                   --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- This unit was originally developed by Matthew J Heaney.                  --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Iterator_Interfaces;
  35 private with Ada.Containers.Hash_Tables;
  36 private with Ada.Streams;
  37 private with Ada.Finalization;
  38
  39 generic
  40    type Element_Type (<>) is private;
  41
  42    with function Hash (Element : Element_Type) return Hash_Type;
  43
  44    with function Equivalent_Elements (Left, Right : Element_Type)
  45                                      return Boolean;
  46
  47    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  48
  49 package Ada.Containers.Indefinite_Hashed_Sets is
  50    pragma Preelaborate;
  51    pragma Remote_Types;
  52
  53    type Set is tagged private
  54      with Constant_Indexing => Constant_Reference,
  55           Default_Iterator  => Iterate,
  56           Iterator_Element  => Element_Type;
  57
  58    pragma Preelaborable_Initialization (Set);
  59
  60    type Cursor is private;
  61    pragma Preelaborable_Initialization (Cursor);
  62
  63    Empty_Set : constant Set;
  64    --  Set objects declared without an initialization expression are
  65    --  initialized to the value Empty_Set.
  66
  67    No_Element : constant Cursor;
  68    --  Cursor objects declared without an initialization expression are
  69    --  initialized to the value No_Element.
  70
  71    function Has_Element (Position : Cursor) return Boolean;
  72    --  Equivalent to Position /= No_Element
  73
  74    package Set_Iterator_Interfaces is new
  75      Ada.Iterator_Interfaces (Cursor, Has_Element);
  76
  77    function "=" (Left, Right : Set) return Boolean;
  78    --  For each element in Left, set equality attempts to find the equal
  79    --  element in Right; if a search fails, then set equality immediately
  80    --  returns False. The search works by calling Hash to find the bucket in
  81    --  the Right set that corresponds to the Left element. If the bucket is
  82    --  non-empty, the search calls the generic formal element equality operator
  83    --  to compare the element (in Left) to the element of each node in the
  84    --  bucket (in Right); the search terminates when a matching node in the
  85    --  bucket is found, or the nodes in the bucket are exhausted. (Note that
  86    --  element equality is called here, not Equivalent_Elements. Set equality
  87    --  is the only operation in which element equality is used. Compare set
  88    --  equality to Equivalent_Sets, which does call Equivalent_Elements.)
  89
  90    function Equivalent_Sets (Left, Right : Set) return Boolean;
  91    --  Similar to set equality, with the difference that the element in Left is
  92    --  compared to the elements in Right using the generic formal
  93    --  Equivalent_Elements operation instead of element equality.
  94
  95    function To_Set (New_Item : Element_Type) return Set;
  96    --  Constructs a singleton set comprising New_Element. To_Set calls Hash to
  97    --  determine the bucket for New_Item.
  98
  99    function Capacity (Container : Set) return Count_Type;
 100    --  Returns the current capacity of the set. Capacity is the maximum length
 101    --  before which rehashing in guaranteed not to occur.
 102
 103    procedure Reserve_Capacity (Container : in out Set; Capacity : Count_Type);
 104    --  Adjusts the current capacity, by allocating a new buckets array. If the
 105    --  requested capacity is less than the current capacity, then the capacity
 106    --  is contracted (to a value not less than the current length). If the
 107    --  requested capacity is greater than the current capacity, then the
 108    --  capacity is expanded (to a value not less than what is requested). In
 109    --  either case, the nodes are rehashed from the old buckets array onto the
 110    --  new buckets array (Hash is called once for each existing element in
 111    --  order to compute the new index), and then the old buckets array is
 112    --  deallocated.
 113
 114    function Length (Container : Set) return Count_Type;
 115    --  Returns the number of items in the set
 116
 117    function Is_Empty (Container : Set) return Boolean;
 118    --  Equivalent to Length (Container) = 0
 119
 120    procedure Clear (Container : in out Set);
 121    --  Removes all of the items from the set
 122
 123    function Element (Position : Cursor) return Element_Type;
 124    --  Returns the element of the node designated by the cursor
 125
 126    procedure Replace_Element
 127      (Container : in out Set;
 128       Position  : Cursor;
 129       New_Item  : Element_Type);
 130    --  If New_Item is equivalent (as determined by calling Equivalent_Elements)
 131    --  to the element of the node designated by Position, then New_Element is
 132    --  assigned to that element. Otherwise, it calls Hash to determine the
 133    --  bucket for New_Item. If the bucket is not empty, then it calls
 134    --  Equivalent_Elements for each node in that bucket to determine whether
 135    --  New_Item is equivalent to an element in that bucket. If
 136    --  Equivalent_Elements returns True then Program_Error is raised (because
 137    --  an element may appear only once in the set); otherwise, New_Item is
 138    --  assigned to the node designated by Position, and the node is moved to
 139    --  its new bucket.
 140
 141    procedure Query_Element
 142      (Position : Cursor;
 143       Process  : not null access procedure (Element : Element_Type));
 144    --  Calls Process with the element (having only a constant view) of the node
 145    --  designated by the cursor.
 146
 147    type Constant_Reference_Type
 148      (Element : not null access constant Element_Type) is private
 149         with Implicit_Dereference => Element;
 150
 151    function Constant_Reference
 152      (Container : aliased Set;
 153       Position  : Cursor)
 154    return Constant_Reference_Type;
 155
 156    procedure Assign (Target : in out Set; Source : Set);
 157
 158    function Copy (Source : Set; Capacity : Count_Type := 0) return Set;
 159
 160    procedure Move (Target : in out Set; Source : in out Set);
 161    --  Clears Target (if it's not empty), and then moves (not copies) the
 162    --  buckets array and nodes from Source to Target.
 163
 164    procedure Insert
 165      (Container : in out Set;
 166       New_Item  : Element_Type;
 167       Position  : out Cursor;
 168       Inserted  : out Boolean);
 169    --  Conditionally inserts New_Item into the set. If New_Item is already in
 170    --  the set, then Inserted returns False and Position designates the node
 171    --  containing the existing element (which is not modified). If New_Item is
 172    --  not already in the set, then Inserted returns True and Position
 173    --  designates the newly-inserted node containing New_Item. The search for
 174    --  an existing element works as follows. Hash is called to determine
 175    --  New_Item's bucket; if the bucket is non-empty, then Equivalent_Elements
 176    --  is called to compare New_Item to the element of each node in that
 177    --  bucket. If the bucket is empty, or there were no equivalent elements in
 178    --  the bucket, the search "fails" and the New_Item is inserted in the set
 179    --  (and Inserted returns True); otherwise, the search "succeeds" (and
 180    --  Inserted returns False).
 181
 182    procedure Insert  (Container : in out Set; New_Item : Element_Type);
 183    --  Attempts to insert New_Item into the set, performing the usual insertion
 184    --  search (which involves calling both Hash and Equivalent_Elements); if
 185    --  the search succeeds (New_Item is equivalent to an element already in the
 186    --  set, and so was not inserted), then this operation raises
 187    --  Constraint_Error. (This version of Insert is similar to Replace, but
 188    --  having the opposite exception behavior. It is intended for use when you
 189    --  want to assert that the item is not already in the set.)
 190
 191    procedure Include (Container : in out Set; New_Item : Element_Type);
 192    --  Attempts to insert New_Item into the set. If an element equivalent to
 193    --  New_Item is already in the set (the insertion search succeeded, and
 194    --  hence New_Item was not inserted), then the value of New_Item is assigned
 195    --  to the existing element. (This insertion operation only raises an
 196    --  exception if cursor tampering occurs. It is intended for use when you
 197    --  want to insert the item in the set, and you don't care whether an
 198    --  equivalent element is already present.)
 199
 200    procedure Replace (Container : in out Set; New_Item : Element_Type);
 201    --  Searches for New_Item in the set; if the search fails (because an
 202    --  equivalent element was not in the set), then it raises
 203    --  Constraint_Error. Otherwise, the existing element is assigned the value
 204    --  New_Item. (This is similar to Insert, but with the opposite exception
 205    --  behavior. It is intended for use when you want to assert that the item
 206    --  is already in the set.)
 207
 208    procedure Exclude (Container : in out Set; Item : Element_Type);
 209    --  Searches for Item in the set, and if found, removes its node from the
 210    --  set and then deallocates it. The search works as follows. The operation
 211    --  calls Hash to determine the item's bucket; if the bucket is not empty,
 212    --  it calls Equivalent_Elements to compare Item to the element of each node
 213    --  in the bucket. (This is the deletion analog of Include. It is intended
 214    --  for use when you want to remove the item from the set, but don't care
 215    --  whether the item is already in the set.)
 216
 217    procedure Delete  (Container : in out Set; Item : Element_Type);
 218    --  Searches for Item in the set (which involves calling both Hash and
 219    --  Equivalent_Elements). If the search fails, then the operation raises
 220    --  Constraint_Error. Otherwise it removes the node from the set and then
 221    --  deallocates it. (This is the deletion analog of non-conditional
 222    --  Insert. It is intended for use when you want to assert that the item is
 223    --  already in the set.)
 224
 225    procedure Delete (Container : in out Set; Position  : in out Cursor);
 226    --  Removes the node designated by Position from the set, and then
 227    --  deallocates the node. The operation calls Hash to determine the bucket,
 228    --  and then compares Position to each node in the bucket until there's a
 229    --  match (it does not call Equivalent_Elements).
 230
 231    procedure Union (Target : in out Set; Source : Set);
 232    --  The operation first calls Reserve_Capacity if the current capacity is
 233    --  less than the sum of the lengths of Source and Target. It then iterates
 234    --  over the Source set, and conditionally inserts each element into Target.
 235
 236    function Union (Left, Right : Set) return Set;
 237    --  The operation first copies the Left set to the result, and then iterates
 238    --  over the Right set to conditionally insert each element into the result.
 239
 240    function "or" (Left, Right : Set) return Set renames Union;
 241
 242    procedure Intersection (Target : in out Set; Source : Set);
 243    --  Iterates over the Target set (calling First and Next), calling Find to
 244    --  determine whether the element is in Source. If an equivalent element is
 245    --  not found in Source, the element is deleted from Target.
 246
 247    function Intersection (Left, Right : Set) return Set;
 248    --  Iterates over the Left set, calling Find to determine whether the
 249    --  element is in Right. If an equivalent element is found, it is inserted
 250    --  into the result set.
 251
 252    function "and" (Left, Right : Set) return Set renames Intersection;
 253
 254    procedure Difference (Target : in out Set; Source : Set);
 255    --  Iterates over the Source (calling First and Next), calling Find to
 256    --  determine whether the element is in Target. If an equivalent element is
 257    --  found, it is deleted from Target.
 258
 259    function Difference (Left, Right : Set) return Set;
 260    --  Iterates over the Left set, calling Find to determine whether the
 261    --  element is in the Right set. If an equivalent element is not found, the
 262    --  element is inserted into the result set.
 263
 264    function "-" (Left, Right : Set) return Set renames Difference;
 265
 266    procedure Symmetric_Difference (Target : in out Set; Source : Set);
 267    --  The operation first calls Reserve_Capacity if the current capacity is
 268    --  less than the sum of the lengths of Source and Target. It then iterates
 269    --  over the Source set, searching for the element in Target (calling Hash
 270    --  and Equivalent_Elements). If an equivalent element is found, it is
 271    --  removed from Target; otherwise it is inserted into Target.
 272
 273    function Symmetric_Difference (Left, Right : Set) return Set;
 274    --  The operation first iterates over the Left set. It calls Find to
 275    --  determine whether the element is in the Right set. If no equivalent
 276    --  element is found, the element from Left is inserted into the result. The
 277    --  operation then iterates over the Right set, to determine whether the
 278    --  element is in the Left set. If no equivalent element is found, the Right
 279    --  element is inserted into the result.
 280
 281    function "xor" (Left, Right : Set) return Set
 282      renames Symmetric_Difference;
 283
 284    function Overlap (Left, Right : Set) return Boolean;
 285    --  Iterates over the Left set (calling First and Next), calling Find to
 286    --  determine whether the element is in the Right set. If an equivalent
 287    --  element is found, the operation immediately returns True. The operation
 288    --  returns False if the iteration over Left terminates without finding any
 289    --  equivalent element in Right.
 290
 291    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean;
 292    --  Iterates over Subset (calling First and Next), calling Find to determine
 293    --  whether the element is in Of_Set. If no equivalent element is found in
 294    --  Of_Set, the operation immediately returns False. The operation returns
 295    --  True if the iteration over Subset terminates without finding an element
 296    --  not in Of_Set (that is, every element in Subset is equivalent to an
 297    --  element in Of_Set).
 298
 299    function First (Container : Set) return Cursor;
 300    --  Returns a cursor that designates the first non-empty bucket, by
 301    --  searching from the beginning of the buckets array.
 302
 303    function Next (Position : Cursor) return Cursor;
 304    --  Returns a cursor that designates the node that follows the current one
 305    --  designated by Position. If Position designates the last node in its
 306    --  bucket, the operation calls Hash to compute the index of this bucket,
 307    --  and searches the buckets array for the first non-empty bucket, starting
 308    --  from that index; otherwise, it simply follows the link to the next node
 309    --  in the same bucket.
 310
 311    procedure Next (Position : in out Cursor);
 312    --  Equivalent to Position := Next (Position)
 313
 314    function Find (Container : Set; Item : Element_Type) return Cursor;
 315    --  Searches for Item in the set. Find calls Hash to determine the item's
 316    --  bucket; if the bucket is not empty, it calls Equivalent_Elements to
 317    --  compare Item to each element in the bucket. If the search succeeds, Find
 318    --  returns a cursor designating the node containing the equivalent element;
 319    --  otherwise, it returns No_Element.
 320
 321    function Contains (Container : Set; Item : Element_Type) return Boolean;
 322    --  Equivalent to Find (Container, Item) /= No_Element
 323
 324    function Equivalent_Elements (Left, Right : Cursor) return Boolean;
 325    --  Returns the result of calling Equivalent_Elements with the elements of
 326    --  the nodes designated by cursors Left and Right.
 327
 328    function Equivalent_Elements
 329      (Left  : Cursor;
 330       Right : Element_Type) return Boolean;
 331    --  Returns the result of calling Equivalent_Elements with element of the
 332    --  node designated by Left and element Right.
 333
 334    function Equivalent_Elements
 335      (Left  : Element_Type;
 336       Right : Cursor) return Boolean;
 337    --  Returns the result of calling Equivalent_Elements with element Left and
 338    --  the element of the node designated by Right.
 339
 340    procedure Iterate
 341      (Container : Set;
 342       Process   : not null access procedure (Position : Cursor));
 343    --  Calls Process for each node in the set
 344
 345    function Iterate (Container : Set)
 346      return Set_Iterator_Interfaces.Forward_Iterator'Class;
 347
 348    generic
 349       type Key_Type (<>) is private;
 350
 351       with function Key (Element : Element_Type) return Key_Type;
 352
 353       with function Hash (Key : Key_Type) return Hash_Type;
 354
 355       with function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
 356
 357    package Generic_Keys is
 358
 359       function Key (Position : Cursor) return Key_Type;
 360       --  Applies generic formal operation Key to the element of the node
 361       --  designated by Position.
 362
 363       function Element (Container : Set; Key : Key_Type) return Element_Type;
 364       --  Searches (as per the key-based Find) for the node containing Key, and
 365       --  returns the associated element.
 366
 367       procedure Replace
 368         (Container : in out Set;
 369          Key       : Key_Type;
 370          New_Item  : Element_Type);
 371       --  Searches (as per the key-based Find) for the node containing Key, and
 372       --  then replaces the element of that node (as per the element-based
 373       --  Replace_Element).
 374
 375       procedure Exclude (Container : in out Set; Key : Key_Type);
 376       --  Searches for Key in the set, and if found, removes its node from the
 377       --  set and then deallocates it. The search works by first calling Hash
 378       --  (on Key) to determine the bucket; if the bucket is not empty, it
 379       --  calls Equivalent_Keys to compare parameter Key to the value of
 380       --  generic formal operation Key applied to element of each node in the
 381       --  bucket.
 382
 383       procedure Delete (Container : in out Set; Key : Key_Type);
 384       --  Deletes the node containing Key as per Exclude, with the difference
 385       --  that Constraint_Error is raised if Key is not found.
 386
 387       function Find (Container : Set; Key : Key_Type) return Cursor;
 388       --  Searches for the node containing Key, and returns a cursor
 389       --  designating the node. The search works by first calling Hash (on Key)
 390       --  to determine the bucket. If the bucket is not empty, the search
 391       --  compares Key to the element of each node in the bucket, and returns
 392       --  the matching node. The comparison itself works by applying the
 393       --  generic formal Key operation to the element of the node, and then
 394       --  calling generic formal operation Equivalent_Keys.
 395
 396       function Contains (Container : Set; Key : Key_Type) return Boolean;
 397       --  Equivalent to Find (Container, Key) /= No_Element
 398
 399       procedure Update_Element_Preserving_Key
 400         (Container : in out Set;
 401          Position  : Cursor;
 402          Process   : not null access
 403                        procedure (Element : in out Element_Type));
 404       --  Calls Process with the element of the node designated by Position,
 405       --  but with the restriction that the key-value of the element is not
 406       --  modified. The operation first makes a copy of the value returned by
 407       --  applying generic formal operation Key on the element of the node, and
 408       --  then calls Process with the element. The operation verifies that the
 409       --  key-part has not been modified by calling generic formal operation
 410       --  Equivalent_Keys to compare the saved key-value to the value returned
 411       --  by applying generic formal operation Key to the post-Process value of
 412       --  element. If the key values compare equal then the operation
 413       --  completes. Otherwise, the node is removed from the map and
 414       --  Program_Error is raised.
 415
 416       type Reference_Type (Element : not null access Element_Type) is private
 417         with Implicit_Dereference => Element;
 418
 419       function Reference_Preserving_Key
 420         (Container : aliased in out Set;
 421          Position  : Cursor) return Reference_Type;
 422
 423       function Reference_Preserving_Key
 424         (Container : aliased in out Set;
 425          Key       : Key_Type) return Reference_Type;
 426
 427    private
 428       type Reference_Type (Element : not null access Element_Type)
 429          is null record;
 430    end Generic_Keys;
 431
 432 private
 433    pragma Inline (Next);
 434
 435    type Node_Type;
 436    type Node_Access is access Node_Type;
 437
 438    type Element_Access is access Element_Type;
 439
 440    type Node_Type is limited record
 441       Element : Element_Access;
 442       Next    : Node_Access;
 443    end record;
 444
 445    package HT_Types is
 446      new Hash_Tables.Generic_Hash_Table_Types (Node_Type, Node_Access);
 447
 448    type Set is new Ada.Finalization.Controlled with record
 449       HT : HT_Types.Hash_Table_Type;
 450    end record;
 451
 452    overriding procedure Adjust (Container : in out Set);
 453
 454    overriding procedure Finalize (Container : in out Set);
 455
 456    use HT_Types;
 457    use Ada.Finalization;
 458    use Ada.Streams;
 459
 460    type Set_Access is access all Set;
 461    for Set_Access'Storage_Size use 0;
 462
 463    type Cursor is record
 464       Container : Set_Access;
 465       Node      : Node_Access;
 466    end record;
 467
 468    procedure Write
 469      (Stream : not null access Root_Stream_Type'Class;
 470       Item   : Cursor);
 471
 472    for Cursor'Write use Write;
 473
 474    procedure Read
 475      (Stream : not null access Root_Stream_Type'Class;
 476       Item   : out Cursor);
 477
 478    for Cursor'Read use Read;
 479
 480    No_Element : constant Cursor := (Container => null, Node => null);
 481
 482    procedure Write
 483      (Stream    : not null access Root_Stream_Type'Class;
 484       Container : Set);
 485
 486    for Set'Write use Write;
 487
 488    procedure Read
 489      (Stream    : not null access Root_Stream_Type'Class;
 490       Container : out Set);
 491
 492    for Set'Read use Read;
 493
 494    type Constant_Reference_Type
 495      (Element : not null access constant Element_Type) is null record;
 496
 497    procedure Read
 498      (Stream : not null access Root_Stream_Type'Class;
 499       Item   : out Constant_Reference_Type);
 500
 501    for Constant_Reference_Type'Read use Read;
 502
 503    procedure Write
 504      (Stream : not null access Root_Stream_Type'Class;
 505       Item   : Constant_Reference_Type);
 506
 507    for Constant_Reference_Type'Write use Write;
 508
 509    Empty_Set : constant Set := (Controlled with HT => (null, 0, 0, 0));
 510
 511 end Ada.Containers.Indefinite_Hashed_Sets;