gcc/ada/comperr.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              C O M P E R R                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2023, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by AdaCore.                         --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package contains routines called when a fatal internal compiler error
  27 --  is detected. Calls to these routines cause termination of the current
  28 --  compilation with appropriate error output.
  29
  30 with Atree;          use Atree;
  31 with Debug;          use Debug;
  32 with Errout;         use Errout;
  33 with Gnatvsn;        use Gnatvsn;
  34 with Lib;            use Lib;
  35 with Namet;          use Namet;
  36 with Opt;            use Opt;
  37 with Osint;          use Osint;
  38 with Output;         use Output;
  39 with Sinfo;          use Sinfo;
  40 with Sinfo.Nodes;    use Sinfo.Nodes;
  41 with Sinput;         use Sinput;
  42 with Sprint;         use Sprint;
  43 with Sdefault;       use Sdefault;
  44 with Treepr;         use Treepr;
  45 with Types;          use Types;
  46
  47 with Ada.Exceptions; use Ada.Exceptions;
  48
  49 with System.OS_Lib;     use System.OS_Lib;
  50 with System.Soft_Links; use System.Soft_Links;
  51
  52 package body Comperr is
  53
  54    ----------------
  55    -- Local Data --
  56    ----------------
  57
  58    Abort_In_Progress : Boolean := False;
  59    --  Used to prevent runaway recursion if something segfaults
  60    --  while processing a previous abort.
  61
  62    -----------------------
  63    -- Local Subprograms --
  64    -----------------------
  65
  66    procedure Repeat_Char (Char : Character; Col : Nat; After : Character);
  67    --  Output Char until current column is at or past Col, and then output
  68    --  the character given by After (if column is already past Col on entry,
  69    --  then the effect is simply to output the After character).
  70
  71    --------------------
  72    -- Compiler_Abort --
  73    --------------------
  74
  75    procedure Compiler_Abort
  76      (X            : String;
  77       Fallback_Loc : String  := "";
  78       From_GCC     : Boolean := False)
  79    is
  80       --  The procedures below output a "bug box" with information about
  81       --  the cause of the compiler abort and about the preferred method
  82       --  of reporting bugs. The default is a bug box appropriate for
  83       --  the FSF version of GNAT, but there are specializations for
  84       --  the GNATPRO and Public releases by AdaCore.
  85
  86       XF : constant Positive := X'First;
  87       --  Start index, usually 1, but we won't assume this
  88
  89       procedure End_Line;
  90       --  Add blanks up to column 76, and then a final vertical bar
  91
  92       --------------
  93       -- End_Line --
  94       --------------
  95
  96       procedure End_Line is
  97       begin
  98          Repeat_Char (' ', 76, '|');
  99          Write_Eol;
 100       end End_Line;
 101
 102       Is_GPL_Version : constant Boolean := Gnatvsn.Build_Type = GPL;
 103       Is_FSF_Version : constant Boolean := Gnatvsn.Build_Type = FSF;
 104
 105    --  Start of processing for Compiler_Abort
 106
 107    begin
 108       Cancel_Special_Output;
 109
 110       --  Prevent recursion through Compiler_Abort, e.g. via SIGSEGV
 111
 112       if Abort_In_Progress then
 113          Exit_Program (E_Abort);
 114       end if;
 115
 116       Abort_In_Progress := True;
 117
 118       --  Generate a "standard" error message instead of a bug box in case
 119       --  of CodePeer rather than generating a bug box, friendlier.
 120
 121       --  Note that the call to Error_Msg_N below sets Serious_Errors_Detected
 122       --  to 1, so we use the regular mechanism below in order to display a
 123       --  "compilation abandoned" message and exit, so we still know we have
 124       --  this case (and -gnatdk can still be used to get the bug box).
 125
 126       if CodePeer_Mode
 127         and then Serious_Errors_Detected = 0
 128         and then not Debug_Flag_K
 129         and then Sloc (Current_Error_Node) > No_Location
 130       then
 131          Error_Msg_N ("cannot generate 'S'C'I'L", Current_Error_Node);
 132       end if;
 133
 134       --  If we are in CodePeer mode, we must also delete SCIL files
 135
 136       if CodePeer_Mode then
 137          Delete_SCIL_Files;
 138       end if;
 139
 140       --  If any errors have already occurred, then we guess that the abort
 141       --  may well be caused by previous errors, and we don't make too much
 142       --  fuss about it, since we want to let programmer fix the errors first.
 143
 144       --  Debug flag K disables this behavior (useful for debugging)
 145
 146       if Serious_Errors_Detected /= 0 and then not Debug_Flag_K then
 147          Errout.Finalize (Last_Call => True);
 148          Errout.Output_Messages;
 149
 150          Set_Standard_Error;
 151          Write_Str ("compilation abandoned due to previous error");
 152          Write_Eol;
 153
 154          Set_Standard_Output;
 155          Source_Dump;
 156          Tree_Dump;
 157          Exit_Program (E_Errors);
 158
 159       --  Otherwise give message with details of the abort
 160
 161       else
 162          Set_Standard_Error;
 163
 164          --  Generate header for bug box
 165
 166          Write_Char ('+');
 167          Repeat_Char ('=', 29, 'G');
 168          Write_Str ("NAT BUG DETECTED");
 169          Repeat_Char ('=', 76, '+');
 170          Write_Eol;
 171
 172          --  Output GNAT version identification
 173
 174          Write_Str ("| ");
 175          Write_Str (Gnat_Version_String);
 176          Write_Str (" (");
 177
 178          --  Output target name, deleting junk final reverse slash
 179
 180          if Target_Name (Target_Name'Last) in '/' | '\' then
 181             Write_Str (Target_Name (1 .. Target_Name'Last - 1));
 182          else
 183             Write_Str (Target_Name.all);
 184          end if;
 185
 186          --  Output identification of error
 187
 188          Write_Str (") ");
 189
 190          if X'Length + Column > 76 then
 191             if From_GCC then
 192                Write_Str ("GCC error:");
 193             end if;
 194
 195             End_Line;
 196
 197             Write_Str ("| ");
 198          end if;
 199
 200          if X'Length > 70 then
 201             declare
 202                Last_Blank : Integer := 70;
 203
 204             begin
 205                for P in 39 .. 68 loop
 206                   if X (XF + P) = ' ' then
 207                      Last_Blank := P;
 208                   end if;
 209                end loop;
 210
 211                Write_Str (X (XF .. XF - 1 + Last_Blank));
 212                End_Line;
 213                Write_Str ("|    ");
 214                Write_Str (X (XF + Last_Blank .. X'Last));
 215             end;
 216          else
 217             Write_Str (X);
 218          end if;
 219
 220          if not From_GCC then
 221
 222             --  For exception case, get exception message from the TSD. Note
 223             --  that it would be neater and cleaner to pass the exception
 224             --  message (obtained from Exception_Message) as a parameter to
 225             --  Compiler_Abort, but we can't do this quite yet since it would
 226             --  cause bootstrap path problems for 3.10 to 3.11.
 227
 228             Write_Char (' ');
 229             Write_Str (Exception_Message (Get_Current_Excep.all.all));
 230          end if;
 231
 232          End_Line;
 233
 234          --  Output source location information
 235
 236          if Sloc (Current_Error_Node) <= No_Location then
 237             if Fallback_Loc'Length > 0 then
 238                Write_Str ("| Error detected around ");
 239                Write_Str (Fallback_Loc);
 240             else
 241                Write_Str ("| No source file position information available");
 242             end if;
 243
 244             End_Line;
 245
 246          else
 247             Write_Str ("| Error detected at ");
 248             Write_Location (Sloc (Current_Error_Node));
 249             End_Line;
 250          end if;
 251
 252          Write_Str ("| Compiling ");
 253          Write_Str (Get_First_Main_File_Name);
 254          End_Line;
 255
 256          --  There are two cases now. If the file gnat_bug.box exists,
 257          --  we use the contents of this file at this point.
 258
 259          declare
 260             FD  : File_Descriptor;
 261             Lo  : Source_Ptr;
 262             Hi  : Source_Ptr;
 263             Src : Source_Buffer_Ptr;
 264
 265          begin
 266             Namet.Unlock;
 267             Name_Buffer (1 .. 12) := "gnat_bug.box";
 268             Name_Len := 12;
 269             Read_Source_File (Name_Enter, 0, Hi, Src, FD);
 270
 271             --  If we get a Src file, we use it
 272
 273             if not Null_Source_Buffer_Ptr (Src) then
 274                Lo := 0;
 275
 276                Outer : while Lo < Hi loop
 277                   Write_Str ("| ");
 278
 279                   Inner : loop
 280                      exit Inner when Src (Lo) = ASCII.CR
 281                        or else Src (Lo) = ASCII.LF;
 282                      Write_Char (Src (Lo));
 283                      Lo := Lo + 1;
 284                   end loop Inner;
 285
 286                   End_Line;
 287
 288                   while Lo <= Hi
 289                     and then (Src (Lo) = ASCII.CR
 290                                 or else Src (Lo) = ASCII.LF)
 291                   loop
 292                      Lo := Lo + 1;
 293                   end loop;
 294                end loop Outer;
 295
 296             --  Otherwise we use the standard fixed text
 297
 298             else
 299                if Is_FSF_Version then
 300                   Write_Str
 301                     ("| Please submit a bug report; see" &
 302                      " https://gcc.gnu.org/bugs/ .");
 303                   End_Line;
 304
 305                elsif Is_GPL_Version then
 306
 307                   Write_Str
 308                     ("| Please submit a bug report by email " &
 309                      "to report@adacore.com.");
 310                   End_Line;
 311
 312                   Write_Str
 313                     ("| GAP members can alternatively use GNAT Tracker:");
 314                   End_Line;
 315
 316                   Write_Str
 317                     ("| https://www.adacore.com/login?mode=gap " &
 318                      "section 'Create New Ticket'.");
 319                   End_Line;
 320
 321                   Write_Str
 322                     ("| See gnatinfo.txt for full info on procedure " &
 323                      "for submitting bugs.");
 324                   End_Line;
 325
 326                else
 327                   Write_Str
 328                     ("| Please submit a bug report using GNAT Tracker:");
 329                   End_Line;
 330
 331                   Write_Str
 332                     ("| https://www.adacore.com/login " &
 333                      "section 'Create New Ticket'.");
 334                   End_Line;
 335
 336                   Write_Str
 337                     ("| Or submit a bug report by email " &
 338                      "to report@adacore.com");
 339                   End_Line;
 340
 341                   Write_Str
 342                     ("| and include your customer number #nnn " &
 343                      "in the subject line.");
 344                   End_Line;
 345                end if;
 346
 347                Write_Str
 348                  ("| Use a subject line meaningful to you" &
 349                   " and us to track the bug.");
 350                End_Line;
 351
 352                Write_Str
 353                  ("| Include the entire contents of this bug " &
 354                   "box in the report.");
 355                End_Line;
 356
 357                Write_Str
 358                  ("| Include the exact command that you entered.");
 359                End_Line;
 360
 361                Write_Str
 362                  ("| Also include sources listed below.");
 363                End_Line;
 364
 365                if not Is_FSF_Version then
 366                   Write_Str
 367                     ("| Use plain ASCII or MIME attachment(s).");
 368                   End_Line;
 369                end if;
 370             end if;
 371          end;
 372
 373          --  Complete output of bug box
 374
 375          Write_Char ('+');
 376          Repeat_Char ('=', 76, '+');
 377          Write_Eol;
 378
 379          if Debug_Flag_3 then
 380             Write_Eol;
 381             Write_Eol;
 382             Print_Tree_Node (Current_Error_Node);
 383             Write_Eol;
 384          end if;
 385
 386          Write_Eol;
 387
 388          Write_Line ("Please include these source files with error report");
 389          Write_Line ("Note that list may not be accurate in some cases, ");
 390          Write_Line ("so please double check that the problem can still ");
 391          Write_Line ("be reproduced with the set of files listed.");
 392          Write_Line ("Consider also -gnatd.n switch (see debug.adb).");
 393          Write_Eol;
 394
 395          begin
 396             Dump_Source_File_Names;
 397
 398          --  If we blow up trying to print the list of file names, just output
 399          --  informative msg and continue.
 400
 401          exception
 402             when others =>
 403                Write_Str ("list may be incomplete");
 404          end;
 405
 406          Write_Eol;
 407          Set_Standard_Output;
 408
 409          Tree_Dump;
 410          Sinput.Unlock; -- so Source_Dump can modify it
 411          Source_Dump;
 412          raise Unrecoverable_Error;
 413       end if;
 414    end Compiler_Abort;
 415
 416    -----------------------
 417    -- Delete_SCIL_Files --
 418    -----------------------
 419
 420    procedure Delete_SCIL_Files is
 421       Main      : Node_Id;
 422       Unit_Name : Node_Id;
 423
 424       Success : Boolean;
 425       pragma Warnings (Off, "modified by call");
 426
 427       procedure Decode_Name_Buffer;
 428       --  Replace "__" by "." in Name_Buffer, and adjust Name_Len accordingly
 429
 430       ------------------------
 431       -- Decode_Name_Buffer --
 432       ------------------------
 433
 434       procedure Decode_Name_Buffer is
 435          J : Natural;
 436          K : Natural;
 437
 438       begin
 439          J := 1;
 440          K := 0;
 441          while J <= Name_Len loop
 442             K := K + 1;
 443
 444             if J < Name_Len
 445               and then Name_Buffer (J) = '_'
 446               and then Name_Buffer (J + 1) = '_'
 447             then
 448                Name_Buffer (K) := '.';
 449                J := J + 1;
 450             else
 451                Name_Buffer (K) := Name_Buffer (J);
 452             end if;
 453
 454             J := J + 1;
 455          end loop;
 456
 457          Name_Len := K;
 458       end Decode_Name_Buffer;
 459
 460    --  Start of processing for Delete_SCIL_Files
 461
 462    begin
 463       --  If parsing was not successful, no Main_Unit is available, so return
 464       --  immediately.
 465
 466       if Main_Source_File <= No_Source_File then
 467          return;
 468       end if;
 469
 470       --  Retrieve unit name, and remove old versions of SCIL/<unit>.scil and
 471       --  SCIL/<unit>__body.scil, ditto for .scilx files.
 472
 473       Main := Unit (Cunit (Main_Unit));
 474
 475       case Nkind (Main) is
 476          when N_Package_Declaration
 477             | N_Subprogram_Body
 478             | N_Subprogram_Declaration
 479             | N_Subprogram_Renaming_Declaration
 480          =>
 481             Unit_Name := Defining_Unit_Name (Specification (Main));
 482
 483          when N_Package_Body =>
 484             Unit_Name := Corresponding_Spec (Main);
 485
 486          when N_Package_Instantiation
 487             | N_Package_Renaming_Declaration
 488          =>
 489             Unit_Name := Defining_Unit_Name (Main);
 490
 491          --  No SCIL file generated for generic unit declarations
 492
 493          when N_Generic_Declaration
 494             | N_Generic_Renaming_Declaration
 495          =>
 496             return;
 497
 498          --  Should never happen, but can be ignored in production
 499
 500          when others =>
 501             pragma Assert (False);
 502             return;
 503       end case;
 504
 505       case Nkind (Unit_Name) is
 506          when N_Defining_Identifier =>
 507             Get_Name_String (Chars (Unit_Name));
 508
 509          when N_Defining_Program_Unit_Name =>
 510             Get_Name_String (Chars (Defining_Identifier (Unit_Name)));
 511             Decode_Name_Buffer;
 512
 513          --  Should never happen, but can be ignored in production
 514
 515          when others =>
 516             pragma Assert (False);
 517             return;
 518       end case;
 519
 520       Delete_File
 521         ("SCIL/" & Name_Buffer (1 .. Name_Len) & ".scil", Success);
 522       Delete_File
 523         ("SCIL/" & Name_Buffer (1 .. Name_Len) & ".scilx", Success);
 524       Delete_File
 525         ("SCIL/" & Name_Buffer (1 .. Name_Len) & "__body.scil", Success);
 526       Delete_File
 527         ("SCIL/" & Name_Buffer (1 .. Name_Len) & "__body.scilx", Success);
 528    end Delete_SCIL_Files;
 529
 530    -----------------
 531    -- Repeat_Char --
 532    -----------------
 533
 534    procedure Repeat_Char (Char : Character; Col : Nat; After : Character) is
 535    begin
 536       while Column < Col loop
 537          Write_Char (Char);
 538       end loop;
 539
 540       Write_Char (After);
 541    end Repeat_Char;
 542
 543 end Comperr;