libjava/configure.in

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 AC_INIT(java/lang/System.java)
   4
   5 # We use these options to decide which functions to include.
   6 AC_ARG_WITH(target-subdir,
   7   AS_HELP_STRING([--with-target-subdir=SUBDIR],
   8                  [configure in a subdirectory]))
   9
  10 # We may get other options which we don't document:
  11 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  12
  13 # When building with srcdir == objdir, links to the source files will
  14 # be created in directories within the target_subdir.  We have to
  15 # adjust toplevel_srcdir accordingly, so that configure finds
  16 # install-sh and other auxiliary files that live in the top-level
  17 # source directory.
  18 if test "${srcdir}" = "."; then
  19   if test -z "${with_target_subdir}"; then
  20     toprel=".."
  21   else
  22     if test "${with_target_subdir}" != "."; then
  23       toprel="${with_multisrctop}../.."
  24     else
  25       toprel="${with_multisrctop}.."
  26     fi
  27   fi
  28 else
  29   toprel=".."
  30 fi
  31
  32 libgcj_basedir=$srcdir/$toprel/./libjava
  33 AC_SUBST(libgcj_basedir)
  34
  35 AC_CONFIG_AUX_DIR(${srcdir}/$toprel)
  36 if :; then :; else
  37   # This overrides the previous occurrence for automake, but not for
  38   # autoconf, which is exactly what we want.
  39   AC_CONFIG_AUX_DIR(..)
  40 fi
  41
  42 AC_CANONICAL_SYSTEM
  43 _GCC_TOPLEV_NONCANONICAL_BUILD
  44 _GCC_TOPLEV_NONCANONICAL_TARGET
  45
  46 AC_SUBST(target_noncanonical)
  47
  48 # This works around the fact that libtool configuration may change LD
  49 # for this particular configuration, but some shells, instead of
  50 # keeping the changes in LD private, export them just because LD is
  51 # exported.
  52 ORIGINAL_LD_FOR_MULTILIBS=$LD
  53
  54 AC_PROG_LN_S
  55
  56 # This works around an automake problem.
  57 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  58 AC_SUBST(mkinstalldirs)
  59
  60 AC_ARG_WITH(cross-host,
  61   AS_HELP_STRING([--with-cross-host=HOST],
  62                  [configure with a cross compiler from HOST]))
  63
  64 AC_ARG_WITH(newlib,
  65   AS_HELP_STRING([--with-newlib],
  66                  [configure with newlib]))
  67
  68 AC_ARG_ENABLE(version-specific-runtime-libs,
  69   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  70                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  71     [case "$enableval" in
  72       yes) version_specific_libs=yes ;;
  73       no)  version_specific_libs=no ;;
  74       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  75      esac],
  76     [version_specific_libs=no]
  77 )
  78
  79 # Default to --enable-multilib
  80 AC_ARG_ENABLE(multilib,
  81   AS_HELP_STRING([--enable-multilib],
  82                  [build many library versions (default)]),
  83 [case "${enableval}" in
  84   yes) multilib=yes ;;
  85   no)  multilib=no ;;
  86   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  87  esac], [multilib=yes])dnl
  88
  89 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  90 GCC_NO_EXECUTABLES
  91
  92 # (1) We use an abnormal CXX (without library references), so we
  93 # must cache it under a different name.
  94 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  95 # the non-multilib-adjusted value will be used in multilibs.
  96 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  97 # (4) As another side effect, automake doesn't automatically include them
  98 # in Makefile.in.
  99 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 100 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 101 # used in later tests.  This may not be necessary in libjava; I don't know.
 102 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 103 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 104 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 105 save_CXXFLAGS="$CXXFLAGS"
 106 CXXFLAGS="$CXXFLAGS -fno-builtin"
 107 AC_PROG_CC
 108 AC_PROG_CXX
 109 CXXFLAGS="$save_CXXFLAGS"
 110 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 111 AC_SUBST(CFLAGS)
 112 AC_SUBST(CXXFLAGS)
 113 AC_SUBST(LDFLAGS)
 114
 115 # version is pulled out to make it a bit easier to change using sed.
 116 version=0.0.7
 117 # Still use "libjava" here to placate dejagnu.
 118 AM_INIT_AUTOMAKE(libjava, $version)
 119
 120 AC_CHECK_TOOL(AS, as)
 121 AC_CHECK_TOOL(AR, ar)
 122 AC_CHECK_TOOL(RANLIB, ranlib, :)
 123
 124 AC_PROG_INSTALL
 125
 126 AM_MAINTAINER_MODE
 127
 128 AC_EXEEXT
 129
 130 # configure.host sets the following important variables
 131 #       libgcj_cflags    - host specific C compiler flags
 132 #       libgcj_cxxflags  - host specific C++ compiler flags
 133 #       libgcj_javaflags - host specific Java compiler flags
 134
 135 libgcj_cflags=
 136 libgcj_cxxflags=
 137 libgcj_javaflags=
 138
 139 . ${srcdir}/configure.host
 140
 141 LIBGCJ_CFLAGS="${libgcj_cflags}"
 142 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 143 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 144 AC_SUBST(LIBGCJ_CFLAGS)
 145 AC_SUBST(LIBGCJ_CXXFLAGS)
 146 AC_SUBST(LIBGCJ_JAVAFLAGS)
 147
 148 AM_CONFIG_HEADER(include/config.h gcj/libgcj-config.h)
 149
 150 # Only use libltdl for non-newlib builds.
 151 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 152    AC_LIBLTDL_CONVENIENCE
 153    AC_LIBTOOL_DLOPEN
 154    DIRLTDL=libltdl
 155    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 156    # Sigh.  Libtool's macro doesn't do the right thing.
 157    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 158    # FIXME: this is a hack.
 159    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 160    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 161 fi
 162 AC_SUBST(INCLTDL)
 163 AC_SUBST(LIBLTDL)
 164 AC_SUBST(DIRLTDL)
 165 AM_PROG_LIBTOOL
 166 AC_CONFIG_SUBDIRS($DIRLTDL)
 167
 168 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
 169    COMPPATH=.
 170 else
 171    COMPPATH=..
 172 fi
 173 AC_SUBST(COMPPATH)
 174
 175 # The -no-testsuite modules omit the test subdir.
 176 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 177
 178 # Should the runtime set system properties by examining the
 179 # environment variable GCJ_PROPERTIES?
 180 AC_ARG_ENABLE(getenv-properties,
 181   AS_HELP_STRING([--disable-getenv-properties],
 182                  [don't set system properties from GCJ_PROPERTIES]))
 183
 184 # Whether GCJ_PROPERTIES is used depends on the target.
 185 if test -z "$enable_getenv_properties"; then
 186    enable_getenv_properties=${enable_getenv_properties_default-yes}
 187 fi
 188 if test "$enable_getenv_properties" = no; then
 189    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 190      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 191 fi
 192
 193 # Whether we should use arguments to main()
 194 if test -z "$enable_main_args"; then
 195    enable_main_args=${enable_main_args_default-yes}
 196 fi
 197 if test "$enable_main_args" = no; then
 198    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 199 fi
 200
 201
 202 # Should we use hashtable-based synchronization?
 203 # Currently works only for Linux X86/ia64
 204 # Typically faster and more space-efficient
 205 AC_ARG_ENABLE(hash-synchronization,
 206   AS_HELP_STRING([--enable-hash-synchronization],
 207                  [use global hash table for monitor locks]))
 208
 209 if test -z "$enable_hash_synchronization"; then
 210    enable_hash_synchronization=$enable_hash_synchronization_default
 211 fi
 212
 213 # Do we allow intermodule optimizations (i.e. compiling many files at once)?
 214 AC_ARG_ENABLE(libgcj-multifile,
 215   AS_HELP_STRING([--enable-libgcj-multifile]
 216                  [allow compilation of several files at once]),
 217 [case "${enableval}" in
 218   yes) enable_libgcj_multifile=yes ;;
 219   no)  enable_libgcj_multifile=no ;;
 220   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libgcj-multifile) ;;
 221 esac],[enable_libgcj_multifile=no])
 222 AM_CONDITIONAL(ONESTEP, test "$enable_libgcj_multifile" = yes)
 223
 224 # What is the native OS API for MinGW?
 225 AC_ARG_WITH(win32-nlsapi,
 226   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 227                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 228 [case "${withval}" in
 229   ansi) with_win32_nlsapi=ansi ;;
 230   unicows) with_win32_nlsapi=unicows ;;
 231   unicode) with_win32_nlsapi=unicode ;;
 232   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 233 esac],[with_win32_nlsapi=ansi])
 234
 235 case "${with_win32_nlsapi}" in
 236   unicows | unicode)
 237     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 238       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 239     ;;
 240 esac
 241
 242 # configure.host sets slow_pthread_self if the synchronization code should
 243 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 244 if test "${slow_pthread_self}" = "yes"; then
 245   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 246     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 247 fi
 248
 249
 250 # See if the user has requested runtime debugging.
 251 LIBGCJDEBUG="false"
 252 AC_SUBST(LIBGCJDEBUG)
 253 AC_ARG_ENABLE(libgcj-debug,
 254   AS_HELP_STRING([--enable-libgcj-debug],
 255                  [enable runtime debugging code]),
 256   [if test "$enable_libgcj_debug" = yes; then
 257     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 258     LIBGCJDEBUG="true"
 259   fi])
 260
 261 # See if the user has the interpreter included.
 262 AC_ARG_ENABLE(interpreter,
 263   AS_HELP_STRING([--enable-interpreter],
 264                  [enable interpreter]),
 265   [if test "$enable_interpreter" = yes; then
 266     # This can also be set in configure.host.
 267     libgcj_interpreter=yes
 268   elif test "$enable_interpreter" = no; then
 269     libgcj_interpreter=no
 270   fi])
 271
 272 if test "$libgcj_interpreter" = yes; then
 273    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 274 fi
 275 INTERPRETER="$libgcj_interpreter"
 276 AC_SUBST(INTERPRETER)
 277
 278 AC_MSG_CHECKING([for exception model to use])
 279 AC_LANG_SAVE
 280 AC_LANG_CPLUSPLUS
 281 AC_ARG_ENABLE(sjlj-exceptions,
 282   AS_HELP_STRING([--enable-sjlj-exceptions],
 283                  [force use of builtin_setjmp for exceptions]),
 284 [:],
 285 [dnl Botheration.  Now we've got to detect the exception model.
 286 dnl Link tests against libgcc.a are problematic since -- at least
 287 dnl as of this writing -- we've not been given proper -L bits for
 288 dnl single-tree newlib and libgloss.
 289 dnl
 290 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 291 dnl conftest files before we got a change to grep them first.
 292 cat > conftest.$ac_ext << EOF
 293 [#]line __oline__ "configure"
 294 struct S { ~S(); };
 295 void bar();
 296 void foo()
 297 {
 298   S s;
 299   bar();
 300 }
 301 EOF
 302 old_CXXFLAGS="$CXXFLAGS"
 303 CXXFLAGS=-S
 304 if AC_TRY_EVAL(ac_compile); then
 305   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 306     enable_sjlj_exceptions=yes
 307   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 308     enable_sjlj_exceptions=no
 309   fi
 310 fi
 311 CXXFLAGS="$old_CXXFLAGS"
 312 rm -f conftest*])
 313 if test x$enable_sjlj_exceptions = xyes; then
 314   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 315         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 316   ac_exception_model_name=sjlj
 317 elif test x$enable_sjlj_exceptions = xno; then
 318   ac_exception_model_name="call frame"
 319 else
 320   AC_MSG_ERROR([unable to detect exception model])
 321 fi
 322 AC_LANG_RESTORE
 323 AC_MSG_RESULT($ac_exception_model_name)
 324
 325 # If we are non using SJLJ exceptions, and this host does not have support
 326 # for unwinding from a signal handler, enable checked dereferences and divides.
 327 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 328   CHECKREFSPEC=-fcheck-references
 329   DIVIDESPEC=-fuse-divide-subroutine
 330   EXCEPTIONSPEC=
 331 fi
 332
 333 # See if the user wants to disable java.net.  This is the mildly
 334 # ugly way that we admit that target-side configuration sucks.
 335 AC_ARG_ENABLE(java-net,
 336   AS_HELP_STRING([--disable-java-net],
 337                  [disable java.net]))
 338
 339 # Whether java.net is built by default can depend on the target.
 340 if test -z "$enable_java_net"; then
 341    enable_java_net=${enable_java_net_default-yes}
 342 fi
 343 if test "$enable_java_net" = no; then
 344    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 345 fi
 346
 347 # See if the user wants to configure without libffi.  Some
 348 # architectures don't support it, and default values are set in
 349 # configure.host.
 350 AC_ARG_WITH(libffi,
 351   AS_HELP_STRING([--without-libffi],
 352                  [don't use libffi]),
 353   [:],
 354   [with_libffi=${with_libffi_default-yes}])
 355
 356 LIBFFI=
 357 LIBFFIINCS=
 358 if test "$with_libffi" != no; then
 359    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 360    LIBFFI=../libffi/libffi_convenience.la
 361    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 362 fi
 363 AC_SUBST(LIBFFI)
 364 AC_SUBST(LIBFFIINCS)
 365
 366 # See if the user wants to disable JVMPI support.
 367 AC_ARG_ENABLE(jvmpi,
 368   AS_HELP_STRING([--disable-jvmpi],
 369                  [disable JVMPI support]))
 370
 371 if test "$enable_jvmpi" != no; then
 372     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 373 fi
 374
 375 # If the target is an eCos system, use the appropriate eCos
 376 # I/O routines.
 377 # FIXME: this should not be a local option but a global target
 378 # system; at present there is no eCos target.
 379 TARGET_ECOS=${PROCESS-"no"}
 380 AC_ARG_WITH(ecos,
 381 [  --with-ecos             enable runtime eCos target support],
 382 TARGET_ECOS="$with_ecos"
 383 )
 384
 385 EXTRA_CC_FILES=
 386 AC_SUBST(EXTRA_CC_FILES)
 387
 388 PLATFORMOBJS=
 389 case "$TARGET_ECOS" in
 390    no) case "$host" in
 391       *mingw*)
 392             PLATFORM=Win32
 393             PLATFORMNET=Win32
 394             PLATFORMOBJS=win32.lo
 395             PLATFORMH=win32.h
 396         CHECK_FOR_BROKEN_MINGW_LD
 397       ;;
 398       *)
 399             PLATFORM=Posix
 400             PLATFORMNET=Posix
 401             PLATFORMOBJS=posix.lo
 402             PLATFORMH=posix.h
 403       ;;
 404       esac
 405       ;;
 406    *)
 407       PLATFORM=Ecos
 408       PLATFORMNET=NoNet
 409       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 410       PLATFORMOBJS=posix.lo
 411       PLATFORMH=posix.h
 412       ;;
 413 esac
 414 AC_SUBST(PLATFORMOBJS)
 415 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 416
 417 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 418                                       [Define if you have int32_t and uint32_t.]))
 419 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 420                                         [Define if you have int32_t and uint32_t.]))
 421 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 422                                           [Define if you have u_int32_t]))
 423 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 424                                            [Define if you have u_int32_t]))
 425
 426
 427 # These may not be defined in a non-ANS conformant embedded system.
 428 # FIXME: Should these case a runtime exception in that case?
 429 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 430                                   [Define is you have 'mktime' in <time.h>]))
 431 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 432                                   [Define is you have 'localtime' in <time.h>]))
 433
 434 # Create the subdirectory for natFile.cc, or the attempt
 435 # to create the link will fail.
 436 test -d java || mkdir java
 437 test -d java/io || mkdir java/io
 438 test -d gnu || mkdir gnu
 439 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 440
 441 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 442 test -d java/lang || mkdir java/lang
 443 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 444 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 445
 446 # Likewise for natInetAddress.cc and natNetworkInterface.cc.
 447 test -d java/net || mkdir java/net
 448 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 449 AC_CONFIG_LINKS(java/net/natNetworkInterface.cc:java/net/natNetworkInterface${PLATFORMNET}.cc)
 450
 451 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 452 test -d gnu/java || mkdir gnu/java
 453 test -d gnu/java/net || mkdir gnu/java/net
 454 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 455 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 456
 457 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 458 test -d gnu/java/nio || mkdir gnu/java/nio
 459 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 460 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 461 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 462 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 463
 464 case "${host}" in
 465     *mingw*)
 466       SYSTEMSPEC="-lgdi32 -lws2_32"
 467       if test "${with_win32_nlsapi}" = "unicows"; then
 468         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 469       fi
 470     ;;
 471     *)
 472       SYSTEMSPEC=
 473     ;;
 474 esac
 475 AC_SUBST(SYSTEMSPEC)
 476
 477 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 478 AC_SUBST(LIBGCJTESTSPEC)
 479
 480 AC_ARG_WITH(system-zlib,
 481   AS_HELP_STRING([--with-system-zlib],
 482                  [use installed libz]))
 483 ZLIBSPEC=
 484 AC_SUBST(ZLIBSPEC)
 485 ZLIBTESTSPEC=
 486 AC_SUBST(ZLIBTESTSPEC)
 487
 488 AC_PATH_XTRA
 489
 490 # Determine which AWT peer libraries to build
 491 AC_ARG_ENABLE(java-awt,
 492   AS_HELP_STRING([--enable-java-awt],
 493                  [list of AWT peer implementations to be built]))
 494
 495 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 496 use_xlib_awt=""
 497 use_gtk_awt=""
 498 # The default toolkit to use is the first one specified.
 499 TOOLKIT=
 500 AC_SUBST(TOOLKIT)
 501
 502 for peer in $peerlibs ; do
 503   case $peer in
 504     xlib)
 505       if test "$no_x" = yes; then
 506         echo "*** xlib peers requested but no X library available" 1>&2
 507         exit 1
 508       else
 509         use_xlib_awt="yes"
 510         if test -z "$TOOLKIT"; then
 511            TOOLKIT=gnu.awt.xlib.XToolkit
 512         fi
 513       fi
 514       ;;
 515     gtk)
 516       if test "$no_x" = yes; then
 517          echo "*** xlib peers requested but no X library available" 1>&2
 518          exit 1
 519       else
 520          use_gtk_awt=yes
 521          if test -z "$TOOLKIT"; then
 522             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 523          fi
 524          test -d jniinclude || mkdir jniinclude
 525       fi
 526       ;;
 527     no)
 528       use_xlib_awt=
 529       use_gtk_awt=
 530       break
 531       ;;
 532     *)
 533       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 534       exit 1
 535   esac
 536 done
 537
 538 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 539 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 540
 541 # determine whether to enable the cairo GTK Graphics2D backend
 542 AC_ARG_ENABLE(gtk-cairo,
 543   AS_HELP_STRING([--enable-gtk-cairo],
 544                  [build the cairo Graphics2D implementation on GTK]))
 545 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 546 if test "x${enable_gtk_cairo}" = xyes
 547 then
 548         PKG_CHECK_MODULES(CAIRO, cairo)
 549         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 550 fi
 551 AC_SUBST(CAIRO_LIBS)
 552 AC_SUBST(CAIRO_CFLAGS)
 553 AC_SUBST(PANGOFT2_LIBS)
 554 AC_SUBST(PANGOFT2_CFLAGS)
 555
 556 # FIXME: this should be _libs on some hosts.
 557 libsubdir=.libs
 558
 559 # Allow the GC to be disabled.  Can be useful when debugging.
 560 AC_MSG_CHECKING([for garbage collector to use])
 561 AC_ARG_ENABLE(java-gc,
 562   AS_HELP_STRING([--enable-java-gc=TYPE],
 563                  [choose garbage collector (default is boehm)]),
 564   [GC=$enableval],
 565   [GC=boehm])
 566 GCLIBS=
 567 GCINCS=
 568 GCDEPS=
 569 GCOBJS=
 570 GCSPEC=
 571 JC1GCSPEC=
 572 GCTESTSPEC=
 573 case "$GC" in
 574  boehm)
 575     AC_MSG_RESULT(boehm)
 576     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 577     JC1GCSPEC='-fuse-boehm-gc'
 578     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 579
 580     # We also want to pick up some cpp flags required when including
 581     # boehm-config.h.  Yuck.
 582     GCINCS="`cat ../boehm-gc/boehm-cflags`"
 583     GCOBJS=boehm.lo
 584     GCHDR=boehm-gc.h
 585     # The POSIX thread support needs to know this.
 586     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 587     ;;
 588  no)
 589     AC_MSG_RESULT(none)
 590     GCOBJS=nogc.lo
 591     GCHDR=no-gc.h
 592     ;;
 593  *)
 594     AC_MSG_ERROR(unrecognized collector \"$GC\")
 595     ;;
 596 esac
 597 AC_SUBST(GCLIBS)
 598 AC_SUBST(GCINCS)
 599 AC_SUBST(GCDEPS)
 600 AC_SUBST(GCOBJS)
 601 AC_SUBST(GCSPEC)
 602 AC_SUBST(JC1GCSPEC)
 603 AC_SUBST(GCTESTSPEC)
 604 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 605
 606
 607 AC_MSG_CHECKING([for thread model used by GCC])
 608 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 609 AC_MSG_RESULT([$THREADS])
 610
 611 case "$THREADS" in
 612  no | none | single)
 613     THREADS=none
 614     ;;
 615  posix | pthreads)
 616     THREADS=posix
 617     case "$host" in
 618      *-*-linux*)
 619         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 620         ;;
 621     esac
 622     ;;
 623  win32)
 624     ;;
 625  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 626     AC_MSG_ERROR(thread package $THREADS not yet supported)
 627     ;;
 628  *)
 629     AC_MSG_ERROR($THREADS is an unknown thread package)
 630     ;;
 631 esac
 632
 633 THREADCXXFLAGS=
 634 THREADLDFLAGS=
 635 THREADLIBS=
 636 THREADINCS=
 637 THREADDEPS=
 638 THREADOBJS=
 639 THREADH=
 640 THREADSPEC=
 641 case "$THREADS" in
 642  posix)
 643     case "$host" in
 644      *-*-cygwin*)
 645         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 646         ;;
 647      *-*-freebsd[[1234]]*)
 648         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 649         # merely adds pthread_* functions) but it does have a -pthread switch
 650         # which is required at link-time to select -lc_r *instead* of -lc.
 651         THREADLDFLAGS=-pthread
 652         # Don't set THREADSPEC here as might be expected since -pthread is
 653         # not processed when found within a spec file, it must come from
 654         # the command line.  For now, the user must provide the -pthread
 655         # switch to link code compiled with gcj.  In future, consider adding
 656         # support for weak references to pthread_* functions ala gthr.h API.
 657         THREADSPEC='%{!pthread: %eUnder this configuration, the user must provide -pthread when linking.}'
 658         ;;
 659      *-*-freebsd*)
 660         # FreeBSD 5 implements a model much closer to other modern UNIX
 661         # which support threads.  However, it still does not support
 662         # -lpthread.
 663         THREADLDFLAGS=-pthread
 664         THREADSPEC=-lc_r
 665         ;;
 666      alpha*-dec-osf*)
 667         THREADCXXFLAGS=-pthread
 668         # boehm-gc needs some functions from librt, so link that too.
 669         THREADLIBS='-lpthread -lrt'
 670         THREADSPEC='-lpthread -lrt'
 671         ;;
 672      *)
 673         THREADLIBS=-lpthread
 674         THREADSPEC=-lpthread
 675         ;;
 676     esac
 677     THREADOBJS=posix-threads.lo
 678     THREADH=posix-threads.h
 679     # MIT pthreads doesn't seem to have the mutexattr functions.
 680     # But for now we don't check for it.  We just assume you aren't
 681     # using MIT pthreads.
 682     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 683
 684     # If we're using the Boehm GC, then we happen to know that it
 685     # defines _REENTRANT, so we don't bother.  Eww.
 686     if test "$GC" != boehm; then
 687        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 688     fi
 689     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 690     ;;
 691
 692  win32)
 693     THREADOBJS=win32-threads.lo
 694     THREADH=win32-threads.h
 695     ;;
 696
 697  none)
 698     THREADOBJS=no-threads.lo
 699     THREADH=no-threads.h
 700     ;;
 701 esac
 702 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 703 AC_SUBST(THREADLIBS)
 704 AC_SUBST(THREADINCS)
 705 AC_SUBST(THREADDEPS)
 706 AC_SUBST(THREADOBJS)
 707 AC_SUBST(THREADSPEC)
 708 AC_SUBST(THREADLDFLAGS)
 709 AC_SUBST(THREADCXXFLAGS)
 710
 711 if test -d sysdep; then true; else mkdir sysdep; fi
 712 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 713
 714 HASH_SYNC_SPEC=
 715 # Hash synchronization is only useful with posix threads right now.
 716 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 717    HASH_SYNC_SPEC=-fhash-synchronization
 718    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 719 fi
 720 AC_SUBST(HASH_SYNC_SPEC)
 721
 722
 723 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 724
 725 # We're in the tree with gcc, and need to include some of its headers.
 726 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 727
 728 # Figure out where generated headers like libgcj-config.h get installed.
 729 gcc_version_trigger=${libgcj_basedir}/../gcc/version.c
 730 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([[^\"]]*\)\".*/\1/'`
 731 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([[^ ]]*\) .*/\1/'`
 732 tool_include_dir='$(libdir)/gcc/$(target_noncanonical)/'${gcc_version}/include
 733 AC_SUBST(tool_include_dir)
 734 AC_SUBST(gcc_version)
 735
 736 if test "x${with_newlib}" = "xyes"; then
 737    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 738    # may not work correctly, because the compiler may not be able to
 739    # link executables.
 740
 741    # We assume newlib.  This lets us hard-code the functions we know
 742    # we'll have.
 743    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 744    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 745    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 746    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 747    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 748    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 749    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 750    # This is only for POSIX threads.
 751    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 752    # We also assume we are using gcc, which provides alloca.
 753    AC_DEFINE(HAVE_ALLOCA)
 754
 755    # Assume we do not have getuid and friends.
 756    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 757    PLATFORMNET=NoNet
 758 else
 759    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep opendir)
 760    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 761    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 762    AC_CHECK_FUNCS(nl_langinfo setlocale)
 763    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 764    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 765    AC_CHECK_FUNCS(fork execvp pipe sigaction ftruncate)
 766    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 767    AC_CHECK_FUNC(backtrace, [
 768      case "$host" in
 769        ia64-*-linux*)
 770          # Has broken backtrace()
 771          ;;
 772        mips*-*-linux*)
 773          # Has broken backtrace(), but we supply our own.
 774          if test -d sysdep; then true; else mkdir -p sysdep; fi
 775          EXTRA_CC_FILES="${EXTRA_CC_FILES} sysdep/dwarf2-backtrace.cc"
 776          AC_DEFINE(HAVE_BACKTRACE, 1,
 777            [Define if your platform has a working backtrace() function.])
 778          ;;
 779        *)
 780          AC_DEFINE(HAVE_BACKTRACE, 1,
 781            [Define if your platform has a working backtrace() function.])
 782          ;;
 783      esac
 784    ], [
 785      case "$host" in
 786        *mingw*)
 787          # Has backtrace() defined in libgcj itself
 788          AC_DEFINE(HAVE_BACKTRACE, 1,
 789            [Define if your platform has a working backtrace() function.])
 790          ;;
 791      esac
 792    ])
 793
 794    AC_CHECK_LIB(dl, dladdr, [
 795      if test "x${disable_dladdr}" = "xyes"; then
 796        #Broken dladdr().
 797        true
 798      else
 799        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 800      fi
 801    ])
 802    if test x"$build" = x"$host"; then
 803      AC_CHECK_FILES(/proc/self/exe, [
 804        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 805    else
 806      case $host in
 807      *-linux*)
 808        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 809        ;;
 810      esac
 811    fi
 812
 813    AM_ICONV
 814    AM_LC_MESSAGES
 815    AC_STRUCT_TIMEZONE
 816
 817    AC_CHECK_FUNCS(gethostbyname_r, [
 818      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 819        [Define if you have the 'gethostbyname_r' function.])
 820      # There are two different kinds of gethostbyname_r.
 821      # We look for the one that returns `int'.
 822      # Hopefully this check is robust enough.
 823      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 824        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 825
 826      case " $GCINCS " in
 827      *" -D_REENTRANT "*) ;;
 828      *)
 829         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 830         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 831         [libjava_cv_gethostbyname_r_needs_reentrant],
 832         [ AC_LANG_SAVE
 833           AC_LANG_CPLUSPLUS
 834           AC_TRY_COMPILE([#include <netdb.h>],
 835             [gethostbyname_r("", 0, 0);],
 836             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 837                 CPPFLAGS_SAVE="$CPPFLAGS"
 838                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 839                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 840                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 841                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 842                 CPPFLAGS="$CPPFLAGS_SAVE"
 843           ])
 844           AC_LANG_RESTORE
 845         ])
 846         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 847           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 848         fi
 849      ;;
 850      esac
 851
 852      AC_CACHE_CHECK([for struct hostent_data],
 853         [libjava_cv_struct_hostent_data], [dnl
 854         AC_TRY_COMPILE([
 855 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 856 # define _REENTRANT 1
 857 #endif
 858 #include <netdb.h>], [struct hostent_data data;],
 859           [libjava_cv_struct_hostent_data=yes],
 860           [libjava_cv_struct_hostent_data=no])])
 861      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 862        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 863          [Define if struct hostent_data is defined in netdb.h])
 864      fi
 865    ])
 866
 867    # FIXME: libjava source code expects to find a prototype for
 868    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 869    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 870    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 871    # linkage check is enough, yet C++ code requires proper prototypes.)
 872    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 873    AC_CHECK_FUNCS(gethostbyaddr_r, [
 874      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 875        [Define if you have the 'gethostbyaddr_r' function.])
 876      # There are two different kinds of gethostbyaddr_r.
 877      # We look for the one that returns `int'.
 878      # Hopefully this check is robust enough.
 879      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 880        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 881          [Define if gethostbyaddr_r returns 'int'.])])])])
 882
 883    AC_CHECK_FUNCS(gethostname, [
 884      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 885        [Define if you have the 'gethostname' function.])
 886      AC_EGREP_HEADER(gethostname, unistd.h, [
 887        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 888          [Define if gethostname is declared in <unistd.h>.])])])
 889
 890    AC_CHECK_FUNCS(usleep, [
 891      AC_EGREP_HEADER(usleep, unistd.h, [
 892        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 893           [Define if usleep is declared in <unistd.h>.])])])
 894
 895    # Look for these functions in the thread library, but only bother
 896    # if using POSIX threads.
 897    if test "$THREADS" = posix; then
 898       save_LIBS="$LIBS"
 899       LIBS="$LIBS $THREADLIBS"
 900       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 901       # E.g., Solaris.
 902       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 903
 904       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 905       # Solaris 7 the name librt is preferred.
 906       AC_CHECK_FUNCS(sched_yield, , [
 907         AC_CHECK_LIB(rt, sched_yield, [
 908           AC_DEFINE(HAVE_SCHED_YIELD)
 909           THREADLIBS="$THREADLIBS -lrt"
 910           THREADSPEC="$THREADSPEC -lrt"], [
 911           AC_CHECK_LIB(posix4, sched_yield, [
 912             AC_DEFINE(HAVE_SCHED_YIELD)
 913             THREADLIBS="$THREADLIBS -lposix4"
 914             THREADSPEC="$THREADSPEC -lposix4"])])])
 915       LIBS="$save_LIBS"
 916
 917       # We can save a little space at runtime if the mutex has m_count
 918       # or __m_count.  This is a nice hack for Linux.
 919       AC_TRY_COMPILE([#include <pthread.h>], [
 920           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 921         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
 922              [Define if pthread_mutex_t has m_count member.]), [
 923         AC_TRY_COMPILE([#include <pthread.h>], [
 924             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 925           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
 926             [Define if pthread_mutex_t has __m_count member.]))])
 927    fi
 928
 929    # We require a way to get the time.
 930    time_found=no
 931    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 932    if test "$time_found" = no; then
 933       AC_MSG_ERROR([no function found to get the time])
 934    fi
 935
 936    AC_CHECK_FUNCS(memmove)
 937
 938    # We require memcpy.
 939    memcpy_found=no
 940    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 941    if test "$memcpy_found" = no; then
 942       AC_MSG_ERROR([memcpy is required])
 943    fi
 944
 945    AC_CHECK_LIB(dl, dlopen, [
 946        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
 947
 948    # Some library-finding code we stole from Tcl.
 949    #--------------------------------------------------------------------
 950    #    Check for the existence of the -lsocket and -lnsl libraries.
 951    #    The order here is important, so that they end up in the right
 952    #    order in the command line generated by make.  Here are some
 953    #    special considerations:
 954    #    1. Use "connect" and "accept" to check for -lsocket, and
 955    #       "gethostbyname" to check for -lnsl.
 956    #    2. Use each function name only once:  can't redo a check because
 957    #       autoconf caches the results of the last check and won't redo it.
 958    #    3. Use -lnsl and -lsocket only if they supply procedures that
 959    #       aren't already present in the normal libraries.  This is because
 960    #       IRIX 5.2 has libraries, but they aren't needed and they're
 961    #       bogus:  they goof up name resolution if used.
 962    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 963    #       To get around this problem, check for both libraries together
 964    #       if -lsocket doesn't work by itself.
 965    #--------------------------------------------------------------------
 966
 967    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 968     [gcj_cv_lib_sockets=
 969      gcj_checkBoth=0
 970      unset ac_cv_func_connect
 971      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 972      if test "$gcj_checkSocket" = 1; then
 973          unset ac_cv_func_connect
 974          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 975                       gcj_checkBoth=1)
 976      fi
 977      if test "$gcj_checkBoth" = 1; then
 978          gcj_oldLibs=$LIBS
 979          LIBS="$LIBS -lsocket -lnsl"
 980          unset ac_cv_func_accept
 981          AC_CHECK_FUNC(accept,
 982                        [gcj_checkNsl=0
 983                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 984          unset ac_cv_func_accept
 985          LIBS=$gcj_oldLibs
 986      fi
 987      unset ac_cv_func_gethostbyname
 988      gcj_oldLibs=$LIBS
 989      LIBS="$LIBS $gcj_cv_lib_sockets"
 990      AC_CHECK_FUNC(gethostbyname, ,
 991                    [AC_CHECK_LIB(nsl, main,
 992                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 993      unset ac_cv_func_gethostbyname
 994      LIBS=$gcj_oldLIBS
 995    ])
 996    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 997
 998    if test "$with_system_zlib" = yes; then
 999       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1000    fi
1001
1002    # Test for Gtk stuff, if asked for.
1003    if test "$use_gtk_awt" = yes; then
1004       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1005       AC_SUBST(GTK_CFLAGS)
1006       AC_SUBST(GTK_LIBS)
1007
1008       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1009       AC_SUBST(GLIB_CFLAGS)
1010       AC_SUBST(GLIB_LIBS)
1011
1012       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1013       AC_SUBST(LIBART_CFLAGS)
1014       AC_SUBST(LIBART_LIBS)
1015    fi
1016
1017    # On Solaris, and maybe other architectures, the Boehm collector
1018    # requires -ldl.
1019    if test "$GC" = boehm; then
1020       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1021    fi
1022 fi
1023
1024 if test -z "${with_multisubdir}"; then
1025    builddotdot=.
1026 else
1027    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
1028 fi
1029
1030 NATIVE=yes
1031
1032 # Which gcj do we use?
1033 which_gcj=default
1034 built_gcc_dir="`cd ${builddotdot}/../../gcc && ${PWDCMD-pwd}`"
1035 if test -n "${with_cross_host}"; then
1036   # We are being configured with a cross compiler. We can't
1037   # use ac_exeext, because that is for the target platform.
1038   NATIVE=no
1039   cross_host_exeext=
1040   case "${with_cross_host}" in
1041      *mingw* | *cygwin*)
1042          cross_host_exeext=.exe
1043      ;;
1044   esac
1045   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
1046      if test x"$build_noncanonical" = x"$with_cross_host"; then
1047         # Ordinary cross (host!=target and host=build)
1048         which_gcj=built
1049      else
1050         # Canadian cross (host!=target and host!=build)
1051         which_gcj=cross
1052      fi
1053   else
1054      which_gcj=cross
1055   fi
1056 else
1057   # We are being configured with a native or crossed-native compiler
1058   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
1059      if test x"$build" = x"$host"; then
1060         # True native build (host=target and host=build)
1061         which_gcj=built
1062      else
1063         # Crossed-native build (host=target and host!=build)
1064         which_gcj=cross
1065      fi
1066   else
1067      which_gcj=path
1068   fi
1069 fi
1070 case "${which_gcj}" in
1071    built)
1072       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
1073       GCJH='$(MULTIBUILDTOP)../$(COMPPATH)/gcc/gcjh'
1074       ZIP='$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1075    ;;
1076    cross)
1077       if test "x${with_newlib}" = "xyes"; then
1078          # FIXME (comment): Why is this needed?
1079          GCC_UNWIND_INCLUDE=
1080          GCJ="${target_noncanonical}-gcj"
1081       else
1082          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
1083       fi
1084       ZIP=jar
1085       GCJH='$(target_noncanonical)-gcjh'
1086    ;;
1087    path)
1088       GCJ="gcj -B`${PWDCMD-pwd}`/"
1089       ## In this case, gcj is found outside the build tree.  However, zip is
1090       ## found in the build tree.
1091       ZIP='$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1092       GCJH=gcjh
1093    ;;
1094 esac
1095
1096 AC_SUBST(GCJH)
1097 AC_SUBST(ZIP)
1098
1099 # Create it, so that compile/link tests don't fail
1100 test -f libgcj.spec || touch libgcj.spec
1101
1102 # We must search the source tree for java.lang, since we still don't
1103 # have libgcj.jar nor java/lang/*.class
1104 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1105 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1106
1107 # Since some classes depend on this one, we need its source available
1108 # before we can do any GCJ compilation test :-(
1109 if test ! -f gnu/classpath/Configuration.java; then
1110   test -d gnu || mkdir gnu
1111   test -d gnu/classpath || mkdir gnu/classpath
1112   sed -e 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
1113       -e 's,@TOOLKIT@,$TOOLKIT,' \
1114         < $srcdir/gnu/classpath/Configuration.java.in \
1115         > gnu/classpath/Configuration.java
1116   # We do not want to redirect the output of the grep below to /dev/null,
1117   # but we add /dev/null to the input list so that grep will print the
1118   # filename of Configuration.java in case it finds any matches.
1119   if grep @ gnu/classpath/Configuration.java /dev/null; then
1120     AC_MSG_ERROR([configure.in is missing the substitutions above])
1121   fi
1122 fi
1123
1124 LT_AC_PROG_GCJ
1125
1126 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1127
1128 AC_COMPILE_CHECK_SIZEOF(void *)
1129
1130 ZLIBS=
1131 SYS_ZLIBS=
1132 ZINCS=
1133
1134 if test -z "$ZLIBSPEC"; then
1135    # Use zlib from the GCC tree.
1136    ZINCS='-I$(top_srcdir)/../zlib'
1137    ZLIBS=../zlib/libzgcj_convenience.la
1138 else
1139    # System's zlib.
1140    SYS_ZLIBS="$ZLIBSPEC"
1141 fi
1142 AC_SUBST(ZLIBS)
1143 AC_SUBST(SYS_ZLIBS)
1144 AC_SUBST(ZINCS)
1145 AC_SUBST(DIVIDESPEC)
1146 AC_SUBST(CHECKREFSPEC)
1147 AC_SUBST(EXCEPTIONSPEC)
1148 AC_SUBST(IEEESPEC)
1149
1150 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1151 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1152 AC_SUBST(GCC_UNWIND_INCLUDE)
1153
1154 # Process the option "--enable-version-specific-runtime-libs"
1155 # Calculate toolexeclibdir
1156 case ${version_specific_libs} in
1157   yes)
1158     # Need the gcc compiler version to know where to install libraries
1159     # and header files if --enable-version-specific-runtime-libs option
1160     # is selected.
1161     includedir='${libdir}/gcc/${target_noncanonical}/'$gcc_version/include/
1162     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1163     toolexecmainlibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1164     toolexeclibdir=$toolexecmainlibdir
1165     ;;
1166   no)
1167     if test -n "$with_cross_host" &&
1168        test x"$with_cross_host" != x"no"; then
1169       # Install a library built with a cross compiler in tooldir, not libdir.
1170       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1171       toolexecmainlibdir='$(toolexecdir)/lib'
1172     else
1173       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1174       toolexecmainlibdir='$(libdir)'
1175     fi
1176     multi_os_directory=`$CC -print-multi-os-directory`
1177     case $multi_os_directory in
1178       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1179       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1180     esac
1181     ;;
1182 esac
1183 AC_SUBST(toolexecdir)
1184 AC_SUBST(toolexecmainlibdir)
1185 AC_SUBST(toolexeclibdir)
1186
1187 # Determine gcj version number.
1188 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1189 GCJVERSION=$gcjversion
1190 AC_SUBST(GCJVERSION)
1191 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1192
1193 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1194 # On that system, sys/ioctl.h will not include sys/filio.h unless
1195 # BSD_COMP is defined; just including sys/filio.h is simpler.
1196 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h pwd.h sys/config.h stdint.h langinfo.h locale.h)
1197 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1198 # for now.  If you change this, you also must update natFile.cc.
1199 AC_CHECK_HEADERS(dirent.h)
1200 AC_CHECK_HEADERS(inttypes.h, [
1201     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1202     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1203 ])
1204 AC_HEADER_SYS_WAIT
1205
1206 AC_CHECK_TYPE([ssize_t], [int])
1207
1208 AC_MSG_CHECKING([for in_addr_t])
1209 AC_TRY_COMPILE([#include <sys/types.h>
1210 #if STDC_HEADERS
1211 #include <stdlib.h>
1212 #include <stddef.h>
1213 #endif
1214 #if HAVE_NETINET_IN_H
1215 #include <netinet/in.h>
1216 #endif], [in_addr_t foo;],
1217   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1218      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1219    AC_MSG_RESULT(yes)],
1220   [AC_MSG_RESULT(no)])
1221
1222 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1223 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
1224   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1225      [Define if struct ip_mreq is defined in netinet/in.h.])
1226    AC_MSG_RESULT(yes)],
1227   [AC_MSG_RESULT(no)])
1228
1229 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1230 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ipv6_mreq mreq6;],
1231   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1232      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1233    AC_MSG_RESULT(yes)],
1234   [AC_MSG_RESULT(no)])
1235
1236 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1237 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
1238   [AC_DEFINE(HAVE_INET6, 1,
1239      [Define if inet6 structures are defined in netinet/in.h.])
1240    AC_MSG_RESULT(yes)],
1241   [AC_MSG_RESULT(no)])
1242
1243 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1244 AC_TRY_COMPILE([#define _POSIX_PII_SOCKET
1245 #include <sys/types.h>
1246 #include <sys/socket.h>], [socklen_t x = 5;],
1247   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1248    AC_MSG_RESULT(yes)],
1249   [AC_MSG_RESULT(no)])
1250
1251 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1252 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
1253   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1254    AC_MSG_RESULT(yes)],
1255   [AC_MSG_RESULT(no)
1256    AC_MSG_CHECKING([for global timezone variable])
1257    dnl FIXME: we don't want a link check here because that won't work
1258    dnl when cross-compiling.  So instead we make an assumption that
1259    dnl the header file will mention timezone if it exists.
1260    dnl Don't find the win32 function timezone
1261    AC_TRY_COMPILE([#include <time.h>], [void i(){long z2 = 2*timezone;}],
1262      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1263       AC_MSG_RESULT(yes)],
1264      [AC_MSG_RESULT(no)
1265        AC_MSG_CHECKING([for global _timezone variable])
1266        dnl FIXME: As above, don't want link check
1267        AC_TRY_COMPILE([#include <time.h>], [long z2 = _timezone;],
1268          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1269             [Define if your platform has the global _timezone variable.])
1270           AC_MSG_RESULT(yes)],
1271           [AC_MSG_RESULT(no)])])])
1272
1273 AC_FUNC_ALLOCA
1274 AC_FUNC_MMAP
1275
1276 AC_CHECK_PROGS(PERL, perl, false)
1277
1278 SYSDEP_SOURCES=
1279 SIGNAL_HANDLER_AUX=
1280
1281 case "${host}" in
1282  i?86-*-linux*)
1283     SIGNAL_HANDLER=include/i386-signal.h
1284     ;;
1285  sparc*-sun-solaris*)
1286     SIGNAL_HANDLER=include/sparc-signal.h
1287     ;;
1288 # ia64-*)
1289 #    SYSDEP_SOURCES=sysdep/ia64.c
1290 #    test -d sysdep || mkdir sysdep
1291 #    ;;
1292  hppa*-*-linux*)
1293     SIGNAL_HANDLER=include/pa-signal.h
1294     ;;
1295  ia64-*-linux*)
1296     SIGNAL_HANDLER=include/dwarf2-signal.h
1297     ;;
1298  powerpc*-*-linux*)
1299     SIGNAL_HANDLER=include/powerpc-signal.h
1300     ;;
1301  alpha*-*-linux*)
1302     SIGNAL_HANDLER=include/dwarf2-signal.h
1303     ;;
1304  s390*-*-linux*)
1305     SIGNAL_HANDLER=include/s390-signal.h
1306     ;;
1307  x86_64*-*-linux*)
1308     SIGNAL_HANDLER=include/x86_64-signal.h
1309     SIGNAL_HANDLER_AUX=include/i386-signal.h
1310     ;;
1311  sparc*-*-linux*)
1312     SIGNAL_HANDLER=include/dwarf2-signal.h
1313     ;;
1314  sh-*-linux* | sh[[34]]*-*-linux*)
1315     SIGNAL_HANDLER=include/dwarf2-signal.h
1316     ;;
1317  *mingw*)
1318     SIGNAL_HANDLER=include/win32-signal.h
1319     ;;
1320  mips*-*-linux*)
1321     SIGNAL_HANDLER=include/mips-signal.h
1322     ;;
1323  *-*-darwin*)
1324     SIGNAL_HANDLER=include/darwin-signal.h
1325     ;;
1326  *)
1327     SIGNAL_HANDLER=include/default-signal.h
1328     ;;
1329 esac
1330
1331 # If we're using sjlj exceptions, forget what we just learned.
1332 if test "$enable_sjlj_exceptions" = yes; then
1333    SIGNAL_HANDLER=include/default-signal.h
1334    SIGNAL_HANDLER_AUX=
1335 fi
1336
1337 # Define here any compiler flags that you need in order to make backtrace() work.
1338 BACKTRACESPEC=
1339 case "${host}" in
1340  x86_64*-*-linux*|i?86-*)
1341     BACKTRACESPEC=-fno-omit-frame-pointer
1342     ;;
1343 esac
1344 AC_SUBST(BACKTRACESPEC)
1345
1346 AC_SUBST(SYSDEP_SOURCES)
1347
1348 if test -z "$SIGNAL_HANDLER_AUX"; then
1349   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1350 fi
1351
1352 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1353                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1354
1355 if test "${multilib}" = "yes"; then
1356   multilib_arg="--enable-multilib"
1357 else
1358   multilib_arg=
1359 fi
1360
1361
1362
1363 here=`${PWDCMD-pwd}`
1364 AC_SUBST(here)
1365
1366 # We get this from the environment.
1367 AC_SUBST(GCJFLAGS)
1368
1369 AC_OUTPUT(Makefile libgcj.pc libgcj.spec libgcj-test.spec gnu/classpath/Configuration.java gcj/Makefile include/Makefile testsuite/Makefile,
1370 [# Only add multilib support code if we just rebuilt top-level Makefile.
1371 case " $CONFIG_FILES " in
1372  *" Makefile "*)
1373    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1374    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1375    ;;
1376 esac
1377
1378 # Make subdirectories and `.d' files.  Look in both srcdir and
1379 # builddir for the .java files.
1380 h=`${PWDCMD-pwd}`
1381 : > deps.mk
1382 ( (cd $srcdir && find . \( -name '*.java' -o -name '*.cc' -o -name '*.c' \) -print) ;
1383   find . \( -name '*.java' -o -name '*.cc' -o -name '*.c' \) -print) | \
1384    fgrep -v testsuite | \
1385    sed -e 's/\.java/.d/'\;'s/\.cc/.d/'\;'s/\.c/.d/' | \
1386    while read f; do
1387       echo "include $f" >> deps.mk
1388       test -f $f || {
1389          d=`echo $f | sed -e 's,/[[^/]]*$,,'`
1390          if test ! -d $d; then
1391            $libgcj_basedir/../mkinstalldirs $d
1392          fi;
1393          echo > $f
1394       }
1395    done
1396 ],
1397 srcdir=${srcdir}
1398 host=${host}
1399 target=${target}
1400 with_multisubdir=${with_multisubdir}
1401 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1402 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1403 libgcj_basedir=${libgcj_basedir}
1404 CC="${CC}"
1405 CXX="${CXX}"
1406 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1407 )