main/gcc/ada/sem_aux.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ A U X                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- As a special exception,  if other files  instantiate  generics from this --
  22 -- unit, or you link  this unit with other files  to produce an executable, --
  23 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  24 -- covered  by the  GNU  General  Public  License.  This exception does not --
  25 -- however invalidate  any other reasons why  the executable file  might be --
  26 -- covered by the  GNU Public License.                                      --
  27 --                                                                          --
  28 -- GNAT was originally developed  by the GNAT team at  New York University. --
  29 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  30 --                                                                          --
  31 ------------------------------------------------------------------------------
  32
  33 --  Package containing utility procedures used throughout the compiler,
  34 --  and also by ASIS so dependencies are limited to ASIS included packages.
  35
  36 --  Historical note. Many of the routines here were originally in Einfo, but
  37 --  Einfo is supposed to be a relatively low level package dealing with the
  38 --  content of entities in the tree, so this package is used for routines that
  39 --  require more than minimal semantic knowledge.
  40
  41 with Alloc; use Alloc;
  42 with Namet; use Namet;
  43 with Table;
  44 with Types; use Types;
  45
  46 package Sem_Aux is
  47
  48    --------------------------------
  49    -- Obsolescent Warnings Table --
  50    --------------------------------
  51
  52    --  This table records entities for which a pragma Obsolescent with a
  53    --  message argument has been processed.
  54
  55    type OWT_Record is record
  56       Ent : Entity_Id;
  57       --  The entity to which the pragma applies
  58
  59       Msg : String_Id;
  60       --  The string containing the message
  61    end record;
  62
  63    package Obsolescent_Warnings is new Table.Table (
  64      Table_Component_Type => OWT_Record,
  65      Table_Index_Type     => Int,
  66      Table_Low_Bound      => 0,
  67      Table_Initial        => Alloc.Obsolescent_Warnings_Initial,
  68      Table_Increment      => Alloc.Obsolescent_Warnings_Increment,
  69      Table_Name           => "Obsolescent_Warnings");
  70
  71    procedure Initialize;
  72    --  Called at the start of compilation of each new main source file to
  73    --  initialize the allocation of the Obsolescent_Warnings table. Note that
  74    --  Initialize must not be called if Tree_Read is used.
  75
  76    procedure Tree_Read;
  77    --  Initializes Obsolescent_Warnings table from current tree file using the
  78    --  relevant Table.Tree_Read routine.
  79
  80    procedure Tree_Write;
  81    --  Writes out Obsolescent_Warnings table to current tree file using the
  82    --  relevant Table.Tree_Write routine.
  83
  84    -----------------
  85    -- Subprograms --
  86    -----------------
  87
  88    function Ancestor_Subtype (Typ : Entity_Id) return Entity_Id;
  89    --  The argument Id is a type or subtype entity. If the argument is a
  90    --  subtype then it returns the subtype or type from which the subtype was
  91    --  obtained, otherwise it returns Empty.
  92
  93    function Available_View (Ent : Entity_Id) return Entity_Id;
  94    --  Ent denotes an abstract state or a type that may come from a limited
  95    --  with clause. Return the non-limited view of Ent if there is one or Ent
  96    --  if this is not the case.
  97
  98    function Constant_Value (Ent : Entity_Id) return Node_Id;
  99    --  Ent is a variable, constant, named integer, or named real entity. This
 100    --  call obtains the initialization expression for the entity. Will return
 101    --  Empty for a deferred constant whose full view is not available or
 102    --  in some other cases of internal entities, which cannot be treated as
 103    --  constants from the point of view of constant folding. Empty is also
 104    --  returned for variables with no initialization expression.
 105
 106    function Corresponding_Unsigned_Type (Typ : Entity_Id) return Entity_Id;
 107    --  Typ is a signed integer subtype. This routine returns the standard
 108    --  unsigned type with the same Esize as the implementation base type of
 109    --  Typ, e.g. Long_Integer => Long_Unsigned.
 110
 111    function Enclosing_Dynamic_Scope (Ent : Entity_Id) return Entity_Id;
 112    --  For any entity, Ent, returns the closest dynamic scope in which the
 113    --  entity is declared or Standard_Standard for library-level entities.
 114
 115    function First_Discriminant (Typ : Entity_Id) return Entity_Id;
 116    --  Typ is a type with discriminants. The discriminants are the first
 117    --  entities declared in the type, so normally this is equivalent to
 118    --  First_Entity. The exception arises for tagged types, where the tag
 119    --  itself is prepended to the front of the entity chain, so the
 120    --  First_Discriminant function steps past the tag if it is present.
 121
 122    function First_Stored_Discriminant (Typ : Entity_Id) return Entity_Id;
 123    --  Typ is a type with discriminants. Gives the first discriminant stored
 124    --  in an object of this type. In many cases, these are the same as the
 125    --  normal visible discriminants for the type, but in the case of renamed
 126    --  discriminants, this is not always the case.
 127    --
 128    --  For tagged types, and untagged types which are root types or derived
 129    --  types but which do not rename discriminants in their root type, the
 130    --  stored discriminants are the same as the actual discriminants of the
 131    --  type, and hence this function is the same as First_Discriminant.
 132    --
 133    --  For derived non-tagged types that rename discriminants in the root type
 134    --  this is the first of the discriminants that occur in the root type. To
 135    --  be precise, in this case stored discriminants are entities attached to
 136    --  the entity chain of the derived type which are a copy of the
 137    --  discriminants of the root type. Furthermore their Is_Completely_Hidden
 138    --  flag is set since although they are actually stored in the object, they
 139    --  are not in the set of discriminants that is visible in the type.
 140    --
 141    --  For derived untagged types, the set of stored discriminants are the real
 142    --  discriminants from Gigi's standpoint, i.e. those that will be stored in
 143    --  actual objects of the type.
 144
 145    function First_Subtype (Typ : Entity_Id) return Entity_Id;
 146    --  Applies to all types and subtypes. For types, yields the first subtype
 147    --  of the type. For subtypes, yields the first subtype of the base type of
 148    --  the subtype.
 149
 150    function First_Tag_Component (Typ : Entity_Id) return Entity_Id;
 151    --  Typ must be a tagged record type. This function returns the Entity for
 152    --  the first _Tag field in the record type.
 153
 154    function Get_Rep_Item
 155      (E             : Entity_Id;
 156       Nam           : Name_Id;
 157       Check_Parents : Boolean := True) return Node_Id;
 158    --  Searches the Rep_Item chain for a given entity E, for an instance of a
 159    --  rep item (pragma, attribute definition clause, or aspect specification)
 160    --  whose name matches the given name Nam. If Check_Parents is False then it
 161    --  only returns rep item that has been directly specified for E (and not
 162    --  inherited from its parents, if any). If one is found, it is returned,
 163    --  otherwise Empty is returned. A special case is that when Nam is
 164    --  Name_Priority, the call will also find Interrupt_Priority.
 165
 166    function Get_Rep_Item
 167      (E             : Entity_Id;
 168       Nam1          : Name_Id;
 169       Nam2          : Name_Id;
 170       Check_Parents : Boolean := True) return Node_Id;
 171    --  Searches the Rep_Item chain for a given entity E, for an instance of a
 172    --  rep item (pragma, attribute definition clause, or aspect specification)
 173    --  whose name matches one of the given names Nam1 or Nam2. If Check_Parents
 174    --  is False then it only returns rep item that has been directly specified
 175    --  for E (and not inherited from its parents, if any). If one is found, it
 176    --  is returned, otherwise Empty is returned. A special case is that when
 177    --  one of the given names is Name_Priority, the call will also find
 178    --  Interrupt_Priority.
 179
 180    function Get_Rep_Pragma
 181      (E             : Entity_Id;
 182       Nam           : Name_Id;
 183       Check_Parents : Boolean := True) return Node_Id;
 184    --  Searches the Rep_Item chain for a given entity E, for an instance of a
 185    --  representation pragma whose name matches the given name Nam. If
 186    --  Check_Parents is False then it only returns representation pragma that
 187    --  has been directly specified for E (and not inherited from its parents,
 188    --  if any). If one is found and if it is the first rep item in the list
 189    --  that matches Nam, it is returned, otherwise Empty is returned. A special
 190    --  case is that when Nam is Name_Priority, the call will also find
 191    --  Interrupt_Priority.
 192
 193    function Get_Rep_Pragma
 194      (E             : Entity_Id;
 195       Nam1          : Name_Id;
 196       Nam2          : Name_Id;
 197       Check_Parents : Boolean := True) return Node_Id;
 198    --  Searches the Rep_Item chain for a given entity E, for an instance of a
 199    --  representation pragma whose name matches one of the given names Nam1 or
 200    --  Nam2. If Check_Parents is False then it only returns representation
 201    --  pragma that has been directly specified for E (and not inherited from
 202    --  its parents, if any). If one is found and if it is the first rep item in
 203    --  the list that matches one of the given names, it is returned, otherwise
 204    --  Empty is returned. A special case is that when one of the given names is
 205    --  Name_Priority, the call will also find Interrupt_Priority.
 206
 207    function Has_Rep_Item
 208      (E             : Entity_Id;
 209       Nam           : Name_Id;
 210       Check_Parents : Boolean := True) return Boolean;
 211    --  Searches the Rep_Item chain for the given entity E, for an instance of a
 212    --  rep item (pragma, attribute definition clause, or aspect specification)
 213    --  with the given name Nam. If Check_Parents is False then it only checks
 214    --  for a rep item that has been directly specified for E (and not inherited
 215    --  from its parents, if any). If found then True is returned, otherwise
 216    --  False indicates that no matching entry was found.
 217
 218    function Has_Rep_Item
 219      (E             : Entity_Id;
 220       Nam1          : Name_Id;
 221       Nam2          : Name_Id;
 222       Check_Parents : Boolean := True) return Boolean;
 223    --  Searches the Rep_Item chain for the given entity E, for an instance of a
 224    --  rep item (pragma, attribute definition clause, or aspect specification)
 225    --  with the given names Nam1 or Nam2. If Check_Parents is False then it
 226    --  only checks for a rep item that has been directly specified for E (and
 227    --  not inherited from its parents, if any). If found then True is returned,
 228    --  otherwise False indicates that no matching entry was found.
 229
 230    function Has_Rep_Pragma
 231      (E             : Entity_Id;
 232       Nam           : Name_Id;
 233       Check_Parents : Boolean := True) return Boolean;
 234    --  Searches the Rep_Item chain for the given entity E, for an instance of a
 235    --  representation pragma with the given name Nam. If Check_Parents is False
 236    --  then it only checks for a representation pragma that has been directly
 237    --  specified for E (and not inherited from its parents, if any). If found
 238    --  and if it is the first rep item in the list that matches Nam then True
 239    --  is returned, otherwise False indicates that no matching entry was found.
 240
 241    function Has_Rep_Pragma
 242      (E             : Entity_Id;
 243       Nam1          : Name_Id;
 244       Nam2          : Name_Id;
 245       Check_Parents : Boolean := True) return Boolean;
 246    --  Searches the Rep_Item chain for the given entity E, for an instance of a
 247    --  representation pragma with the given names Nam1 or Nam2. If
 248    --  Check_Parents is False then it only checks for a rep item that has been
 249    --  directly specified for E (and not inherited from its parents, if any).
 250    --  If found and if it is the first rep item in the list that matches one of
 251    --  the given names then True is returned, otherwise False indicates that no
 252    --  matching entry was found.
 253
 254    function Has_Unconstrained_Elements (T : Entity_Id) return Boolean;
 255    --  True if T has discriminants and is unconstrained, or is an array type
 256    --  whose element type Has_Unconstrained_Elements.
 257
 258    function In_Generic_Body (Id : Entity_Id) return Boolean;
 259    --  Determine whether entity Id appears inside a generic body
 260
 261    function Initialization_Suppressed (Typ : Entity_Id) return Boolean;
 262    pragma Inline (Initialization_Suppressed);
 263    --  Returns True if initialization should be suppressed for the given type
 264    --  or subtype. This is true if Suppress_Initialization is set either for
 265    --  the subtype itself, or for the corresponding base type.
 266
 267    function Is_Body (N : Node_Id) return Boolean;
 268    --  Determine whether an arbitrary node denotes a body
 269
 270    function Is_By_Copy_Type (Ent : Entity_Id) return Boolean;
 271    --  Ent is any entity. Returns True if Ent is a type entity where the type
 272    --  is required to be passed by copy, as defined in (RM 6.2(3)).
 273
 274    function Is_By_Reference_Type (Ent : Entity_Id) return Boolean;
 275    --  Ent is any entity. Returns True if Ent is a type entity where the type
 276    --  is required to be passed by reference, as defined in (RM 6.2(4-9)).
 277
 278    function Is_Derived_Type (Ent : Entity_Id) return Boolean;
 279    --  Determines if the given entity Ent is a derived type. Result is always
 280    --  false if argument is not a type.
 281
 282    function Is_Generic_Formal (E : Entity_Id) return Boolean;
 283    --  Determine whether E is a generic formal parameter. In particular this is
 284    --  used to set the visibility of generic formals of a generic package
 285    --  declared with a box or with partial parameterization.
 286
 287    function Is_Indefinite_Subtype (Ent : Entity_Id) return Boolean;
 288    --  Ent is any entity. Determines if given entity is an unconstrained array
 289    --  type or subtype, a discriminated record type or subtype with no initial
 290    --  discriminant values or a class wide type or subtype and returns True if
 291    --  so. False for other type entities, or any entities that are not types.
 292
 293    function Is_Immutably_Limited_Type (Ent : Entity_Id) return Boolean;
 294    --  Implements definition in Ada 2012 RM-7.5 (8.1/3). This differs from the
 295    --  following predicate in that an untagged record with immutably limited
 296    --  components is NOT by itself immutably limited. This matters, e.g. when
 297    --  checking the legality of an access to the current instance.
 298
 299    function Is_Limited_View (Ent : Entity_Id) return Boolean;
 300    --  Ent is any entity. True for a type that is "inherently" limited (i.e.
 301    --  cannot become nonlimited). From the Ada 2005 RM-7.5(8.1/2), "a type with
 302    --  a part that is of a task, protected, or explicitly limited record type".
 303    --  These are the types that are defined as return-by-reference types in Ada
 304    --  95 (see RM95-6.5(11-16)). In Ada 2005, these are the types that require
 305    --  build-in-place for function calls. Note that build-in-place is allowed
 306    --  for other types, too. This is also used for identifying pure procedures
 307    --  whose calls should not be eliminated (RM 10.2.1(18/2)).
 308
 309    function Is_Limited_Type (Ent : Entity_Id) return Boolean;
 310    --  Ent is any entity. Returns true if Ent is a limited type (limited
 311    --  private type, limited interface type, task type, protected type,
 312    --  composite containing a limited component, or a subtype of any of
 313    --  these types). This older routine overlaps with the previous one, this
 314    --  should be cleaned up???
 315
 316    function Nearest_Ancestor (Typ : Entity_Id) return Entity_Id;
 317    --  Given a subtype Typ, this function finds out the nearest ancestor from
 318    --  which constraints and predicates are inherited. There is no simple link
 319    --  for doing this, consider:
 320    --
 321    --     subtype R is Integer range 1 .. 10;
 322    --     type T is new R;
 323    --
 324    --  In this case the nearest ancestor is R, but the Etype of T'Base will
 325    --  point to R'Base, so we have to go rummaging in the declarations to get
 326    --  this information. It is used for making sure we freeze this before we
 327    --  freeze Typ, and also for retrieving inherited predicate information.
 328    --  For the case of base types or first subtypes, there is no useful entity
 329    --  to return, so Empty is returned.
 330    --
 331    --  Note: this is similar to Ancestor_Subtype except that it also deals
 332    --  with the case of derived types.
 333
 334    function Nearest_Dynamic_Scope (Ent : Entity_Id) return Entity_Id;
 335    --  This is similar to Enclosing_Dynamic_Scope except that if Ent is itself
 336    --  a dynamic scope, then it is returned. Otherwise the result is the same
 337    --  as that returned by Enclosing_Dynamic_Scope.
 338
 339    function Next_Tag_Component (Tag : Entity_Id) return Entity_Id;
 340    --  Tag must be an entity representing a _Tag field of a tagged record.
 341    --  The result returned is the next _Tag field in this record, or Empty
 342    --  if this is the last such field.
 343
 344    function Number_Discriminants (Typ : Entity_Id) return Pos;
 345    --  Typ is a type with discriminants, yields number of discriminants in type
 346
 347    function Object_Type_Has_Constrained_Partial_View
 348      (Typ  : Entity_Id;
 349       Scop : Entity_Id) return Boolean;
 350    --  Return True if type of object has attribute Has_Constrained_Partial_View
 351    --  set to True; in addition, within a generic body, return True if subtype
 352    --  of the object is a descendant of an untagged generic formal private or
 353    --  derived type, and the subtype is not an unconstrained array subtype
 354    --  (RM 3.3(23.10/3)).
 355
 356    function Ultimate_Alias (Prim : Entity_Id) return Entity_Id;
 357    pragma Inline (Ultimate_Alias);
 358    --  Return the last entity in the chain of aliased entities of Prim. If Prim
 359    --  has no alias return Prim.
 360
 361    function Unit_Declaration_Node (Unit_Id : Entity_Id) return Node_Id;
 362    --  Unit_Id is the simple name of a program unit, this function returns the
 363    --  corresponding xxx_Declaration node for the entity. Also applies to the
 364    --  body entities for subprograms, tasks and protected units, in which case
 365    --  it returns the subprogram, task or protected body node for it. The unit
 366    --  may be a child unit with any number of ancestors.
 367
 368    function Package_Specification (Pack_Id : Entity_Id) return Node_Id;
 369    --  Given an entity for a package or generic package, return corresponding
 370    --  package specification. Simplifies handling of child units, and better
 371    --  than the old idiom: Specification (Unit_Declaration_Node (Pack_Id)).
 372 end Sem_Aux;