libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:14:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is now required.
  77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  78 AH_TEMPLATE(PACKAGE, [Name of package])
  79 AH_TEMPLATE(VERSION, [Version number of package])
  80
  81 # -fno-builtin must be present here so that a non-conflicting form of
  82 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  83
  84 save_CXXFLAGS="$CXXFLAGS"
  85 CXXFLAGS="$CXXFLAGS -fno-builtin"
  86 AC_PROG_CC
  87 AC_PROG_CXX
  88 CXXFLAGS="$save_CXXFLAGS"
  89
  90 # Runs configure.host, and assorted other critical bits.  Sets
  91 # up critical shell variables.
  92 GLIBCXX_CONFIGURE
  93
  94 if test "x${with_newlib}" != "xyes"; then
  95   AC_LIBTOOL_DLOPEN
  96 fi
  97 AM_PROG_LIBTOOL
  98 AC_SUBST(enable_shared)
  99 AC_SUBST(enable_static)
 100
 101 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 102 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 103
 104 # Possibly disable most of the library.
 105 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 106 ## than just ignoring the results.  Faster /and/ more correct, win win.
 107 GLIBCXX_ENABLE_HOSTED
 108
 109 # Enable compiler support that doesn't require linking.
 110 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 111 GLIBCXX_ENABLE_PCH($is_hosted)
 112 GLIBCXX_ENABLE_THREADS
 113 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 114 GLIBCXX_ENABLE_DECIMAL_FLOAT
 115
 116 # Checks for compiler support that doesn't require linking.
 117 GLIBCXX_CHECK_COMPILER_FEATURES
 118
 119 # Enable all the variable C++ runtime options that don't require linking.
 120 GLIBCXX_ENABLE_CSTDIO
 121 GLIBCXX_ENABLE_CLOCALE
 122 GLIBCXX_ENABLE_ALLOCATOR
 123 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 124 GLIBCXX_ENABLE_LONG_LONG([yes])
 125 GLIBCXX_ENABLE_WCHAR_T([yes])
 126 GLIBCXX_ENABLE_C99([yes])
 127 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 128 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 129 GLIBCXX_ENABLE_DEBUG([no])
 130 GLIBCXX_ENABLE_PARALLEL([yes])
 131 GLIBCXX_ENABLE_CXX_FLAGS
 132 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 133
 134 # Checks for operating systems support that doesn't require linking.
 135 GLIBCXX_CHECK_SYSTEM_ERROR
 136
 137 # For the streamoff typedef.
 138 GLIBCXX_CHECK_INT64_T
 139
 140 # For LFS support.
 141 GLIBCXX_CHECK_LFS
 142
 143 # For showmanyc_helper().
 144 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 145 GLIBCXX_CHECK_POLL
 146 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 147
 148 # For xsputn_2().
 149 AC_CHECK_HEADERS(sys/uio.h)
 150 GLIBCXX_CHECK_WRITEV
 151
 152 # For C99 support to TR1.
 153 GLIBCXX_CHECK_C99_TR1
 154
 155 # For common values of EOF, SEEK_CUR, SEEK_END.
 156 GLIBCXX_CHECK_STDIO_MACROS
 157
 158 # For gettimeofday support.
 159 GLIBCXX_CHECK_GETTIMEOFDAY
 160
 161 # For clock_gettime, nanosleep and sched_yield support.
 162 # NB: The default is [no], because otherwise it requires linking.
 163 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
 164
 165 # For gthread support
 166 GLIBCXX_CHECK_GTHREADS
 167
 168 AC_LC_MESSAGES
 169
 170 # Check for available headers.
 171 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 172 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 173 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 174 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 175 wchar.h wctype.h])
 176
 177 # Only do link tests if native. Else, hardcode.
 178 if $GLIBCXX_IS_NATIVE; then
 179
 180   # We can do more elaborate tests that assume a working linker.
 181   CANADIAN=no
 182
 183   GLIBCXX_CHECK_LINKER_FEATURES
 184   GLIBCXX_CHECK_MATH_SUPPORT
 185   GLIBCXX_CHECK_STDLIB_SUPPORT
 186
 187   # For /dev/random and /dev/urandom for TR1.
 188   GLIBCXX_CHECK_RANDOM_TR1
 189
 190   # For TLS support.
 191   GCC_CHECK_TLS
 192
 193   # For iconv support.
 194   AM_ICONV
 195
 196 else
 197
 198   # This lets us hard-code the functionality we know we'll have in the cross
 199   # target environment.  "Let" is a sugar-coated word placed on an especially
 200   # dull and tedious hack, actually.
 201   #
 202   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 203   # that involve linking, can't be used:
 204   #    "cannot open sim-crt0.o"
 205   #    "cannot open crt0.o"
 206   # etc.  All this is because there currently exists no unified, consistent
 207   # way for top level CC information to be passed down to target directories:
 208   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 209   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 210   # crosses can be removed.
 211
 212   # If Canadian cross, then don't pick up tools from the build directory.
 213   # Used only in GLIBCXX_EXPORT_INCLUDES.
 214   if test -n "$with_cross_host" &&
 215      test x"$build_alias" != x"$with_cross_host" &&
 216      test x"$build" != x"$target";
 217   then
 218     CANADIAN=yes
 219   else
 220     CANADIAN=no
 221   fi
 222
 223   # Construct crosses by hand, eliminating bits that need ld...
 224   # GLIBCXX_CHECK_MATH_SUPPORT
 225
 226   # First, test for "known" system libraries.  We may be using newlib even
 227   # on a hosted environment.
 228   if test "x${with_newlib}" = "xyes"; then
 229     os_include_dir="os/newlib"
 230     AC_DEFINE(HAVE_HYPOT)
 231
 232     # GLIBCXX_CHECK_STDLIB_SUPPORT
 233     AC_DEFINE(HAVE_STRTOF)
 234
 235     AC_DEFINE(HAVE_ACOSF)
 236     AC_DEFINE(HAVE_ASINF)
 237     AC_DEFINE(HAVE_ATAN2F)
 238     AC_DEFINE(HAVE_ATANF)
 239     AC_DEFINE(HAVE_CEILF)
 240     AC_DEFINE(HAVE_COSF)
 241     AC_DEFINE(HAVE_COSHF)
 242     AC_DEFINE(HAVE_EXPF)
 243     AC_DEFINE(HAVE_FABSF)
 244     AC_DEFINE(HAVE_FLOORF)
 245     AC_DEFINE(HAVE_FMODF)
 246     AC_DEFINE(HAVE_FREXPF)
 247     AC_DEFINE(HAVE_LDEXPF)
 248     AC_DEFINE(HAVE_LOG10F)
 249     AC_DEFINE(HAVE_LOGF)
 250     AC_DEFINE(HAVE_MODFF)
 251     AC_DEFINE(HAVE_POWF)
 252     AC_DEFINE(HAVE_SINF)
 253     AC_DEFINE(HAVE_SINHF)
 254     AC_DEFINE(HAVE_SQRTF)
 255     AC_DEFINE(HAVE_TANF)
 256     AC_DEFINE(HAVE_TANHF)
 257
 258     AC_DEFINE(HAVE_ICONV)
 259   else
 260     GLIBCXX_CROSSCONFIG
 261   fi
 262
 263   # At some point, we should differentiate between architectures
 264   # like x86, which have long double versions, and alpha/powerpc/etc.,
 265   # which don't. For the time being, punt.
 266   if test x"long_double_math_on_this_cpu" = x"yes"; then
 267     AC_DEFINE(HAVE_ACOSL)
 268     AC_DEFINE(HAVE_ASINL)
 269     AC_DEFINE(HAVE_ATAN2L)
 270     AC_DEFINE(HAVE_ATANL)
 271     AC_DEFINE(HAVE_CEILL)
 272     AC_DEFINE(HAVE_COSL)
 273     AC_DEFINE(HAVE_COSHL)
 274     AC_DEFINE(HAVE_EXPL)
 275     AC_DEFINE(HAVE_FABSL)
 276     AC_DEFINE(HAVE_FLOORL)
 277     AC_DEFINE(HAVE_FMODL)
 278     AC_DEFINE(HAVE_FREXPL)
 279     AC_DEFINE(HAVE_LDEXPL)
 280     AC_DEFINE(HAVE_LOG10L)
 281     AC_DEFINE(HAVE_LOGL)
 282     AC_DEFINE(HAVE_MODFL)
 283     AC_DEFINE(HAVE_POWL)
 284     AC_DEFINE(HAVE_SINCOSL)
 285     AC_DEFINE(HAVE_SINL)
 286     AC_DEFINE(HAVE_SINHL)
 287     AC_DEFINE(HAVE_SQRTL)
 288     AC_DEFINE(HAVE_TANL)
 289     AC_DEFINE(HAVE_TANHL)
 290   fi
 291 fi
 292
 293 # Check for _Unwind_GetIPInfo.
 294 GCC_CHECK_UNWIND_GETIPINFO
 295
 296
 297 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 298
 299 GCC_HEADER_STDINT(include/gstdint.h)
 300
 301 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 302 GLIBCXX_ENABLE_SYMVERS([yes])
 303 GLIBCXX_ENABLE_VISIBILITY([yes])
 304
 305 ac_ldbl_compat=no
 306 case "$target" in
 307   powerpc*-*-linux* | \
 308   powerpc*-*-gnu* | \
 309   sparc*-*-linux* | \
 310   s390*-*-linux* | \
 311   alpha*-*-linux*)
 312   AC_TRY_COMPILE(, [
 313 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 314 #error no need for long double compatibility
 315 #endif
 316   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 317   if test "$ac_ldbl_compat" = yes; then
 318     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 319               [Define if compatibility should be provided for -mlong-double-64.])
 320     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 321   fi
 322 esac
 323 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 324
 325 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 326 GLIBCXX_CONFIGURE_TESTSUITE
 327
 328 # Propagate the target-specific source directories through the build chain.
 329 ATOMICITY_SRCDIR=config/${atomicity_dir}
 330 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 331 ATOMIC_FLAGS=${atomic_flags}
 332 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 333 OS_INC_SRCDIR=config/${os_include_dir}
 334 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 335 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 336 AC_SUBST(ATOMICITY_SRCDIR)
 337 AC_SUBST(ATOMIC_WORD_SRCDIR)
 338 AC_SUBST(ATOMIC_FLAGS)
 339 AC_SUBST(CPU_DEFINES_SRCDIR)
 340 AC_SUBST(ABI_TWEAKS_SRCDIR)
 341 AC_SUBST(OS_INC_SRCDIR)
 342 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 343
 344
 345 # Determine cross-compile flags and AM_CONDITIONALs.
 346 #AC_SUBST(GLIBCXX_IS_NATIVE)
 347 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 348 GLIBCXX_EVALUATE_CONDITIONALS
 349
 350 AC_CACHE_SAVE
 351
 352 if test ${multilib} = yes; then
 353   multilib_arg="--enable-multilib"
 354 else
 355   multilib_arg=
 356 fi
 357
 358 # Export all the install information.
 359 GLIBCXX_EXPORT_INSTALL_INFO
 360
 361 # Export all the include and flag information to Makefiles.
 362 GLIBCXX_EXPORT_INCLUDES
 363 GLIBCXX_EXPORT_FLAGS
 364
 365 if test "$enable_shared" = yes; then
 366   LIBSUPCXX_PICFLAGS="-prefer-pic"
 367 else
 368   LIBSUPCXX_PICFLAGS=
 369 fi
 370 AC_SUBST(LIBSUPCXX_PICFLAGS)
 371
 372 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 373 dnl which can all be called multiple times as needed, plus one (different)
 374 dnl AC_OUTPUT macro.  This one lists the files to be created:
 375 AC_CONFIG_FILES(Makefile)
 376 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 377
 378 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 379 # that multilib installs will end up installed in the correct place.
 380 # The testsuite needs it for multilib-aware ABI baseline files.
 381 # To work around this not being passed down from config-ml.in ->
 382 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 383 # append it here.  Only modify Makefiles that have just been created.
 384 #
 385 # Also, get rid of this simulated-VPATH thing that automake does.
 386 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 387   [cat > vpsed$$ << \_EOF
 388 s!`test -f '$<' || echo '$(srcdir)/'`!!
 389 _EOF
 390    sed -f vpsed$$ $ac_file > tmp$$
 391    mv tmp$$ $ac_file
 392    rm vpsed$$
 393    echo 'MULTISUBDIR =' >> $ac_file
 394    ml_norecursion=yes
 395    . ${multi_basedir}/config-ml.in
 396    AS_UNSET([ml_norecursion])
 397 ])
 398
 399 AC_CONFIG_COMMANDS([generate-headers],
 400   [(cd include && ${MAKE-make} pch_build= )])
 401
 402 dnl And this actually makes things happen:
 403 AC_OUTPUT