gcc/ada/libgnat/a-cbprqu.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                  ADA.CONTAINERS.BOUNDED_PRIORITY_QUEUES                  --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2011-2023, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- This unit was originally developed by Matthew J Heaney.                  --
  32 ------------------------------------------------------------------------------
  33
  34 with System;
  35
  36 with Ada.Containers.Synchronized_Queue_Interfaces;
  37 with Ada.Containers.Bounded_Doubly_Linked_Lists;
  38
  39 generic
  40    with package Queue_Interfaces is
  41      new Ada.Containers.Synchronized_Queue_Interfaces (<>);
  42
  43    type Queue_Priority is private;
  44
  45    with function Get_Priority
  46      (Element : Queue_Interfaces.Element_Type) return Queue_Priority is <>;
  47
  48    with function Before
  49      (Left, Right : Queue_Priority) return Boolean is <>;
  50
  51    Default_Capacity : Count_Type;
  52    Default_Ceiling  : System.Any_Priority := System.Priority'Last;
  53
  54 package Ada.Containers.Bounded_Priority_Queues with
  55   SPARK_Mode => Off
  56 is
  57    pragma Annotate (CodePeer, Skip_Analysis);
  58    pragma Preelaborate;
  59
  60    package Implementation is
  61
  62       --  All identifiers in this unit are implementation defined
  63
  64       pragma Implementation_Defined;
  65
  66       type List_Type (Capacity : Count_Type) is tagged limited private;
  67
  68       procedure Enqueue
  69         (List     : in out List_Type;
  70          New_Item : Queue_Interfaces.Element_Type);
  71
  72       procedure Dequeue
  73         (List    : in out List_Type;
  74          Element : out Queue_Interfaces.Element_Type);
  75
  76       procedure Dequeue
  77         (List     : in out List_Type;
  78          At_Least : Queue_Priority;
  79          Element  : in out Queue_Interfaces.Element_Type;
  80          Success  : out Boolean);
  81
  82       function First_Element
  83         (List : List_Type) return Queue_Interfaces.Element_Type;
  84
  85       function Length (List : List_Type) return Count_Type;
  86
  87       function Max_Length (List : List_Type) return Count_Type;
  88
  89    private
  90
  91       --  We need a better data structure here, such as a proper heap.  ???
  92
  93       pragma Warnings (Off);
  94       --  Otherwise, we get warnings for the uninitialized variable in Insert
  95       --  in Ada.Containers.Bounded_Doubly_Linked_Lists.
  96       package List_Types is new Bounded_Doubly_Linked_Lists
  97         (Element_Type => Queue_Interfaces.Element_Type,
  98          "="          => Queue_Interfaces."=");
  99       pragma Warnings (On);
 100
 101       type List_Type (Capacity : Count_Type) is tagged limited record
 102          Container  : List_Types.List (Capacity);
 103          Max_Length : Count_Type := 0;
 104       end record;
 105
 106    end Implementation;
 107
 108    protected type Queue
 109      (Capacity : Count_Type := Default_Capacity;
 110       Ceiling  : System.Any_Priority := Default_Ceiling)
 111    with
 112      Priority => Ceiling
 113    is new Queue_Interfaces.Queue with
 114
 115       overriding entry Enqueue (New_Item : Queue_Interfaces.Element_Type);
 116
 117       overriding entry Dequeue (Element : out Queue_Interfaces.Element_Type);
 118
 119       --  The priority queue operation Dequeue_Only_High_Priority had been a
 120       --  protected entry in early drafts of AI05-0159, but it was discovered
 121       --  that that operation as specified was not in fact implementable. The
 122       --  operation was changed from an entry to a protected procedure per the
 123       --  ARG meeting in Edinburgh (June 2011), with a different signature and
 124       --  semantics.
 125
 126       procedure Dequeue_Only_High_Priority
 127         (At_Least : Queue_Priority;
 128          Element  : in out Queue_Interfaces.Element_Type;
 129          Success  : out Boolean);
 130
 131       overriding function Current_Use return Count_Type;
 132
 133       overriding function Peak_Use return Count_Type;
 134
 135    private
 136       List : Implementation.List_Type (Capacity);
 137    end Queue;
 138
 139 end Ada.Containers.Bounded_Priority_Queues;