gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008, 2009, 2010, 2011, 2012 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.64)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [AS_HELP_STRING([--with-local-prefix=DIR],
 109                 [specifies directory to put local include])],
 110 [case "${withval}" in
 111 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 112 no)     ;;
 113 *)      local_prefix=$with_local_prefix ;;
 114 esac])
 115
 116 # Default local prefix if it is empty
 117 if test x$local_prefix = x; then
 118         local_prefix=/usr/local
 119 fi
 120
 121 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 122 # passed in by the toplevel make and thus we'd get different behavior
 123 # depending on where we built the sources.
 124 gcc_gxx_include_dir=
 125 # Specify the g++ header file directory
 126 AC_ARG_WITH(gxx-include-dir,
 127 [AS_HELP_STRING([--with-gxx-include-dir=DIR],
 128                 [specifies directory to put g++ header files])],
 129 [case "${withval}" in
 130 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 131 no)     ;;
 132 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 133 esac])
 134
 135 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 136 if test x${gcc_gxx_include_dir} = x; then
 137   if test x${enable_version_specific_runtime_libs} = xyes; then
 138     gcc_gxx_include_dir='${libsubdir}/include/c++'
 139   else
 140     libstdcxx_incdir='include/c++/$(version)'
 141     if test x$host != x$target; then
 142        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 143     fi
 144     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 145   fi
 146 fi
 147
 148 gcc_gxx_include_dir_add_sysroot=0
 149 if test "${with_sysroot+set}" = set; then
 150   gcc_gxx_without_sysroot=`expr "${gcc_gxx_include_dir}" : "${with_sysroot}"'\(.*\)'`
 151   if test "${gcc_gxx_without_sysroot}"; then
 152     gcc_gxx_include_dir="${gcc_gxx_without_sysroot}"
 153     gcc_gxx_include_dir_add_sysroot=1
 154   fi
 155 fi
 156
 157 AC_ARG_WITH(cpp_install_dir,
 158 [AC_HELP_STRING([--with-cpp-install-dir=DIR],
 159                 [install the user visible C preprocessor in DIR
 160                  (relative to PREFIX) as well as PREFIX/bin])],
 161 [if test x$withval = xyes; then
 162   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 163 elif test x$withval != xno; then
 164   cpp_install_dir=$withval
 165 fi])
 166
 167 # We would like to our source tree to be readonly.  However when releases or
 168 # pre-releases are generated, the flex/bison generated files as well as the
 169 # various formats of manuals need to be included along with the rest of the
 170 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 171 # just that.
 172
 173 AC_MSG_CHECKING([whether to place generated files in the source directory])
 174   dnl generated-files-in-srcdir is disabled by default
 175   AC_ARG_ENABLE(generated-files-in-srcdir,
 176     [AS_HELP_STRING([--enable-generated-files-in-srcdir],
 177                     [put copies of generated files in source dir
 178                      intended for creating source tarballs for users
 179                      without texinfo bison or flex])],
 180       generated_files_in_srcdir=$enableval,
 181       generated_files_in_srcdir=no)
 182
 183 AC_MSG_RESULT($generated_files_in_srcdir)
 184
 185 if test "$generated_files_in_srcdir" = "yes"; then
 186   GENINSRC=''
 187 else
 188   GENINSRC='#'
 189 fi
 190 AC_SUBST(GENINSRC)
 191
 192 # -------------------
 193 # Find default linker
 194 # -------------------
 195
 196 # With GNU ld
 197 AC_ARG_WITH(gnu-ld,
 198 [AS_HELP_STRING([--with-gnu-ld], [arrange to work with GNU ld])],
 199 gnu_ld_flag="$with_gnu_ld",
 200 gnu_ld_flag=no)
 201
 202 # With pre-defined ld
 203 AC_ARG_WITH(ld,
 204 [AS_HELP_STRING([--with-ld], [arrange to use the specified ld (full pathname)])],
 205 DEFAULT_LINKER="$with_ld")
 206 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 207   if test ! -x "$DEFAULT_LINKER"; then
 208     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 209   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 210     gnu_ld_flag=yes
 211   fi
 212   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 213         [Define to enable the use of a default linker.])
 214 fi
 215
 216 AC_MSG_CHECKING([whether a default linker was specified])
 217 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 218   if test x"$gnu_ld_flag" = x"no"; then
 219     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 220   else
 221     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 222   fi
 223 else
 224   AC_MSG_RESULT(no)
 225 fi
 226
 227 # With demangler in GNU ld
 228 AC_ARG_WITH(demangler-in-ld,
 229 [AS_HELP_STRING([--with-demangler-in-ld], [try to use demangler in GNU ld])],
 230 demangler_in_ld="$with_demangler_in_ld",
 231 demangler_in_ld=yes)
 232
 233 # ----------------------
 234 # Find default assembler
 235 # ----------------------
 236
 237 # With GNU as
 238 AC_ARG_WITH(gnu-as,
 239 [AS_HELP_STRING([--with-gnu-as], [arrange to work with GNU as])],
 240 gas_flag="$with_gnu_as",
 241 gas_flag=no)
 242
 243 AC_ARG_WITH(as,
 244 [AS_HELP_STRING([--with-as], [arrange to use the specified as (full pathname)])],
 245 DEFAULT_ASSEMBLER="$with_as")
 246 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 247   if test ! -x "$DEFAULT_ASSEMBLER"; then
 248     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 249   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 250     gas_flag=yes
 251   fi
 252   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 253         [Define to enable the use of a default assembler.])
 254 fi
 255
 256 AC_MSG_CHECKING([whether a default assembler was specified])
 257 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 258   if test x"$gas_flag" = x"no"; then
 259     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 260   else
 261     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 262   fi
 263 else
 264   AC_MSG_RESULT(no)
 265 fi
 266
 267 # ---------------
 268 # Find C compiler
 269 # ---------------
 270
 271 # If a non-executable a.out is present (e.g. created by GNU as above even if
 272 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 273 # file, even when creating an executable, so an execution test fails.
 274 # Remove possible default executable files to avoid this.
 275 #
 276 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 277 # Autoconf includes it.
 278 rm -f a.out a.exe b.out
 279
 280 # Find the native compiler
 281 AC_PROG_CC
 282 AM_PROG_CC_C_O
 283 AC_PROG_CXX
 284 ACX_PROG_GNAT([-I"$srcdir"/ada])
 285
 286 # autoconf is lame and doesn't give us any substitution variable for this.
 287 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 288   NO_MINUS_C_MINUS_O=yes
 289 else
 290   OUTPUT_OPTION='-o $@'
 291 fi
 292 AC_SUBST(NO_MINUS_C_MINUS_O)
 293 AC_SUBST(OUTPUT_OPTION)
 294
 295 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 296 # optimizations to be activated explicitly by the toplevel.
 297 case "$CC" in
 298   */prev-gcc/xgcc*) ;;
 299   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" `
 300      CXXFLAGS=`echo $CXXFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 301 esac
 302 AC_SUBST(CFLAGS)
 303 AC_SUBST(CXXFLAGS)
 304
 305 # Determine PICFLAG for target gnatlib.
 306 GCC_PICFLAG_FOR_TARGET
 307 AC_SUBST(PICFLAG_FOR_TARGET)
 308
 309 # -------------------------
 310 # Check C compiler features
 311 # -------------------------
 312
 313 AC_USE_SYSTEM_EXTENSIONS
 314 AC_PROG_CPP
 315 AC_C_INLINE
 316
 317 AC_SYS_LARGEFILE
 318
 319 # sizeof(char) is 1 by definition.
 320 AC_CHECK_SIZEOF(void *)
 321 AC_CHECK_SIZEOF(short)
 322 AC_CHECK_SIZEOF(int)
 323 AC_CHECK_SIZEOF(long)
 324 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 325 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 326 GCC_STDINT_TYPES
 327
 328 # ---------------------
 329 # Warnings and checking
 330 # ---------------------
 331
 332 # Check $CC warning features (if it's GCC).
 333 # We want to use -pedantic, but we don't want warnings about
 334 # * 'long long'
 335 # * variadic macros
 336 # * overlong strings
 337 # * C++11 narrowing conversions in { }
 338 # So, we only use -pedantic if we can disable those warnings.
 339
 340 ACX_PROG_CC_WARNING_OPTS(
 341         m4_quote(m4_do([-W -Wall -Wno-narrowing -Wwrite-strings -Wcast-qual])), [loose_warn])
 342 ACX_PROG_CC_WARNING_OPTS(
 343         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
 344         [c_loose_warn])
 345 ACX_PROG_CC_WARNING_OPTS(
 346         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
 347 ACX_PROG_CC_WARNING_OPTS(
 348         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
 349 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 350         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 351                        [-Wno-overlength-strings])), [strict_warn])
 352 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 353
 354 # The above macros do nothing if the compiler is not GCC.  However, the
 355 # Makefile has more goo to add other flags, so these variables are used
 356 # to enable warnings only for GCC.
 357 warn_cflags=
 358 warn_cxxflags=
 359 if test "x$GCC" = "xyes"; then
 360   warn_cflags='$(GCC_WARN_CFLAGS)'
 361   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
 362 fi
 363 AC_SUBST(warn_cflags)
 364 AC_SUBST(warn_cxxflags)
 365
 366 # Disable exceptions and RTTI if building with g++
 367 ACX_PROG_CC_WARNING_OPTS(
 368         m4_quote(m4_do([-fno-exceptions -fno-rtti])), [noexception_flags])
 369
 370 # Enable expensive internal checks
 371 is_release=
 372 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 373   is_release=yes
 374 fi
 375
 376 AC_ARG_ENABLE(checking,
 377 [AS_HELP_STRING([[--enable-checking[=LIST]]],
 378                 [enable expensive run-time checks.  With LIST,
 379                  enable only specific categories of checks.
 380                  Categories are: yes,no,all,none,release.
 381                  Flags are: assert,df,fold,gc,gcac,gimple,misc,
 382                  rtlflag,rtl,runtime,tree,valgrind,types])],
 383 [ac_checking_flags="${enableval}"],[
 384 # Determine the default checks.
 385 if test x$is_release = x ; then
 386   ac_checking_flags=yes
 387 else
 388   ac_checking_flags=release
 389 fi])
 390 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 391 for check in release $ac_checking_flags
 392 do
 393         case $check in
 394         # these set all the flags to specific states
 395         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 396                         ac_fold_checking= ; ac_gc_checking=1 ;
 397                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 398                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 399                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 400                         ac_types_checking=1 ;;
 401         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 402                         ac_fold_checking= ; ac_gc_checking= ;
 403                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 404                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 405                         ac_tree_checking= ; ac_valgrind_checking= ;
 406                         ac_types_checking= ;;
 407         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 408                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 409                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 410                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 411                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 412                         ac_types_checking=1 ;;
 413         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 414                         ac_fold_checking= ; ac_gc_checking= ;
 415                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 416                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 417                         ac_tree_checking= ; ac_valgrind_checking= ;
 418                         ac_types_checking= ;;
 419         # these enable particular checks
 420         assert)         ac_assert_checking=1 ;;
 421         df)             ac_df_checking=1 ;;
 422         fold)           ac_fold_checking=1 ;;
 423         gc)             ac_gc_checking=1 ;;
 424         gcac)           ac_gc_always_collect=1 ;;
 425         gimple)         ac_gimple_checking=1 ;;
 426         misc)           ac_checking=1 ;;
 427         rtl)            ac_rtl_checking=1 ;;
 428         rtlflag)        ac_rtlflag_checking=1 ;;
 429         runtime)        ac_runtime_checking=1 ;;
 430         tree)           ac_tree_checking=1 ;;
 431         types)          ac_types_checking=1 ;;
 432         valgrind)       ac_valgrind_checking=1 ;;
 433         *)      AC_MSG_ERROR(unknown check category $check) ;;
 434         esac
 435 done
 436 IFS="$ac_save_IFS"
 437
 438 nocommon_flag=""
 439 if test x$ac_checking != x ; then
 440   AC_DEFINE(ENABLE_CHECKING, 1,
 441 [Define if you want more run-time sanity checks.  This one gets a grab
 442    bag of miscellaneous but relatively cheap checks.])
 443   nocommon_flag=-fno-common
 444 fi
 445 AC_SUBST(nocommon_flag)
 446 if test x$ac_df_checking != x ; then
 447   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 448 [Define if you want more run-time sanity checks for dataflow.])
 449 fi
 450 if test x$ac_assert_checking != x ; then
 451   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 452 [Define if you want assertions enabled.  This is a cheap check.])
 453 fi
 454 if test x$ac_gimple_checking != x ; then
 455   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 456 [Define if you want operations on GIMPLE (the basic data structure of
 457 the high-level optimizers) to be checked for dynamic type safety at
 458 runtime.  This is moderately expensive.])
 459 fi
 460 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 461 if test x$ac_runtime_checking != x ; then
 462   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 463 [Define if you want runtime assertions enabled.  This is a cheap check.])
 464 fi
 465 if test x$ac_tree_checking != x ; then
 466   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 467 [Define if you want all operations on trees (the basic data
 468    structure of the front ends) to be checked for dynamic type safety
 469    at runtime.  This is moderately expensive.  The tree browser debugging
 470    routines will also be enabled by this option.
 471    ])
 472   TREEBROWSER=tree-browser.o
 473 fi
 474 if test x$ac_types_checking != x ; then
 475   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 476 [Define if you want all gimple types to be verified after gimplifiation.
 477    This is cheap.
 478    ])
 479 fi
 480 AC_SUBST(TREEBROWSER)
 481 if test x$ac_rtl_checking != x ; then
 482   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 483 [Define if you want all operations on RTL (the basic data structure
 484    of the optimizer and back end) to be checked for dynamic type safety
 485    at runtime.  This is quite expensive.])
 486 fi
 487 if test x$ac_rtlflag_checking != x ; then
 488   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 489 [Define if you want RTL flag accesses to be checked against the RTL
 490    codes that are supported for each access macro.  This is relatively
 491    cheap.])
 492 fi
 493 if test x$ac_gc_checking != x ; then
 494   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 495 [Define if you want the garbage collector to do object poisoning and
 496    other memory allocation checks.  This is quite expensive.])
 497 fi
 498 if test x$ac_gc_always_collect != x ; then
 499   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 500 [Define if you want the garbage collector to operate in maximally
 501    paranoid mode, validating the entire heap and collecting garbage at
 502    every opportunity.  This is extremely expensive.])
 503 fi
 504 if test x$ac_fold_checking != x ; then
 505   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 506 [Define if you want fold checked that it never destructs its argument.
 507    This is quite expensive.])
 508 fi
 509 valgrind_path_defines=
 510 valgrind_command=
 511
 512 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 513 dnl # an if statement.  This was the source of very frustrating bugs
 514 dnl # in converting to autoconf 2.5x!
 515 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 516
 517 if test x$ac_valgrind_checking != x ; then
 518   # It is certainly possible that there's valgrind but no valgrind.h.
 519   # GCC relies on making annotations so we must have both.
 520   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 521   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 522     [[#include <valgrind/memcheck.h>
 523 #ifndef VALGRIND_DISCARD
 524 #error VALGRIND_DISCARD not defined
 525 #endif]])],
 526   [gcc_cv_header_valgrind_memcheck_h=yes],
 527   [gcc_cv_header_valgrind_memcheck_h=no])
 528   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 529   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 530   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 531     [[#include <memcheck.h>
 532 #ifndef VALGRIND_DISCARD
 533 #error VALGRIND_DISCARD not defined
 534 #endif]])],
 535   [gcc_cv_header_memcheck_h=yes],
 536   [gcc_cv_header_memcheck_h=no])
 537   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 538   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 539         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 540   if test "x$valgrind_path" = "x" \
 541     || (test $have_valgrind_h = no \
 542         && test $gcc_cv_header_memcheck_h = no \
 543         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 544         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 545   fi
 546   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 547   valgrind_command="$valgrind_path -q"
 548   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 549 [Define if you want to run subprograms and generated programs
 550    through valgrind (a memory checker).  This is extremely expensive.])
 551   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 552     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 553         [Define if valgrind's valgrind/memcheck.h header is installed.])
 554   fi
 555   if test $gcc_cv_header_memcheck_h = yes; then
 556     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 557         [Define if valgrind's memcheck.h header is installed.])
 558   fi
 559 fi
 560 AC_SUBST(valgrind_path_defines)
 561 AC_SUBST(valgrind_command)
 562
 563 # Enable code coverage collection
 564 AC_ARG_ENABLE(coverage,
 565 [AS_HELP_STRING([[--enable-coverage[=LEVEL]]],
 566                 [enable compiler's code coverage collection.
 567                  Use to measure compiler performance and locate
 568                  unused parts of the compiler. With LEVEL, specify
 569                  optimization. Values are opt, noopt,
 570                  default is noopt])],
 571 [case "${enableval}" in
 572   yes|noopt)
 573     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 574     ;;
 575   opt)
 576     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 577     ;;
 578   no)
 579     # a.k.a. --disable-coverage
 580     coverage_flags=""
 581     ;;
 582   *)
 583     AC_MSG_ERROR(unknown coverage setting $enableval)
 584     ;;
 585 esac],
 586 [coverage_flags=""])
 587 AC_SUBST(coverage_flags)
 588
 589 AC_ARG_ENABLE(gather-detailed-mem-stats,
 590 [AS_HELP_STRING([--enable-gather-detailed-mem-stats],
 591                 [enable detailed memory allocation stats gathering])], [],
 592 [enable_gather_detailed_mem_stats=no])
 593 gather_stats=`if test $enable_gather_detailed_mem_stats != no; then echo 1; else echo 0; fi`
 594 AC_DEFINE_UNQUOTED(GATHER_STATISTICS, $gather_stats,
 595 [Define to enable detailed memory allocation stats gathering.])
 596
 597 # -------------------------------
 598 # Miscenalleous configure options
 599 # -------------------------------
 600
 601 # With stabs
 602 AC_ARG_WITH(stabs,
 603 [AS_HELP_STRING([--with-stabs],
 604                 [arrange to use stabs instead of host debug format])],
 605 stabs="$with_stabs",
 606 stabs=no)
 607
 608 # Determine whether or not multilibs are enabled.
 609 AC_ARG_ENABLE(multilib,
 610 [AS_HELP_STRING([--enable-multilib],
 611                 [enable library support for multiple ABIs])],
 612 [], [enable_multilib=yes])
 613 AC_SUBST(enable_multilib)
 614
 615 # Enable __cxa_atexit for C++.
 616 AC_ARG_ENABLE(__cxa_atexit,
 617 [AS_HELP_STRING([--enable-__cxa_atexit], [enable __cxa_atexit for C++])],
 618 [], [])
 619
 620 # Enable C extension for decimal float if target supports it.
 621 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
 622
 623 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 624 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 625 [Define to 1 to enable decimal float extension to C.])
 626
 627 # Use default_decimal_float for dependency.
 628 enable_decimal_float=$default_decimal_float
 629
 630 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 631 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 632 [Define to 1 to specify that we are using the BID decimal floating
 633 point format instead of DPD])
 634
 635 # Enable C extension for fixed-point arithmetic.
 636 AC_ARG_ENABLE(fixed-point,
 637 [AS_HELP_STRING([--enable-fixed-point],
 638                 [enable fixed-point arithmetic extension to C])],
 639 [],
 640 [
 641   case $target in
 642     arm*)
 643       enable_fixed_point=yes
 644       ;;
 645
 646     mips*-*-*)
 647       enable_fixed_point=yes
 648       ;;
 649     *)
 650       AC_MSG_WARN([fixed-point is not supported for this target, ignored])
 651       enable_fixed_point=no
 652       ;;
 653   esac
 654 ])
 655 AC_SUBST(enable_fixed_point)
 656
 657 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 658 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 659 [Define to 1 to enable fixed-point arithmetic extension to C.])
 660
 661 # Enable threads
 662 # Pass with no value to take the default
 663 # Pass with a value to specify a thread package
 664 AC_ARG_ENABLE(threads,
 665 [AS_HELP_STRING([[--enable-threads[=LIB]]],
 666                 [enable thread usage for target GCC,
 667                  using LIB thread package])],,
 668 [enable_threads=''])
 669
 670 AC_ARG_ENABLE(tls,
 671 [AS_HELP_STRING([--enable-tls],
 672                 [enable or disable generation of tls code
 673                  overriding the assembler check for tls support])],
 674 [
 675   case $enable_tls in
 676     yes | no) ;;
 677     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 678 Valid choices are 'yes' and 'no'.]) ;;
 679   esac
 680 ], [enable_tls=''])
 681
 682 AC_ARG_ENABLE(objc-gc,
 683 [AS_HELP_STRING([--enable-objc-gc],
 684                 [enable the use of Boehm's garbage collector with
 685                  the GNU Objective-C runtime])],
 686 if test x$enable_objc_gc = xno; then
 687         objc_boehm_gc=''
 688 else
 689         objc_boehm_gc=1
 690 fi,
 691 objc_boehm_gc='')
 692
 693 AC_ARG_WITH(dwarf2,
 694 [AS_HELP_STRING([--with-dwarf2], [force the default debug format to be DWARF 2])],
 695 dwarf2="$with_dwarf2",
 696 dwarf2=no)
 697
 698 AC_ARG_ENABLE(shared,
 699 [AS_HELP_STRING([--disable-shared], [don't provide a shared libgcc])],
 700 [
 701   case $enable_shared in
 702   yes | no) ;;
 703   *)
 704     enable_shared=no
 705     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 706     for pkg in $enableval; do
 707       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 708         enable_shared=yes
 709       fi
 710     done
 711     IFS="$ac_save_ifs"
 712     ;;
 713   esac
 714 ], [enable_shared=yes])
 715 AC_SUBST(enable_shared)
 716
 717 AC_ARG_WITH([native-system-header-dir],
 718   [  --with-native-system-header-dir=dir
 719                           use dir as the directory to look for standard
 720                           system header files in.  Defaults to /usr/include.],
 721 [
 722  case ${with_native_system_header_dir} in
 723  yes|no) AC_MSG_ERROR([bad value ${withval} given for --with-native-system-header-dir]) ;;
 724  /* | [[A-Za-z]]:[[\\/]]*) ;;
 725  *) AC_MSG_ERROR([--with-native-system-header-dir argument ${withval} must be an absolute directory]) ;;
 726  esac
 727  configured_native_system_header_dir="${withval}"
 728 ], [configured_native_system_header_dir=])
 729
 730 AC_ARG_WITH(build-sysroot,
 731   [AS_HELP_STRING([--with-build-sysroot=sysroot],
 732                   [use sysroot as the system root during the build])],
 733   [if test x"$withval" != x ; then
 734      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
 735    fi],
 736   [SYSROOT_CFLAGS_FOR_TARGET=])
 737 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
 738
 739 if test "x$prefix" = xNONE; then
 740  test_prefix=/usr/local
 741 else
 742  test_prefix=$prefix
 743 fi
 744 if test "x$exec_prefix" = xNONE; then
 745  test_exec_prefix=$test_prefix
 746 else
 747  test_exec_prefix=$exec_prefix
 748 fi
 749
 750 AC_ARG_WITH(sysroot,
 751 [AS_HELP_STRING([[--with-sysroot[=DIR]]],
 752                 [search for usr/lib, usr/include, et al, within DIR])],
 753 [
 754  case ${with_sysroot} in
 755  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 756  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 757  esac
 758
 759  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 760  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 761
 762  case ${TARGET_SYSTEM_ROOT} in
 763  "${test_prefix}"|"${test_prefix}/"*|\
 764  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 765  '${prefix}'|'${prefix}/'*|\
 766  '${exec_prefix}'|'${exec_prefix}/'*)
 767    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 768    TARGET_SYSTEM_ROOT_DEFINE="$t"
 769    ;;
 770  esac
 771 ], [
 772  TARGET_SYSTEM_ROOT=
 773  TARGET_SYSTEM_ROOT_DEFINE=
 774  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 775 ])
 776 AC_SUBST(TARGET_SYSTEM_ROOT)
 777 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 778 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 779
 780 AC_ARG_WITH(specs,
 781   [AS_HELP_STRING([--with-specs=SPECS],
 782                   [add SPECS to driver command-line processing])],
 783   [CONFIGURE_SPECS=$withval],
 784   [CONFIGURE_SPECS=]
 785 )
 786 AC_SUBST(CONFIGURE_SPECS)
 787
 788 ACX_PKGVERSION([GCC])
 789 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 790
 791 # Sanity check enable_languages in case someone does not run the toplevel
 792 # configure # script.
 793 AC_ARG_ENABLE(languages,
 794 [AS_HELP_STRING([--enable-languages=LIST], [specify which front-ends to build])],
 795 [case ,${enable_languages}, in
 796        ,,|,yes,)
 797                 # go safe -- we cannot be much sure without the toplevel
 798                 # configure's
 799                 # analysis of which target libs are present and usable
 800                 enable_languages=c
 801                 ;;
 802          *,all,*)
 803                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 804                 ;;
 805         *,c,*)
 806                 ;;
 807         *)
 808                 enable_languages=c,${enable_languages}
 809                 ;;
 810 esac],
 811 [enable_languages=c])
 812
 813 AC_ARG_WITH(multilib-list,
 814 [AS_HELP_STRING([--with-multilib-list], [select multilibs (SH and x86-64 only)])],
 815 :,
 816 with_multilib_list=default)
 817
 818 # -------------------------
 819 # Checks for other programs
 820 # -------------------------
 821
 822 AC_PROG_MAKE_SET
 823
 824 # Find some useful tools
 825 AC_PROG_AWK
 826 # We need awk to create options.c and options.h.
 827 # Bail out if it's missing.
 828 case ${AWK} in
 829   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 830 esac
 831
 832 gcc_AC_PROG_LN_S
 833 ACX_PROG_LN($LN_S)
 834 AC_PROG_RANLIB
 835 ranlib_flags=""
 836 AC_SUBST(ranlib_flags)
 837
 838 gcc_AC_PROG_INSTALL
 839
 840 # See if cmp has --ignore-initial.
 841 gcc_AC_PROG_CMP_IGNORE_INITIAL
 842
 843 # See if we have the mktemp command.
 844 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 845
 846 # See if makeinfo has been installed and is modern enough
 847 # that we can use it.
 848 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 849   [GNU texinfo.* \([0-9][0-9.]*\)],
 850   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 851 if test $gcc_cv_prog_makeinfo_modern = no; then
 852   AC_MSG_WARN([
 853 *** Makeinfo is missing or too old.
 854 *** Info documentation will not be built.])
 855   BUILD_INFO=
 856 else
 857   BUILD_INFO=info
 858 fi
 859 AC_SUBST(BUILD_INFO)
 860
 861 # Is pod2man recent enough to regenerate manpages?
 862 AC_MSG_CHECKING([for recent Pod::Man])
 863 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 864   AC_MSG_RESULT(yes)
 865   GENERATED_MANPAGES=generated-manpages
 866 else
 867   AC_MSG_RESULT(no)
 868   GENERATED_MANPAGES=
 869 fi
 870 AC_SUBST(GENERATED_MANPAGES)
 871
 872 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 873
 874 # How about lex?
 875 dnl Don't use AC_PROG_LEX; we insist on flex.
 876 dnl LEXLIB is not useful in gcc.
 877 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 878
 879 # Bison?
 880 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 881
 882 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 883 # check for build == host before using them.
 884
 885 # NM
 886 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 887   && test -d ../binutils ; then
 888   NM='${objdir}/../binutils/nm-new'
 889 else
 890   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 891 fi
 892
 893 # AR
 894 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 895   && test -d ../binutils ; then
 896   AR='${objdir}/../binutils/ar'
 897 else
 898   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 899 fi
 900
 901
 902 # --------------------
 903 # Checks for C headers
 904 # --------------------
 905
 906 # Need to reject headers which give warnings, so that the -Werror bootstrap
 907 # works later. *sigh*  This needs to come before all header checks.
 908 AC_PROG_CPP_WERROR
 909
 910 AC_HEADER_STDC
 911 AC_HEADER_TIME
 912 ACX_HEADER_STRING
 913 AC_HEADER_SYS_WAIT
 914 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 915                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 916                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 917                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h libintl.h)
 918
 919 # Check for thread headers.
 920 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 921 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 922
 923 # These tests can't be done till we know if we have limits.h.
 924 gcc_AC_C_CHAR_BIT
 925 AC_C_BIGENDIAN
 926
 927 # ----------------------
 928 # Checks for C++ headers
 929 # ----------------------
 930
 931 dnl Autoconf will give an error in the configure script if there is no
 932 dnl C++ preprocessor.  Hack to prevent that.
 933 m4_pushdef([AC_MSG_ERROR], m4_defn([AC_MSG_WARN]))[]dnl
 934 AC_PROG_CXXCPP
 935 m4_popdef([AC_MSG_ERROR])[]dnl
 936
 937 AC_LANG_PUSH(C++)
 938
 939 AC_CHECK_HEADERS(unordered_map)
 940 AC_CHECK_HEADERS(tr1/unordered_map)
 941 AC_CHECK_HEADERS(ext/hash_map)
 942
 943 AC_LANG_POP(C++)
 944
 945 # --------
 946 # UNSORTED
 947 # --------
 948
 949
 950 # These libraries may be used by collect2.
 951 # We may need a special search path to get them linked.
 952 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 953 [save_LIBS="$LIBS"
 954 for libs in '' -lld -lmld \
 955                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 956                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 957 do
 958         LIBS="$libs"
 959         AC_TRY_LINK_FUNC(ldopen,
 960                 [gcc_cv_collect2_libs="$libs"; break])
 961 done
 962 LIBS="$save_LIBS"
 963 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 964 case $gcc_cv_collect2_libs in
 965         "none required")        ;;
 966         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 967 esac
 968 AC_SUBST(COLLECT2_LIBS)
 969
 970 # When building Ada code on Alpha, we need exc_resume which is usually in
 971 # -lexc.  So test for it.
 972 save_LIBS="$LIBS"
 973 LIBS=
 974 AC_SEARCH_LIBS(exc_resume, exc)
 975 GNAT_LIBEXC="$LIBS"
 976 LIBS="$save_LIBS"
 977 AC_SUBST(GNAT_LIBEXC)
 978
 979 # To support -mcpu=native on Solaris/SPARC, we need libkstat.
 980 save_LIBS="$LIBS"
 981 LIBS=
 982 AC_SEARCH_LIBS(kstat_open, kstat)
 983 EXTRA_GCC_LIBS="$LIBS"
 984 LIBS="$save_LIBS"
 985 AC_SUBST(EXTRA_GCC_LIBS)
 986
 987 # Some systems put ldexp and frexp in libm instead of libc; assume
 988 # they're both in the same place.  jcf-dump needs them.
 989 save_LIBS="$LIBS"
 990 LIBS=
 991 AC_SEARCH_LIBS(ldexp, m)
 992 LDEXP_LIB="$LIBS"
 993 LIBS="$save_LIBS"
 994 AC_SUBST(LDEXP_LIB)
 995
 996 # Use <inttypes.h> only if it exists,
 997 # doesn't clash with <sys/types.h>, and declares intmax_t.
 998 AC_MSG_CHECKING(for inttypes.h)
 999 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1000 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1001 [[#include <sys/types.h>
1002 #include <inttypes.h>]],
1003   [[intmax_t i = -1;]])],
1004   [gcc_cv_header_inttypes_h=yes],
1005   [gcc_cv_header_inttypes_h=no])])
1006 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1007 if test $gcc_cv_header_inttypes_h = yes; then
1008   AC_DEFINE(HAVE_INTTYPES_H, 1,
1009         [Define if you have a working <inttypes.h> header file.])
1010 fi
1011
1012 dnl Disabled until we have a complete test for buggy enum bitfields.
1013 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1014
1015 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1016   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1017   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1018   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1019   putchar_unlocked putc_unlocked)
1020 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1021         sysconf strsignal getrusage nl_langinfo \
1022         gettimeofday mbstowcs wcswidth mmap setlocale \
1023         gcc_UNLOCKED_FUNCS madvise)
1024
1025 if test x$ac_cv_func_mbstowcs = xyes; then
1026   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1027 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1028 int main()
1029 {
1030   mbstowcs(0, "", 0);
1031   return 0;
1032 }]])],
1033     [gcc_cv_func_mbstowcs_works=yes],
1034     [gcc_cv_func_mbstowcs_works=no],
1035     [gcc_cv_func_mbstowcs_works=yes])])
1036   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1037     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1038   [Define this macro if mbstowcs does not crash when its
1039    first argument is NULL.])
1040   fi
1041 fi
1042
1043 AC_CHECK_TYPE(ssize_t, int)
1044 AC_CHECK_TYPE(caddr_t, char *)
1045
1046 GCC_AC_FUNC_MMAP_BLACKLIST
1047
1048 case "${host}" in
1049 *-*-*vms*)
1050   # Under VMS, vfork works very differently than on Unix. The standard test
1051   # won't work, and it isn't easily adaptable. It makes more sense to
1052   # just force it.
1053   ac_cv_func_vfork_works=yes
1054   ;;
1055 esac
1056 AC_FUNC_FORK
1057
1058 # g++ on Solaris 10+ defines _XOPEN_SOURCE=600, which exposes a different
1059 # iconv() prototype.
1060 AC_LANG_PUSH([C++])
1061 AM_ICONV
1062 AC_LANG_POP([C++])
1063
1064 # Until we have in-tree GNU iconv:
1065 LIBICONV_DEP=
1066 AC_SUBST(LIBICONV_DEP)
1067
1068 AM_LC_MESSAGES
1069
1070 AM_LANGINFO_CODESET
1071
1072 # We will need to find libiberty.h and ansidecl.h
1073 saved_CFLAGS="$CFLAGS"
1074 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1075 saved_CXXFLAGS="$CXXFLAGS"
1076 CXXFLAGS="$CXXFLAGS -I${srcdir} -I${srcdir}/../include"
1077 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1078         strsignal strstr stpcpy strverscmp \
1079         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1080         free basename getopt clock getpagesize ffs gcc_UNLOCKED_FUNCS, , ,[
1081 #include "ansidecl.h"
1082 #include "system.h"])
1083
1084 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1085 #include "ansidecl.h"
1086 #include "system.h"
1087 #ifdef HAVE_SYS_RESOURCE_H
1088 #include <sys/resource.h>
1089 #endif
1090 ])
1091
1092 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1093 #include "ansidecl.h"
1094 #include "system.h"
1095 #ifdef HAVE_SYS_RESOURCE_H
1096 #include <sys/resource.h>
1097 #endif
1098 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1099 [Define to `long' if <sys/resource.h> doesn't define.])])
1100
1101 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1102 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1103 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1104 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1105 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1106 #include "ansidecl.h"
1107 #include "system.h"
1108 #ifdef HAVE_LDFCN_H
1109 #undef FREAD
1110 #undef FWRITE
1111 #include <ldfcn.h>
1112 #endif
1113 ])
1114
1115 gcc_AC_CHECK_DECLS(times, , ,[
1116 #include "ansidecl.h"
1117 #include "system.h"
1118 #ifdef HAVE_SYS_TIMES_H
1119 #include <sys/times.h>
1120 #endif
1121 ])
1122
1123 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1124 #include "ansidecl.h"
1125 #include "system.h"
1126 #include <signal.h>
1127 ])
1128
1129 # g++ on Solaris 10+ defines _XOPEN_SOURCE=600, which hides the madvise()
1130 # prototype.
1131 AC_LANG_PUSH([C++])
1132 gcc_AC_CHECK_DECLS(madvise, , ,[
1133   #include "ansidecl.h"
1134   #include "system.h"
1135 ])
1136 AC_LANG_POP([C++])
1137
1138 # More time-related stuff.
1139 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1140 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1141 #include "ansidecl.h"
1142 #include "system.h"
1143 #ifdef HAVE_SYS_TIMES_H
1144 #include <sys/times.h>
1145 #endif
1146 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1147 if test $ac_cv_struct_tms = yes; then
1148   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1149   [Define if <sys/times.h> defines struct tms.])
1150 fi
1151
1152 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1153 # revisit after autoconf 2.50.
1154 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1155 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1156 #include "ansidecl.h"
1157 #include "system.h"
1158 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1159 if test $gcc_cv_type_clock_t = yes; then
1160   AC_DEFINE(HAVE_CLOCK_T, 1,
1161   [Define if <time.h> defines clock_t.])
1162 fi
1163
1164 # Check if F_SETLKW is supported by fcntl.
1165 AC_CACHE_CHECK(for F_SETLKW, ac_cv_f_setlkw, [
1166 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1167 #include <fcntl.h>]], [[
1168 struct flock fl;
1169 fl.l_whence = 0;
1170 fl.l_start = 0;
1171 fl.l_len = 0;
1172 fl.l_pid = 0;
1173 return fcntl (1, F_SETLKW, &fl);]])],
1174 [ac_cv_f_setlkw=yes],[ac_cv_f_setlkw=no])])
1175 if test $ac_cv_f_setlkw = yes; then
1176   AC_DEFINE(HOST_HAS_F_SETLKW, 1,
1177   [Define if F_SETLKW supported by fcntl.])
1178 fi
1179
1180 # Restore CFLAGS, CXXFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1181 CFLAGS="$saved_CFLAGS"
1182 CXXFLAGS="$saved_CXXFLAGS"
1183
1184 # mkdir takes a single argument on some systems.
1185 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1186
1187 # File extensions
1188 manext='.1'
1189 objext='.o'
1190 AC_SUBST(manext)
1191 AC_SUBST(objext)
1192
1193 # With Setjmp/Longjmp based exception handling.
1194 AC_ARG_ENABLE(sjlj-exceptions,
1195 [AS_HELP_STRING([--enable-sjlj-exceptions],
1196                 [arrange to use setjmp/longjmp exception handling])],
1197 [case $target in
1198   *-*-hpux10*)
1199     if test $enableval != yes; then
1200       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1201       enableval=yes
1202     fi
1203     ;;
1204 esac
1205 force_sjlj_exceptions=yes],
1206 [case $target in
1207   *-*-hpux10*)
1208     force_sjlj_exceptions=yes
1209     enableval=yes
1210     ;;
1211   *)
1212     force_sjlj_exceptions=no
1213     ;;
1214 esac])
1215 if test $force_sjlj_exceptions = yes; then
1216   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1217   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1218     [Define 0/1 to force the choice for exception handling model.])
1219 fi
1220
1221 # --------------------------------------------------------
1222 # Build, host, and target specific configuration fragments
1223 # --------------------------------------------------------
1224
1225 # Collect build-machine-specific information.
1226 . ${srcdir}/config.build
1227
1228 # Collect host-machine-specific information.
1229 . ${srcdir}/config.host
1230
1231 target_gtfiles=
1232
1233 # Collect target-machine-specific information.
1234 . ${srcdir}/config.gcc
1235
1236 extra_objs="${host_extra_objs} ${extra_objs}"
1237 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1238
1239 # Default the target-machine variables that were not explicitly set.
1240 if test x"$tm_file" = x
1241 then tm_file=$cpu_type/$cpu_type.h; fi
1242
1243 if test x"$extra_headers" = x
1244 then extra_headers=; fi
1245
1246 if test x$md_file = x
1247 then md_file=$cpu_type/$cpu_type.md; fi
1248
1249 if test x$out_file = x
1250 then out_file=$cpu_type/$cpu_type.c; fi
1251
1252 if test x"$tmake_file" = x
1253 then tmake_file=$cpu_type/t-$cpu_type
1254 fi
1255
1256 # Support --enable-initfini-array.
1257 if test x$enable_initfini_array != xno; then
1258   tm_file="${tm_file} initfini-array.h"
1259 fi
1260
1261 if test x"$dwarf2" = xyes
1262 then tm_file="$tm_file tm-dwarf2.h"
1263 fi
1264
1265 # Say what files are being used for the output code and MD file.
1266 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1267 echo "Using \`$srcdir/config/$md_file' as machine description file."
1268
1269 # If any of the xm_file variables contain nonexistent files, warn
1270 # about them and drop them.
1271
1272 bx=
1273 for x in $build_xm_file; do
1274   if    test -f $srcdir/config/$x
1275   then      bx="$bx $x"
1276   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1277   fi
1278 done
1279 build_xm_file="$bx"
1280
1281 hx=
1282 for x in $host_xm_file; do
1283   if    test -f $srcdir/config/$x
1284   then      hx="$hx $x"
1285   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1286   fi
1287 done
1288 host_xm_file="$hx"
1289
1290 tx=
1291 for x in $xm_file; do
1292   if    test -f $srcdir/config/$x
1293   then      tx="$tx $x"
1294   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1295   fi
1296 done
1297 xm_file="$tx"
1298
1299 count=a
1300 for f in $tm_file; do
1301         count=${count}x
1302 done
1303 if test $count = ax; then
1304         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1305 else
1306         echo "Using the following target machine macro files:"
1307         for f in $tm_file; do
1308                 echo "  $srcdir/config/$f"
1309         done
1310 fi
1311
1312 if test x$need_64bit_hwint = xyes; then
1313         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1314 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1315 fi
1316
1317 if test x$use_long_long_for_widest_fast_int = xyes; then
1318         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1319 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1320 efficiently supported by the host hardware.])
1321 fi
1322
1323 gnu_ld_bool=`if test x"$gnu_ld" = x"yes"; then echo 1; else echo 0; fi`
1324 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld_bool, [Define to 1 if using GNU ld.])
1325
1326 gnu_as_bool=`if test x"$gas" = x"yes"; then echo 1; else echo 0; fi`
1327 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as_bool, [Define to 1 if using GNU as.])
1328
1329 count=a
1330 for f in $host_xm_file; do
1331         count=${count}x
1332 done
1333 if test $count = a; then
1334         :
1335 elif test $count = ax; then
1336         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1337 else
1338         echo "Using the following host machine macro files:"
1339         for f in $host_xm_file; do
1340                 echo "  $srcdir/config/$f"
1341         done
1342 fi
1343 echo "Using ${out_host_hook_obj} for host machine hooks."
1344
1345 if test "$host_xm_file" != "$build_xm_file"; then
1346         count=a
1347         for f in $build_xm_file; do
1348                 count=${count}x
1349         done
1350         if test $count = a; then
1351                 :
1352         elif test $count = ax; then
1353                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1354         else
1355                 echo "Using the following build machine macro files:"
1356                 for f in $build_xm_file; do
1357                         echo "  $srcdir/config/$f"
1358                 done
1359         fi
1360 fi
1361
1362 if test -n "$configured_native_system_header_dir"; then
1363   native_system_header_dir=$configured_native_system_header_dir
1364 fi
1365 NATIVE_SYSTEM_HEADER_DIR="$native_system_header_dir"
1366 AC_SUBST(NATIVE_SYSTEM_HEADER_DIR)
1367
1368 case ${host} in
1369   powerpc*-*-darwin*)
1370     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1371       gcc_cv_mcontext_underscores,
1372       AC_COMPILE_IFELSE([
1373 #include <sys/cdefs.h>
1374 #include <sys/signal.h>
1375 #include <ucontext.h>
1376 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1377 ],
1378         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1379       if test $gcc_cv_mcontext_underscores = yes; then
1380         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1381           [mcontext_t fields start with __])
1382       fi
1383     ;;
1384 esac
1385
1386 # ---------
1387 # Threading
1388 # ---------
1389
1390 # Check if a valid thread package
1391 case ${enable_threads} in
1392   "" | no)
1393     # No threads
1394     target_thread_file='single'
1395     ;;
1396   yes)
1397     # default
1398     target_thread_file='single'
1399     ;;
1400   aix | dce | lynx | mipssde | posix | rtems | \
1401   single | tpf | vxworks | win32)
1402     target_thread_file=${enable_threads}
1403     ;;
1404   *)
1405     echo "${enable_threads} is an unknown thread package" 1>&2
1406     exit 1
1407     ;;
1408 esac
1409
1410 if test x${thread_file} = x; then
1411   # No thread file set by target-specific clauses in config.gcc,
1412   # so use file chosen by default logic above
1413   thread_file=${target_thread_file}
1414 fi
1415
1416 # --------
1417 # UNSORTED
1418 # --------
1419
1420 use_cxa_atexit=no
1421 if test x$enable___cxa_atexit = xyes || \
1422    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1423   if test x$host = x$target; then
1424     case $host in
1425       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1426       # keyed to flag_use_cxa_atexit
1427       *-*-mingw32*)
1428         use_cxa_atexit=yes
1429         ;;
1430       *)
1431         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1432           [echo "__cxa_atexit can't be enabled on this target"])
1433         ;;
1434     esac
1435   else
1436     # We can't check for __cxa_atexit when building a cross, so assume
1437     # it is available
1438     use_cxa_atexit=yes
1439   fi
1440   if test x$use_cxa_atexit = xyes; then
1441     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1442       [Define if you want to use __cxa_atexit, rather than atexit, to
1443       register C++ destructors for local statics and global objects.
1444       This is essential for fully standards-compliant handling of
1445       destructors, but requires __cxa_atexit in libc.])
1446   fi
1447 fi
1448
1449 # Look for a file containing extra machine modes.
1450 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1451   extra_modes_file='$(srcdir)'/config/${extra_modes}
1452   AC_SUBST(extra_modes_file)
1453   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1454   [Define to the name of a file containing a list of extra machine modes
1455    for this architecture.])
1456 fi
1457
1458 # Convert extra_options into a form suitable for Makefile use.
1459 extra_opt_files=
1460 all_opt_files=
1461 for f in $extra_options; do
1462   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1463   all_opt_files="$all_opt_files $srcdir/config/$f"
1464 done
1465 AC_SUBST(extra_opt_files)
1466
1467 # auto-host.h is the file containing items generated by autoconf and is
1468 # the first file included by config.h.
1469 # If host=build, it is correct to have bconfig include auto-host.h
1470 # as well.  If host!=build, we are in error and need to do more
1471 # work to find out the build config parameters.
1472 if test x$host = x$build
1473 then
1474         build_auto=auto-host.h
1475 else
1476         # We create a subdir, then run autoconf in the subdir.
1477         # To prevent recursion we set host and build for the new
1478         # invocation of configure to the build for this invocation
1479         # of configure.
1480         tempdir=build.$$
1481         rm -rf $tempdir
1482         mkdir $tempdir
1483         cd $tempdir
1484         case ${srcdir} in
1485         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1486         *) realsrcdir=../${srcdir};;
1487         esac
1488         saved_CFLAGS="${CFLAGS}"
1489         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1490         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1491         ${realsrcdir}/configure \
1492                 --enable-languages=${enable_languages-all} \
1493                 --target=$target_alias --host=$build_alias --build=$build_alias
1494         CFLAGS="${saved_CFLAGS}"
1495
1496         # We just finished tests for the build machine, so rename
1497         # the file auto-build.h in the gcc directory.
1498         mv auto-host.h ../auto-build.h
1499         cd ..
1500         rm -rf $tempdir
1501         build_auto=auto-build.h
1502 fi
1503 AC_SUBST(build_subdir)
1504
1505 tm_file="${tm_file} defaults.h"
1506 tm_p_file="${tm_p_file} tm-preds.h"
1507 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1508 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1509 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1510 # put this back in temporarily.
1511 xm_file="auto-host.h ansidecl.h ${xm_file}"
1512
1513 # --------
1514 # UNSORTED
1515 # --------
1516
1517 changequote(,)dnl
1518 # Compile in configure arguments.
1519 if test -f configargs.h ; then
1520         # Being re-configured.
1521         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1522         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1523 else
1524         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1525 fi
1526
1527 # Double all backslashes and backslash all quotes to turn
1528 # gcc_config_arguments into a C string.
1529 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1530 $gcc_config_arguments
1531 EOF
1532 gcc_config_arguments_str=`cat conftest.out`
1533 rm -f conftest.out
1534
1535 cat > configargs.h <<EOF
1536 /* Generated automatically. */
1537 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1538 static const char thread_model[] = "$thread_file";
1539
1540 static const struct {
1541   const char *name, *value;
1542 } configure_default_options[] = $configure_default_options;
1543 EOF
1544 changequote([,])dnl
1545
1546 changequote(,)dnl
1547 gcc_BASEVER=`cat $srcdir/BASE-VER`
1548 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1549 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1550 if test -f $srcdir/REVISION ; then
1551         gcc_REVISION=`cat $srcdir/REVISION`
1552 else
1553         gcc_REVISION=""
1554 fi
1555 cat > plugin-version.h <<EOF
1556 #include "configargs.h"
1557
1558 #define GCCPLUGIN_VERSION_MAJOR   `echo $gcc_BASEVER | sed -e 's/^\([0-9]*\).*$/\1/'`
1559 #define GCCPLUGIN_VERSION_MINOR   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.\([0-9]*\).*$/\1/'`
1560 #define GCCPLUGIN_VERSION_PATCHLEVEL   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.[0-9]*\.\([0-9]*\)$/\1/'`
1561 #define GCCPLUGIN_VERSION  (GCCPLUGIN_VERSION_MAJOR*1000 + GCCPLUGIN_VERSION_MINOR)
1562
1563 static char basever[] = "$gcc_BASEVER";
1564 static char datestamp[] = "$gcc_DATESTAMP";
1565 static char devphase[] = "$gcc_DEVPHASE";
1566 static char revision[] = "$gcc_REVISION";
1567
1568 /* FIXME plugins: We should make the version information more precise.
1569    One way to do is to add a checksum. */
1570
1571 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1572                                                 devphase, revision,
1573                                                 configuration_arguments};
1574 EOF
1575 changequote([,])dnl
1576
1577 # Internationalization
1578 ZW_GNU_GETTEXT_SISTER_DIR
1579
1580 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1581 # -liconv on the link line twice.
1582 case "$LIBINTL" in *$LIBICONV*)
1583         LIBICONV= ;;
1584 esac
1585
1586 AC_ARG_ENABLE(secureplt,
1587 [AS_HELP_STRING([--enable-secureplt],
1588                 [enable -msecure-plt by default for PowerPC])],
1589 [], [])
1590
1591 AC_ARG_ENABLE(leading-mingw64-underscores,
1592   AS_HELP_STRING([--enable-leading-mingw64-underscores],
1593                  [enable leading underscores on 64 bit mingw targets]),
1594   [],[])
1595 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
1596   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
1597     [Define if we should use leading underscore on 64 bit mingw targets])])
1598
1599 AC_ARG_ENABLE(cld,
1600 [AS_HELP_STRING([--enable-cld], [enable -mcld by default for 32bit x86])], [],
1601 [enable_cld=no])
1602
1603 AC_ARG_ENABLE(frame-pointer,
1604 [AS_HELP_STRING([--enable-frame-pointer],
1605                 [enable -fno-omit-frame-pointer by default for 32bit x86])], [],
1606 [
1607 case $target_os in
1608 linux* | darwin[[8912]]*)
1609   # Enable -fomit-frame-pointer by default for Linux and Darwin with
1610   # DWARF2.
1611   enable_frame_pointer=no
1612   ;;
1613 *)
1614   enable_frame_pointer=yes
1615   ;;
1616 esac
1617 ])
1618
1619 # Windows32 Registry support for specifying GCC installation paths.
1620 AC_ARG_ENABLE(win32-registry,
1621 [AS_HELP_STRING([--disable-win32-registry],
1622                 [disable lookup of installation paths in the
1623                  Registry on Windows hosts])
1624 AS_HELP_STRING([--enable-win32-registry], [enable registry lookup (default)])
1625 AS_HELP_STRING([--enable-win32-registry=KEY],
1626                [use KEY instead of GCC version as the last portion
1627                 of the registry key])],,)
1628
1629 case $host_os in
1630   win32 | pe | cygwin* | mingw32* | uwin*)
1631     if test "x$enable_win32_registry" != xno; then
1632       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1633     fi
1634
1635     if test "x$enable_win32_registry" != xno; then
1636       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1637   [Define to 1 if installation paths should be looked up in the Windows
1638    Registry. Ignored on non-Windows hosts.])
1639
1640       if test "x$enable_win32_registry" != xyes \
1641          && test "x$enable_win32_registry" != x; then
1642         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1643   [Define to be the last component of the Windows registry key under which
1644    to look for installation paths.  The full key used will be
1645    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1646    The default is the GCC version number.])
1647       fi
1648     fi
1649   ;;
1650 esac
1651
1652 # Get an absolute path to the GCC top-level source directory
1653 holddir=`${PWDCMD-pwd}`
1654 cd $srcdir
1655 topdir=`${PWDCMD-pwd}`
1656 cd $holddir
1657
1658 # Conditionalize the makefile for this host machine.
1659 xmake_file=
1660 for f in ${host_xmake_file}
1661 do
1662         if test -f ${srcdir}/config/$f
1663         then
1664                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1665         fi
1666 done
1667
1668 # Conditionalize the makefile for this target machine.
1669 tmake_file_=
1670 for f in ${tmake_file}
1671 do
1672         if test -f ${srcdir}/config/$f
1673         then
1674                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1675         fi
1676 done
1677 tmake_file="${tmake_file_}"
1678
1679 out_object_file=`basename $out_file .c`.o
1680 common_out_object_file=`basename $common_out_file .c`.o
1681
1682 tm_file_list="options.h"
1683 tm_include_list="options.h insn-constants.h"
1684 for f in $tm_file; do
1685   case $f in
1686     ./* )
1687        f=`echo $f | sed 's/^..//'`
1688        tm_file_list="${tm_file_list} $f"
1689        tm_include_list="${tm_include_list} $f"
1690        ;;
1691     defaults.h )
1692        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1693        tm_include_list="${tm_include_list} $f"
1694        ;;
1695     * )
1696        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1697        tm_include_list="${tm_include_list} config/$f"
1698        ;;
1699   esac
1700 done
1701
1702 tm_p_file_list=
1703 tm_p_include_list=
1704 for f in $tm_p_file; do
1705   case $f in
1706     tm-preds.h )
1707        tm_p_file_list="${tm_p_file_list} $f"
1708        tm_p_include_list="${tm_p_include_list} $f"
1709        ;;
1710     * )
1711        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1712        tm_p_include_list="${tm_p_include_list} config/$f"
1713   esac
1714 done
1715
1716 xm_file_list=
1717 xm_include_list=
1718 for f in $xm_file; do
1719   case $f in
1720     ansidecl.h )
1721        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1722        xm_include_list="${xm_include_list} $f"
1723        ;;
1724     auto-host.h )
1725        xm_file_list="${xm_file_list} $f"
1726        xm_include_list="${xm_include_list} $f"
1727        ;;
1728     * )
1729        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1730        xm_include_list="${xm_include_list} config/$f"
1731        ;;
1732   esac
1733 done
1734
1735 host_xm_file_list=
1736 host_xm_include_list=
1737 for f in $host_xm_file; do
1738   case $f in
1739     ansidecl.h )
1740        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1741        host_xm_include_list="${host_xm_include_list} $f"
1742        ;;
1743     auto-host.h )
1744        host_xm_file_list="${host_xm_file_list} $f"
1745        host_xm_include_list="${host_xm_include_list} $f"
1746        ;;
1747     * )
1748        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1749        host_xm_include_list="${host_xm_include_list} config/$f"
1750        ;;
1751   esac
1752 done
1753
1754 build_xm_file_list=
1755 for f in $build_xm_file; do
1756   case $f in
1757     ansidecl.h )
1758        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1759        build_xm_include_list="${build_xm_include_list} $f"
1760        ;;
1761     auto-build.h | auto-host.h )
1762        build_xm_file_list="${build_xm_file_list} $f"
1763        build_xm_include_list="${build_xm_include_list} $f"
1764        ;;
1765     * )
1766        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1767        build_xm_include_list="${build_xm_include_list} config/$f"
1768        ;;
1769   esac
1770 done
1771
1772 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1773 # cross-compiler which does not use the native headers and libraries.
1774 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1775 CROSS=                                          AC_SUBST(CROSS)
1776 ALL=all.internal                                AC_SUBST(ALL)
1777 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1778
1779 if test "x$with_build_sysroot" != x; then
1780   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1781 else
1782   # This value is used, even on a native system, because
1783   # CROSS_SYSTEM_HEADER_DIR is just
1784   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1785   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1786 fi
1787
1788 if test x$host != x$target
1789 then
1790         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1791         ALL=all.cross
1792         SYSTEM_HEADER_DIR=$build_system_header_dir
1793         case "$host","$target" in
1794         # Darwin crosses can use the host system's libraries and headers,
1795         # because of the fat library support.  Of course, it must be the
1796         # same version of Darwin on both sides.  Allow the user to
1797         # just say --target=foo-darwin without a version number to mean
1798         # "the version on this system".
1799             *-*-darwin*,*-*-darwin*)
1800                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1801                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1802                 if test $hostos = $targetos -o $targetos = darwin ; then
1803                     CROSS=
1804                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1805                     with_headers=yes
1806                 fi
1807                 ;;
1808
1809             i?86-*-*,x86_64-*-* \
1810             | powerpc*-*-*,powerpc64*-*-*)
1811                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1812         esac
1813
1814         case $target in
1815                 *-*-mingw*)
1816                         if test "x$with_headers" = x; then
1817                                 with_headers=yes
1818                         fi
1819                         ;;
1820                 *)
1821                         ;;
1822         esac
1823 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1824         SYSTEM_HEADER_DIR=$build_system_header_dir
1825 fi
1826
1827 # If this is a cross-compiler that does not
1828 # have its own set of headers then define
1829 # inhibit_libc
1830
1831 # If this is using newlib, without having the headers available now,
1832 # then define inhibit_libc in LIBGCC2_CFLAGS.
1833 # This prevents libgcc2 from containing any code which requires libc
1834 # support.
1835 : ${inhibit_libc=false}
1836 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1837        test x$with_newlib = xyes ; } &&
1838      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1839        inhibit_libc=true
1840 fi
1841 AC_SUBST(inhibit_libc)
1842
1843 # When building gcc with a cross-compiler, we need to adjust things so
1844 # that the generator programs are still built with the native compiler.
1845 # Also, we cannot run fixincludes.
1846
1847 # These are the normal (build=host) settings:
1848 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1849 CXX_FOR_BUILD='$(CXX)'          AC_SUBST(CXX_FOR_BUILD)
1850 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1851 BUILD_CXXFLAGS='$(ALL_CXXFLAGS)' AC_SUBST(BUILD_CXXFLAGS)
1852 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1853 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1854
1855 # And these apply if build != host, or we are generating coverage data
1856 if test x$build != x$host || test "x$coverage_flags" != x
1857 then
1858     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1859     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1860 fi
1861
1862 # Expand extra_headers to include complete path.
1863 # This substitutes for lots of t-* files.
1864 extra_headers_list=
1865 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1866 for file in ${extra_headers} ; do
1867   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1868 done
1869
1870 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1871 if test x"$use_gcc_tgmath" = xyes
1872 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1873 fi
1874
1875 # Define collect2 in Makefile.
1876 case $host_can_use_collect2 in
1877   no) collect2= ;;
1878   *) collect2='collect2$(exeext)' ;;
1879 esac
1880 AC_SUBST([collect2])
1881
1882 # Add a definition of USE_COLLECT2 if system wants one.
1883 case $use_collect2 in
1884   no) use_collect2= ;;
1885   "") ;;
1886   *)
1887     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1888     xm_defines="${xm_defines} USE_COLLECT2"
1889     case $host_can_use_collect2 in
1890       no)
1891         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1892         ;;
1893     esac
1894     ;;
1895 esac
1896
1897 AC_DEFINE_UNQUOTED(LTOPLUGINSONAME,"${host_lto_plugin_soname}",
1898 [Define to the name of the LTO plugin DSO that must be
1899   passed to the linker's -plugin=LIB option.])
1900
1901 # ---------------------------
1902 # Assembler & linker features
1903 # ---------------------------
1904
1905 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1906 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1907 # However when ld-new is first executed from the build tree, libtool will
1908 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1909 # to the build tree.  While doing this we need to use the previous-stage
1910 # linker, or we have an infinite loop.  The presence of a shell script as
1911 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1912 # the gcc/collect-ld script.  So we need to know how libtool works, or
1913 # exec-tool will fail.
1914
1915 m4_defun([_LT_CONFIG_COMMANDS], [])
1916 AC_PROG_LIBTOOL
1917 AC_SUBST(objdir)
1918 AC_SUBST(enable_fast_install)
1919
1920 # Identify the assembler which will work hand-in-glove with the newly
1921 # built GCC, so that we can examine its features.  This is the assembler
1922 # which will be driven by the driver program.
1923 #
1924 # If build != host, and we aren't building gas in-tree, we identify a
1925 # build->target assembler and hope that it will have the same features
1926 # as the host->target assembler we'll be using.
1927 gcc_cv_gas_major_version=
1928 gcc_cv_gas_minor_version=
1929 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1930
1931 m4_pattern_allow([AS_FOR_TARGET])dnl
1932 AS_VAR_SET_IF(gcc_cv_as,, [
1933 if test -x "$DEFAULT_ASSEMBLER"; then
1934         gcc_cv_as="$DEFAULT_ASSEMBLER"
1935 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1936      && test -f ../gas/Makefile \
1937      && test x$build = x$host; then
1938         gcc_cv_as=../gas/as-new$build_exeext
1939 elif test -x as$build_exeext; then
1940         # Build using assembler in the current directory.
1941         gcc_cv_as=./as$build_exeext
1942 elif ( set dummy $AS_FOR_TARGET; test -x $[2] ); then
1943         gcc_cv_as="$AS_FOR_TARGET"
1944 else
1945         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1946 fi])
1947
1948 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1949 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1950 case "$ORIGINAL_AS_FOR_TARGET" in
1951   ./as | ./as$build_exeext) ;;
1952   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1953 esac
1954
1955 AC_MSG_CHECKING(what assembler to use)
1956 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1957   # Single tree build which includes gas.  We want to prefer it
1958   # over whatever linker top-level may have detected, since
1959   # we'll use what we're building after installation anyway.
1960   AC_MSG_RESULT(newly built gas)
1961   in_tree_gas=yes
1962   _gcc_COMPUTE_GAS_VERSION
1963   in_tree_gas_is_elf=no
1964   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1965      || (grep 'obj_format = multi' ../gas/Makefile \
1966          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1967   then
1968     in_tree_gas_is_elf=yes
1969   fi
1970 else
1971   AC_MSG_RESULT($gcc_cv_as)
1972   in_tree_gas=no
1973 fi
1974
1975 # Identify the linker which will work hand-in-glove with the newly
1976 # built GCC, so that we can examine its features.  This is the linker
1977 # which will be driven by the driver program.
1978 #
1979 # If build != host, and we aren't building gas in-tree, we identify a
1980 # build->target linker and hope that it will have the same features
1981 # as the host->target linker we'll be using.
1982 gcc_cv_gld_major_version=
1983 gcc_cv_gld_minor_version=
1984 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1985 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1986
1987 AS_VAR_SET_IF(gcc_cv_ld,, [
1988 if test -x "$DEFAULT_LINKER"; then
1989         gcc_cv_ld="$DEFAULT_LINKER"
1990 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1991      && test -f ../ld/Makefile \
1992      && test x$build = x$host; then
1993         gcc_cv_ld=../ld/ld-new$build_exeext
1994 elif test -x collect-ld$build_exeext; then
1995         # Build using linker in the current directory.
1996         gcc_cv_ld=./collect-ld$build_exeext
1997 elif ( set dummy $LD_FOR_TARGET; test -x $[2] ); then
1998         gcc_cv_ld="$LD_FOR_TARGET"
1999 else
2000         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
2001 fi])
2002
2003 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
2004 PLUGIN_LD_SUFFIX=`basename $gcc_cv_ld | sed -e "s,$target_alias-,,"`
2005 AC_ARG_WITH(plugin-ld,
2006 [AS_HELP_STRING([[--with-plugin-ld=[ARG]]], [specify the plugin linker])],
2007 [if test x"$withval" != x; then
2008    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
2009    PLUGIN_LD_SUFFIX=`echo $withval | sed -e "s,$target_alias-,,"`
2010  fi])
2011 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
2012 AC_DEFINE_UNQUOTED(PLUGIN_LD_SUFFIX, "$PLUGIN_LD_SUFFIX", [Specify plugin linker])
2013
2014 # Check to see if we are using gold instead of ld
2015 AC_MSG_CHECKING(whether we are using gold)
2016 ld_is_gold=no
2017 if test x$gcc_cv_ld != x; then
2018   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
2019      | grep "GNU gold" > /dev/null; then
2020     ld_is_gold=yes
2021   fi
2022 fi
2023 AC_MSG_RESULT($ld_is_gold)
2024
2025 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
2026 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
2027 case "$ORIGINAL_LD_FOR_TARGET" in
2028   ./collect-ld | ./collect-ld$build_exeext) ;;
2029   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
2030 esac
2031
2032 AC_MSG_CHECKING(what linker to use)
2033 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext \
2034    || test "$gcc_cv_ld" = ../gold/ld-new$build_exeext; then
2035         # Single tree build which includes ld.  We want to prefer it
2036         # over whatever linker top-level may have detected, since
2037         # we'll use what we're building after installation anyway.
2038         AC_MSG_RESULT(newly built ld)
2039         in_tree_ld=yes
2040         in_tree_ld_is_elf=no
2041         if (grep 'EMUL = .*elf' ../ld/Makefile \
2042             || grep 'EMUL = .*linux' ../ld/Makefile \
2043             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
2044           in_tree_ld_is_elf=yes
2045         elif test "$ld_is_gold" = yes; then
2046           in_tree_ld_is_elf=yes
2047         fi
2048         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
2049         do
2050 changequote(,)dnl
2051                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
2052                 if test x$gcc_cv_gld_version != x; then
2053                         break
2054                 fi
2055         done
2056         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
2057         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
2058 changequote([,])dnl
2059 else
2060         AC_MSG_RESULT($gcc_cv_ld)
2061         in_tree_ld=no
2062 fi
2063
2064 # Figure out what nm we will be using.
2065 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
2066 AS_VAR_SET_IF(gcc_cv_nm,, [
2067 if test -f $gcc_cv_binutils_srcdir/configure.in \
2068      && test -f ../binutils/Makefile \
2069      && test x$build = x$host; then
2070         gcc_cv_nm=../binutils/nm-new$build_exeext
2071 elif test -x nm$build_exeext; then
2072         gcc_cv_nm=./nm$build_exeext
2073 elif ( set dummy $NM_FOR_TARGET; test -x $[2] ); then
2074         gcc_cv_nm="$NM_FOR_TARGET"
2075 else
2076         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
2077 fi])
2078
2079 AC_MSG_CHECKING(what nm to use)
2080 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2081         # Single tree build which includes binutils.
2082         AC_MSG_RESULT(newly built nm)
2083         in_tree_nm=yes
2084 else
2085         AC_MSG_RESULT($gcc_cv_nm)
2086         in_tree_nm=no
2087 fi
2088
2089 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2090 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2091 case "$ORIGINAL_NM_FOR_TARGET" in
2092   ./nm | ./nm$build_exeext) ;;
2093   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2094 esac
2095
2096
2097 # Figure out what objdump we will be using.
2098 AS_VAR_SET_IF(gcc_cv_objdump,, [
2099 if test -f $gcc_cv_binutils_srcdir/configure.in \
2100      && test -f ../binutils/Makefile \
2101      && test x$build = x$host; then
2102         # Single tree build which includes binutils.
2103         gcc_cv_objdump=../binutils/objdump$build_exeext
2104 elif test -x objdump$build_exeext; then
2105         gcc_cv_objdump=./objdump$build_exeext
2106 elif ( set dummy $OBJDUMP_FOR_TARGET; test -x $[2] ); then
2107         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2108 else
2109         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2110 fi])
2111
2112 AC_MSG_CHECKING(what objdump to use)
2113 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2114         # Single tree build which includes binutils.
2115         AC_MSG_RESULT(newly built objdump)
2116 elif test x$gcc_cv_objdump = x; then
2117         AC_MSG_RESULT(not found)
2118 else
2119         AC_MSG_RESULT($gcc_cv_objdump)
2120 fi
2121
2122 # Figure out what readelf we will be using.
2123 AS_VAR_SET_IF(gcc_cv_readelf,, [
2124 if test -f $gcc_cv_binutils_srcdir/configure.in \
2125      && test -f ../binutils/Makefile \
2126      && test x$build = x$host; then
2127         # Single tree build which includes binutils.
2128         gcc_cv_readelf=../binutils/readelf$build_exeext
2129 elif test -x readelf$build_exeext; then
2130         gcc_cv_readelf=./readelf$build_exeext
2131 else
2132         AC_PATH_PROG(gcc_cv_readelf, readelf)
2133 fi])
2134
2135 AC_MSG_CHECKING(what readelf to use)
2136 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2137         # Single tree build which includes binutils.
2138         AC_MSG_RESULT(newly built readelf)
2139 elif test x$gcc_cv_readelf = x; then
2140         AC_MSG_RESULT(not found)
2141 else
2142         AC_MSG_RESULT($gcc_cv_readelf)
2143 fi
2144
2145 # Figure out what assembler alignment features are present.
2146 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2147  [2,6,0],,
2148 [.balign 4
2149 .p2align 2],,
2150 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2151   [Define if your assembler supports .balign and .p2align.])])
2152
2153 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2154  [2,8,0],,
2155  [.p2align 4,,7],,
2156 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2157   [Define if your assembler supports specifying the maximum number
2158    of bytes to skip when using the GAS .p2align command.])])
2159
2160 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2161  [2,8,0],,
2162  [.literal16],,
2163 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2164   [Define if your assembler supports .literal16.])])
2165
2166 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2167  [elf,2,9,0],,
2168  [conftest_label1: .word 0
2169 .subsection -1
2170 conftest_label2: .word 0
2171 .previous],
2172  [if test x$gcc_cv_nm != x; then
2173     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2174     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2175     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2176     then :
2177     else gcc_cv_as_subsection_m1=yes
2178     fi
2179     rm -f conftest.nm1 conftest.nm2
2180   fi],
2181  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2182   [Define if your assembler supports .subsection and .subsection -1 starts
2183    emitting at the beginning of your section.])])
2184
2185 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2186  [2,2,0],,
2187  [      .weak foobar],,
2188 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2189
2190 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2191  [2,17,0],,
2192  [      .weakref foobar, barfnot],,
2193 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2194
2195 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2196  [2,15,91],,
2197  [      .SPACE $TEXT$
2198         .NSUBSPA $CODE$,COMDAT],,
2199 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2200
2201 # .hidden needs to be supported in both the assembler and the linker,
2202 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2203 # This is irritatingly difficult to feature test for; we have to check the
2204 # date string after the version number.  If we've got an in-tree
2205 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2206 # to be safe.
2207 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2208 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2209  [elf,2,13,0],,
2210 [       .hidden foobar
2211 foobar:],[
2212 # Solaris 9/x86 as incorrectly emits an alias for a hidden symbol with
2213 # STV_HIDDEN, so disable .hidden support if so.
2214 case "${target}" in
2215   i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
2216     if test x$gcc_cv_as != x && test x$gcc_cv_objdump != x; then
2217       cat > conftest.s <<EOF
2218 .globl hidden
2219         .hidden hidden
2220 hidden:
2221 .globl default
2222         .set    default,hidden
2223 EOF
2224       if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
2225         && $gcc_cv_objdump -t conftest.o 2>/dev/null | \
2226         grep '\.hidden default' > /dev/null; then
2227         gcc_cv_as_hidden=no
2228       else
2229         gcc_cv_as_hidden=yes
2230       fi
2231     else
2232       # Assume bug is present if objdump is missing.
2233       gcc_cv_as_hidden=no
2234     fi
2235     ;;
2236   *)
2237     gcc_cv_as_hidden=yes
2238     ;;
2239 esac])
2240 case "${target}" in
2241   *-*-darwin*)
2242     # Darwin as has some visibility support, though with a different syntax.
2243     gcc_cv_as_hidden=yes
2244     ;;
2245 esac
2246
2247 # gnu_indirect_function type is an extension proposed at
2248 # http://groups.google/com/group/generic-abi/files. It allows dynamic runtime
2249 # selection of function implementation
2250 AC_ARG_ENABLE(gnu-indirect-function,
2251  [AS_HELP_STRING([--enable-gnu-indirect-function],
2252                  [enable the use of the @gnu_indirect_function to glibc systems])],
2253  [case $enable_gnu_indirect_function in
2254     yes | no) ;;
2255     *) AC_MSG_ERROR(['$enable_gnu_indirect_function' is an invalid value for --enable-gnu-indirect-function.
2256 Valid choices are 'yes' and 'no'.]) ;;
2257   esac],
2258  [enable_gnu_indirect_function="$default_gnu_indirect_function"])
2259 if test x$enable_gnu_indirect_function = xyes; then
2260   AC_DEFINE(HAVE_GNU_INDIRECT_FUNCTION, 1,
2261    [Define if your system supports gnu indirect functions.])
2262 fi
2263
2264 changequote(,)dnl
2265 if test $in_tree_ld != yes ; then
2266   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2267   if echo "$ld_ver" | grep GNU > /dev/null; then
2268     if test x"$ld_is_gold" = xyes; then
2269       # GNU gold --version looks like this:
2270       #
2271       # GNU gold (GNU Binutils 2.21.51.20110225) 1.11
2272       #
2273       # We extract the binutils version which is more familiar and specific
2274       # than the gold version.
2275       ld_vers=`echo $ld_ver | sed -n \
2276           -e 's,^[^)]*[  ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
2277     else
2278       # GNU ld --version looks like this:
2279       #
2280       # GNU ld (GNU Binutils) 2.21.51.20110225
2281       ld_vers=`echo $ld_ver | sed -n \
2282           -e 's,^.*[     ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2283     fi
2284     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2285     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2286     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2287     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2288   else
2289     case "${target}" in
2290       *-*-solaris2*)
2291         # See acinclude.m4 (gcc_SUN_LD_VERSION) for the version number
2292         # format.
2293         #
2294         # Don't reuse gcc_gv_sun_ld_vers_* in case a linker other than
2295         # /usr/ccs/bin/ld has been configured.
2296         ld_ver=`$gcc_cv_ld -V 2>&1`
2297         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2298           ld_vers=`echo $ld_ver | sed -n \
2299             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2300           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2301           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2302         fi
2303         ;;
2304     esac
2305   fi
2306 fi
2307 changequote([,])dnl
2308
2309 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2310 [[if test $in_tree_ld = yes ; then
2311   gcc_cv_ld_hidden=no
2312   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2313      && test $in_tree_ld_is_elf = yes; then
2314      gcc_cv_ld_hidden=yes
2315   fi
2316 else
2317   gcc_cv_ld_hidden=yes
2318   if test x"$ld_is_gold" = xyes; then
2319     :
2320   elif echo "$ld_ver" | grep GNU > /dev/null; then
2321     if test 0"$ld_date" -lt 20020404; then
2322       if test -n "$ld_date"; then
2323         # If there was date string, but was earlier than 2002-04-04, fail
2324         gcc_cv_ld_hidden=no
2325       elif test -z "$ld_vers"; then
2326         # If there was no date string nor ld version number, something is wrong
2327         gcc_cv_ld_hidden=no
2328       else
2329         test -z "$ld_vers_patch" && ld_vers_patch=0
2330         if test "$ld_vers_major" -lt 2; then
2331           gcc_cv_ld_hidden=no
2332         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2333           gcc_cv_ld_hidden="no"
2334         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2335           gcc_cv_ld_hidden=no
2336         fi
2337       fi
2338     fi
2339   else
2340     case "${target}" in
2341       *-*-darwin*)
2342         # Darwin ld has some visibility support.
2343         gcc_cv_ld_hidden=yes
2344         ;;
2345       hppa64*-*-hpux* | ia64*-*-hpux*)
2346         gcc_cv_ld_hidden=yes
2347         ;;
2348       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2349         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
2350         # .symbolic was only added in Solaris 9 12/02.
2351         gcc_cv_ld_hidden=yes
2352         ;;
2353       *)
2354         gcc_cv_ld_hidden=no
2355         ;;
2356     esac
2357   fi
2358 fi]])
2359 libgcc_visibility=no
2360 AC_SUBST(libgcc_visibility)
2361 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2362 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2363   libgcc_visibility=yes
2364   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2365   [Define if your assembler and linker support .hidden.])
2366 fi
2367
2368 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2369 gcc_cv_ld_ro_rw_mix=unknown
2370 if test $in_tree_ld = yes ; then
2371   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2372      && test $in_tree_ld_is_elf = yes; then
2373     gcc_cv_ld_ro_rw_mix=read-write
2374   fi
2375 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2376   echo '.section myfoosect, "a"' > conftest1.s
2377   echo '.section myfoosect, "aw"' > conftest2.s
2378   echo '.byte 1' >> conftest2.s
2379   echo '.section myfoosect, "a"' > conftest3.s
2380   echo '.byte 0' >> conftest3.s
2381   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2382      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2383      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2384      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2385         conftest2.o conftest3.o > /dev/null 2>&1; then
2386     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2387                          | sed -e '/myfoosect/!d' -e N`
2388     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2389       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2390         gcc_cv_ld_ro_rw_mix=read-only
2391       else
2392         gcc_cv_ld_ro_rw_mix=read-write
2393       fi
2394     fi
2395   fi
2396 changequote(,)dnl
2397   rm -f conftest.* conftest[123].*
2398 changequote([,])dnl
2399 fi
2400 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2401         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2402   [Define if your linker links a mix of read-only
2403    and read-write sections into a read-write section.])
2404 fi
2405 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2406
2407 gcc_AC_INITFINI_ARRAY
2408
2409 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2410 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2411   [elf,2,11,0],,
2412 [       .data
2413         .uleb128 L2 - L1
2414 L1:
2415         .uleb128 1280
2416         .sleb128 -1010
2417 L2:],
2418 [[# GAS versions before 2.11 do not support uleb128,
2419   # despite appearing to.
2420   # ??? There exists an elf-specific test that will crash
2421   # the assembler.  Perhaps it's better to figure out whether
2422   # arbitrary sections are supported and try the test.
2423   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2424   if echo "$as_ver" | grep GNU > /dev/null; then
2425     as_vers=`echo $as_ver | sed -n \
2426         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2427     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2428     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2429     if test $as_major -eq 2 && test $as_minor -lt 11
2430     then :
2431     else gcc_cv_as_leb128=yes
2432     fi
2433   fi]],
2434   [AC_DEFINE(HAVE_AS_LEB128, 1,
2435     [Define if your assembler supports .sleb128 and .uleb128.])])
2436
2437 # Check if we have assembler support for unwind directives.
2438 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2439   ,,
2440 [       .text
2441         .cfi_startproc
2442         .cfi_offset 0, 0
2443         .cfi_same_value 1
2444         .cfi_def_cfa 1, 2
2445         .cfi_escape 1, 2, 3, 4, 5
2446         .cfi_endproc],
2447 [case "$target" in
2448   *-*-solaris*)
2449     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2450     # read-only and read-write sections, we need to make sure that the
2451     # assembler used emits read-write .eh_frame sections.
2452     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2453       if test "x$gcc_cv_objdump" != x; then
2454         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2455                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2456           gcc_cv_as_cfi_directive=no
2457         else
2458           case "$target" in
2459             i?86-*-solaris2.1[[0-9]]* | x86_64-*-solaris2.1[[0-9]]*)
2460               # On Solaris/x86, make sure that GCC and gas agree on using
2461               # read-only .eh_frame sections for 64-bit.
2462               if $gcc_cv_as --64 -o conftest.o conftest.s > /dev/null 2>&1 && \
2463                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2464                         sed -e /.eh_frame/!d -e N | \
2465                         grep READONLY > /dev/null; then
2466                 gcc_cv_as_cfi_directive=yes
2467               else
2468                 gcc_cv_as_cfi_directive=no
2469               fi
2470               ;;
2471             *)
2472               gcc_cv_as_cfi_directive=yes
2473               ;;
2474           esac
2475         fi
2476       else
2477         # no objdump, err on the side of caution
2478         gcc_cv_as_cfi_directive=no
2479       fi
2480     else
2481       gcc_cv_as_cfi_directive=yes
2482     fi
2483     ;;
2484   *-*-*)
2485     gcc_cv_as_cfi_directive=yes
2486     ;;
2487 esac])
2488 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_objdump != x; then
2489 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2490   ,,
2491 [       .text
2492         .cfi_startproc
2493         .cfi_adjust_cfa_offset 64
2494         .skip 75040, 0
2495         .cfi_adjust_cfa_offset 128
2496         .cfi_endproc],
2497 [[
2498 if $gcc_cv_objdump -Wf conftest.o 2>/dev/null \
2499     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2500    gcc_cv_as_cfi_advance_working=yes
2501 fi
2502 ]])
2503 else
2504   # no objdump, err on the side of caution
2505   gcc_cv_as_cfi_advance_working=no
2506 fi
2507 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_DIRECTIVE)
2508 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2509   [`if test $gcc_cv_as_cfi_directive = yes \
2510        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2511   [Define 0/1 if your assembler supports CFI directives.])
2512
2513 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE)
2514 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2515   gcc_cv_as_cfi_personality_directive, ,,
2516 [       .text
2517         .cfi_startproc
2518         .cfi_personality 0, symbol
2519         .cfi_endproc])
2520 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2521   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2522     then echo 1; else echo 0; fi`],
2523   [Define 0/1 if your assembler supports .cfi_personality.])
2524
2525 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2526   gcc_cv_as_cfi_sections_directive, ,,
2527 [       .text
2528         .cfi_sections .debug_frame, .eh_frame
2529         .cfi_startproc
2530         .cfi_endproc],
2531 [case $target_os in
2532   win32 | pe | cygwin* | mingw32* | uwin*)
2533     # Need to check that we generated the correct relocation for the
2534     # .debug_frame section.  This was fixed for binutils 2.21.
2535     gcc_cv_as_cfi_sections_directive=no
2536     if test "x$gcc_cv_objdump" != x; then
2537      if $gcc_cv_objdump -j .debug_frame -r conftest.o 2>/dev/null | \
2538         grep secrel > /dev/null; then
2539       gcc_cv_as_cfi_sections_directive=yes
2540      fi
2541     fi
2542     ;;
2543   *)
2544     gcc_cv_as_cfi_sections_directive=yes
2545     ;;
2546 esac])
2547 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_SECTIONS_DIRECTIVE)
2548 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2549   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2550     then echo 1; else echo 0; fi`],
2551   [Define 0/1 if your assembler supports .cfi_sections.])
2552
2553 # GAS versions up to and including 2.11.0 may mis-optimize
2554 # .eh_frame data.
2555 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2556   [elf,2,12,0],,
2557 [       .text
2558 .LFB1:
2559         .4byte  0
2560 .L1:
2561         .4byte  0
2562 .LFE1:
2563         .section        .eh_frame,"aw",@progbits
2564 __FRAME_BEGIN__:
2565         .4byte  .LECIE1-.LSCIE1
2566 .LSCIE1:
2567         .4byte  0x0
2568         .byte   0x1
2569         .ascii "z\0"
2570         .byte   0x1
2571         .byte   0x78
2572         .byte   0x1a
2573         .byte   0x0
2574         .byte   0x4
2575         .4byte  1
2576         .p2align 1
2577 .LECIE1:
2578 .LSFDE1:
2579         .4byte  .LEFDE1-.LASFDE1
2580 .LASFDE1:
2581         .4byte  .LASFDE1-__FRAME_BEGIN__
2582         .4byte  .LFB1
2583         .4byte  .LFE1-.LFB1
2584         .byte   0x4
2585         .4byte  .LFE1-.LFB1
2586         .byte   0x4
2587         .4byte  .L1-.LFB1
2588 .LEFDE1:],
2589 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2590 cat > conftest.lit <<EOF
2591  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2592  0010 01000000 12000000 18000000 00000000  ................
2593  0020 08000000 04080000 0044               .........D      @&t@
2594 EOF
2595 cat > conftest.big <<EOF
2596  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2597  0010 00000001 00000012 00000018 00000000  ................
2598  0020 00000008 04000000 0844               .........D      @&t@
2599 EOF
2600   # If the assembler didn't choke, and we can objdump,
2601   # and we got the correct data, then succeed.
2602   # The text in the here-document typically retains its unix-style line
2603   # endings, while the output of objdump will use host line endings.
2604   # Therefore, use diff -b for the comparisons.
2605   if test x$gcc_cv_objdump != x \
2606   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2607      | tail -3 > conftest.got \
2608   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2609     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2610   then
2611     gcc_cv_as_eh_frame=yes
2612   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2613     gcc_cv_as_eh_frame=buggy
2614   else
2615     # Uh oh, what do we do now?
2616     gcc_cv_as_eh_frame=no
2617   fi])
2618
2619 if test $gcc_cv_as_eh_frame = buggy; then
2620   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2621   [Define if your assembler mis-optimizes .eh_frame data.])
2622 fi
2623
2624 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2625  [elf,2,12,0], [--fatal-warnings],
2626  [.section .rodata.str, "aMS", @progbits, 1])
2627 if test $gcc_cv_as_shf_merge = no; then
2628   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2629     [elf,2,12,0], [--fatal-warnings],
2630     [.section .rodata.str, "aMS", %progbits, 1])
2631 fi
2632 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2633   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2634 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2635
2636 gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as)],
2637  gcc_cv_as_comdat_group,
2638  [elf,2,16,0], [--fatal-warnings],
2639  [.section .text,"axG",@progbits,.foo,comdat])
2640 if test $gcc_cv_as_comdat_group = yes; then
2641   gcc_cv_as_comdat_group_percent=no
2642   gcc_cv_as_comdat_group_group=no
2643 else
2644  gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as, %type)],
2645    gcc_cv_as_comdat_group_percent,
2646    [elf,2,16,0], [--fatal-warnings],
2647    [.section .text,"axG",%progbits,.foo,comdat])
2648  if test $gcc_cv_as_comdat_group_percent = yes; then
2649    gcc_cv_as_comdat_group_group=no
2650  else
2651    case "${target}" in
2652      # Sun as uses a completely different syntax.
2653      *-*-solaris2*)
2654        case "${target}" in
2655          sparc*-*-solaris2*)
2656            conftest_s='
2657                .group foo,".text%foo",#comdat
2658                .section ".text%foo", #alloc,#execinstr,#progbits
2659                .globl foo
2660              foo:
2661              '
2662            ;;
2663          i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
2664            conftest_s='
2665                .group foo,.text%foo,#comdat
2666                .section .text%foo, "ax", @progbits
2667                .globl  foo
2668              foo:
2669              '
2670            ;;
2671        esac
2672        gcc_GAS_CHECK_FEATURE([COMDAT group support (Sun as, .group)],
2673          gcc_cv_as_comdat_group_group,
2674          ,, [$conftest_s])
2675        ;;
2676    esac
2677  fi
2678 fi
2679 if test x"$ld_is_gold" = xyes; then
2680   comdat_group=yes
2681 elif test $in_tree_ld = yes ; then
2682   comdat_group=no
2683   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2684      && test $in_tree_ld_is_elf = yes; then
2685      comdat_group=yes
2686   fi
2687 elif echo "$ld_ver" | grep GNU > /dev/null; then
2688   comdat_group=yes
2689   if test 0"$ld_date" -lt 20050308; then
2690     if test -n "$ld_date"; then
2691       # If there was date string, but was earlier than 2005-03-08, fail
2692       comdat_group=no
2693     elif test "$ld_vers_major" -lt 2; then
2694       comdat_group=no
2695     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2696       comdat_group=no
2697     fi
2698   fi
2699 else
2700 changequote(,)dnl
2701   case "${target}" in
2702     *-*-solaris2.1[1-9]*)
2703       comdat_group=no
2704       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
2705       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
2706       # version 1.688.
2707       #
2708       # If using Sun as for COMDAT group as emitted by GCC, one needs at
2709       # least ld version 1.2267.
2710       if test "$ld_vers_major" -gt 1; then
2711         comdat_group=yes
2712       elif test "x$gas_flag" = xyes && test "$ld_vers_minor" -ge 1688; then
2713         comdat_group=yes
2714       elif test "$ld_vers_minor" -ge 2267; then
2715         comdat_group=yes
2716       fi
2717       ;;
2718     *)
2719       # Assume linkers other than GNU ld don't support COMDAT group.
2720       comdat_group=no
2721       ;;
2722   esac
2723 changequote([,])dnl
2724 fi
2725 # Allow overriding the automatic COMDAT group tests above.
2726 AC_ARG_ENABLE(comdat,
2727   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
2728   [comdat_group="$enable_comdat"])
2729 if test $comdat_group = no; then
2730   gcc_cv_as_comdat_group=no
2731   gcc_cv_as_comdat_group_percent=no
2732   gcc_cv_as_comdat_group_group=no
2733 fi
2734 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2735   [`if test $gcc_cv_as_comdat_group = yes \
2736     || test $gcc_cv_as_comdat_group_percent = yes \
2737     || test $gcc_cv_as_comdat_group_group = yes; then echo 1; else echo 0; fi`],
2738 [Define 0/1 if your assembler and linker support COMDAT groups.])
2739
2740 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2741  gcc_cv_as_discriminator,
2742  [2,19,51],,
2743 [       .text
2744         .file 1 "conf.c"
2745         .loc 1 1 0 discriminator 1],,
2746 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2747   [Define if your assembler supports the .loc discriminator sub-directive.])])
2748
2749 # Thread-local storage - the check is heavily parameterized.
2750 conftest_s=
2751 tls_first_major=
2752 tls_first_minor=
2753 tls_as_opt=
2754 case "$target" in
2755 changequote(,)dnl
2756   alpha*-*-*)
2757     conftest_s='
2758         .section ".tdata","awT",@progbits
2759 foo:    .long   25
2760         .text
2761         ldq     $27,__tls_get_addr($29)         !literal!1
2762         lda     $16,foo($29)                    !tlsgd!1
2763         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2764         ldq     $27,__tls_get_addr($29)         !literal!2
2765         lda     $16,foo($29)                    !tlsldm!2
2766         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2767         ldq     $1,foo($29)                     !gotdtprel
2768         ldah    $2,foo($29)                     !dtprelhi
2769         lda     $3,foo($2)                      !dtprello
2770         lda     $4,foo($29)                     !dtprel
2771         ldq     $1,foo($29)                     !gottprel
2772         ldah    $2,foo($29)                     !tprelhi
2773         lda     $3,foo($2)                      !tprello
2774         lda     $4,foo($29)                     !tprel'
2775         tls_first_major=2
2776         tls_first_minor=13
2777         tls_as_opt=--fatal-warnings
2778         ;;
2779   cris-*-*|crisv32-*-*)
2780     conftest_s='
2781         .section ".tdata","awT",@progbits
2782 x:      .long   25
2783         .text
2784         move.d x:IE,$r10
2785         nop'
2786         tls_first_major=2
2787         tls_first_minor=20
2788         tls_as_opt=--fatal-warnings
2789         ;;
2790   frv*-*-*)
2791     conftest_s='
2792         .section ".tdata","awT",@progbits
2793 x:      .long   25
2794         .text
2795         call    #gettlsoff(x)'
2796         tls_first_major=2
2797         tls_first_minor=14
2798         ;;
2799   hppa*-*-linux*)
2800     conftest_s='
2801 t1:     .reg    %r20
2802 t2:     .reg    %r21
2803 gp:     .reg    %r19
2804         .section ".tdata","awT",@progbits
2805 foo:    .long   25
2806         .text
2807         .align  4
2808         addil LT%foo-$tls_gdidx$,gp
2809         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2810         b __tls_get_addr
2811         nop
2812         addil LT%foo-$tls_ldidx$,gp
2813         b __tls_get_addr
2814         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2815         addil LR%foo-$tls_dtpoff$,%ret0
2816         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2817         mfctl %cr27,%t1
2818         addil LT%foo-$tls_ieoff$,gp
2819         ldw RT%foo-$tls_ieoff$(%r1),%t2
2820         add %t1,%t2,%t3
2821         mfctl %cr27,%t1
2822         addil LR%foo-$tls_leoff$,%t1
2823         ldo RR%foo-$tls_leoff$(%r1),%t2'
2824         tls_first_major=2
2825         tls_first_minor=15
2826         tls_as_opt=--fatal-warnings
2827         ;;
2828   arm*-*-*)
2829     conftest_s='
2830         .section ".tdata","awT",%progbits
2831 foo:    .long   25
2832         .text
2833 .word foo(gottpoff)
2834 .word foo(tpoff)
2835 .word foo(tlsgd)
2836 .word foo(tlsldm)
2837 .word foo(tlsldo)'
2838         tls_first_major=2
2839         tls_first_minor=17
2840         ;;
2841   i[34567]86-*-* | x86_64-*-solaris2.1[0-9]*)
2842     case "$target" in
2843       i[34567]86-*-solaris2.*)
2844         on_solaris=yes
2845         tga_func=___tls_get_addr
2846         ;;
2847       x86_64-*-solaris2.1[0-9]*)
2848         on_solaris=yes
2849         tga_func=__tls_get_addr
2850         ;;
2851       *)
2852         on_solaris=no
2853         ;;
2854     esac
2855     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2856       conftest_s='
2857         .section .tdata,"awt",@progbits'
2858       tls_first_major=0
2859       tls_first_minor=0
2860 changequote([,])dnl
2861       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
2862 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
2863 changequote(,)dnl
2864     else
2865       conftest_s='
2866         .section ".tdata","awT",@progbits'
2867       tls_first_major=2
2868       tls_first_minor=14
2869       tls_as_opt="--fatal-warnings"
2870     fi
2871     conftest_s="$conftest_s
2872 foo:    .long   25
2873         .text
2874         movl    %gs:0, %eax
2875         leal    foo@tlsgd(,%ebx,1), %eax
2876         leal    foo@tlsldm(%ebx), %eax
2877         leal    foo@dtpoff(%eax), %edx
2878         movl    foo@gottpoff(%ebx), %eax
2879         subl    foo@gottpoff(%ebx), %eax
2880         addl    foo@gotntpoff(%ebx), %eax
2881         movl    foo@indntpoff, %eax
2882         movl    \$foo@tpoff, %eax
2883         subl    \$foo@tpoff, %eax
2884         leal    foo@ntpoff(%ecx), %eax"
2885     ;;
2886   x86_64-*-*)
2887     conftest_s='
2888         .section ".tdata","awT",@progbits
2889 foo:    .long   25
2890         .text
2891         movq    %fs:0, %rax
2892         leaq    foo@TLSGD(%rip), %rdi
2893         leaq    foo@TLSLD(%rip), %rdi
2894         leaq    foo@DTPOFF(%rax), %rdx
2895         movq    foo@GOTTPOFF(%rip), %rax
2896         movq    $foo@TPOFF, %rax'
2897         tls_first_major=2
2898         tls_first_minor=14
2899         tls_as_opt=--fatal-warnings
2900         ;;
2901   ia64-*-*)
2902     conftest_s='
2903         .section ".tdata","awT",@progbits
2904 foo:    data8   25
2905         .text
2906         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2907         addl    r17 = @ltoff(@dtprel(foo#)), gp
2908         addl    r18 = @ltoff(@tprel(foo#)), gp
2909         addl    r19 = @dtprel(foo#), gp
2910         adds    r21 = @dtprel(foo#), r13
2911         movl    r23 = @dtprel(foo#)
2912         addl    r20 = @tprel(foo#), gp
2913         adds    r22 = @tprel(foo#), r13
2914         movl    r24 = @tprel(foo#)'
2915         tls_first_major=2
2916         tls_first_minor=13
2917         tls_as_opt=--fatal-warnings
2918         ;;
2919   mips*-*-*)
2920     conftest_s='
2921         .section .tdata,"awT",@progbits
2922 x:
2923         .word 2
2924         .text
2925         addiu $4, $28, %tlsgd(x)
2926         addiu $4, $28, %tlsldm(x)
2927         lui $4, %dtprel_hi(x)
2928         addiu $4, $4, %dtprel_lo(x)
2929         lw $4, %gottprel(x)($28)
2930         lui $4, %tprel_hi(x)
2931         addiu $4, $4, %tprel_lo(x)'
2932         tls_first_major=2
2933         tls_first_minor=16
2934         tls_as_opt='-32 --fatal-warnings'
2935         ;;
2936   m68k-*-*)
2937     conftest_s='
2938         .section .tdata,"awT",@progbits
2939 x:
2940         .word 2
2941         .text
2942 foo:
2943         move.l x@TLSGD(%a5),%a0
2944         move.l x@TLSLDM(%a5),%a0
2945         move.l x@TLSLDO(%a5),%a0
2946         move.l x@TLSIE(%a5),%a0
2947         move.l x@TLSLE(%a5),%a0'
2948         tls_first_major=2
2949         tls_first_minor=19
2950         tls_as_opt='--fatal-warnings'
2951         ;;
2952   powerpc-*-*)
2953     conftest_s='
2954         .section ".tdata","awT",@progbits
2955         .align 2
2956 ld0:    .space 4
2957 ld1:    .space 4
2958 x1:     .space 4
2959 x2:     .space 4
2960 x3:     .space 4
2961         .text
2962         addi 3,31,ld0@got@tlsgd
2963         bl __tls_get_addr
2964         addi 3,31,x1@got@tlsld
2965         bl __tls_get_addr
2966         addi 9,3,x1@dtprel
2967         addis 9,3,x2@dtprel@ha
2968         addi 9,9,x2@dtprel@l
2969         lwz 9,x3@got@tprel(31)
2970         add 9,9,x@tls
2971         addi 9,2,x1@tprel
2972         addis 9,2,x2@tprel@ha
2973         addi 9,9,x2@tprel@l'
2974         tls_first_major=2
2975         tls_first_minor=14
2976         tls_as_opt="-a32 --fatal-warnings"
2977         ;;
2978   powerpc64-*-*)
2979     conftest_s='
2980         .section ".tdata","awT",@progbits
2981         .align 3
2982 ld0:    .space 8
2983 ld1:    .space 8
2984 x1:     .space 8
2985 x2:     .space 8
2986 x3:     .space 8
2987         .text
2988         addi 3,2,ld0@got@tlsgd
2989         bl .__tls_get_addr
2990         nop
2991         addi 3,2,ld1@toc
2992         bl .__tls_get_addr
2993         nop
2994         addi 3,2,x1@got@tlsld
2995         bl .__tls_get_addr
2996         nop
2997         addi 9,3,x1@dtprel
2998         bl .__tls_get_addr
2999         nop
3000         addis 9,3,x2@dtprel@ha
3001         addi 9,9,x2@dtprel@l
3002         bl .__tls_get_addr
3003         nop
3004         ld 9,x3@got@dtprel(2)
3005         add 9,9,3
3006         bl .__tls_get_addr
3007         nop'
3008         tls_first_major=2
3009         tls_first_minor=14
3010         tls_as_opt="-a64 --fatal-warnings"
3011         ;;
3012   s390-*-*)
3013     conftest_s='
3014         .section ".tdata","awT",@progbits
3015 foo:    .long   25
3016         .text
3017         .long   foo@TLSGD
3018         .long   foo@TLSLDM
3019         .long   foo@DTPOFF
3020         .long   foo@NTPOFF
3021         .long   foo@GOTNTPOFF
3022         .long   foo@INDNTPOFF
3023         l       %r1,foo@GOTNTPOFF(%r12)
3024         l       %r1,0(%r1):tls_load:foo
3025         bas     %r14,0(%r1,%r13):tls_gdcall:foo
3026         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
3027         tls_first_major=2
3028         tls_first_minor=14
3029         tls_as_opt="-m31 --fatal-warnings"
3030         ;;
3031   s390x-*-*)
3032     conftest_s='
3033         .section ".tdata","awT",@progbits
3034 foo:    .long   25
3035         .text
3036         .quad   foo@TLSGD
3037         .quad   foo@TLSLDM
3038         .quad   foo@DTPOFF
3039         .quad   foo@NTPOFF
3040         .quad   foo@GOTNTPOFF
3041         lg      %r1,foo@GOTNTPOFF(%r12)
3042         larl    %r1,foo@INDNTPOFF
3043         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
3044         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
3045         tls_first_major=2
3046         tls_first_minor=14
3047         tls_as_opt="-m64 -Aesame --fatal-warnings"
3048         ;;
3049   sh-*-* | sh[34]-*-*)
3050     conftest_s='
3051         .section ".tdata","awT",@progbits
3052 foo:    .long   25
3053         .text
3054         .long   foo@TLSGD
3055         .long   foo@TLSLDM
3056         .long   foo@DTPOFF
3057         .long   foo@GOTTPOFF
3058         .long   foo@TPOFF'
3059         tls_first_major=2
3060         tls_first_minor=13
3061         tls_as_opt=--fatal-warnings
3062         ;;
3063   sparc*-*-*)
3064     case "$target" in
3065       sparc*-sun-solaris2.*)
3066         on_solaris=yes
3067         tga_func=__tls_get_addr
3068         ;;
3069       *)
3070         on_solaris=no
3071         ;;
3072     esac
3073     if test x$on_solaris = xyes && test x$gas_flag = xno; then
3074       conftest_s='
3075         .section ".tdata",#alloc,#write,#tls'
3076         tls_first_major=0
3077         tls_first_minor=0
3078     else
3079       conftest_s='
3080         .section ".tdata","awT",@progbits'
3081         tls_first_major=2
3082         tls_first_minor=14
3083         tls_as_opt="-32 --fatal-warnings"
3084     fi
3085     conftest_s="$conftest_s
3086 foo:    .long   25
3087         .text
3088         sethi   %tgd_hi22(foo), %o0
3089         add     %o0, %tgd_lo10(foo), %o1
3090         add     %l7, %o1, %o0, %tgd_add(foo)
3091         call    __tls_get_addr, %tgd_call(foo)
3092         sethi   %tldm_hi22(foo), %l1
3093         add     %l1, %tldm_lo10(foo), %l2
3094         add     %l7, %l2, %o0, %tldm_add(foo)
3095         call    __tls_get_addr, %tldm_call(foo)
3096         sethi   %tldo_hix22(foo), %l3
3097         xor     %l3, %tldo_lox10(foo), %l4
3098         add     %o0, %l4, %l5, %tldo_add(foo)
3099         sethi   %tie_hi22(foo), %o3
3100         add     %o3, %tie_lo10(foo), %o3
3101         ld      [%l7 + %o3], %o2, %tie_ld(foo)
3102         add     %g7, %o2, %o4, %tie_add(foo)
3103         sethi   %tle_hix22(foo), %l1
3104         xor     %l1, %tle_lox10(foo), %o5
3105         ld      [%g7 + %o5], %o1"
3106         ;;
3107   tilepro*-*-*)
3108       conftest_s='
3109         .section ".tdata","awT",@progbits
3110 foo:    .long   25
3111         .text
3112         addli   r0, zero, tls_gd(foo)
3113         auli    r0, zero, tls_gd_ha16(foo)
3114         addli   r0, r0, tls_gd_lo16(foo)
3115         jal     __tls_get_addr
3116         addli   r0, zero, tls_ie(foo)
3117         auli    r0, r0, tls_ie_ha16(foo)
3118         addli   r0, r0, tls_ie_lo16(foo)'
3119         tls_first_major=2
3120         tls_first_minor=22
3121         tls_as_opt="--fatal-warnings"
3122         ;;
3123   tilegx*-*-*)
3124       conftest_s='
3125         .section ".tdata","awT",@progbits
3126 foo:    .long   25
3127         .text
3128         shl16insli r0, zero, hw0_last_tls_gd(foo)
3129         shl16insli r0, zero, hw1_last_tls_gd(foo)
3130         shl16insli r0, r0,   hw0_tls_gd(foo)
3131         jal        __tls_get_addr
3132         shl16insli r0, zero, hw1_last_tls_ie(foo)
3133         shl16insli r0, r0,   hw0_tls_ie(foo)'
3134         tls_first_major=2
3135         tls_first_minor=22
3136         tls_as_opt="--fatal-warnings"
3137         ;;
3138   xtensa*-*-*)
3139     conftest_s='
3140         .section ".tdata","awT",@progbits
3141 foo:    .long   25
3142         .text
3143         movi    a8, foo@TLSFUNC
3144         movi    a10, foo@TLSARG
3145         callx8.tls a8, foo@TLSCALL'
3146         tls_first_major=2
3147         tls_first_minor=19
3148         ;;
3149 changequote([,])dnl
3150 esac
3151 set_have_as_tls=no
3152 if test "x$enable_tls" = xno ; then
3153   : # TLS explicitly disabled.
3154 elif test "x$enable_tls" = xyes ; then
3155   set_have_as_tls=yes # TLS explicitly enabled.
3156 elif test -z "$tls_first_major"; then
3157   : # If we don't have a check, assume no support.
3158 else
3159   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
3160   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
3161   [set_have_as_tls=yes])
3162 fi
3163 case "$target" in
3164   # TLS was introduced in the Solaris 9 FCS release.  Support for GNU-style
3165   # TLS on x86 was only introduced in Solaris 9 4/04, replacing the earlier
3166   # Sun style that Sun ld and GCC don't support any longer.
3167   *-*-solaris2.*)
3168     AC_MSG_CHECKING(linker and ld.so.1 TLS support)
3169     ld_tls_support=no
3170     # Check ld and ld.so.1 TLS support.
3171     if echo "$ld_ver" | grep GNU > /dev/null; then
3172       # Assume all interesting versions of GNU ld have TLS support.
3173       # FIXME: still need ld.so.1 support, i.e. ld version checks below.
3174       ld_tls_support=yes
3175     else
3176       case "$target" in
3177         # Solaris 9/x86 ld has GNU style TLS support since version 1.374.
3178         i?86-*-solaris2.9)
3179           min_tls_ld_vers_minor=374
3180           ;;
3181         # Solaris 9/SPARC and Solaris 10+ ld have TLS support since FCS.
3182         sparc*-*-solaris2.9 | *-*-solaris2.1[[0-9]]*)
3183           min_tls_ld_vers_minor=343
3184           ;;
3185       esac
3186       if test "$ld_vers_major" -gt 1 || \
3187         test "$ld_vers_minor" -ge "$min_tls_ld_vers_minor"; then
3188         ld_tls_support=yes
3189       else
3190         set_have_as_tls=no
3191       fi
3192     fi
3193     AC_MSG_RESULT($ld_tls_support)
3194
3195     save_LIBS="$LIBS"
3196     save_LDFLAGS="$LDFLAGS"
3197     LIBS=
3198     LDFLAGS=
3199
3200     AC_MSG_CHECKING(library containing $tga_func)
3201     # Before Solaris 10, __tls_get_addr (SPARC/x64) resp. ___tls_get_addr
3202     # (32-bit x86) only lived in libthread, so check for that.  Keep
3203     # set_have_as_tls if found, disable if not.
3204     AC_SEARCH_LIBS([$tga_func], [thread],, [set_have_as_tls=no])
3205     # Clear LIBS if we cannot support TLS.
3206     if test $set_have_as_tls = no; then
3207       LIBS=
3208     fi
3209     # Always define LIB_TLS_SPEC, even without TLS support.
3210     AC_DEFINE_UNQUOTED(LIB_TLS_SPEC, "$LIBS",
3211         [Define to the library containing __tls_get_addr/___tls_get_addr.])
3212     AC_MSG_RESULT($LIBS)
3213
3214     LIBS="$save_LIBS"
3215     LDFLAGS="$save_LDFLAGS"
3216     ;;
3217 esac
3218 if test $set_have_as_tls = yes ; then
3219   AC_DEFINE(HAVE_AS_TLS, 1,
3220             [Define if your assembler and linker support thread-local storage.])
3221 fi
3222
3223 # Target-specific assembler checks.
3224
3225 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
3226 gcc_cv_ld_static_dynamic=no
3227 gcc_cv_ld_static_option='-Bstatic'
3228 gcc_cv_ld_dynamic_option='-Bdynamic'
3229 if test $in_tree_ld = yes ; then
3230   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
3231     gcc_cv_ld_static_dynamic=yes
3232   fi
3233 elif test x$gcc_cv_ld != x; then
3234   # Check if linker supports -Bstatic/-Bdynamic option
3235   if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
3236      && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
3237       gcc_cv_ld_static_dynamic=yes
3238   else
3239     case "$target" in
3240       # HP-UX ld uses -a flags to select between shared and archive.
3241       *-*-hpux*)
3242         if test x"$gnu_ld" = xno; then
3243           gcc_cv_ld_static_dynamic=yes
3244           gcc_cv_ld_static_option="-aarchive_shared"
3245           gcc_cv_ld_dynamic_option="-adefault"
3246         fi
3247         ;;
3248       # Solaris 2 ld always supports -Bstatic/-Bdynamic.
3249       *-*-solaris2*)
3250         gcc_cv_ld_static_dynamic=yes
3251         ;;
3252     esac
3253   fi
3254 fi
3255 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
3256         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
3257 [Define if your linker supports -Bstatic/-Bdynamic or equivalent options.])
3258         AC_DEFINE_UNQUOTED(LD_STATIC_OPTION, "$gcc_cv_ld_static_option",
3259 [Define to the linker option to disable use of shared objects.])
3260         AC_DEFINE_UNQUOTED(LD_DYNAMIC_OPTION, "$gcc_cv_ld_dynamic_option",
3261 [Define to the linker option to enable use of shared objects.])
3262 fi
3263 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
3264
3265 if test x"$demangler_in_ld" = xyes; then
3266   AC_MSG_CHECKING(linker --demangle support)
3267   gcc_cv_ld_demangle=no
3268   if test $in_tree_ld = yes; then
3269     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
3270       gcc_cv_ld_demangle=yes
3271     fi
3272   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
3273     # Check if the GNU linker supports --demangle option
3274     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
3275       gcc_cv_ld_demangle=yes
3276     fi
3277   fi
3278   if test x"$gcc_cv_ld_demangle" = xyes; then
3279     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
3280 [Define if your linker supports --demangle option.])
3281   fi
3282   AC_MSG_RESULT($gcc_cv_ld_demangle)
3283 fi
3284
3285 AC_MSG_CHECKING(linker plugin support)
3286 gcc_cv_lto_plugin=0
3287 if test -f liblto_plugin.la; then
3288   save_ld_ver="$ld_ver"
3289   save_ld_vers_major="$ld_vers_major"
3290   save_ld_vers_minor="$ld_vers_minor"
3291   save_ld_is_gold="$ld_is_gold"
3292
3293   ld_is_gold=no
3294
3295   if test $in_tree_ld = yes -a x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" = x"$gcc_cv_ld"; then
3296     ld_ver="GNU ld"
3297     # FIXME: ld_is_gold?
3298     ld_vers_major="$gcc_cv_gld_major_version"
3299     ld_vers_minor="$gcc_cv_gld_minor_version"
3300   else
3301     # Determine plugin linker version.
3302     # FIXME: Partial duplicate from above, generalize.
3303 changequote(,)dnl
3304     ld_ver=`$ORIGINAL_PLUGIN_LD_FOR_TARGET --version 2>/dev/null | sed 1q`
3305     if echo "$ld_ver" | grep GNU > /dev/null; then
3306       if echo "$ld_ver" | grep "GNU gold" > /dev/null; then
3307         ld_is_gold=yes
3308         ld_vers=`echo $ld_ver | sed -n \
3309             -e 's,^[^)]*[        ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
3310       else
3311         ld_vers=`echo $ld_ver | sed -n \
3312             -e 's,^.*[   ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
3313       fi
3314       ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
3315       ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
3316     fi
3317 changequote([,])dnl
3318   fi
3319
3320   # Determine plugin support.
3321   if echo "$ld_ver" | grep GNU > /dev/null; then
3322     # Require GNU ld or gold 2.21+ for plugin support by default.
3323     if test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -ge 21; then
3324       gcc_cv_lto_plugin=2
3325     # Allow -fuse-linker-plugin to enable plugin support in GNU gold 2.20.
3326     elif test "$ld_is_gold" = yes -a "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 20; then
3327       gcc_cv_lto_plugin=1
3328     fi
3329   fi
3330
3331   ld_ver="$save_ld_ver"
3332   ld_vers_major="$save_ld_vers_major"
3333   ld_vers_minor="$save_ld_vers_minor"
3334   ld_is_gold="$save_ld_is_gold"
3335 fi
3336 AC_DEFINE_UNQUOTED(HAVE_LTO_PLUGIN, $gcc_cv_lto_plugin,
3337   [Define to the level of your linker's plugin support.])
3338 AC_MSG_RESULT($gcc_cv_lto_plugin)
3339
3340 case "$target" in
3341   # All TARGET_ABI_OSF targets.
3342   alpha*-*-linux* | alpha*-*-*bsd*)
3343     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3344         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3345 [       .set nomacro
3346         .text
3347         extbl   $3, $2, $3      !lituse_bytoff!1
3348         ldq     $2, a($29)      !literal!1
3349         ldq     $4, b($29)      !literal!2
3350         ldq_u   $3, 0($2)       !lituse_base!1
3351         ldq     $27, f($29)     !literal!5
3352         jsr     $26, ($27), f   !lituse_jsr!5
3353         ldah    $29, 0($26)     !gpdisp!3
3354         lda     $0, c($29)      !gprel
3355         ldah    $1, d($29)      !gprelhigh
3356         lda     $1, d($1)       !gprellow
3357         lda     $29, 0($29)     !gpdisp!3],,
3358     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3359   [Define if your assembler supports explicit relocations.])])
3360     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3361         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3362 [       .set nomacro
3363         .text
3364         ldq     $27, a($29)     !literal!1
3365         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3366     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3367   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3368     ;;
3369
3370   cris-*-*)
3371     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3372       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3373       [-no-mul-bug-abort], [.text],,
3374       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3375                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3376     ;;
3377
3378   sparc*-*-*)
3379     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3380       [.register %g2, #scratch],,
3381       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3382                 [Define if your assembler supports .register.])])
3383
3384     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3385       [-relax], [.text],,
3386       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3387                 [Define if your assembler supports -relax option.])])
3388
3389     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3390       gcc_cv_as_sparc_gotdata_op,,
3391       [-K PIC],
3392 [.text
3393 .align 4
3394 foo:
3395         nop
3396 bar:
3397         sethi %gdop_hix22(foo), %g1
3398         xor    %g1, %gdop_lox10(foo), %g1
3399         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3400       [if test x$gcc_cv_ld != x \
3401        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3402          if test x$gcc_cv_objdump != x; then
3403            if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3404               | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3405                gcc_cv_as_sparc_gotdata_op=no
3406            else
3407                gcc_cv_as_sparc_gotdata_op=yes
3408            fi
3409          fi
3410        fi
3411        rm -f conftest],
3412       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3413                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3414
3415     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3416       gcc_cv_as_sparc_ua_pcrel,,
3417       [-K PIC],
3418 [.text
3419 foo:
3420         nop
3421 .data
3422 .align 4
3423 .byte 0
3424 .uaword %r_disp32(foo)],
3425       [if test x$gcc_cv_ld != x \
3426        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3427          gcc_cv_as_sparc_ua_pcrel=yes
3428        fi
3429        rm -f conftest],
3430       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3431                 [Define if your assembler and linker support unaligned PC relative relocs.])
3432
3433       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3434         gcc_cv_as_sparc_ua_pcrel_hidden,,
3435         [-K PIC],
3436 [.data
3437 .align 4
3438 .byte 0x31
3439 .uaword %r_disp32(foo)
3440 .byte 0x32, 0x33, 0x34
3441 .global foo
3442 .hidden foo
3443 foo:
3444 .skip 4],
3445         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3446          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3447          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3448             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3449             if $gcc_cv_objdump -R conftest 2> /dev/null \
3450                | grep 'DISP32' > /dev/null 2>&1; then
3451                 :
3452             else
3453                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3454             fi
3455          fi
3456          rm -f conftest],
3457          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3458                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3459     ]) # unaligned pcrel relocs
3460
3461     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3462       gcc_cv_as_sparc_offsetable_lo10,,
3463       [-xarch=v9],
3464 [.text
3465         or %g1, %lo(ab) + 12, %g1
3466         or %g1, %lo(ab + 12), %g1],
3467       [if test x$gcc_cv_objdump != x \
3468        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3469           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3470          gcc_cv_as_sparc_offsetable_lo10=yes
3471        fi],
3472        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3473                  [Define if your assembler supports offsetable %lo().])])
3474
3475     gcc_GAS_CHECK_FEATURE([FMAF, HPC, and VIS 3.0 instructions],
3476       gcc_cv_as_sparc_fmaf,,
3477       [-xarch=v9d],
3478       [.text
3479        .register %g2, #scratch
3480        .register %g3, #scratch
3481        .align 4
3482        fmaddd %f0, %f2, %f4, %f6
3483        addxccc %g1, %g2, %g3
3484        fsrl32 %f2, %f4, %f8
3485        fnaddd %f10, %f12, %f14],,
3486       [AC_DEFINE(HAVE_AS_FMAF_HPC_VIS3, 1,
3487                 [Define if your assembler supports FMAF, HPC, and VIS 3.0 instructions.])])
3488     ;;
3489
3490 changequote(,)dnl
3491   i[34567]86-*-* | x86_64-*-*)
3492 changequote([,])dnl
3493     case $target_os in
3494       cygwin*)
3495         # Full C++ conformance when using a shared libstdc++-v3 requires some
3496         # support from the Cygwin DLL, which in more recent versions exports
3497         # wrappers to aid in interposing and redirecting operators new, delete,
3498         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3499         # are configuring for a version of Cygwin that exports the wrappers.
3500         if test x$host = x$target; then
3501           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3502         else
3503           # Can't check presence of libc functions during cross-compile, so
3504           # we just have to assume we're building for an up-to-date target.
3505           gcc_ac_cygwin_dll_wrappers=yes
3506         fi
3507         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3508           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3509           [Define if you want to generate code by default that assumes that the
3510            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3511     esac
3512     case $target_os in
3513       cygwin* | pe | mingw32* | interix*)
3514         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3515         # definition is used unconditionally to initialise the default state of
3516         # the target option variable that governs usage of the feature.
3517         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3518          [2,19,52],,[.comm foo,1,32])
3519         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3520           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3521           [Define if your assembler supports specifying the alignment
3522            of objects allocated using the GAS .comm command.])
3523         # Used for DWARF 2 in PE
3524         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3525           gcc_cv_as_ix86_pe_secrel32,
3526           [2,15,91],,
3527 [.text
3528 foo:    nop
3529 .data
3530         .secrel32 foo],
3531           [if test x$gcc_cv_ld != x \
3532            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
3533              gcc_cv_as_ix86_pe_secrel32=yes
3534            fi
3535            rm -f conftest],
3536           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
3537             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
3538         # Test if the assembler supports the extended form of the .section
3539         # directive that specifies section alignment.  LTO support uses this,
3540         # but normally only after installation, so we warn but don't fail the
3541         # configure if LTO is enabled but the assembler does not support it.
3542         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
3543           [2,20,1],-fatal-warnings,[.section lto_test,"dr0"])
3544         if test x$gcc_cv_as_section_has_align != xyes; then
3545           case ",$enable_languages," in
3546             *,lto,*)
3547               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
3548               ;;
3549           esac
3550         fi
3551         # Test if the assembler supports the section flag 'e' for specifying
3552         # an excluded section.
3553         gcc_GAS_CHECK_FEATURE([.section with e], gcc_cv_as_section_has_e,
3554           [2,22,51],,
3555 [.section foo1,"e"
3556 .byte 0,0,0,0])
3557         AC_DEFINE_UNQUOTED(HAVE_GAS_SECTION_EXCLUDE,
3558           [`if test $gcc_cv_as_section_has_e = yes; then echo 1; else echo 0; fi`],
3559           [Define if your assembler supports specifying the section flag e.])
3560         ;;
3561     esac
3562
3563     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
3564        gcc_cv_as_ix86_filds,,,
3565        [filds mem; fists mem],,
3566        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
3567          [Define if your assembler uses filds and fists mnemonics.])])
3568
3569     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3570        gcc_cv_as_ix86_fildq,,,
3571        [fildq mem; fistpq mem],,
3572        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3573          [Define if your assembler uses fildq and fistq mnemonics.])])
3574
3575     gcc_GAS_CHECK_FEATURE([cmov syntax],
3576       gcc_cv_as_ix86_cmov_sun_syntax,,,
3577       [cmovl.l %edx, %eax],,
3578       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3579         [Define if your assembler supports the Sun syntax for cmov.])])
3580
3581     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3582       gcc_cv_as_ix86_ffreep,,,
3583       [ffreep %st(1)],,
3584       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3585         [Define if your assembler supports the ffreep mnemonic.])])
3586
3587     gcc_GAS_CHECK_FEATURE([.quad directive],
3588       gcc_cv_as_ix86_quad,,,
3589       [.quad 0],,
3590       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
3591         [Define if your assembler supports the .quad directive.])])
3592
3593     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3594       gcc_cv_as_ix86_sahf,,,
3595       [.code64
3596        sahf],,
3597       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3598         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
3599
3600     gcc_GAS_CHECK_FEATURE([hle prefixes],
3601       gcc_cv_as_ix86_hle,,,
3602       [lock xacquire cmpxchg %esi, (%ecx)],,
3603       [AC_DEFINE(HAVE_AS_IX86_HLE, 1,
3604         [Define if your assembler supports HLE prefixes.])])
3605
3606     gcc_GAS_CHECK_FEATURE([swap suffix],
3607       gcc_cv_as_ix86_swap,,,
3608       [movl.s %esp, %ebp],,
3609       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
3610         [Define if your assembler supports the swap suffix.])])
3611
3612     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3613       gcc_cv_as_ix86_diff_sect_delta,,,
3614       [.section .rodata
3615 .L1:
3616         .long .L2-.L1
3617         .long .L3-.L1
3618         .text
3619 .L3:    nop
3620 .L2:    nop],,
3621       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3622         [Define if your assembler supports the subtraction of symbols in different sections.])])
3623
3624     # These two are used unconditionally by i386.[ch]; it is to be defined
3625     # to 1 if the feature is present, 0 otherwise.
3626     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3627         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3628 [       .text
3629 .L0:
3630         nop
3631         .data
3632         .long .L0@GOTOFF])
3633     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3634       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3635       [Define true if the assembler supports '.long foo@GOTOFF'.])
3636
3637     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
3638         gcc_cv_as_ix86_rep_lock_prefix,,,
3639         [rep movsl
3640          rep ret
3641          rep nop
3642          rep bsf %ecx, %eax
3643          rep bsr %ecx, %eax
3644          lock addl %edi, (%eax,%esi)
3645          lock orl $0, (%esp)],,
3646         [AC_DEFINE(HAVE_AS_IX86_REP_LOCK_PREFIX, 1,
3647           [Define if the assembler supports 'rep <insn>, lock <insn>'.])])
3648
3649     gcc_GAS_CHECK_FEATURE([R_386_TLS_GD_PLT reloc],
3650         gcc_cv_as_ix86_tlsgdplt,,,
3651         [call    tls_gd@tlsgdplt],
3652         [if test x$gcc_cv_ld != x \
3653          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3654            gcc_cv_as_ix86_tlsgdplt=yes
3655          fi
3656          rm -f conftest],
3657       [AC_DEFINE(HAVE_AS_IX86_TLSGDPLT, 1,
3658         [Define if your assembler and linker support @tlsgdplt.])])
3659
3660     gcc_GAS_CHECK_FEATURE([R_386_TLS_LDM_PLT reloc],
3661         gcc_cv_as_ix86_tlsldmplt,,,
3662         [tls_ld:
3663          call    tls_ld@tlsldmplt],
3664         [if test x$gcc_cv_ld != x \
3665          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3666            gcc_cv_as_ix86_tlsldmplt=yes
3667          fi
3668          rm -f conftest],
3669       [AC_DEFINE(HAVE_AS_IX86_TLSLDMPLT, 1,
3670         [Define if your assembler and linker support @tlsldmplt.])])
3671
3672     ;;
3673
3674   ia64*-*-*)
3675     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3676         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3677 [       .text
3678         addl r15 = @ltoffx(x#), gp
3679         ;;
3680         ld8.mov r16 = [[r15]], x#],,
3681     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3682           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3683
3684     ;;
3685
3686   powerpc*-*-*)
3687     case $target in
3688       *-*-aix*) conftest_s='    .machine "pwr5"
3689         .csect .text[[PR]]
3690         mfcr 3,128';;
3691       *-*-darwin*)
3692         gcc_GAS_CHECK_FEATURE([.machine directive support],
3693           gcc_cv_as_machine_directive,,,
3694           [     .machine ppc7400])
3695         if test x$gcc_cv_as_machine_directive != xyes; then
3696           echo "*** This target requires an assembler supporting \".machine\"" >&2
3697           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3698           test x$build = x$target && exit 1
3699         fi
3700         conftest_s='    .text
3701         mfcr r3,128';;
3702       *) conftest_s='   .machine power4
3703         .text
3704         mfcr 3,128';;
3705     esac
3706
3707     gcc_GAS_CHECK_FEATURE([mfcr field support],
3708       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3709       [$conftest_s],,
3710       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3711           [Define if your assembler supports mfcr field.])])
3712
3713     case $target in
3714       *-*-aix*) conftest_s='    .machine "pwr5"
3715         .csect .text[[PR]]
3716         popcntb 3,3';;
3717       *) conftest_s='   .machine power5
3718         .text
3719         popcntb 3,3';;
3720     esac
3721
3722     gcc_GAS_CHECK_FEATURE([popcntb support],
3723       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3724       [$conftest_s],,
3725       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3726           [Define if your assembler supports popcntb field.])])
3727
3728     case $target in
3729       *-*-aix*) conftest_s='    .machine "pwr5x"
3730         .csect .text[[PR]]
3731         frin 1,1';;
3732       *) conftest_s='   .machine power5
3733         .text
3734         frin 1,1';;
3735     esac
3736
3737     gcc_GAS_CHECK_FEATURE([fp round support],
3738       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3739       [$conftest_s],,
3740       [AC_DEFINE(HAVE_AS_FPRND, 1,
3741           [Define if your assembler supports fprnd.])])
3742
3743     case $target in
3744       *-*-aix*) conftest_s='    .machine "pwr6"
3745         .csect .text[[PR]]
3746         mffgpr 1,3';;
3747       *) conftest_s='   .machine power6
3748         .text
3749         mffgpr 1,3';;
3750     esac
3751
3752     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3753       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
3754       [$conftest_s],,
3755       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3756           [Define if your assembler supports mffgpr and mftgpr.])])
3757
3758     case $target in
3759       *-*-aix*) conftest_s='    .csect .text[[PR]]
3760 LCF..0:
3761         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3762       *-*-darwin*)
3763         conftest_s='    .text
3764 LCF0:
3765         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3766       *) conftest_s='   .text
3767 .LCF0:
3768         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3769     esac
3770
3771     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3772       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3773       [$conftest_s],,
3774       [AC_DEFINE(HAVE_AS_REL16, 1,
3775           [Define if your assembler supports R_PPC_REL16 relocs.])])
3776
3777     case $target in
3778       *-*-aix*) conftest_s='    .machine "pwr6"
3779         .csect .text[[PR]]
3780         cmpb 3,4,5';;
3781       *) conftest_s='   .machine power6
3782         .text
3783         cmpb 3,4,5';;
3784     esac
3785
3786     gcc_GAS_CHECK_FEATURE([compare bytes support],
3787       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
3788       [$conftest_s],,
3789       [AC_DEFINE(HAVE_AS_CMPB, 1,
3790           [Define if your assembler supports cmpb.])])
3791
3792     case $target in
3793       *-*-aix*) conftest_s='    .machine "pwr6"
3794         .csect .text[[PR]]
3795         dadd 1,2,3';;
3796       *) conftest_s='   .machine power6
3797         .text
3798         dadd 1,2,3';;
3799     esac
3800
3801     gcc_GAS_CHECK_FEATURE([decimal float support],
3802       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
3803       [$conftest_s],,
3804       [AC_DEFINE(HAVE_AS_DFP, 1,
3805           [Define if your assembler supports DFP instructions.])])
3806
3807     case $target in
3808       *-*-aix*) conftest_s='    .machine "pwr7"
3809         .csect .text[[PR]]
3810         lxvd2x 1,2,3';;
3811       *) conftest_s='   .machine power7
3812         .text
3813         lxvd2x 1,2,3';;
3814     esac
3815
3816     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3817       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
3818       [$conftest_s],,
3819       [AC_DEFINE(HAVE_AS_VSX, 1,
3820           [Define if your assembler supports VSX instructions.])])
3821
3822     case $target in
3823       *-*-aix*) conftest_s='    .machine "pwr7"
3824         .csect .text[[PR]]
3825         popcntd 3,3';;
3826       *) conftest_s='   .machine power7
3827         .text
3828         popcntd 3,3';;
3829     esac
3830
3831     gcc_GAS_CHECK_FEATURE([popcntd support],
3832       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
3833       [$conftest_s],,
3834       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
3835           [Define if your assembler supports POPCNTD instructions.])])
3836
3837     case $target in
3838       *-*-aix*) conftest_s='    .csect .text[[PR]]
3839         lwsync';;
3840       *) conftest_s='   .text
3841         lwsync';;
3842     esac
3843
3844     gcc_GAS_CHECK_FEATURE([lwsync support],
3845       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
3846       [$conftest_s],,
3847       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
3848           [Define if your assembler supports LWSYNC instructions.])])
3849
3850     case $target in
3851       *-*-aix*) conftest_s='    .machine "476"
3852         .csect .text[[PR]]
3853         dci 0';;
3854       *) conftest_s='   .machine "476"
3855         .text
3856         dci 0';;
3857     esac
3858
3859     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
3860       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
3861       [$conftest_s],,
3862       [AC_DEFINE(HAVE_AS_DCI, 1,
3863           [Define if your assembler supports the DCI/ICI instructions.])])
3864
3865     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3866       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3867       [.gnu_attribute 4,1],,
3868       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3869           [Define if your assembler supports .gnu_attribute.])])
3870
3871     gcc_GAS_CHECK_FEATURE([tls marker support],
3872       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3873       [ bl __tls_get_addr(x@tlsgd)],,
3874       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3875           [Define if your assembler supports arg info for __tls_get_addr.])])
3876
3877     case $target in
3878       *-*-aix*)
3879         gcc_GAS_CHECK_FEATURE([.ref support],
3880           gcc_cv_as_aix_ref, [2.21.0],,
3881           [     .csect stuff[[rw]]
3882              stuff:
3883                 .long 1
3884                 .extern sym
3885                 .ref sym
3886           ],,
3887           [AC_DEFINE(HAVE_AS_REF, 1,
3888             [Define if your assembler supports .ref])])
3889         ;;
3890     esac
3891     ;;
3892
3893   mips*-*-*)
3894     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3895       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3896 [       lw $4,%gp_rel(foo)($4)],,
3897       [if test x$target_cpu_default = x
3898        then target_cpu_default=MASK_EXPLICIT_RELOCS
3899        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3900        fi])
3901     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3902       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3903       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3904                  [Define if the assembler understands -mno-shared.])])
3905
3906     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3907       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3908       [.gnu_attribute 4,1],,
3909       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3910           [Define if your assembler supports .gnu_attribute.])])
3911
3912     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3913       gcc_cv_as_mips_dtprelword, [2,18,0],,
3914       [.section .tdata,"awT",@progbits
3915 x:
3916         .word 2
3917         .text
3918         .dtprelword x+0x8000],,
3919       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3920           [Define if your assembler supports .dtprelword.])])
3921
3922     gcc_GAS_CHECK_FEATURE([DSPR1 mult with four accumulators support],
3923       gcc_cv_as_mips_dspr1_mult,,,
3924 [       .set    mips32r2
3925         .set    nodspr2
3926         .set    dsp
3927         madd    $ac3,$4,$5
3928         maddu   $ac3,$4,$5
3929         msub    $ac3,$4,$5
3930         msubu   $ac3,$4,$5
3931         mult    $ac3,$4,$5
3932         multu   $ac3,$4,$5],,
3933       [AC_DEFINE(HAVE_AS_DSPR1_MULT, 1,
3934           [Define if your assembler supports DSPR1 mult.])])
3935
3936     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
3937     gcc_cv_as_ld_jalr_reloc=no
3938     if test $gcc_cv_as_mips_explicit_relocs = yes; then
3939       if test $in_tree_ld = yes ; then
3940         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
3941            && test $in_tree_ld_is_elf = yes; then
3942           gcc_cv_as_ld_jalr_reloc=yes
3943         fi
3944       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
3945         echo '  .ent x' > conftest.s
3946         echo 'x:        ld $2,%got_disp(y)($3)' >> conftest.s
3947         echo '  ld $25,%call16(y)($28)' >> conftest.s
3948         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
3949         echo '1:        jalr $25' >> conftest.s
3950         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
3951         echo '1:        jalr $25' >> conftest.s
3952         echo '  .end x' >> conftest.s
3953         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
3954            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
3955           if $gcc_cv_objdump -d conftest.so | grep jalr >/dev/null 2>&1 \
3956              && $gcc_cv_objdump -d conftest.so | grep "bal.*<x>" >/dev/null 2>&1; then
3957             gcc_cv_as_ld_jalr_reloc=yes
3958           fi
3959         fi
3960         rm -f conftest.*
3961       fi
3962     fi
3963     if test $gcc_cv_as_ld_jalr_reloc = yes; then
3964       if test x$target_cpu_default = x; then
3965         target_cpu_default=MASK_RELAX_PIC_CALLS
3966       else
3967         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
3968       fi
3969     fi
3970     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
3971
3972     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
3973       [gcc_cv_ld_mips_personality_relaxation],
3974       [gcc_cv_ld_mips_personality_relaxation=no
3975        if test $in_tree_ld = yes ; then
3976          if test "$gcc_cv_gld_major_version" -eq 2 \
3977                  -a "$gcc_cv_gld_minor_version" -ge 21 \
3978                  -o "$gcc_cv_gld_major_version" -gt 2; then
3979            gcc_cv_ld_mips_personality_relaxation=yes
3980          fi
3981        elif test x$gcc_cv_as != x \
3982                  -a x$gcc_cv_ld != x \
3983                  -a x$gcc_cv_readelf != x ; then
3984          cat > conftest.s <<EOF
3985         .cfi_startproc
3986         .cfi_personality 0x80,indirect_ptr
3987         .ent test
3988 test:
3989         nop
3990         .end test
3991         .cfi_endproc
3992
3993         .section .data,"aw",@progbits
3994 indirect_ptr:
3995         .dc.a personality
3996 EOF
3997          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
3998             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
3999            if $gcc_cv_readelf -d conftest 2>&1 \
4000               | grep TEXTREL > /dev/null 2>&1; then
4001              :
4002            elif $gcc_cv_readelf --relocs conftest 2>&1 \
4003                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
4004              :
4005            else
4006              gcc_cv_ld_mips_personality_relaxation=yes
4007            fi
4008          fi
4009        fi
4010        rm -f conftest.s conftest.o conftest])
4011     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
4012             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
4013       [Define if your linker can relax absolute .eh_frame personality
4014 pointers into PC-relative form.])
4015     fi
4016     ;;
4017 esac
4018
4019 # Mips and HP-UX need the GNU assembler.
4020 # Linux on IA64 might be able to use the Intel assembler.
4021
4022 case "$target" in
4023   mips*-*-* | *-*-hpux* )
4024     if test x$gas_flag = xyes \
4025        || test x"$host" != x"$build" \
4026        || test ! -x "$gcc_cv_as" \
4027        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
4028       :
4029     else
4030       echo "*** This configuration requires the GNU assembler" >&2
4031       exit 1
4032     fi
4033     ;;
4034 esac
4035
4036 # ??? Not all targets support dwarf2 debug_line, even within a version
4037 # of gas.  Moreover, we need to emit a valid instruction to trigger any
4038 # info to the output file.  So, as supported targets are added to gas 2.11,
4039 # add some instruction here to (also) show we expect this might work.
4040 # ??? Once 2.11 is released, probably need to add first known working
4041 # version to the per-target configury.
4042 case "$cpu_type" in
4043   alpha | arm | avr | bfin | cris | i386 | m32c | m68k | microblaze | mips \
4044   | pa | rs6000 | score | sparc | spu | tilegx | tilepro | xstormy16 | xtensa)
4045     insn="nop"
4046     ;;
4047   ia64 | s390)
4048     insn="nop 0"
4049     ;;
4050   mmix)
4051     insn="swym 0"
4052     ;;
4053 esac
4054 if test x"$insn" != x; then
4055  conftest_s="\
4056         .file 1 \"conftest.s\"
4057         .loc 1 3 0
4058         $insn"
4059  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
4060   gcc_cv_as_dwarf2_debug_line,
4061   [elf,2,11,0],, [$conftest_s],
4062   [if test x$gcc_cv_objdump != x \
4063    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
4064       | grep debug_line > /dev/null 2>&1; then
4065      gcc_cv_as_dwarf2_debug_line=yes
4066    fi])
4067
4068 # The .debug_line file table must be in the exact order that
4069 # we specified the files, since these indices are also used
4070 # by DW_AT_decl_file.  Approximate this test by testing if
4071 # the assembler bitches if the same index is assigned twice.
4072  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
4073   gcc_cv_as_dwarf2_file_buggy,,,
4074 [       .file 1 "foo.s"
4075         .file 1 "bar.s"])
4076
4077  if test $gcc_cv_as_dwarf2_debug_line = yes \
4078  && test $gcc_cv_as_dwarf2_file_buggy = no; then
4079         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
4080   [Define if your assembler supports dwarf2 .file/.loc directives,
4081    and preserves file table indices exactly as given.])
4082  fi
4083
4084  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
4085   gcc_cv_as_gdwarf2_flag,
4086   [elf,2,11,0], [--gdwarf2], [$insn],,
4087   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
4088 [Define if your assembler supports the --gdwarf2 option.])])
4089
4090  gcc_GAS_CHECK_FEATURE([--gstabs option],
4091   gcc_cv_as_gstabs_flag,
4092   [elf,2,11,0], [--gstabs], [$insn],
4093   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
4094    # and warns about it, but still exits successfully.  So check for
4095    # this.
4096    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
4097    then :
4098    else gcc_cv_as_gstabs_flag=yes
4099    fi],
4100   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
4101 [Define if your assembler supports the --gstabs option.])])
4102
4103  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
4104   gcc_cv_as_debug_prefix_map_flag,
4105   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
4106   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
4107 [Define if your assembler supports the --debug-prefix-map option.])])
4108 fi
4109
4110 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
4111  ,,
4112 [.lcomm bar,4,16],,
4113 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
4114   [Define if your assembler supports .lcomm with an alignment field.])])
4115
4116 AC_ARG_ENABLE(gnu-unique-object,
4117  [AS_HELP_STRING([--enable-gnu-unique-object],
4118    [enable the use of the @gnu_unique_object ELF extension on glibc systems])],
4119  [case $enable_gnu_unique_object in
4120     yes | no) ;;
4121     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
4122 Valid choices are 'yes' and 'no'.]) ;;
4123   esac],
4124  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
4125    [elf,2,19,52],,
4126    [.type foo, '$target_type_format_char'gnu_unique_object],,
4127 # We need to unquote above to to use the definition from config.gcc.
4128 # Also check for ld.so support, i.e. glibc 2.11 or higher.
4129    [[if test x$host = x$build -a x$host = x$target &&
4130        ldd --version 2>/dev/null &&
4131        glibcver=`ldd --version 2>/dev/null | sed 's/.* //;q'`; then
4132       glibcmajor=`expr "$glibcver" : "\([0-9]*\)"`
4133       glibcminor=`expr "$glibcver" : "[2-9]*\.\([0-9]*\)"`
4134       glibcnum=`expr $glibcmajor \* 1000 + $glibcminor`
4135       if test "$glibcnum" -ge 2011 ; then
4136         enable_gnu_unique_object=yes
4137       fi
4138     fi]])])
4139 if test x$enable_gnu_unique_object = xyes; then
4140   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
4141    [Define if your assembler supports @gnu_unique_object.])
4142 fi
4143
4144 AC_CACHE_CHECK([assembler for tolerance to line number 0],
4145  [gcc_cv_as_line_zero],
4146  [gcc_cv_as_line_zero=no
4147   if test $in_tree_gas = yes; then
4148     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
4149   elif test "x$gcc_cv_as" != x; then
4150     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
4151     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
4152        test "x`cat conftest.out`" = x
4153     then
4154       gcc_cv_as_line_zero=yes
4155     else
4156       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
4157       cat conftest.s >&AS_MESSAGE_LOG_FD
4158       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
4159       cat conftest.out >&AS_MESSAGE_LOG_FD
4160     fi
4161     rm -f conftest.o conftest.s conftest.out
4162   fi])
4163 if test "x$gcc_cv_as_line_zero" = xyes; then
4164   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
4165 [Define if the assembler won't complain about a line such as # 0 "" 2.])
4166 fi
4167
4168 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
4169 gcc_cv_ld_eh_frame_hdr=no
4170 if test $in_tree_ld = yes ; then
4171   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
4172      && test $in_tree_ld_is_elf = yes; then
4173     gcc_cv_ld_eh_frame_hdr=yes
4174   fi
4175 elif test x$gcc_cv_ld != x; then
4176   if echo "$ld_ver" | grep GNU > /dev/null; then
4177     # Check if linker supports --eh-frame-hdr option
4178     if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
4179       gcc_cv_ld_eh_frame_hdr=yes
4180     fi
4181   else
4182     case "$target" in
4183       *-*-solaris2*)
4184         # Sun ld has various bugs in .eh_frame_hdr support before version 1.2251.
4185         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2251; then
4186           gcc_cv_ld_eh_frame_hdr=yes
4187         fi
4188         ;;
4189     esac
4190   fi
4191 fi
4192 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
4193 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
4194         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
4195 [Define if your linker supports .eh_frame_hdr.])
4196 fi
4197 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
4198
4199 AC_MSG_CHECKING(linker position independent executable support)
4200 gcc_cv_ld_pie=no
4201 if test $in_tree_ld = yes ; then
4202   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
4203      && test $in_tree_ld_is_elf = yes; then
4204     gcc_cv_ld_pie=yes
4205   fi
4206 elif test x$gcc_cv_ld != x; then
4207         # Check if linker supports -pie option
4208         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
4209                 gcc_cv_ld_pie=yes
4210         fi
4211 fi
4212 if test x"$gcc_cv_ld_pie" = xyes; then
4213         AC_DEFINE(HAVE_LD_PIE, 1,
4214 [Define if your linker supports -pie option.])
4215 fi
4216 AC_MSG_RESULT($gcc_cv_ld_pie)
4217
4218 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
4219 gcc_cv_ld_eh_gc_sections=no
4220 if test $in_tree_ld = yes ; then
4221   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
4222      && test $in_tree_ld_is_elf = yes; then
4223     gcc_cv_ld_eh_gc_sections=yes
4224   fi
4225 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
4226   cat > conftest.s <<EOF
4227         .section        .text
4228 .globl _start
4229         .type _start, @function
4230 _start:
4231         .long foo
4232         .size _start, .-_start
4233         .section        .text.foo,"ax",@progbits
4234         .type foo, @function
4235 foo:
4236         .long 0
4237         .size foo, .-foo
4238         .section        .gcc_except_table.foo,"a",@progbits
4239 .L0:
4240         .long 0
4241         .section        .eh_frame,"a",@progbits
4242         .long .L0
4243 EOF
4244   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4245     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4246          | grep "gc-sections option ignored" > /dev/null; then
4247       gcc_cv_ld_eh_gc_sections=no
4248     elif $gcc_cv_objdump -h conftest 2> /dev/null \
4249          | grep gcc_except_table > /dev/null; then
4250       gcc_cv_ld_eh_gc_sections=yes
4251       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
4252       if test x$gcc_cv_as_comdat_group != xyes; then
4253         gcc_cv_ld_eh_gc_sections=no
4254         cat > conftest.s <<EOF
4255         .section        .text
4256 .globl _start
4257         .type _start, @function
4258 _start:
4259         .long foo
4260         .size _start, .-_start
4261         .section        .gnu.linkonce.t.foo,"ax",@progbits
4262         .type foo, @function
4263 foo:
4264         .long 0
4265         .size foo, .-foo
4266         .section        .gcc_except_table.foo,"a",@progbits
4267 .L0:
4268         .long 0
4269         .section        .eh_frame,"a",@progbits
4270         .long .L0
4271 EOF
4272         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4273           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4274                | grep "gc-sections option ignored" > /dev/null; then
4275             gcc_cv_ld_eh_gc_sections=no
4276           elif $gcc_cv_objdump -h conftest 2> /dev/null \
4277                | grep gcc_except_table > /dev/null; then
4278             gcc_cv_ld_eh_gc_sections=yes
4279           fi
4280         fi
4281       fi
4282     fi
4283   fi
4284   rm -f conftest.s conftest.o conftest
4285 fi
4286 case "$target" in
4287   hppa*-*-linux*)
4288     # ??? This apparently exposes a binutils bug with PC-relative relocations.
4289     gcc_cv_ld_eh_gc_sections=no
4290     ;;
4291 esac
4292 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
4293         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
4294   [Define if your linker supports garbage collection of
4295    sections in presence of EH frames.])
4296 fi
4297 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
4298
4299 AC_MSG_CHECKING(linker EH garbage collection of sections bug)
4300 gcc_cv_ld_eh_gc_sections_bug=no
4301 if test $in_tree_ld = yes ; then
4302   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -lt 19 -o "$gcc_cv_gld_major_version" -lt 2 \
4303      && test $in_tree_ld_is_elf = yes; then
4304     gcc_cv_ld_eh_gc_sections_bug=yes
4305   fi
4306 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x -a x$gcc_cv_as_comdat_group = xyes; then
4307   gcc_cv_ld_eh_gc_sections_bug=yes
4308   cat > conftest.s <<EOF
4309         .section        .text
4310 .globl _start
4311         .type _start, @function
4312 _start:
4313         .long foo
4314         .size _start, .-_start
4315         .section        .text.startup.foo,"ax",@progbits
4316         .type foo, @function
4317 foo:
4318         .long 0
4319         .size foo, .-foo
4320         .section        .gcc_except_table.foo,"a",@progbits
4321 .L0:
4322         .long 0
4323         .section        .eh_frame,"a",@progbits
4324         .long .L0
4325 EOF
4326   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4327     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4328          | grep "gc-sections option ignored" > /dev/null; then
4329       :
4330     elif $gcc_cv_objdump -h conftest 2> /dev/null \
4331          | grep gcc_except_table > /dev/null; then
4332       gcc_cv_ld_eh_gc_sections_bug=no
4333     fi
4334   fi
4335   rm -f conftest.s conftest.o conftest
4336 fi
4337 if test x$gcc_cv_ld_eh_gc_sections_bug = xyes; then
4338         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS_BUG, 1,
4339   [Define if your linker has buggy garbage collection of
4340    sections support when .text.startup.foo like sections are used.])
4341 fi
4342 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections_bug)
4343
4344 # --------
4345 # UNSORTED
4346 # --------
4347
4348 AC_CACHE_CHECK(linker --as-needed support,
4349 gcc_cv_ld_as_needed,
4350 [gcc_cv_ld_as_needed=no
4351 if test $in_tree_ld = yes ; then
4352   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
4353      && test $in_tree_ld_is_elf = yes; then
4354     gcc_cv_ld_as_needed=yes
4355   fi
4356 elif test x$gcc_cv_ld != x; then
4357         # Check if linker supports --as-needed and --no-as-needed options
4358         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
4359                 gcc_cv_ld_as_needed=yes
4360         fi
4361 fi
4362 ])
4363 if test x"$gcc_cv_ld_as_needed" = xyes; then
4364         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
4365 [Define if your linker supports --as-needed and --no-as-needed options.])
4366 fi
4367
4368 case "$target:$tm_file" in
4369   powerpc64-*-freebsd* | powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
4370   case "$target" in
4371      *-*-linux*)
4372      emul_name="-melf64ppc"
4373       ;;
4374      *-*-freebsd*)
4375      emul_name="-melf64ppc_fbsd"
4376       ;;
4377   esac
4378     AC_CACHE_CHECK(linker support for omitting dot symbols,
4379     gcc_cv_ld_no_dot_syms,
4380     [gcc_cv_ld_no_dot_syms=no
4381     if test $in_tree_ld = yes ; then
4382       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
4383         gcc_cv_ld_no_dot_syms=yes
4384       fi
4385     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4386       cat > conftest1.s <<EOF
4387         .text
4388         bl .foo
4389 EOF
4390       cat > conftest2.s <<EOF
4391         .section ".opd","aw"
4392         .align 3
4393         .globl foo
4394         .type foo,@function
4395 foo:
4396         .quad .LEfoo,.TOC.@tocbase,0
4397         .text
4398 .LEfoo:
4399         blr
4400         .size foo,.-.LEfoo
4401 EOF
4402       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
4403          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
4404          && $gcc_cv_ld $emul_name -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
4405         gcc_cv_ld_no_dot_syms=yes
4406       fi
4407       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
4408     fi
4409     ])
4410     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
4411       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
4412     [Define if your PowerPC64 linker only needs function descriptor syms.])
4413     fi
4414
4415     AC_CACHE_CHECK(linker large toc support,
4416     gcc_cv_ld_large_toc,
4417     [gcc_cv_ld_large_toc=no
4418     if test $in_tree_ld = yes ; then
4419       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2; then
4420         gcc_cv_ld_large_toc=yes
4421       fi
4422     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4423       cat > conftest.s <<EOF
4424         .section ".tbss","awT",@nobits
4425         .align 3
4426 ie0:    .space 8
4427         .global _start
4428         .text
4429 _start:
4430         addis 9,13,ie0@got@tprel@ha
4431         ld 9,ie0@got@tprel@l(9)
4432 EOF
4433       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
4434          && $gcc_cv_ld $emul_name --no-toc-sort -o conftest conftest.o > /dev/null 2>&1; then
4435         gcc_cv_ld_large_toc=yes
4436       fi
4437       rm -f conftest conftest.o conftest.s
4438     fi
4439     ])
4440     if test x"$gcc_cv_ld_large_toc" = xyes; then
4441       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
4442     [Define if your PowerPC64 linker supports a large TOC.])
4443     fi
4444     ;;
4445 esac
4446
4447 AC_CACHE_CHECK(linker --build-id support,
4448   gcc_cv_ld_buildid,
4449   [gcc_cv_ld_buildid=no
4450   if test $in_tree_ld = yes ; then
4451     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4452        "$gcc_cv_gld_minor_version" -ge 18 -o \
4453        "$gcc_cv_gld_major_version" -gt 2 \
4454        && test $in_tree_ld_is_elf = yes; then
4455       gcc_cv_ld_buildid=yes
4456     fi
4457   elif test x$gcc_cv_ld != x; then
4458     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
4459       gcc_cv_ld_buildid=yes
4460     fi
4461   fi])
4462 if test x"$gcc_cv_ld_buildid" = xyes; then
4463   AC_DEFINE(HAVE_LD_BUILDID, 1,
4464   [Define if your linker supports --build-id.])
4465 fi
4466
4467 AC_ARG_ENABLE(linker-build-id,
4468 [AS_HELP_STRING([--enable-linker-build-id],
4469                 [compiler will always pass --build-id to linker])],
4470 [],
4471 enable_linker_build_id=no)
4472
4473 if test x"$enable_linker_build_id" = xyes; then
4474   if test x"$gcc_cv_ld_buildid" = xyes; then
4475     AC_DEFINE(ENABLE_LD_BUILDID, 1,
4476     [Define if gcc should always pass --build-id to linker.])
4477   else
4478     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
4479   fi
4480 fi
4481
4482 # In binutils 2.21, GNU ld gained support for new emulations fully
4483 # supporting the Solaris 2 ABI.  Detect their presence in the linker used.
4484 AC_CACHE_CHECK(linker *_sol2 emulation support,
4485   gcc_cv_ld_sol2_emulation,
4486   [gcc_cv_ld_sol2_emulation=no
4487   if test $in_tree_ld = yes ; then
4488     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4489        "$gcc_cv_gld_minor_version" -ge 21 -o \
4490        "$gcc_cv_gld_major_version" -gt 2 \
4491        && test $in_tree_ld_is_elf = yes; then
4492       gcc_cv_ld_sol2_emulation=yes
4493     fi
4494   elif test x$gcc_cv_ld != x; then
4495     if $gcc_cv_ld -V 2>/dev/null | sed -e '1,/Supported emulations/d;q' | \
4496        grep _sol2 > /dev/null; then
4497       gcc_cv_ld_sol2_emulation=yes
4498     fi
4499   fi])
4500 if test x"$gcc_cv_ld_sol2_emulation" = xyes; then
4501   AC_DEFINE(HAVE_LD_SOL2_EMULATION, 1,
4502   [Define if your linker supports the *_sol2 emulations.])
4503 fi
4504
4505 AC_CACHE_CHECK(linker --sysroot support,
4506   gcc_cv_ld_sysroot,
4507   [gcc_cv_ld_sysroot=no
4508   if test $in_tree_ld = yes ; then
4509       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
4510         gcc_cv_ld_sysroot=yes
4511       fi
4512   elif test x$gcc_cv_ld != x; then
4513     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
4514       gcc_cv_ld_sysroot=yes
4515     fi
4516   fi])
4517 if test x"$gcc_cv_ld_sysroot" = xyes; then
4518   AC_DEFINE(HAVE_LD_SYSROOT, 1,
4519   [Define if your linker supports --sysroot.])
4520 fi
4521
4522 if test x$with_sysroot = x && test x$host = x$target \
4523    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
4524    && test "$prefix" != "NONE"; then
4525   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
4526 [Define to PREFIX/include if cpp should also search that directory.])
4527 fi
4528
4529 if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
4530   if test "x$with_headers" != x; then
4531     target_header_dir=$with_headers
4532   elif test "x$with_sysroot" = x; then
4533     target_header_dir="${test_exec_prefix}/${target_noncanonical}/sys-include"
4534   elif test "x$with_build_sysroot" != "x"; then
4535     target_header_dir="${with_build_sysroot}${native_system_header_dir}"
4536   elif test "x$with_sysroot" = xyes; then
4537     target_header_dir="${test_exec_prefix}/${target_noncanonical}/sys-root${native_system_header_dir}"
4538   else
4539     target_header_dir="${with_sysroot}${native_system_header_dir}"
4540   fi
4541 else
4542   target_header_dir=${native_system_header_dir}
4543 fi
4544
4545 # Test for stack protector support in target C library.
4546 AC_CACHE_CHECK(__stack_chk_fail in target C library,
4547       gcc_cv_libc_provides_ssp,
4548       [gcc_cv_libc_provides_ssp=no
4549     case "$target" in
4550        *-*-linux* | *-*-kfreebsd*-gnu | *-*-knetbsd*-gnu)
4551       [# glibc 2.4 and later provides __stack_chk_fail and
4552       # either __stack_chk_guard, or TLS access to stack guard canary.
4553       if test -f $target_header_dir/features.h \
4554          && $EGREP '^[  ]*#[    ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
4555             $target_header_dir/features.h > /dev/null; then
4556         if $EGREP '^[   ]*#[    ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
4557            $target_header_dir/features.h > /dev/null; then
4558           gcc_cv_libc_provides_ssp=yes
4559         elif $EGREP '^[         ]*#[    ]*define[       ]+__GLIBC__[    ]+2' \
4560              $target_header_dir/features.h > /dev/null \
4561              && $EGREP '^[      ]*#[    ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
4562              $target_header_dir/features.h > /dev/null; then
4563           gcc_cv_libc_provides_ssp=yes
4564         elif $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC__[   ]+1' \
4565              $target_header_dir/features.h > /dev/null && \
4566              test -f $target_header_dir/bits/uClibc_config.h && \
4567              $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
4568              $target_header_dir/bits/uClibc_config.h > /dev/null; then
4569           gcc_cv_libc_provides_ssp=yes
4570         fi
4571       # all versions of Bionic support stack protector
4572       elif test -f $target_header_dir/sys/cdefs.h \
4573         && $EGREP '^[  ]*#[    ]*define[       ]+__BIONIC__[   ]+1' \
4574            $target_header_dir/sys/cdefs.h > /dev/null; then
4575          gcc_cv_libc_provides_ssp=yes
4576       fi]
4577         ;;
4578        *-*-gnu*)
4579          # Avoid complicated tests (see
4580          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
4581          # simply assert that glibc does provide this, which is true for all
4582          # realistically usable GNU/Hurd configurations.
4583          gcc_cv_libc_provides_ssp=yes;;
4584        *-*-darwin* | *-*-freebsd*)
4585          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
4586            [echo "no __stack_chk_fail on this target"])
4587         ;;
4588   *) gcc_cv_libc_provides_ssp=no ;;
4589     esac])
4590
4591 if test x$gcc_cv_libc_provides_ssp = xyes; then
4592   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
4593             [Define if your target C library provides stack protector support])
4594 fi
4595
4596 # Test for <sys/sdt.h> on the target.
4597 GCC_TARGET_TEMPLATE([HAVE_SYS_SDT_H])
4598 AC_MSG_CHECKING(sys/sdt.h in the target C library)
4599 have_sys_sdt_h=no
4600 if test -f $target_header_dir/sys/sdt.h; then
4601   have_sys_sdt_h=yes
4602   AC_DEFINE(HAVE_SYS_SDT_H, 1,
4603             [Define if your target C library provides sys/sdt.h])
4604 fi
4605 AC_MSG_RESULT($have_sys_sdt_h)
4606
4607 # Check if TFmode long double should be used by default or not.
4608 # Some glibc targets used DFmode long double, but with glibc 2.4
4609 # and later they can use TFmode.
4610 case "$target" in
4611   powerpc*-*-linux* | \
4612   sparc*-*-linux* | \
4613   s390*-*-linux* | \
4614   alpha*-*-linux*)
4615     AC_ARG_WITH(long-double-128,
4616       [AS_HELP_STRING([--with-long-double-128],
4617                       [use 128-bit long double by default])],
4618       gcc_cv_target_ldbl128="$with_long_double_128",
4619       [[gcc_cv_target_ldbl128=no
4620       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
4621         $target_header_dir/bits/wordsize.h > /dev/null 2>&1 \
4622       && gcc_cv_target_ldbl128=yes
4623       ]])
4624     ;;
4625 esac
4626 if test x$gcc_cv_target_ldbl128 = xyes; then
4627   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
4628             [Define if TFmode long double should be the default])
4629 fi
4630
4631 AC_MSG_CHECKING(dl_iterate_phdr in target C library)
4632 gcc_cv_target_dl_iterate_phdr=unknown
4633 case "$target" in
4634   # Restrict to Solaris 11+.  While most of the Solaris 11 linker changes
4635   # were backported to Solaris 10 Update 10, dl_iterate_phdr only lives in
4636   # libdl there, both complicating its use and breaking compatibility
4637   # between Solaris 10 updates.
4638   *-*-solaris2.1[[1-9]]*)
4639     # <link.h> needs both a dl_iterate_phdr declaration and support for
4640     # compilation with largefile support.
4641     if grep dl_iterate_phdr $target_header_dir/link.h > /dev/null 2>&1 \
4642       && grep 'large file capable' $target_header_dir/link.h > /dev/null 2>&1; then
4643       gcc_cv_target_dl_iterate_phdr=yes
4644     else
4645       gcc_cv_target_dl_iterate_phdr=no
4646     fi
4647     ;;
4648 esac
4649 GCC_TARGET_TEMPLATE([TARGET_DL_ITERATE_PHDR])
4650 if test x$gcc_cv_target_dl_iterate_phdr = xyes; then
4651    AC_DEFINE(TARGET_DL_ITERATE_PHDR, 1,
4652 [Define if your target C library provides the `dl_iterate_phdr' function.])
4653 fi
4654 AC_MSG_RESULT($gcc_cv_target_dl_iterate_phdr)
4655
4656 # Find out what GC implementation we want, or may, use.
4657 AC_ARG_WITH(gc,
4658 [AS_HELP_STRING([--with-gc={page,zone}],
4659                 [choose the garbage collection mechanism to use
4660                  with the compiler])],
4661 [case "$withval" in
4662   page)
4663     GGC=ggc-$withval
4664     ;;
4665   zone)
4666     GGC=ggc-$withval
4667     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
4668     ;;
4669   *)
4670     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
4671     ;;
4672 esac],
4673 [GGC=ggc-page])
4674 AC_SUBST(GGC)
4675 echo "Using $GGC for garbage collection."
4676
4677 # Libraries to use on the host.  This will normally be set by the top
4678 # level Makefile.  Here we simply capture the value for our Makefile.
4679 if test -z "${HOST_LIBS+set}"; then
4680   HOST_LIBS=
4681 fi
4682 AC_SUBST(HOST_LIBS)
4683
4684 # Use the system's zlib library.
4685 zlibdir=-L../zlib
4686 zlibinc="-I\$(srcdir)/../zlib"
4687 AC_ARG_WITH(system-zlib,
4688 [AS_HELP_STRING([--with-system-zlib], [use installed libz])],
4689 zlibdir=
4690 zlibinc=
4691 )
4692 AC_SUBST(zlibdir)
4693 AC_SUBST(zlibinc)
4694
4695 dnl Very limited version of automake's enable-maintainer-mode
4696
4697 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
4698   dnl maintainer-mode is disabled by default
4699   AC_ARG_ENABLE(maintainer-mode,
4700 [AS_HELP_STRING([--enable-maintainer-mode],
4701                 [enable make rules and dependencies not useful
4702                  (and sometimes confusing) to the casual installer])],
4703       maintainer_mode=$enableval,
4704       maintainer_mode=no)
4705
4706 AC_MSG_RESULT($maintainer_mode)
4707
4708 if test "$maintainer_mode" = "yes"; then
4709   MAINT=''
4710 else
4711   MAINT='#'
4712 fi
4713 AC_SUBST(MAINT)dnl
4714
4715 # --------------
4716 # Language hooks
4717 # --------------
4718
4719 # Make empty files to contain the specs and options for each language.
4720 # Then add #include lines to for a compiler that has specs and/or options.
4721
4722 subdirs=
4723 lang_opt_files=
4724 lang_specs_files=
4725 lang_tree_files=
4726 # These (without "all_") are set in each config-lang.in.
4727 # `language' must be a single word so is spelled singularly.
4728 all_languages=
4729 all_compilers=
4730 all_outputs='Makefile'
4731 # List of language makefile fragments.
4732 all_lang_makefrags=
4733 # Additional files for gengtype
4734 all_gtfiles="$target_gtfiles"
4735
4736 # These are the languages that are set in --enable-languages,
4737 # and are available in the GCC tree.
4738 all_selected_languages=
4739
4740 # Add the language fragments.
4741 # Languages are added via two mechanisms.  Some information must be
4742 # recorded in makefile variables, these are defined in config-lang.in.
4743 # We accumulate them and plug them into the main Makefile.
4744 # The other mechanism is a set of hooks for each of the main targets
4745 # like `clean', `install', etc.
4746
4747 language_hooks="Make-hooks"
4748
4749 for lang in ${srcdir}/*/config-lang.in
4750 do
4751 changequote(,)dnl
4752         test "$lang" = "${srcdir}/*/config-lang.in" && continue
4753
4754         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
4755         if test "x$lang_alias" = x
4756         then
4757               echo "$lang doesn't set \$language." 1>&2
4758               exit 1
4759         fi
4760         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
4761         subdirs="$subdirs $subdir"
4762
4763         # $gcc_subdir is where the gcc integration files are to be found
4764         # for a language, both for internal compiler purposes (compiler
4765         # sources implementing front-end to GCC tree converters), and for
4766         # build infrastructure purposes (Make-lang.in, etc.)
4767         #
4768         # This will be <subdir> (relative to $srcdir) if a line like
4769         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
4770         # is found in <langdir>/config-lang.in, and will remain <langdir>
4771         # otherwise.
4772         #
4773         # Except for the language alias (fetched above), the regular
4774         # "config-lang.in" contents are always retrieved from $gcc_subdir,
4775         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
4776         # only this and the language alias.
4777
4778         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
4779         if [ "$gcc_subdir" = "" ]; then
4780            gcc_subdir="$subdir"
4781         fi
4782
4783         case ",$enable_languages," in
4784         *,$lang_alias,*)
4785             all_selected_languages="$all_selected_languages $lang_alias"
4786             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
4787                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
4788             fi
4789             ;;
4790         esac
4791 changequote([,])dnl
4792
4793         language=
4794         boot_language=
4795         compilers=
4796         outputs=
4797         gtfiles=
4798         subdir_requires=
4799         . ${srcdir}/$gcc_subdir/config-lang.in
4800         if test "x$language" = x
4801         then
4802                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
4803                 exit 1
4804         fi
4805
4806         ok=:
4807         case ",$enable_languages," in
4808                 *,$lang_alias,*) ;;
4809                 *)
4810                         for i in $subdir_requires; do
4811                                 test -f "${srcdir}/$i/config-lang.in" && continue
4812                                 ok=false
4813                                 break
4814                         done
4815                 ;;
4816         esac
4817         $ok || continue
4818
4819         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
4820         if test -f $srcdir/$gcc_subdir/lang.opt; then
4821             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
4822             all_opt_files="$all_opt_files $srcdir/$gcc_subdir/lang.opt"
4823         fi
4824         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
4825             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
4826         fi
4827         all_languages="$all_languages $language"
4828         all_compilers="$all_compilers $compilers"
4829         all_outputs="$all_outputs $outputs"
4830         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
4831         case ",$enable_languages," in
4832                 *,lto,*)
4833                     AC_DEFINE(ENABLE_LTO, 1, [Define to enable LTO support.])
4834                     enable_lto=yes
4835                     AC_SUBST(enable_lto)
4836                     ;;
4837                 *) ;;
4838         esac
4839 done
4840
4841 check_languages=
4842 for language in $all_selected_languages
4843 do
4844         check_languages="$check_languages check-$language"
4845 done
4846
4847 # We link each language in with a set of hooks, reached indirectly via
4848 # lang.${target}.  Only do so for selected languages.
4849
4850 rm -f Make-hooks
4851 touch Make-hooks
4852 target_list="all.cross start.encap rest.encap tags \
4853         install-common install-man install-info install-pdf install-html dvi \
4854         pdf html uninstall info man srcextra srcman srcinfo \
4855         mostlyclean clean distclean maintainer-clean install-plugin"
4856
4857 for t in $target_list
4858 do
4859         x=
4860         for lang in $all_selected_languages
4861         do
4862                 x="$x $lang.$t"
4863         done
4864         echo "lang.$t: $x" >> Make-hooks
4865 done
4866
4867 # --------
4868 # Option include files
4869 # --------
4870
4871 ${AWK} -f $srcdir/opt-include.awk $all_opt_files > option-includes.mk
4872 option_includes="option-includes.mk"
4873 AC_SUBST_FILE(option_includes)
4874
4875 # --------
4876 # UNSORTED
4877 # --------
4878
4879 # Create .gdbinit.
4880
4881 echo "dir ." > .gdbinit
4882 echo "dir ${srcdir}" >> .gdbinit
4883 if test x$gdb_needs_out_file_path = xyes
4884 then
4885         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
4886 fi
4887 if test "x$subdirs" != x; then
4888         for s in $subdirs
4889         do
4890                 echo "dir ${srcdir}/$s" >> .gdbinit
4891         done
4892 fi
4893 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
4894
4895 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
4896 AC_SUBST(gcc_tooldir)
4897 AC_SUBST(dollar)
4898
4899 # Find a directory in which to install a shared libgcc.
4900
4901 AC_ARG_ENABLE(version-specific-runtime-libs,
4902 [AS_HELP_STRING([--enable-version-specific-runtime-libs],
4903                 [specify that runtime libraries should be
4904                  installed in a compiler-specific directory])])
4905
4906 # Substitute configuration variables
4907 AC_SUBST(subdirs)
4908 AC_SUBST(srcdir)
4909 AC_SUBST(all_compilers)
4910 AC_SUBST(all_gtfiles)
4911 AC_SUBST(all_lang_makefrags)
4912 AC_SUBST(all_languages)
4913 AC_SUBST(all_selected_languages)
4914 AC_SUBST(build_exeext)
4915 AC_SUBST(build_install_headers_dir)
4916 AC_SUBST(build_xm_file_list)
4917 AC_SUBST(build_xm_include_list)
4918 AC_SUBST(build_xm_defines)
4919 AC_SUBST(build_file_translate)
4920 AC_SUBST(check_languages)
4921 AC_SUBST(cpp_install_dir)
4922 AC_SUBST(xmake_file)
4923 AC_SUBST(tmake_file)
4924 AC_SUBST(TM_ENDIAN_CONFIG)
4925 AC_SUBST(TM_MULTILIB_CONFIG)
4926 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
4927 AC_SUBST(extra_gcc_objs)
4928 AC_SUBST(user_headers_inc_next_pre)
4929 AC_SUBST(user_headers_inc_next_post)
4930 AC_SUBST(extra_headers_list)
4931 AC_SUBST(extra_objs)
4932 AC_SUBST(extra_programs)
4933 AC_SUBST(float_h_file)
4934 AC_SUBST(gcc_config_arguments)
4935 AC_SUBST(gcc_gxx_include_dir)
4936 AC_SUBST(gcc_gxx_include_dir_add_sysroot)
4937 AC_SUBST(host_exeext)
4938 AC_SUBST(host_xm_file_list)
4939 AC_SUBST(host_xm_include_list)
4940 AC_SUBST(host_xm_defines)
4941 AC_SUBST(out_host_hook_obj)
4942 AC_SUBST(install)
4943 AC_SUBST(lang_opt_files)
4944 AC_SUBST(lang_specs_files)
4945 AC_SUBST(lang_tree_files)
4946 AC_SUBST(local_prefix)
4947 AC_SUBST(md_file)
4948 AC_SUBST(objc_boehm_gc)
4949 AC_SUBST(out_file)
4950 AC_SUBST(out_object_file)
4951 AC_SUBST(common_out_file)
4952 AC_SUBST(common_out_object_file)
4953 AC_SUBST(tm_file_list)
4954 AC_SUBST(tm_include_list)
4955 AC_SUBST(tm_defines)
4956 AC_SUBST(tm_p_file_list)
4957 AC_SUBST(tm_p_include_list)
4958 AC_SUBST(xm_file_list)
4959 AC_SUBST(xm_include_list)
4960 AC_SUBST(xm_defines)
4961 AC_SUBST(use_gcc_stdint)
4962 AC_SUBST(c_target_objs)
4963 AC_SUBST(cxx_target_objs)
4964 AC_SUBST(fortran_target_objs)
4965 AC_SUBST(target_cpu_default)
4966
4967 AC_SUBST_FILE(language_hooks)
4968
4969 # Echo link setup.
4970 if test x${build} = x${host} ; then
4971   if test x${host} = x${target} ; then
4972     echo "Links are now set up to build a native compiler for ${target}." 1>&2
4973   else
4974     echo "Links are now set up to build a cross-compiler" 1>&2
4975     echo " from ${host} to ${target}." 1>&2
4976   fi
4977 else
4978   if test x${host} = x${target} ; then
4979     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
4980     echo " for ${target}." 1>&2
4981   else
4982     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
4983     echo " from ${host} to ${target}." 1>&2
4984   fi
4985 fi
4986
4987 AC_ARG_VAR(GMPLIBS,[How to link GMP])
4988 AC_ARG_VAR(GMPINC,[How to find GMP include files])
4989
4990 AC_ARG_VAR(ISLLIBS,[How to link ISL])
4991 AC_ARG_VAR(ISLINC,[How to find ISL include files])
4992
4993 AC_ARG_VAR(CLOOGLIBS,[How to link CLOOG])
4994 AC_ARG_VAR(CLOOGINC,[How to find CLOOG include files])
4995 if test "x${CLOOGLIBS}" != "x" ; then
4996    AC_DEFINE(HAVE_cloog, 1, [Define if cloog is in use.])
4997 fi
4998
4999 # Check for plugin support
5000 AC_ARG_ENABLE(plugin,
5001 [AS_HELP_STRING([--enable-plugin], [enable plugin support])],
5002 enable_plugin=$enableval,
5003 enable_plugin=yes; default_plugin=yes)
5004
5005 pluginlibs=
5006
5007 case "${host}" in
5008   *-*-darwin*)
5009     if test x$build = x$host; then
5010       export_sym_check="nm${exeext} -g"
5011     elif test x$host = x$target; then
5012       export_sym_check="$gcc_cv_nm -g"
5013     else
5014       export_sym_check=
5015     fi
5016   ;;
5017   *)
5018     if test x$build = x$host; then
5019       export_sym_check="objdump${exeext} -T"
5020     elif test x$host = x$target; then
5021       export_sym_check="$gcc_cv_objdump -T"
5022     else
5023       export_sym_check=
5024     fi
5025   ;;
5026 esac
5027
5028 if test x"$enable_plugin" = x"yes"; then
5029
5030   AC_MSG_CHECKING([for exported symbols])
5031   if test "x$export_sym_check" != x; then
5032     echo "int main() {return 0;} int foobar() {return 0;}" > conftest.c
5033     ${CC} ${CFLAGS} ${LDFLAGS} conftest.c -o conftest > /dev/null 2>&1
5034     if $export_sym_check conftest | grep foobar > /dev/null; then
5035       : # No need to use a flag
5036       AC_MSG_RESULT([yes])
5037     else
5038       AC_MSG_RESULT([yes])
5039       AC_MSG_CHECKING([for -rdynamic])
5040       ${CC} ${CFLAGS} ${LDFLAGS} -rdynamic conftest.c -o conftest > /dev/null 2>&1
5041       if $export_sym_check conftest | grep foobar > /dev/null; then
5042         plugin_rdynamic=yes
5043         pluginlibs="-rdynamic"
5044       else
5045         plugin_rdynamic=no
5046         enable_plugin=no
5047       fi
5048       AC_MSG_RESULT([$plugin_rdynamic])
5049     fi
5050   else
5051     AC_MSG_RESULT([unable to check])
5052   fi
5053
5054   # Check -ldl
5055   saved_LIBS="$LIBS"
5056   AC_SEARCH_LIBS([dlopen], [dl])
5057   if test x"$ac_cv_search_dlopen" = x"-ldl"; then
5058     pluginlibs="$pluginlibs -ldl"
5059   fi
5060   LIBS="$saved_LIBS"
5061
5062   # Check that we can build shared objects with -fPIC -shared
5063   saved_LDFLAGS="$LDFLAGS"
5064   saved_CFLAGS="$CFLAGS"
5065   case "${host}" in
5066     *-*-darwin*)
5067       CFLAGS=`echo $CFLAGS | sed s/-mdynamic-no-pic//g`
5068       CFLAGS="$CFLAGS -fPIC"
5069       LDFLAGS="$LDFLAGS -shared -undefined dynamic_lookup"
5070     ;;
5071     *)
5072       CFLAGS="$CFLAGS -fPIC"
5073       LDFLAGS="$LDFLAGS -fPIC -shared"
5074     ;;
5075   esac
5076   AC_MSG_CHECKING([for -fPIC -shared])
5077   AC_TRY_LINK(
5078     [extern int X;],[return X == 0;],
5079     [AC_MSG_RESULT([yes]); have_pic_shared=yes],
5080     [AC_MSG_RESULT([no]); have_pic_shared=no])
5081   if test x"$have_pic_shared" != x"yes" -o x"$ac_cv_search_dlopen" = x"no"; then
5082     pluginlibs=
5083     enable_plugin=no
5084   fi
5085   LDFLAGS="$saved_LDFLAGS"
5086   CFLAGS="$saved_CFLAGS"
5087
5088   # If plugin support had been requested but not available, fail.
5089   if test x"$enable_plugin" = x"no" ; then
5090     if test x"$default_plugin" != x"yes"; then
5091       AC_MSG_ERROR([
5092 Building GCC with plugin support requires a host that supports
5093 -fPIC, -shared, -ldl and -rdynamic.])
5094     fi
5095   fi
5096 fi
5097
5098 AC_SUBST(pluginlibs)
5099 AC_SUBST(enable_plugin)
5100 if test x"$enable_plugin" = x"yes"; then
5101   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
5102 fi
5103
5104
5105 AC_ARG_ENABLE(libquadmath-support,
5106 [AS_HELP_STRING([--disable-libquadmath-support],
5107   [disable libquadmath support for Fortran])],
5108 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
5109 ENABLE_LIBQUADMATH_SUPPORT=yes)
5110 if test "${ENABLE_LIBQUADMATH_SUPPORT}" != "no" ; then
5111   AC_DEFINE(ENABLE_LIBQUADMATH_SUPPORT, 1,
5112             [Define to 1 to enable libquadmath support])
5113 fi
5114
5115
5116 # Specify what hash style to use by default.
5117 AC_ARG_WITH([linker-hash-style],
5118 [AC_HELP_STRING([--with-linker-hash-style={sysv,gnu,both}],
5119                 [specify the linker hash style])],
5120 [case x"$withval" in
5121    xsysv)
5122      LINKER_HASH_STYLE=sysv
5123      ;;
5124    xgnu)
5125      LINKER_HASH_STYLE=gnu
5126      ;;
5127    xboth)
5128      LINKER_HASH_STYLE=both
5129      ;;
5130    *)
5131      AC_MSG_ERROR([$withval is an invalid option to --with-linker-hash-style])
5132      ;;
5133  esac],
5134 [LINKER_HASH_STYLE=''])
5135 if test x"${LINKER_HASH_STYLE}" != x; then
5136   AC_DEFINE_UNQUOTED(LINKER_HASH_STYLE, "$LINKER_HASH_STYLE",
5137                                          [The linker hash style])
5138 fi
5139
5140 # Configure the subdirectories
5141 # AC_CONFIG_SUBDIRS($subdirs)
5142
5143 # Create the Makefile
5144 # and configure language subdirectories
5145 AC_CONFIG_FILES($all_outputs)
5146
5147 AC_CONFIG_COMMANDS([default],
5148 [
5149 case ${CONFIG_HEADERS} in
5150   *auto-host.h:config.in*)
5151   echo > cstamp-h ;;
5152 esac
5153 # Make sure all the subdirs exist.
5154 for d in $subdirs doc build common c-family
5155 do
5156     test -d $d || mkdir $d
5157 done
5158 ],
5159 [subdirs='$subdirs'])
5160 AC_OUTPUT
5161