libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT([GNU OpenMP Runtime Library], 1.0,,[libgomp])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  14    [Specify that runtime libraries should be installed in a compiler-specific directory],
  15    permit yes|no)
  16 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  17
  18 # We would like our source tree to be readonly. However when releases or
  19 # pre-releases are generated, the flex/bison generated files as well as the
  20 # various formats of manuals need to be included along with the rest of the
  21 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  22 # just that.
  23 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  24 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  25    [put copies of generated files in source dir intended for creating source
  26     tarballs for users without texinfo bison or flex.],
  27    permit yes|no)
  28 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  29 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  30
  31
  32 # -------
  33 # -------
  34
  35 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  36 #
  37 # You will slowly go insane if you do not grok the following fact:  when
  38 # building this library, the top-level /target/ becomes the library's /host/.
  39 #
  40 # configure then causes --target to default to --host, exactly like any
  41 # other package using autoconf.  Therefore, 'target' and 'host' will
  42 # always be the same.  This makes sense both for native and cross compilers
  43 # just think about it for a little while.  :-)
  44 #
  45 # Also, if this library is being configured as part of a cross compiler, the
  46 # top-level configure script will pass the "real" host as $with_cross_host.
  47 #
  48 # Do not delete or change the following two lines.  For why, see
  49 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  50 AC_CANONICAL_SYSTEM
  51 target_alias=${target_alias-$host_alias}
  52
  53 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  54 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  55 #  1.9.0:  minimum required version
  56 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  57 #              of other PACKAGE_* variables will, however, and there's nothing
  58 #              we can do about that; they come from AC_INIT).
  59 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  60 #            file in the top srcdir, etc, etc), so stop complaining.
  61 #  no-dist:  we don't want 'dist' and related rules.
  62 #  -Wall:  turns on all automake warnings...
  63 #  -Wno-portability:  ...except this one, since GNU make is required.
  64 #  -Wno-override: ... and this one, since we do want this in testsuite.
  65 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  66 AM_ENABLE_MULTILIB(, ..)
  67
  68 # Calculate toolexeclibdir
  69 # Also toolexecdir, though it's only used in toolexeclibdir
  70 case ${enable_version_specific_runtime_libs} in
  71   yes)
  72     # Need the gcc compiler version to know where to install libraries
  73     # and header files if --enable-version-specific-runtime-libs option
  74     # is selected.
  75     toolexecdir='$(libdir)/gcc/$(target_alias)'
  76     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  77     ;;
  78   no)
  79     if test -n "$with_cross_host" &&
  80        test x"$with_cross_host" != x"no"; then
  81       # Install a library built with a cross compiler in tooldir, not libdir.
  82       toolexecdir='$(exec_prefix)/$(target_alias)'
  83       toolexeclibdir='$(toolexecdir)/lib'
  84     else
  85       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  86       toolexeclibdir='$(libdir)'
  87     fi
  88     multi_os_directory=`$CC -print-multi-os-directory`
  89     case $multi_os_directory in
  90       .) ;; # Avoid trailing /.
  91       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  92     esac
  93     ;;
  94 esac
  95 AC_SUBST(toolexecdir)
  96 AC_SUBST(toolexeclibdir)
  97
  98 # Check the compiler.
  99 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 100 # We must force CC to /not/ be precious variables; otherwise
 101 # the wrong, non-multilib-adjusted value will be used in multilibs.
 102 # As a side effect, we have to subst CFLAGS ourselves.
 103
 104 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 105 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 106 AC_PROG_CC
 107 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108
 109 AC_SUBST(CFLAGS)
 110
 111 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 112 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 113 # in both places for now and restore CFLAGS at the end of config.
 114 save_CFLAGS="$CFLAGS"
 115
 116 # Add -Wall -Werror if we are using GCC.
 117 if test "x$GCC" = "xyes"; then
 118   XCFLAGS="$XCFLAGS -Wall -Werror"
 119 fi
 120
 121 # Find other programs we need.
 122 AC_CHECK_TOOL(AR, ar)
 123 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 124 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 125 AC_PROG_MAKE_SET
 126 AC_PROG_INSTALL
 127
 128 # See if makeinfo has been installed and is modern enough
 129 # that we can use it.
 130 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 131                    [GNU texinfo.* \([0-9][0-9.]*\)],
 132                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 133 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 134
 135
 136 # Configure libtool
 137 AM_PROG_LIBTOOL
 138 AC_SUBST(enable_shared)
 139 AC_SUBST(enable_static)
 140
 141 AM_MAINTAINER_MODE
 142
 143 # We need gfortran to compile parts of the library
 144 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 145 #AC_PROG_FC(gfortran)
 146 case `echo $GFORTRAN` in
 147   -* | no* )
 148     FC=no ;;
 149   *)
 150     set dummy $GFORTRAN; ac_word=$2
 151     if test -x "$ac_word"; then
 152       FC="$GFORTRAN"
 153     else
 154       FC=no
 155     fi ;;
 156 esac
 157 AC_PROG_FC(gfortran)
 158 FCFLAGS="$FCFLAGS -Wall"
 159
 160 # For libtool versioning info, format is CURRENT:REVISION:AGE
 161 libtool_VERSION=1:0:0
 162 AC_SUBST(libtool_VERSION)
 163
 164 # Check header files.
 165 AC_STDC_HEADERS
 166 AC_HEADER_TIME
 167 ACX_HEADER_STRING
 168 AC_CHECK_HEADERS(unistd.h semaphore.h sys/loadavg.h sys/time.h sys/time.h)
 169
 170 GCC_HEADER_STDINT(gstdint.h)
 171
 172 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 173 # In case the pthread.h system header is not found, this test will fail.
 174 XPCFLAGS=""
 175 CFLAGS="$CFLAGS -pthread"
 176 AC_LINK_IFELSE(
 177  [AC_LANG_PROGRAM(
 178   [#include <pthread.h>
 179    void *g(void *d) { return NULL; }],
 180   [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 181  [XPCFLAGS=" -Wc,-pthread"],
 182  [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 183   AC_LINK_IFELSE(
 184    [AC_LANG_PROGRAM(
 185     [#include <pthread.h>
 186      void *g(void *d) { return NULL; }],
 187     [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 188    [],
 189    [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 190
 191 # Check for functions needed.
 192 AC_CHECK_FUNCS(getloadavg clock_gettime strtoull)
 193
 194 # Check for broken semaphore implementation on darwin.
 195 # sem_init returns: sem_init error: Function not implemented.
 196 case "$host" in
 197   *-darwin*)
 198     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 199         Define if the POSIX Semaphores do not work on your system.)
 200     ;;
 201 esac
 202
 203 GCC_LINUX_FUTEX(:)
 204
 205 # Check for pthread_{,attr_}[sg]etaffinity_np.
 206 AC_LINK_IFELSE(
 207  [AC_LANG_PROGRAM(
 208   [#define _GNU_SOURCE
 209    #include <pthread.h>],
 210   [cpu_set_t cpuset;
 211    pthread_attr_t attr;
 212    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 213    if (CPU_ISSET (0, &cpuset))
 214      CPU_SET (1, &cpuset);
 215    else
 216      CPU_ZERO (&cpuset);
 217    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 218    pthread_attr_init (&attr);
 219    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 220    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 221   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 222 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 223
 224 # At least for glibc, clock_gettime is in librt.  But don't pull that
 225 # in if it still doesn't give us the function we want.
 226 if test $ac_cv_func_clock_gettime = no; then
 227   AC_CHECK_LIB(rt, clock_gettime,
 228     [LIBS="-lrt $LIBS"
 229      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 230                [Define to 1 if you have the `clock_gettime' function.])])
 231 fi
 232
 233 # See if we support thread-local storage.
 234 GCC_CHECK_TLS
 235
 236 # See what sort of export controls are availible.
 237 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 238 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 239 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 240 LIBGOMP_ENABLE_SYMVERS
 241
 242 if test $enable_symvers = gnu; then
 243   AC_DEFINE(LIBGOMP_GNU_SYMBOL_VERSIONING, 1,
 244             [Define to 1 if GNU symbol versioning is used for libgomp.])
 245 fi
 246
 247 # Get target configury.
 248 . ${srcdir}/configure.tgt
 249 CFLAGS="$save_CFLAGS $XCFLAGS"
 250
 251 # Check for __sync_val_compare_and_swap, but only after the target has
 252 # had a chance to set XCFLAGS.
 253 LIBGOMP_CHECK_SYNC_BUILTINS
 254
 255 XCFLAGS="$XCFLAGS$XPCFLAGS"
 256
 257 AC_SUBST(config_path)
 258 AC_SUBST(XCFLAGS)
 259 AC_SUBST(XLDFLAGS)
 260
 261 # Cleanup and exit.
 262 CFLAGS="$save_CFLAGS"
 263 AC_CACHE_SAVE
 264
 265 if test ${multilib} = yes; then
 266   multilib_arg="--enable-multilib"
 267 else
 268   multilib_arg=
 269 fi
 270
 271 # Set up the set of libraries that we need to link against for libgomp.
 272 # Note that the GOMP_SELF_SPEC in gcc.c will force -pthread for -fopenmp,
 273 # which will force linkage against -lpthread (or equivalent for the system).
 274 # That's not 100% ideal, but about the best we can do easily.
 275 if test $enable_shared = yes; then
 276   link_gomp="-lgomp %{static: $LIBS}"
 277 else
 278   link_gomp="-lgomp $LIBS"
 279 fi
 280 AC_SUBST(link_gomp)
 281
 282 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 283
 284 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 285 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 286 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 287 # need to copy this macro to our acinclude.m4.
 288 save_CFLAGS="$CFLAGS"
 289 for i in $config_path; do
 290   if test -f $srcdir/config/$i/omp-lock.h; then
 291     CFLAGS="$CFLAGS -include confdefs.h -include $srcdir/config/$i/omp-lock.h"
 292     break
 293   fi
 294 done
 295
 296 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 297   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 298 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 299 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 300 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 301 _AC_COMPUTE_INT([sizeof (omp_lock_25_t)], [OMP_LOCK_25_SIZE],,
 302   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_25_t)])])
 303 _AC_COMPUTE_INT([__alignof (omp_lock_25_t)], [OMP_LOCK_25_ALIGN])
 304 _AC_COMPUTE_INT([sizeof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_SIZE])
 305 _AC_COMPUTE_INT([__alignof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_ALIGN])
 306
 307 # If the lock fits in an integer, then arrange for Fortran to use that
 308 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 309 # Except that we don't have a way at present to multi-lib the installed
 310 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 311 # actual target.
 312 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 313 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 314 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 315   OMP_LOCK_KIND=8
 316 fi
 317 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 318   OMP_NEST_LOCK_KIND=8
 319 fi
 320 OMP_LOCK_25_KIND=$OMP_LOCK_25_SIZE
 321 OMP_NEST_LOCK_25_KIND=$OMP_NEST_LOCK_25_SIZE
 322 if test $OMP_LOCK_25_SIZE -gt 8 || test $OMP_LOCK_25_ALIGN -gt $OMP_LOCK_25_SIZE; then
 323   OMP_LOCK_25_KIND=8
 324 fi
 325 if test $OMP_NEST_LOCK_25_SIZE -gt 8 || test $OMP_NEST_LOCK_25_ALIGN -gt $OMP_NEST_LOCK_25_SIZE; then
 326   OMP_NEST_LOCK_25_KIND=8
 327 fi
 328
 329 AC_SUBST(OMP_LOCK_SIZE)
 330 AC_SUBST(OMP_LOCK_ALIGN)
 331 AC_SUBST(OMP_NEST_LOCK_SIZE)
 332 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 333 AC_SUBST(OMP_LOCK_KIND)
 334 AC_SUBST(OMP_NEST_LOCK_KIND)
 335 AC_SUBST(OMP_LOCK_25_SIZE)
 336 AC_SUBST(OMP_LOCK_25_ALIGN)
 337 AC_SUBST(OMP_NEST_LOCK_25_SIZE)
 338 AC_SUBST(OMP_NEST_LOCK_25_ALIGN)
 339 AC_SUBST(OMP_LOCK_25_KIND)
 340 AC_SUBST(OMP_NEST_LOCK_25_KIND)
 341 CFLAGS="$save_CFLAGS"
 342
 343 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 344 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 345 AC_OUTPUT