gcc/ada/sem_scil.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ S C I L                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2009-2023, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Einfo;          use Einfo;
  27 with Einfo.Entities; use Einfo.Entities;
  28 with Einfo.Utils;    use Einfo.Utils;
  29 with Nlists;         use Nlists;
  30 with Rtsfind;        use Rtsfind;
  31 with Sem_Aux;        use Sem_Aux;
  32 with Sinfo;          use Sinfo;
  33 with Sinfo.Nodes;    use Sinfo.Nodes;
  34 with Stand;          use Stand;
  35 with SCIL_LL;        use SCIL_LL;
  36
  37 package body Sem_SCIL is
  38
  39    ---------------------
  40    -- Check_SCIL_Node --
  41    ---------------------
  42
  43    function Check_SCIL_Node (N : Node_Id) return Traverse_Result is
  44       SCIL_Node : constant Node_Id := Get_SCIL_Node (N);
  45       Ctrl_Tag  : Node_Id;
  46       Ctrl_Typ  : Entity_Id;
  47
  48    begin
  49       --  For nodes that do not have SCIL node continue traversing the tree
  50
  51       if No (SCIL_Node) then
  52          return OK;
  53       end if;
  54
  55       case Nkind (SCIL_Node) is
  56          when N_SCIL_Dispatch_Table_Tag_Init =>
  57             pragma Assert (Nkind (N) = N_Object_Declaration);
  58             null;
  59
  60          when N_SCIL_Dispatching_Call =>
  61             Ctrl_Tag := SCIL_Controlling_Tag (SCIL_Node);
  62
  63             --  Parent of SCIL dispatching call nodes MUST be a subprogram call
  64
  65             if Nkind (N) not in N_Subprogram_Call then
  66                raise Program_Error;
  67
  68             --  In simple cases the controlling tag is the tag of the
  69             --  controlling argument (i.e. Obj.Tag).
  70
  71             elsif Nkind (Ctrl_Tag) = N_Selected_Component then
  72                Ctrl_Typ := Etype (Ctrl_Tag);
  73
  74                --  Interface types are unsupported
  75
  76                if Is_Interface (Ctrl_Typ)
  77                  or else Is_RTE (Ctrl_Typ, RE_Interface_Tag)
  78                then
  79                   null;
  80
  81                else
  82                   pragma Assert (Is_RTE (Ctrl_Typ, RE_Tag));
  83                   null;
  84                end if;
  85
  86             --  When the controlling tag of a dispatching call is an identifier
  87             --  the SCIL_Controlling_Tag attribute references the corresponding
  88             --  object or parameter declaration. Interface types are still
  89             --  unsupported.
  90
  91             elsif Nkind (Ctrl_Tag) in N_Object_Renaming_Declaration
  92                                     | N_Object_Declaration
  93                                     | N_Parameter_Specification
  94             then
  95                Ctrl_Typ := Etype (Defining_Identifier (Ctrl_Tag));
  96
  97                --  Interface types are unsupported.
  98
  99                if Is_Interface (Ctrl_Typ)
 100                  or else Is_RTE (Ctrl_Typ, RE_Interface_Tag)
 101                  or else (Is_Access_Type (Ctrl_Typ)
 102                            and then
 103                              Is_Interface
 104                                (Available_View
 105                                  (Base_Type (Designated_Type (Ctrl_Typ)))))
 106                then
 107                   null;
 108
 109                else
 110                   pragma Assert
 111                     (Is_RTE (Ctrl_Typ, RE_Tag)
 112                        or else
 113                          (Is_Access_Type (Ctrl_Typ)
 114                             and then
 115                           Is_RTE
 116                             (Available_View
 117                                (Base_Type (Designated_Type (Ctrl_Typ))),
 118                              RE_Tag)));
 119                   null;
 120                end if;
 121
 122             --  Interface types are unsupported
 123
 124             elsif Is_Interface (Etype (Ctrl_Tag)) then
 125                null;
 126
 127             else
 128                pragma Assert (False);
 129                raise Program_Error;
 130             end if;
 131
 132             return Skip;
 133
 134          when N_SCIL_Membership_Test =>
 135
 136             --  Check contents of the boolean expression associated with the
 137             --  membership test.
 138
 139             pragma Assert
 140               (Nkind (N) in
 141                  N_Identifier | N_And_Then | N_Or_Else |
 142                  N_Expression_With_Actions | N_Function_Call
 143               and then Etype (N) = Standard_Boolean);
 144
 145             --  Check the entity identifier of the associated tagged type (that
 146             --  is, in testing for membership in T'Class, the entity id of the
 147             --  specific type T).
 148
 149             --  Note: When the SCIL node is generated the private and full-view
 150             --    of the tagged types may have been swapped and hence the node
 151             --    referenced by attribute SCIL_Entity may be the private view.
 152             --    Therefore, in order to uniformly locate the full-view we use
 153             --    attribute Underlying_Type.
 154
 155             pragma Assert
 156               (Is_Tagged_Type (Underlying_Type (SCIL_Entity (SCIL_Node))));
 157
 158             --  Interface types are unsupported
 159
 160             pragma Assert
 161               (not Is_Interface (Underlying_Type (SCIL_Entity (SCIL_Node))));
 162
 163             --  Check the decoration of the expression that denotes the tag
 164             --  value being tested
 165
 166             Ctrl_Tag := SCIL_Tag_Value (SCIL_Node);
 167
 168             case Nkind (Ctrl_Tag) is
 169
 170                --  For class-wide membership tests the SCIL tag value is the
 171                --  tag of the tested object (i.e. Obj.Tag).
 172
 173                when N_Selected_Component =>
 174                   pragma Assert (Is_RTE (Etype (Ctrl_Tag), RE_Tag));
 175                   null;
 176
 177                when others =>
 178                   pragma Assert (False);
 179                   null;
 180             end case;
 181
 182             return Skip;
 183
 184          when others =>
 185             pragma Assert (False);
 186             raise Program_Error;
 187       end case;
 188
 189       return Skip;
 190    end Check_SCIL_Node;
 191
 192    -------------------------
 193    -- First_Non_SCIL_Node --
 194    -------------------------
 195
 196    function First_Non_SCIL_Node (L : List_Id) return Node_Id is
 197       N : Node_Id;
 198
 199    begin
 200       N := First (L);
 201       while Nkind (N) in N_SCIL_Node loop
 202          Next (N);
 203       end loop;
 204
 205       return N;
 206    end First_Non_SCIL_Node;
 207
 208    ------------------------
 209    -- Next_Non_SCIL_Node --
 210    ------------------------
 211
 212    function Next_Non_SCIL_Node (N : Node_Id) return Node_Id is
 213       Aux_N : Node_Id;
 214
 215    begin
 216       Aux_N := Next (N);
 217       while Nkind (Aux_N) in N_SCIL_Node loop
 218          Next (Aux_N);
 219       end loop;
 220
 221       return Aux_N;
 222    end Next_Non_SCIL_Node;
 223
 224 end Sem_SCIL;