gcc/ada/expander.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P A N D E R                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.120 $
  10 --                                                                          --
  11 --          Copyright (C) 1992-2001 Free Software Foundation, Inc.          --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- GNAT was originally developed  by the GNAT team at  New York University. --
  25 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  26 --                                                                          --
  27 ------------------------------------------------------------------------------
  28
  29 with Atree;     use Atree;
  30 with Debug_A;   use Debug_A;
  31 with Errout;    use Errout;
  32 with Exp_Aggr;  use Exp_Aggr;
  33 with Exp_Attr;  use Exp_Attr;
  34 with Exp_Ch2;   use Exp_Ch2;
  35 with Exp_Ch3;   use Exp_Ch3;
  36 with Exp_Ch4;   use Exp_Ch4;
  37 with Exp_Ch5;   use Exp_Ch5;
  38 with Exp_Ch6;   use Exp_Ch6;
  39 with Exp_Ch7;   use Exp_Ch7;
  40 with Exp_Ch8;   use Exp_Ch8;
  41 with Exp_Ch9;   use Exp_Ch9;
  42 with Exp_Ch11;  use Exp_Ch11;
  43 with Exp_Ch12;  use Exp_Ch12;
  44 with Exp_Ch13;  use Exp_Ch13;
  45 with Exp_Prag;  use Exp_Prag;
  46 with Opt;       use Opt;
  47 with Sem;       use Sem;
  48 with Sem_Ch8;   use Sem_Ch8;
  49 with Sem_Util;  use Sem_Util;
  50 with Sinfo;     use Sinfo;
  51 with Table;
  52
  53 package body Expander is
  54
  55    ----------------
  56    -- Local Data --
  57    ----------------
  58
  59    --  The following table is used to save values of the Expander_Active
  60    --  flag when they are saved by Expander_Mode_Save_And_Set. We use an
  61    --  extendible table (which is a bit of overkill) because it is easier
  62    --  than figuring out a maximum value or bothering with range checks!
  63
  64    package Expander_Flags is new Table.Table (
  65      Table_Component_Type => Boolean,
  66      Table_Index_Type     => Int,
  67      Table_Low_Bound      => 0,
  68      Table_Initial        => 32,
  69      Table_Increment      => 200,
  70      Table_Name           => "Expander_Flags");
  71
  72    ------------
  73    -- Expand --
  74    ------------
  75
  76    procedure Expand (N : Node_Id) is
  77    begin
  78       --  If we were analyzing a default expression the Full_Analysis flag
  79       --  must have be off. If we are in expansion mode then we must be
  80       --  performing a full analysis. If we are analyzing a generic then
  81       --  Expansion must be off.
  82
  83       pragma Assert
  84         (not (Full_Analysis and then In_Default_Expression)
  85          and then (Full_Analysis or else not Expander_Active)
  86          and then not (Inside_A_Generic and then Expander_Active));
  87
  88       --  There are three reasons for the Expander_Active flag to be false.
  89       --
  90       --  The first is when are not generating code. In this mode the
  91       --  Full_Analysis flag indicates whether we are performing a complete
  92       --  analysis, in which case Full_Analysis = True or a pre-analysis in
  93       --  which case Full_Analysis = False. See the spec of Sem for more
  94       --  info on this.
  95       --
  96       --  The second reason for the Expander_Active flag to be False is that
  97       --  we are performing a pre-analysis. During pre-analysis all
  98       --  expansion activity is turned off to make sure nodes are
  99       --  semantically decorated but no extra nodes are generated.  This is
 100       --  for instance needed for the first pass of aggregate semantic
 101       --  processing. Note that in this case the Full_Analysis flag is set
 102       --  to False because the node will subsequently be re-analyzed with
 103       --  expansion on (see the spec of sem).
 104
 105       --  Finally, expansion is turned off in a regular compilation if there
 106       --  are semantic errors. In that case there will be no further expansion,
 107       --  but one cleanup action may be required: if a transient scope was
 108       --  created (e.g. for a function that returns an unconstrained type)
 109       --  the scope may still be on the stack, and must be removed explicitly,
 110       --  given that the expansion actions that would normally process it will
 111       --  not take place. This prevents cascaded errors due to stack mismatch.
 112
 113       if not Expander_Active then
 114          Set_Analyzed (N, Full_Analysis);
 115
 116          if Errors_Detected > 0
 117            and then Scope_Is_Transient
 118          then
 119             Scope_Stack.Table
 120              (Scope_Stack.Last).Actions_To_Be_Wrapped_Before := No_List;
 121             Scope_Stack.Table
 122              (Scope_Stack.Last).Actions_To_Be_Wrapped_After  := No_List;
 123
 124             Pop_Scope;
 125          end if;
 126
 127          return;
 128
 129       else
 130
 131          Debug_A_Entry ("expanding  ", N);
 132
 133          --  Processing depends on node kind. For full details on the expansion
 134          --  activity required in each case, see bodies of corresponding
 135          --  expand routines
 136
 137          case Nkind (N) is
 138
 139             when N_Abort_Statement =>
 140                Expand_N_Abort_Statement (N);
 141
 142             when N_Accept_Statement =>
 143                Expand_N_Accept_Statement (N);
 144
 145             when N_Aggregate =>
 146                Expand_N_Aggregate (N);
 147
 148             when N_Allocator =>
 149                Expand_N_Allocator (N);
 150
 151             when N_And_Then =>
 152                Expand_N_And_Then (N);
 153
 154             when N_Assignment_Statement =>
 155                Expand_N_Assignment_Statement (N);
 156
 157             when N_Asynchronous_Select =>
 158                Expand_N_Asynchronous_Select (N);
 159
 160             when N_Attribute_Definition_Clause =>
 161                Expand_N_Attribute_Definition_Clause (N);
 162
 163             when N_Attribute_Reference =>
 164                Expand_N_Attribute_Reference (N);
 165
 166             when N_Block_Statement =>
 167                Expand_N_Block_Statement (N);
 168
 169             when N_Case_Statement =>
 170                Expand_N_Case_Statement (N);
 171
 172             when N_Conditional_Entry_Call =>
 173                Expand_N_Conditional_Entry_Call (N);
 174
 175             when N_Conditional_Expression =>
 176                Expand_N_Conditional_Expression (N);
 177
 178             when N_Delay_Relative_Statement =>
 179                Expand_N_Delay_Relative_Statement (N);
 180
 181             when N_Delay_Until_Statement =>
 182                Expand_N_Delay_Until_Statement (N);
 183
 184             when N_Entry_Body =>
 185                Expand_N_Entry_Body (N);
 186
 187             when N_Entry_Call_Statement =>
 188                Expand_N_Entry_Call_Statement (N);
 189
 190             when N_Entry_Declaration =>
 191                Expand_N_Entry_Declaration (N);
 192
 193             when N_Exception_Declaration =>
 194                Expand_N_Exception_Declaration (N);
 195
 196             when N_Exception_Renaming_Declaration =>
 197                Expand_N_Exception_Renaming_Declaration (N);
 198
 199             when N_Exit_Statement =>
 200                Expand_N_Exit_Statement (N);
 201
 202             when N_Expanded_Name =>
 203                Expand_N_Expanded_Name (N);
 204
 205             when N_Explicit_Dereference =>
 206                Expand_N_Explicit_Dereference (N);
 207
 208             when N_Extension_Aggregate =>
 209                Expand_N_Extension_Aggregate (N);
 210
 211             when N_Freeze_Entity =>
 212                Expand_N_Freeze_Entity (N);
 213
 214             when N_Full_Type_Declaration =>
 215                Expand_N_Full_Type_Declaration (N);
 216
 217             when N_Function_Call =>
 218                Expand_N_Function_Call (N);
 219
 220             when N_Generic_Instantiation =>
 221                Expand_N_Generic_Instantiation (N);
 222
 223             when N_Goto_Statement =>
 224                Expand_N_Goto_Statement (N);
 225
 226             when N_Handled_Sequence_Of_Statements =>
 227                Expand_N_Handled_Sequence_Of_Statements (N);
 228
 229             when N_Identifier =>
 230                Expand_N_Identifier (N);
 231
 232             when N_Indexed_Component =>
 233                Expand_N_Indexed_Component (N);
 234
 235             when N_If_Statement =>
 236                Expand_N_If_Statement (N);
 237
 238             when N_In =>
 239                Expand_N_In (N);
 240
 241             when N_Loop_Statement =>
 242                Expand_N_Loop_Statement (N);
 243
 244             when N_Not_In =>
 245                Expand_N_Not_In (N);
 246
 247             when N_Null =>
 248                Expand_N_Null (N);
 249
 250             when N_Object_Declaration =>
 251                Expand_N_Object_Declaration (N);
 252
 253             when N_Object_Renaming_Declaration =>
 254                Expand_N_Object_Renaming_Declaration (N);
 255
 256             when N_Op_Add =>
 257                Expand_N_Op_Add (N);
 258
 259             when N_Op_Abs =>
 260                Expand_N_Op_Abs (N);
 261
 262             when N_Op_And =>
 263                Expand_N_Op_And (N);
 264
 265             when N_Op_Concat =>
 266                Expand_N_Op_Concat (N);
 267
 268             when N_Op_Divide =>
 269                Expand_N_Op_Divide (N);
 270
 271             when N_Op_Eq =>
 272                Expand_N_Op_Eq (N);
 273
 274             when N_Op_Expon =>
 275                Expand_N_Op_Expon (N);
 276
 277             when N_Op_Ge =>
 278                Expand_N_Op_Ge (N);
 279
 280             when N_Op_Gt =>
 281                Expand_N_Op_Gt (N);
 282
 283             when N_Op_Le =>
 284                Expand_N_Op_Le (N);
 285
 286             when N_Op_Lt =>
 287                Expand_N_Op_Lt (N);
 288
 289             when N_Op_Minus =>
 290                Expand_N_Op_Minus (N);
 291
 292             when N_Op_Mod =>
 293                Expand_N_Op_Mod (N);
 294
 295             when N_Op_Multiply =>
 296                Expand_N_Op_Multiply (N);
 297
 298             when N_Op_Ne =>
 299                Expand_N_Op_Ne (N);
 300
 301             when N_Op_Not =>
 302                Expand_N_Op_Not (N);
 303
 304             when N_Op_Or =>
 305                Expand_N_Op_Or (N);
 306
 307             when N_Op_Plus =>
 308                Expand_N_Op_Plus (N);
 309
 310             when N_Op_Rem =>
 311                Expand_N_Op_Rem (N);
 312
 313             when N_Op_Rotate_Left =>
 314                Expand_N_Op_Rotate_Left (N);
 315
 316             when N_Op_Rotate_Right =>
 317                Expand_N_Op_Rotate_Right (N);
 318
 319             when N_Op_Shift_Left =>
 320                Expand_N_Op_Shift_Left (N);
 321
 322             when N_Op_Shift_Right =>
 323                Expand_N_Op_Shift_Right (N);
 324
 325             when N_Op_Shift_Right_Arithmetic =>
 326                Expand_N_Op_Shift_Right_Arithmetic (N);
 327
 328             when N_Op_Subtract =>
 329                Expand_N_Op_Subtract (N);
 330
 331             when N_Op_Xor =>
 332                Expand_N_Op_Xor (N);
 333
 334             when N_Or_Else =>
 335                Expand_N_Or_Else (N);
 336
 337             when N_Package_Body =>
 338                Expand_N_Package_Body (N);
 339
 340             when N_Package_Declaration =>
 341                Expand_N_Package_Declaration (N);
 342
 343             when N_Package_Renaming_Declaration =>
 344                Expand_N_Package_Renaming_Declaration (N);
 345
 346             when N_Pragma =>
 347                Expand_N_Pragma (N);
 348
 349             when N_Procedure_Call_Statement =>
 350                Expand_N_Procedure_Call_Statement (N);
 351
 352             when N_Protected_Type_Declaration =>
 353                Expand_N_Protected_Type_Declaration (N);
 354
 355             when N_Protected_Body =>
 356                Expand_N_Protected_Body (N);
 357
 358             when N_Qualified_Expression =>
 359                Expand_N_Qualified_Expression (N);
 360
 361             when N_Raise_Statement =>
 362                Expand_N_Raise_Statement (N);
 363
 364             when N_Raise_Constraint_Error =>
 365                Expand_N_Raise_Constraint_Error (N);
 366
 367             when N_Raise_Program_Error =>
 368                Expand_N_Raise_Program_Error (N);
 369
 370             when N_Raise_Storage_Error =>
 371                Expand_N_Raise_Storage_Error (N);
 372
 373             when N_Real_Literal =>
 374                Expand_N_Real_Literal (N);
 375
 376             when N_Record_Representation_Clause =>
 377                Expand_N_Record_Representation_Clause (N);
 378
 379             when N_Requeue_Statement =>
 380                Expand_N_Requeue_Statement (N);
 381
 382             when N_Return_Statement =>
 383                Expand_N_Return_Statement (N);
 384
 385             when N_Selected_Component =>
 386                Expand_N_Selected_Component (N);
 387
 388             when N_Selective_Accept =>
 389                Expand_N_Selective_Accept (N);
 390
 391             when N_Single_Task_Declaration =>
 392                Expand_N_Single_Task_Declaration (N);
 393
 394             when N_Slice =>
 395                Expand_N_Slice (N);
 396
 397             when N_Subtype_Indication =>
 398                Expand_N_Subtype_Indication (N);
 399
 400             when N_Subprogram_Body =>
 401                Expand_N_Subprogram_Body (N);
 402
 403             when N_Subprogram_Body_Stub =>
 404                Expand_N_Subprogram_Body_Stub (N);
 405
 406             when N_Subprogram_Declaration =>
 407                Expand_N_Subprogram_Declaration (N);
 408
 409             when N_Subprogram_Info =>
 410                Expand_N_Subprogram_Info (N);
 411
 412             when N_Task_Body =>
 413                Expand_N_Task_Body (N);
 414
 415             when N_Task_Type_Declaration =>
 416                Expand_N_Task_Type_Declaration (N);
 417
 418             when N_Timed_Entry_Call =>
 419                Expand_N_Timed_Entry_Call (N);
 420
 421             when N_Type_Conversion =>
 422                Expand_N_Type_Conversion (N);
 423
 424             when N_Unchecked_Expression =>
 425                Expand_N_Unchecked_Expression (N);
 426
 427             when N_Unchecked_Type_Conversion =>
 428                Expand_N_Unchecked_Type_Conversion (N);
 429
 430             when N_Variant_Part =>
 431                Expand_N_Variant_Part (N);
 432
 433             --  For all other node kinds, no expansion activity is required
 434
 435             when others => null;
 436
 437          end case;
 438
 439          --  Set result as analyzed and then do a possible transient wrap. The
 440          --  transient wrap must be done after the Analyzed flag is set on, so
 441          --  that we do not get a recursive attempt to expand the node N.
 442
 443          Set_Analyzed (N);
 444
 445          --  Deal with transient scopes
 446
 447          if Scope_Is_Transient and then N = Node_To_Be_Wrapped then
 448
 449             case Nkind (N) is
 450                when N_Statement_Other_Than_Procedure_Call |
 451                     N_Procedure_Call_Statement            =>
 452                   Wrap_Transient_Statement (N);
 453
 454                when N_Object_Declaration          |
 455                     N_Object_Renaming_Declaration |
 456                     N_Subtype_Declaration         =>
 457                   Wrap_Transient_Declaration (N);
 458
 459                when others => Wrap_Transient_Expression (N);
 460             end case;
 461          end if;
 462
 463          Debug_A_Exit ("expanding  ", N, "  (done)");
 464       end if;
 465    end Expand;
 466
 467    ---------------------------
 468    -- Expander_Mode_Restore --
 469    ---------------------------
 470
 471    procedure Expander_Mode_Restore is
 472    begin
 473       Expander_Active := Expander_Flags.Table (Expander_Flags.Last);
 474       Expander_Flags.Decrement_Last;
 475
 476       if Errors_Detected /= 0 then
 477          Expander_Active := False;
 478       end if;
 479    end Expander_Mode_Restore;
 480
 481    --------------------------------
 482    -- Expander_Mode_Save_And_Set --
 483    --------------------------------
 484
 485    procedure Expander_Mode_Save_And_Set (Status : Boolean) is
 486    begin
 487       Expander_Flags.Increment_Last;
 488       Expander_Flags.Table (Expander_Flags.Last) := Expander_Active;
 489       Expander_Active := Status;
 490    end Expander_Mode_Save_And_Set;
 491
 492 end Expander;