gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.59)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 # autoconf is lame and doesn't give us any substitution variable for this.
 280 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 281   NO_MINUS_C_MINUS_O=yes
 282 else
 283   OUTPUT_OPTION='-o $@'
 284 fi
 285 AC_SUBST(NO_MINUS_C_MINUS_O)
 286 AC_SUBST(OUTPUT_OPTION)
 287
 288 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 289 # optimizations to be activated explicitly by the toplevel.
 290 case "$CC" in
 291   */prev-gcc/xgcc*) ;;
 292   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 293 esac
 294 AC_SUBST(CFLAGS)
 295
 296 # -------------------------
 297 # Check C compiler features
 298 # -------------------------
 299
 300 AC_PROG_CPP
 301 AC_C_INLINE
 302
 303 # sizeof(char) is 1 by definition.
 304 AC_CHECK_SIZEOF(void *)
 305 AC_CHECK_SIZEOF(short)
 306 AC_CHECK_SIZEOF(int)
 307 AC_CHECK_SIZEOF(long)
 308 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 309 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 310
 311 # ---------------------
 312 # Warnings and checking
 313 # ---------------------
 314
 315 # Check $CC warning features (if it's GCC).
 316 # We want to use -pedantic, but we don't want warnings about
 317 # * 'long long'
 318 # * variadic macros
 319 # * overlong strings
 320 # So, we only use -pedantic if we can disable those warnings.
 321
 322 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 323                           -Wmissing-prototypes], [loose_warn])
 324 ACX_PROG_CC_WARNING_OPTS([-Wc++-compat], [cxx_compat_warn])
 325 ACX_PROG_CC_WARNING_OPTS([-Wold-style-definition \
 326                           -Wmissing-format-attribute], [strict_warn])
 327 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long -Wno-variadic-macros \
 328                                      -Wno-overlength-strings], [strict_warn])
 329 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 330
 331 # The above macros do nothing if the compiler is not GCC.  However, the
 332 # Makefile has more goo to add other flags, so this variabl is used to
 333 # enables warnings only for GCC.
 334 warn_cflags=
 335 if test "x$GCC" = "xyes"; then
 336   warn_cflags='$(GCC_WARN_CFLAGS)'
 337 fi
 338 AC_SUBST(warn_cflags)
 339
 340 # Enable expensive internal checks
 341 is_release=
 342 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 343   is_release=yes
 344 fi
 345
 346 AC_ARG_ENABLE(checking,
 347 [  --enable-checking[=LIST]
 348                           enable expensive run-time checks.  With LIST,
 349                           enable only specific categories of checks.
 350                           Categories are: yes,no,all,none,release.
 351                           Flags are: assert,df,fold,gc,gcac,misc,
 352                           rtlflag,rtl,runtime,tree,valgrind,types.],
 353 [ac_checking_flags="${enableval}"],[
 354 # Determine the default checks.
 355 if test x$is_release = x ; then
 356   ac_checking_flags=yes
 357 else
 358   ac_checking_flags=release
 359 fi])
 360 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 361 for check in release $ac_checking_flags
 362 do
 363         case $check in
 364         # these set all the flags to specific states
 365         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 366                         ac_fold_checking= ; ac_gc_checking=1 ;
 367                         ac_gc_always_collect= ; ac_rtl_checking= ;
 368                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 369                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 370                         ac_types_checking= ;;
 371         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 372                         ac_fold_checking= ; ac_gc_checking= ;
 373                         ac_gc_always_collect= ; ac_rtl_checking= ;
 374                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 375                         ac_tree_checking= ; ac_valgrind_checking= ;
 376                         ac_types_checking= ;;
 377         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 378                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 379                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 380                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 381                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 382                         ac_types_checking=1 ;;
 383         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 384                         ac_fold_checking= ; ac_gc_checking= ;
 385                         ac_gc_always_collect= ; ac_rtl_checking= ;
 386                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 387                         ac_tree_checking= ; ac_valgrind_checking= ;
 388                         ac_types_checking= ;;
 389         # these enable particular checks
 390         assert)         ac_assert_checking=1 ;;
 391         df)             ac_df_checking=1 ;;
 392         fold)           ac_fold_checking=1 ;;
 393         gc)             ac_gc_checking=1 ;;
 394         gcac)           ac_gc_always_collect=1 ;;
 395         misc)           ac_checking=1 ;;
 396         rtl)            ac_rtl_checking=1 ;;
 397         rtlflag)        ac_rtlflag_checking=1 ;;
 398         runtime)        ac_runtime_checking=1 ;;
 399         tree)           ac_tree_checking=1 ;;
 400         types)          ac_types_checking=1 ;;
 401         valgrind)       ac_valgrind_checking=1 ;;
 402         *)      AC_MSG_ERROR(unknown check category $check) ;;
 403         esac
 404 done
 405 IFS="$ac_save_IFS"
 406
 407 nocommon_flag=""
 408 if test x$ac_checking != x ; then
 409   AC_DEFINE(ENABLE_CHECKING, 1,
 410 [Define if you want more run-time sanity checks.  This one gets a grab
 411    bag of miscellaneous but relatively cheap checks.])
 412   nocommon_flag=-fno-common
 413 fi
 414 AC_SUBST(nocommon_flag)
 415 if test x$ac_df_checking != x ; then
 416   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 417 [Define if you want more run-time sanity checks for dataflow.])
 418 fi
 419 if test x$ac_assert_checking != x ; then
 420   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 421 [Define if you want assertions enabled.  This is a cheap check.])
 422 fi
 423 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 424 if test x$ac_runtime_checking != x ; then
 425   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 426 [Define if you want runtime assertions enabled.  This is a cheap check.])
 427 fi
 428 if test x$ac_tree_checking != x ; then
 429   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 430 [Define if you want all operations on trees (the basic data
 431    structure of the front ends) to be checked for dynamic type safety
 432    at runtime.  This is moderately expensive.  The tree browser debugging
 433    routines will also be enabled by this option.
 434    ])
 435   TREEBROWSER=tree-browser.o
 436 fi
 437 if test x$ac_types_checking != x ; then
 438   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 439 [Define if you want all gimple types to be verified after gimplifiation.
 440    This is cheap.
 441    ])
 442 fi
 443 AC_SUBST(TREEBROWSER)
 444 if test x$ac_rtl_checking != x ; then
 445   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 446 [Define if you want all operations on RTL (the basic data structure
 447    of the optimizer and back end) to be checked for dynamic type safety
 448    at runtime.  This is quite expensive.])
 449 fi
 450 if test x$ac_rtlflag_checking != x ; then
 451   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 452 [Define if you want RTL flag accesses to be checked against the RTL
 453    codes that are supported for each access macro.  This is relatively
 454    cheap.])
 455 fi
 456 if test x$ac_gc_checking != x ; then
 457   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 458 [Define if you want the garbage collector to do object poisoning and
 459    other memory allocation checks.  This is quite expensive.])
 460 fi
 461 if test x$ac_gc_always_collect != x ; then
 462   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 463 [Define if you want the garbage collector to operate in maximally
 464    paranoid mode, validating the entire heap and collecting garbage at
 465    every opportunity.  This is extremely expensive.])
 466 fi
 467 if test x$ac_fold_checking != x ; then
 468   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 469 [Define if you want fold checked that it never destructs its argument.
 470    This is quite expensive.])
 471 fi
 472 valgrind_path_defines=
 473 valgrind_command=
 474
 475 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 476 dnl # an if statement.  This was the source of very frustrating bugs
 477 dnl # in converting to autoconf 2.5x!
 478 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 479
 480 if test x$ac_valgrind_checking != x ; then
 481   # It is certainly possible that there's valgrind but no valgrind.h.
 482   # GCC relies on making annotations so we must have both.
 483   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 484   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 485     [[#include <valgrind/memcheck.h>
 486 #ifndef VALGRIND_DISCARD
 487 #error VALGRIND_DISCARD not defined
 488 #endif]])],
 489   [gcc_cv_header_valgrind_memcheck_h=yes],
 490   [gcc_cv_header_valgrind_memcheck_h=no])
 491   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 492   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 493   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 494     [[#include <memcheck.h>
 495 #ifndef VALGRIND_DISCARD
 496 #error VALGRIND_DISCARD not defined
 497 #endif]])],
 498   [gcc_cv_header_memcheck_h=yes],
 499   [gcc_cv_header_memcheck_h=no])
 500   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 501   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 502         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 503   if test "x$valgrind_path" = "x" \
 504     || (test $have_valgrind_h = no \
 505         && test $gcc_cv_header_memcheck_h = no \
 506         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 507         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 508   fi
 509   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 510   valgrind_command="$valgrind_path -q"
 511   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 512 [Define if you want to run subprograms and generated programs
 513    through valgrind (a memory checker).  This is extremely expensive.])
 514   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 515     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 516         [Define if valgrind's valgrind/memcheck.h header is installed.])
 517   fi
 518   if test $gcc_cv_header_memcheck_h = yes; then
 519     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 520         [Define if valgrind's memcheck.h header is installed.])
 521   fi
 522 fi
 523 AC_SUBST(valgrind_path_defines)
 524 AC_SUBST(valgrind_command)
 525
 526 AC_ARG_ENABLE(mapped-location,
 527 [  --enable-mapped-location   location_t is fileline integer cookie],,
 528 enable_mapped_location=no)
 529
 530 if test "$enable_mapped_location" = yes ; then
 531   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 532 [Define if location_t is fileline integer cookie.])
 533 fi
 534
 535 # Enable code coverage collection
 536 AC_ARG_ENABLE(coverage,
 537 [  --enable-coverage[=LEVEL]
 538                           enable compiler's code coverage collection.
 539                           Use to measure compiler performance and locate
 540                           unused parts of the compiler. With LEVEL, specify
 541                           optimization. Values are opt, noopt,
 542                           default is noopt],
 543 [case "${enableval}" in
 544   yes|noopt)
 545     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 546     ;;
 547   opt)
 548     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 549     ;;
 550   no)
 551     # a.k.a. --disable-coverage
 552     coverage_flags=""
 553     ;;
 554   *)
 555     AC_MSG_ERROR(unknown coverage setting $enableval)
 556     ;;
 557 esac],
 558 [coverage_flags=""])
 559 AC_SUBST(coverage_flags)
 560
 561 AC_ARG_ENABLE(gather-detailed-mem-stats,
 562 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 563 [enable_gather_detailed_mem_stats=no])
 564 if test x$enable_gather_detailed_mem_stats = xyes ; then
 565   AC_DEFINE(GATHER_STATISTICS, 1,
 566         [Define to enable detailed memory allocation stats gathering.])
 567 fi
 568
 569 # -------------------------------
 570 # Miscenalleous configure options
 571 # -------------------------------
 572
 573 # With stabs
 574 AC_ARG_WITH(stabs,
 575 [  --with-stabs            arrange to use stabs instead of host debug format],
 576 stabs="$with_stabs",
 577 stabs=no)
 578
 579 # Determine whether or not multilibs are enabled.
 580 AC_ARG_ENABLE(multilib,
 581 [  --enable-multilib       enable library support for multiple ABIs],
 582 [], [enable_multilib=yes])
 583 AC_SUBST(enable_multilib)
 584
 585 # Enable __cxa_atexit for C++.
 586 AC_ARG_ENABLE(__cxa_atexit,
 587 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 588 [], [])
 589
 590 # Enable C extension for decimal float if target supports it.
 591 AC_ARG_ENABLE(decimal-float,
 592 [  --enable-decimal-float={no,yes,bid,dpd}
 593                         enable decimal float extension to C.  Selecting 'bid'
 594                         or 'dpd' choses which decimal floating point format
 595                         to use],
 596 [
 597   case $enable_decimal_float in
 598     yes | no | bid | dpd) ;;
 599     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 600 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 601   esac
 602 ],
 603 [
 604   case $target in
 605     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 606       enable_decimal_float=yes
 607       ;;
 608     *)
 609       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 610       enable_decimal_float=no
 611       ;;
 612   esac
 613 ])
 614
 615 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 616 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 617 [Define to 1 to enable decimal float extension to C.])
 618
 619 # x86's use BID format instead of DPD
 620 case x$enable_decimal_float in
 621   xyes)
 622     case $target in
 623       i?86*-*-linux* | x86_64*-*-linux*)
 624         enable_decimal_float=bid
 625         ;;
 626       *)
 627         enable_decimal_float=dpd
 628         ;;
 629     esac
 630     ;;
 631   xno)
 632     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 633     # dependency on libdecnumber.
 634     enable_decimal_float=dpd
 635     ;;
 636 esac
 637 AC_SUBST(enable_decimal_float)
 638
 639 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 640 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 641 [Define to 1 to specify that we are using the BID decimal floating
 642 point format instead of DPD])
 643
 644 # Enable threads
 645 # Pass with no value to take the default
 646 # Pass with a value to specify a thread package
 647 AC_ARG_ENABLE(threads,
 648 [  --enable-threads        enable thread usage for target GCC
 649   --enable-threads=LIB    use LIB thread package for target GCC],,
 650 [enable_threads=''])
 651
 652 AC_ARG_ENABLE(tls,
 653 [  --enable-tls            enable or disable generation of tls code
 654                           overriding the assembler check for tls support],
 655 [
 656   case $enable_tls in
 657     yes | no) ;;
 658     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 659 Valid choices are 'yes' and 'no'.]) ;;
 660   esac
 661 ], [enable_tls=''])
 662
 663 AC_ARG_ENABLE(objc-gc,
 664 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 665                           the GNU Objective-C runtime],
 666 if test x$enable_objc_gc = xno; then
 667         objc_boehm_gc=''
 668 else
 669         objc_boehm_gc=1
 670 fi,
 671 objc_boehm_gc='')
 672
 673 AC_ARG_WITH(dwarf2,
 674 [  --with-dwarf2           force the default debug format to be DWARF 2],
 675 dwarf2="$with_dwarf2",
 676 dwarf2=no)
 677
 678 AC_ARG_ENABLE(shared,
 679 [  --disable-shared        don't provide a shared libgcc],
 680 [
 681   case $enable_shared in
 682   yes | no) ;;
 683   *)
 684     enable_shared=no
 685     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 686     for pkg in $enableval; do
 687       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 688         enable_shared=yes
 689       fi
 690     done
 691     IFS="$ac_save_ifs"
 692     ;;
 693   esac
 694 ], [enable_shared=yes])
 695 AC_SUBST(enable_shared)
 696
 697 AC_ARG_WITH(build-sysroot,
 698   [  --with-build-sysroot=sysroot
 699                           use sysroot as the system root during the build])
 700
 701 AC_ARG_WITH(sysroot,
 702 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 703 [
 704  case ${with_sysroot} in
 705  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 706  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 707  esac
 708
 709  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 710  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 711
 712  if test "x$prefix" = xNONE; then
 713   test_prefix=/usr/local
 714  else
 715   test_prefix=$prefix
 716  fi
 717  if test "x$exec_prefix" = xNONE; then
 718   test_exec_prefix=$test_prefix
 719  else
 720   test_exec_prefix=$exec_prefix
 721  fi
 722  case ${TARGET_SYSTEM_ROOT} in
 723  "${test_prefix}"|"${test_prefix}/"*|\
 724  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 725  '${prefix}'|'${prefix}/'*|\
 726  '${exec_prefix}'|'${exec_prefix}/'*)
 727    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 728    TARGET_SYSTEM_ROOT_DEFINE="$t"
 729    ;;
 730  esac
 731 ], [
 732  TARGET_SYSTEM_ROOT=
 733  TARGET_SYSTEM_ROOT_DEFINE=
 734  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 735 ])
 736 AC_SUBST(TARGET_SYSTEM_ROOT)
 737 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 738 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 739
 740 # Build with intermodule optimisations
 741 AC_ARG_ENABLE(intermodule,
 742 [  --enable-intermodule    build the compiler in one step],
 743 [case ${enable_intermodule} in
 744   yes) onestep="-onestep";;
 745   *) onestep="";;
 746 esac],
 747 [onestep=""])
 748 AC_SUBST(onestep)
 749
 750 # Sanity check enable_languages in case someone does not run the toplevel
 751 # configure # script.
 752 AC_ARG_ENABLE(languages,
 753 [  --enable-languages=LIST specify which front-ends to build],
 754 [case ,${enable_languages}, in
 755        ,,|,yes,)
 756                 # go safe -- we cannot be much sure without the toplevel
 757                 # configure's
 758                 # analysis of which target libs are present and usable
 759                 enable_languages=c
 760                 ;;
 761          *,all,*)
 762                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 763                 ;;
 764         *,c,*)
 765                 ;;
 766         *)
 767                 enable_languages=c,${enable_languages}
 768                 ;;
 769 esac],
 770 [enable_languages=c])
 771
 772 # Used by documentation targets
 773 AC_SUBST(datarootdir)
 774 AC_SUBST(docdir)
 775 AC_SUBST(htmldir)
 776
 777 # -------------------------
 778 # Checks for other programs
 779 # -------------------------
 780
 781 AC_PROG_MAKE_SET
 782
 783 # Find some useful tools
 784 AC_PROG_AWK
 785 # We need awk to create options.c and options.h.
 786 # Bail out if it's missing.
 787 case ${AWK} in
 788   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 789 esac
 790
 791 gcc_AC_PROG_LN_S
 792 ACX_PROG_LN($LN_S)
 793 AC_PROG_RANLIB
 794 case "${host}" in
 795 *-*-darwin*)
 796   # By default, the Darwin ranlib will not treat common symbols as
 797   # definitions when  building the archive table of contents.  Other
 798   # ranlibs do that; pass an option to the Darwin ranlib that makes
 799   # it behave similarly.
 800   ranlib_flags="-c"
 801   ;;
 802 *)
 803   ranlib_flags=""
 804 esac
 805 AC_SUBST(ranlib_flags)
 806
 807 gcc_AC_PROG_INSTALL
 808
 809 # See if cmp has --ignore-initial.
 810 gcc_AC_PROG_CMP_IGNORE_INITIAL
 811
 812 # See if we have the mktemp command.
 813 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 814
 815 # See if makeinfo has been installed and is modern enough
 816 # that we can use it.
 817 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 818   [GNU texinfo.* \([0-9][0-9.]*\)],
 819   [4.[4-9]*])
 820 if test $gcc_cv_prog_makeinfo_modern = no; then
 821   AC_MSG_WARN([
 822 *** Makeinfo is missing or too old.
 823 *** Info documentation will not be built.])
 824   BUILD_INFO=
 825 else
 826   BUILD_INFO=info
 827 fi
 828 AC_SUBST(BUILD_INFO)
 829
 830 # Is pod2man recent enough to regenerate manpages?
 831 AC_MSG_CHECKING([for recent Pod::Man])
 832 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 833   AC_MSG_RESULT(yes)
 834   GENERATED_MANPAGES=generated-manpages
 835 else
 836   AC_MSG_RESULT(no)
 837   GENERATED_MANPAGES=
 838 fi
 839 AC_SUBST(GENERATED_MANPAGES)
 840
 841 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 842
 843 # How about lex?
 844 dnl Don't use AC_PROG_LEX; we insist on flex.
 845 dnl LEXLIB is not useful in gcc.
 846 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 847
 848 # Bison?
 849 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 850
 851 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 852 # check for build == host before using them.
 853
 854 # NM
 855 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 856   && test -d ../binutils ; then
 857   NM='$(objdir)/../binutils/nm-new'
 858 else
 859   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 860 fi
 861
 862 # AR
 863 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 864   && test -d ../binutils ; then
 865   AR='$(objdir)/../binutils/ar'
 866 else
 867   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 868 fi
 869
 870
 871 # --------------------
 872 # Checks for C headers
 873 # --------------------
 874
 875 AC_MSG_CHECKING(for GNU C library)
 876 AC_CACHE_VAL(gcc_cv_glibc,
 877 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 878   [[#include <features.h>]], [[
 879 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 880 #error Not a GNU C library system
 881 #endif]])],
 882   [gcc_cv_glibc=yes],
 883   [gcc_cv_glibc=no])])
 884 AC_MSG_RESULT($gcc_cv_glibc)
 885 if test $gcc_cv_glibc = yes; then
 886   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 887 fi
 888
 889 # Need to reject headers which give warnings, so that the -Werror bootstrap
 890 # works later. *sigh*  This needs to come before all header checks.
 891 AC_PROG_CPP_WERROR
 892
 893 AC_HEADER_STDC
 894 AC_HEADER_TIME
 895 ACX_HEADER_STRING
 896 AC_HEADER_SYS_WAIT
 897 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 898                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 899                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 900                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 901
 902 # Check for thread headers.
 903 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 904 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 905
 906 # These tests can't be done till we know if we have limits.h.
 907 gcc_AC_C_CHAR_BIT
 908 AC_C_BIGENDIAN
 909
 910 # --------
 911 # UNSORTED
 912 # --------
 913
 914
 915 # These libraries may be used by collect2.
 916 # We may need a special search path to get them linked.
 917 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 918 [save_LIBS="$LIBS"
 919 for libs in '' -lld -lmld \
 920                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 921                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 922 do
 923         LIBS="$libs"
 924         AC_TRY_LINK_FUNC(ldopen,
 925                 [gcc_cv_collect2_libs="$libs"; break])
 926 done
 927 LIBS="$save_LIBS"
 928 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 929 case $gcc_cv_collect2_libs in
 930         "none required")        ;;
 931         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 932 esac
 933 AC_SUBST(COLLECT2_LIBS)
 934
 935 # When building Ada code on Alpha, we need exc_resume which is usually in
 936 # -lexc.  So test for it.
 937 save_LIBS="$LIBS"
 938 LIBS=
 939 AC_SEARCH_LIBS(exc_resume, exc)
 940 GNAT_LIBEXC="$LIBS"
 941 LIBS="$save_LIBS"
 942 AC_SUBST(GNAT_LIBEXC)
 943
 944 # Some systems put ldexp and frexp in libm instead of libc; assume
 945 # they're both in the same place.  jcf-dump needs them.
 946 save_LIBS="$LIBS"
 947 LIBS=
 948 AC_SEARCH_LIBS(ldexp, m)
 949 LDEXP_LIB="$LIBS"
 950 LIBS="$save_LIBS"
 951 AC_SUBST(LDEXP_LIB)
 952
 953 # Use <inttypes.h> only if it exists,
 954 # doesn't clash with <sys/types.h>, and declares intmax_t.
 955 AC_MSG_CHECKING(for inttypes.h)
 956 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 957 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 958 [[#include <sys/types.h>
 959 #include <inttypes.h>]],
 960   [[intmax_t i = -1;]])],
 961   [gcc_cv_header_inttypes_h=yes],
 962   [gcc_cv_header_inttypes_h=no])])
 963 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 964 if test $gcc_cv_header_inttypes_h = yes; then
 965   AC_DEFINE(HAVE_INTTYPES_H, 1,
 966         [Define if you have a working <inttypes.h> header file.])
 967 fi
 968
 969 dnl Disabled until we have a complete test for buggy enum bitfields.
 970 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 971
 972 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 973   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 974   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 975   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 976   putchar_unlocked putc_unlocked)
 977 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
 978         sysconf strsignal getrusage nl_langinfo scandir alphasort \
 979         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
 980         gcc_UNLOCKED_FUNCS)
 981
 982 if test x$ac_cv_func_mbstowcs = xyes; then
 983   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 984 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 985 int main()
 986 {
 987   mbstowcs(0, "", 0);
 988   return 0;
 989 }]])],
 990     [gcc_cv_func_mbstowcs_works=yes],
 991     [gcc_cv_func_mbstowcs_works=no],
 992     [gcc_cv_func_mbstowcs_works=yes])])
 993   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 994     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 995   [Define this macro if mbstowcs does not crash when its
 996    first argument is NULL.])
 997   fi
 998 fi
 999
1000 AC_CHECK_TYPE(ssize_t, int)
1001
1002 # Try to determine the array type of the second argument of getgroups
1003 # for the target system (int or gid_t).
1004 AC_TYPE_GETGROUPS
1005 if test "${target}" = "${build}"; then
1006   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1007 else
1008   case "${target}" in
1009         # This condition may need some tweaking.  It should include all
1010         # targets where the array type of the second argument of getgroups
1011         # is int and the type of gid_t is not equivalent to int.
1012         *-*-sunos* | *-*-ultrix*)
1013                 TARGET_GETGROUPS_T=int
1014                 ;;
1015         *)
1016                 TARGET_GETGROUPS_T=gid_t
1017                 ;;
1018   esac
1019 fi
1020 AC_SUBST(TARGET_GETGROUPS_T)
1021
1022 gcc_AC_FUNC_MMAP_BLACKLIST
1023
1024 case "${host}" in
1025 *-*-*vms*)
1026   # Under VMS, vfork works very differently than on Unix. The standard test
1027   # won't work, and it isn't easily adaptable. It makes more sense to
1028   # just force it.
1029   ac_cv_func_vfork_works=yes
1030   ;;
1031 esac
1032 AC_FUNC_FORK
1033
1034 AM_ICONV
1035 # Until we have in-tree GNU iconv:
1036 LIBICONV_DEP=
1037 AC_SUBST(LIBICONV_DEP)
1038
1039 AM_LC_MESSAGES
1040
1041 AM_LANGINFO_CODESET
1042
1043 # We will need to find libiberty.h and ansidecl.h
1044 saved_CFLAGS="$CFLAGS"
1045 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1046 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1047         strsignal strstr strverscmp \
1048         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1049         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1050 #include "ansidecl.h"
1051 #include "system.h"])
1052
1053 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1054 #include "ansidecl.h"
1055 #include "system.h"
1056 #ifdef HAVE_SYS_RESOURCE_H
1057 #include <sys/resource.h>
1058 #endif
1059 ])
1060
1061 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1062 #include "ansidecl.h"
1063 #include "system.h"
1064 #ifdef HAVE_SYS_RESOURCE_H
1065 #include <sys/resource.h>
1066 #endif
1067 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1068 [Define to \`long' if <sys/resource.h> doesn't define.])])
1069
1070 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1071 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1072 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1073 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1074 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1075 #include "ansidecl.h"
1076 #include "system.h"
1077 #ifdef HAVE_LDFCN_H
1078 #undef FREAD
1079 #undef FWRITE
1080 #include <ldfcn.h>
1081 #endif
1082 ])
1083
1084 gcc_AC_CHECK_DECLS(times, , ,[
1085 #include "ansidecl.h"
1086 #include "system.h"
1087 #ifdef HAVE_SYS_TIMES_H
1088 #include <sys/times.h>
1089 #endif
1090 ])
1091
1092 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1093 #include "ansidecl.h"
1094 #include "system.h"
1095 #include <signal.h>
1096 ])
1097
1098 # More time-related stuff.
1099 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1100 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1101 #include "ansidecl.h"
1102 #include "system.h"
1103 #ifdef HAVE_SYS_TIMES_H
1104 #include <sys/times.h>
1105 #endif
1106 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1107 if test $ac_cv_struct_tms = yes; then
1108   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1109   [Define if <sys/times.h> defines struct tms.])
1110 fi
1111
1112 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1113 # revisit after autoconf 2.50.
1114 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1115 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1116 #include "ansidecl.h"
1117 #include "system.h"
1118 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1119 if test $gcc_cv_type_clock_t = yes; then
1120   AC_DEFINE(HAVE_CLOCK_T, 1,
1121   [Define if <time.h> defines clock_t.])
1122 fi
1123
1124 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1125 CFLAGS="$saved_CFLAGS"
1126
1127 gcc_AC_INITFINI_ARRAY
1128
1129 # mkdir takes a single argument on some systems.
1130 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1131
1132 # File extensions
1133 manext='.1'
1134 objext='.o'
1135 AC_SUBST(manext)
1136 AC_SUBST(objext)
1137
1138 # With Setjmp/Longjmp based exception handling.
1139 AC_ARG_ENABLE(sjlj-exceptions,
1140 [  --enable-sjlj-exceptions
1141                           arrange to use setjmp/longjmp exception handling],
1142 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1143 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1144   [Define 0/1 to force the choice for exception handling model.])])
1145
1146 # For platforms with the unwind ABI which includes an unwind library,
1147 # libunwind, we can choose to use the system libunwind.
1148 AC_ARG_WITH(system-libunwind,
1149 [  --with-system-libunwind use installed libunwind])
1150
1151 # config.gcc also contains tests of with_system_libunwind.
1152 if test x$with_system_libunwind = xyes; then
1153         AC_DEFINE(HAVE_GETIPINFO, 1,
1154 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1155 fi
1156
1157 # --------------------------------------------------------
1158 # Build, host, and target specific configuration fragments
1159 # --------------------------------------------------------
1160
1161 # Collect build-machine-specific information.
1162 . ${srcdir}/config.build
1163
1164 # Collect host-machine-specific information.
1165 . ${srcdir}/config.host
1166
1167 target_gtfiles=
1168
1169 # Collect target-machine-specific information.
1170 . ${srcdir}/config.gcc
1171
1172 extra_objs="${host_extra_objs} ${extra_objs}"
1173 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1174
1175 # Default the target-machine variables that were not explicitly set.
1176 if test x"$tm_file" = x
1177 then tm_file=$cpu_type/$cpu_type.h; fi
1178
1179 if test x"$extra_headers" = x
1180 then extra_headers=; fi
1181
1182 if test x$md_file = x
1183 then md_file=$cpu_type/$cpu_type.md; fi
1184
1185 if test x$out_file = x
1186 then out_file=$cpu_type/$cpu_type.c; fi
1187
1188 if test x"$tmake_file" = x
1189 then tmake_file=$cpu_type/t-$cpu_type
1190 fi
1191
1192 if test x"$dwarf2" = xyes
1193 then tm_file="$tm_file tm-dwarf2.h"
1194 fi
1195
1196 # Say what files are being used for the output code and MD file.
1197 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1198 echo "Using \`$srcdir/config/$md_file' as machine description file."
1199
1200 # If any of the xm_file variables contain nonexistent files, warn
1201 # about them and drop them.
1202
1203 bx=
1204 for x in $build_xm_file; do
1205   if    test -f $srcdir/config/$x
1206   then      bx="$bx $x"
1207   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1208   fi
1209 done
1210 build_xm_file="$bx"
1211
1212 hx=
1213 for x in $host_xm_file; do
1214   if    test -f $srcdir/config/$x
1215   then      hx="$hx $x"
1216   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1217   fi
1218 done
1219 host_xm_file="$hx"
1220
1221 tx=
1222 for x in $xm_file; do
1223   if    test -f $srcdir/config/$x
1224   then      tx="$tx $x"
1225   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1226   fi
1227 done
1228 xm_file="$tx"
1229
1230 count=a
1231 for f in $tm_file; do
1232         count=${count}x
1233 done
1234 if test $count = ax; then
1235         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1236 else
1237         echo "Using the following target machine macro files:"
1238         for f in $tm_file; do
1239                 echo "  $srcdir/config/$f"
1240         done
1241 fi
1242
1243 if test x$need_64bit_hwint = xyes; then
1244         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1245 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1246 fi
1247
1248 if test x$use_long_long_for_widest_fast_int = xyes; then
1249         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1250 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1251 efficiently supported by the host hardware.])
1252 fi
1253
1254 count=a
1255 for f in $host_xm_file; do
1256         count=${count}x
1257 done
1258 if test $count = a; then
1259         :
1260 elif test $count = ax; then
1261         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1262 else
1263         echo "Using the following host machine macro files:"
1264         for f in $host_xm_file; do
1265                 echo "  $srcdir/config/$f"
1266         done
1267 fi
1268 echo "Using ${out_host_hook_obj} for host machine hooks."
1269
1270 if test "$host_xm_file" != "$build_xm_file"; then
1271         count=a
1272         for f in $build_xm_file; do
1273                 count=${count}x
1274         done
1275         if test $count = a; then
1276                 :
1277         elif test $count = ax; then
1278                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1279         else
1280                 echo "Using the following build machine macro files:"
1281                 for f in $build_xm_file; do
1282                         echo "  $srcdir/config/$f"
1283                 done
1284         fi
1285 fi
1286
1287 case ${host} in
1288   powerpc*-*-darwin*)
1289     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1290       gcc_cv_mcontext_underscores,
1291       AC_COMPILE_IFELSE([
1292 #include <sys/cdefs.h>
1293 #include <sys/signal.h>
1294 #include <ucontext.h>
1295 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1296 ],
1297         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1298       if test $gcc_cv_mcontext_underscores = yes; then
1299         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1300           [mcontext_t fields start with __])
1301       fi
1302     ;;
1303 esac
1304
1305 # ---------
1306 # Threading
1307 # ---------
1308
1309 # Check if a valid thread package
1310 case ${enable_threads} in
1311   "" | no)
1312     # No threads
1313     target_thread_file='single'
1314     ;;
1315   yes)
1316     # default
1317     target_thread_file='single'
1318     ;;
1319   aix | dce | gnat | irix | posix | posix95 | rtems | \
1320   single | solaris | vxworks | win32 )
1321     target_thread_file=${enable_threads}
1322     ;;
1323   *)
1324     echo "${enable_threads} is an unknown thread package" 1>&2
1325     exit 1
1326     ;;
1327 esac
1328
1329 if test x${thread_file} = x; then
1330   # No thread file set by target-specific clauses in config.gcc,
1331   # so use file chosen by default logic above
1332   thread_file=${target_thread_file}
1333 fi
1334
1335 # Make gthr-default.h if we have a thread file.
1336 gthread_flags=
1337 if test $thread_file != single; then
1338   rm -f gthr-default.h
1339   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1340   gthread_flags=-DHAVE_GTHR_DEFAULT
1341 fi
1342 AC_SUBST(gthread_flags)
1343
1344 # --------
1345 # UNSORTED
1346 # --------
1347
1348 use_cxa_atexit=no
1349 if test x$enable___cxa_atexit = xyes || \
1350    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1351   if test x$host = x$target; then
1352     case $host in
1353       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1354       # keyed to flag_use_cxa_atexit
1355       *-*-mingw32*)
1356         use_cxa_atexit=yes
1357         ;;
1358       *)
1359         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1360           [echo "__cxa_atexit can't be enabled on this target"])
1361         ;;
1362     esac
1363   else
1364     # We can't check for __cxa_atexit when building a cross, so assume
1365     # it is available
1366     use_cxa_atexit=yes
1367   fi
1368   if test x$use_cxa_atexit = xyes; then
1369     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1370       [Define if you want to use __cxa_atexit, rather than atexit, to
1371       register C++ destructors for local statics and global objects.
1372       This is essential for fully standards-compliant handling of
1373       destructors, but requires __cxa_atexit in libc.])
1374   fi
1375 fi
1376
1377 use_getipinfo=yes
1378 if test x$with_system_libunwind = xyes; then
1379    if test x$host = x$target; then
1380      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1381    fi
1382 fi
1383 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1384 if test x$use_getipinfo = xyes; then
1385    AC_DEFINE(HAVE_GETIPINFO, 1,
1386         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1387 else
1388    echo "The system unwind library does not support _Unwind_GetIPInfo."
1389 fi
1390
1391 # Look for a file containing extra machine modes.
1392 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1393   extra_modes_file='$(srcdir)'/config/${extra_modes}
1394   AC_SUBST(extra_modes_file)
1395   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1396   [Define to the name of a file containing a list of extra machine modes
1397    for this architecture.])
1398 fi
1399
1400 # Convert extra_options into a form suitable for Makefile use.
1401 extra_opt_files=
1402 for f in $extra_options; do
1403   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1404 done
1405 AC_SUBST(extra_opt_files)
1406
1407 # auto-host.h is the file containing items generated by autoconf and is
1408 # the first file included by config.h.
1409 # If host=build, it is correct to have bconfig include auto-host.h
1410 # as well.  If host!=build, we are in error and need to do more
1411 # work to find out the build config parameters.
1412 if test x$host = x$build
1413 then
1414         build_auto=auto-host.h
1415 else
1416         # We create a subdir, then run autoconf in the subdir.
1417         # To prevent recursion we set host and build for the new
1418         # invocation of configure to the build for this invocation
1419         # of configure.
1420         tempdir=build.$$
1421         rm -rf $tempdir
1422         mkdir $tempdir
1423         cd $tempdir
1424         case ${srcdir} in
1425         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1426         *) realsrcdir=../${srcdir};;
1427         esac
1428         saved_CFLAGS="${CFLAGS}"
1429         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1430         ${realsrcdir}/configure \
1431                 --enable-languages=${enable_languages-all} \
1432                 --target=$target_alias --host=$build_alias --build=$build_alias
1433         CFLAGS="${saved_CFLAGS}"
1434
1435         # We just finished tests for the build machine, so rename
1436         # the file auto-build.h in the gcc directory.
1437         mv auto-host.h ../auto-build.h
1438         cd ..
1439         rm -rf $tempdir
1440         build_auto=auto-build.h
1441 fi
1442 AC_SUBST(build_subdir)
1443
1444 tm_file="${tm_file} defaults.h"
1445 tm_p_file="${tm_p_file} tm-preds.h"
1446 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1447 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1448 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1449 # put this back in temporarily.
1450 xm_file="auto-host.h ansidecl.h ${xm_file}"
1451
1452 # --------
1453 # UNSORTED
1454 # --------
1455
1456 changequote(,)dnl
1457 # Compile in configure arguments.
1458 if test -f configargs.h ; then
1459         # Being re-configured.
1460         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1461         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1462 else
1463         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1464 fi
1465
1466 # Double all backslashes and backslash all quotes to turn
1467 # gcc_config_arguments into a C string.
1468 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1469 $gcc_config_arguments
1470 EOF
1471 gcc_config_arguments_str=`cat conftest.out`
1472 rm -f conftest.out
1473
1474 cat > configargs.h <<EOF
1475 /* Generated automatically. */
1476 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1477 static const char thread_model[] = "$thread_file";
1478
1479 static const struct {
1480   const char *name, *value;
1481 } configure_default_options[] = $configure_default_options;
1482 EOF
1483 changequote([,])dnl
1484
1485 # Internationalization
1486 ZW_GNU_GETTEXT_SISTER_DIR
1487
1488 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1489 # -liconv on the link line twice.
1490 case "$LIBINTL" in *$LIBICONV*)
1491         LIBICONV= ;;
1492 esac
1493
1494 AC_ARG_ENABLE(secureplt,
1495 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1496 [], [])
1497
1498 # Windows32 Registry support for specifying GCC installation paths.
1499 AC_ARG_ENABLE(win32-registry,
1500 [  --disable-win32-registry
1501                           disable lookup of installation paths in the
1502                           Registry on Windows hosts
1503   --enable-win32-registry enable registry lookup (default)
1504   --enable-win32-registry=KEY
1505                           use KEY instead of GCC version as the last portion
1506                           of the registry key],,)
1507
1508 case $host_os in
1509   win32 | pe | cygwin* | mingw32* | uwin*)
1510     if test "x$enable_win32_registry" != xno; then
1511       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1512     fi
1513
1514     if test "x$enable_win32_registry" != xno; then
1515       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1516   [Define to 1 if installation paths should be looked up in the Windows
1517    Registry. Ignored on non-Windows hosts.])
1518
1519       if test "x$enable_win32_registry" != xyes \
1520          && test "x$enable_win32_registry" != x; then
1521         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1522   [Define to be the last component of the Windows registry key under which
1523    to look for installation paths.  The full key used will be
1524    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1525    The default is the GCC version number.])
1526       fi
1527     fi
1528   ;;
1529 esac
1530
1531 # Get an absolute path to the GCC top-level source directory
1532 holddir=`${PWDCMD-pwd}`
1533 cd $srcdir
1534 topdir=`${PWDCMD-pwd}`
1535 cd $holddir
1536
1537 # Conditionalize the makefile for this host machine.
1538 xmake_file=
1539 for f in ${host_xmake_file}
1540 do
1541         if test -f ${srcdir}/config/$f
1542         then
1543                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1544         fi
1545 done
1546
1547 # Conditionalize the makefile for this target machine.
1548 tmake_file_=
1549 for f in ${tmake_file}
1550 do
1551         if test -f ${srcdir}/config/$f
1552         then
1553                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1554         fi
1555 done
1556 tmake_file="${tmake_file_}"
1557
1558 # This is a terrible hack which will go away some day.
1559 host_cc_for_libada=${CC}
1560 AC_SUBST(host_cc_for_libada)
1561
1562 out_object_file=`basename $out_file .c`.o
1563
1564 tm_file_list="options.h"
1565 tm_include_list="options.h"
1566 for f in $tm_file; do
1567   case $f in
1568     ./* )
1569        f=`echo $f | sed 's/^..//'`
1570        tm_file_list="${tm_file_list} $f"
1571        tm_include_list="${tm_include_list} $f"
1572        ;;
1573     defaults.h )
1574        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1575        tm_include_list="${tm_include_list} $f"
1576        ;;
1577     * )
1578        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1579        tm_include_list="${tm_include_list} config/$f"
1580        ;;
1581   esac
1582 done
1583
1584 tm_p_file_list=
1585 tm_p_include_list=
1586 for f in $tm_p_file; do
1587   case $f in
1588     tm-preds.h )
1589        tm_p_file_list="${tm_p_file_list} $f"
1590        tm_p_include_list="${tm_p_include_list} $f"
1591        ;;
1592     * )
1593        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1594        tm_p_include_list="${tm_p_include_list} config/$f"
1595   esac
1596 done
1597
1598 xm_file_list=
1599 xm_include_list=
1600 for f in $xm_file; do
1601   case $f in
1602     ansidecl.h )
1603        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1604        xm_include_list="${xm_include_list} $f"
1605        ;;
1606     auto-host.h )
1607        xm_file_list="${xm_file_list} $f"
1608        xm_include_list="${xm_include_list} $f"
1609        ;;
1610     * )
1611        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1612        xm_include_list="${xm_include_list} config/$f"
1613        ;;
1614   esac
1615 done
1616
1617 host_xm_file_list=
1618 host_xm_include_list=
1619 for f in $host_xm_file; do
1620   case $f in
1621     ansidecl.h )
1622        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1623        host_xm_include_list="${host_xm_include_list} $f"
1624        ;;
1625     auto-host.h )
1626        host_xm_file_list="${host_xm_file_list} $f"
1627        host_xm_include_list="${host_xm_include_list} $f"
1628        ;;
1629     * )
1630        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1631        host_xm_include_list="${host_xm_include_list} config/$f"
1632        ;;
1633   esac
1634 done
1635
1636 build_xm_file_list=
1637 for f in $build_xm_file; do
1638   case $f in
1639     ansidecl.h )
1640        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1641        build_xm_include_list="${build_xm_include_list} $f"
1642        ;;
1643     auto-build.h | auto-host.h )
1644        build_xm_file_list="${build_xm_file_list} $f"
1645        build_xm_include_list="${build_xm_include_list} $f"
1646        ;;
1647     * )
1648        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1649        build_xm_include_list="${build_xm_include_list} config/$f"
1650        ;;
1651   esac
1652 done
1653
1654 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1655 # cross-compiler which does not use the native headers and libraries.
1656 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1657 CROSS=                                          AC_SUBST(CROSS)
1658 ALL=all.internal                                AC_SUBST(ALL)
1659 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1660
1661 if test "x$with_build_sysroot" != x; then
1662   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1663 else
1664   # This value is used, even on a native system, because
1665   # CROSS_SYSTEM_HEADER_DIR is just
1666   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1667   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1668 fi
1669
1670 if test x$host != x$target
1671 then
1672         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1673         ALL=all.cross
1674         SYSTEM_HEADER_DIR=$build_system_header_dir
1675         case "$host","$target" in
1676         # Darwin crosses can use the host system's libraries and headers,
1677         # because of the fat library support.  Of course, it must be the
1678         # same version of Darwin on both sides.  Allow the user to
1679         # just say --target=foo-darwin without a version number to mean
1680         # "the version on this system".
1681             *-*-darwin*,*-*-darwin*)
1682                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1683                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1684                 if test $hostos = $targetos -o $targetos = darwin ; then
1685                     CROSS=
1686                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1687                     with_headers=yes
1688                 fi
1689                 ;;
1690
1691             i?86-*-*,x86_64-*-* \
1692             | powerpc*-*-*,powerpc64*-*-*)
1693                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1694         esac
1695 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1696         SYSTEM_HEADER_DIR=$build_system_header_dir
1697 fi
1698
1699 # If this is a cross-compiler that does not
1700 # have its own set of headers then define
1701 # inhibit_libc
1702
1703 # If this is using newlib, without having the headers available now,
1704 # then define inhibit_libc in LIBGCC2_CFLAGS.
1705 # This prevents libgcc2 from containing any code which requires libc
1706 # support.
1707 inhibit_libc=false
1708 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1709        test x$with_newlib = xyes ; } &&
1710      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1711        inhibit_libc=true
1712 fi
1713 AC_SUBST(inhibit_libc)
1714
1715 # When building gcc with a cross-compiler, we need to adjust things so
1716 # that the generator programs are still built with the native compiler.
1717 # Also, we cannot run fixincludes or fix-header.
1718
1719 # These are the normal (build=host) settings:
1720 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1721 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1722 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1723
1724 # Possibly disable fixproto, on a per-target basis.
1725 case ${use_fixproto} in
1726   no)
1727     STMP_FIXPROTO=
1728     ;;
1729   yes)
1730     STMP_FIXPROTO=stmp-fixproto
1731     ;;
1732 esac
1733 AC_SUBST(STMP_FIXPROTO)
1734
1735 # And these apply if build != host, or we are generating coverage data
1736 if test x$build != x$host || test "x$coverage_flags" != x
1737 then
1738     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1739
1740     if test "x$TARGET_SYSTEM_ROOT" = x; then
1741         if test "x$STMP_FIXPROTO" != x; then
1742           STMP_FIXPROTO=stmp-install-fixproto
1743         fi
1744     fi
1745 fi
1746
1747 # Expand extra_headers to include complete path.
1748 # This substitutes for lots of t-* files.
1749 extra_headers_list=
1750 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1751 for file in ${extra_headers} ; do
1752   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1753 done
1754
1755 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1756 if test x"$use_gcc_tgmath" = xyes
1757 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1758 fi
1759
1760 # Define collect2 in Makefile.
1761 case $host_can_use_collect2 in
1762   no) collect2= ;;
1763   *) collect2='collect2$(exeext)' ;;
1764 esac
1765 AC_SUBST([collect2])
1766
1767 # Add a definition of USE_COLLECT2 if system wants one.
1768 case $use_collect2 in
1769   no) use_collect2= ;;
1770   "") ;;
1771   *)
1772     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1773     xm_defines="${xm_defines} USE_COLLECT2"
1774     case $host_can_use_collect2 in
1775       no)
1776         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1777         ;;
1778     esac
1779     ;;
1780 esac
1781
1782 # ---------------------------
1783 # Assembler & linker features
1784 # ---------------------------
1785
1786 # Identify the assembler which will work hand-in-glove with the newly
1787 # built GCC, so that we can examine its features.  This is the assembler
1788 # which will be driven by the driver program.
1789 #
1790 # If build != host, and we aren't building gas in-tree, we identify a
1791 # build->target assembler and hope that it will have the same features
1792 # as the host->target assembler we'll be using.
1793 gcc_cv_gas_major_version=
1794 gcc_cv_gas_minor_version=
1795 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1796
1797 m4_pattern_allow([AS_FOR_TARGET])dnl
1798 AS_VAR_SET_IF(gcc_cv_as,, [
1799 if test -x "$DEFAULT_ASSEMBLER"; then
1800         gcc_cv_as="$DEFAULT_ASSEMBLER"
1801 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1802      && test -f ../gas/Makefile \
1803      && test x$build = x$host; then
1804         gcc_cv_as=../gas/as-new$build_exeext
1805 elif test -x as$build_exeext; then
1806         # Build using assembler in the current directory.
1807         gcc_cv_as=./as$build_exeext
1808 elif test -x $AS_FOR_TARGET; then
1809         gcc_cv_as="$AS_FOR_TARGET"
1810 else
1811         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1812 fi])
1813
1814 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1815 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1816 case "$ORIGINAL_AS_FOR_TARGET" in
1817   ./as | ./as$build_exeext) ;;
1818   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1819 esac
1820
1821 AC_MSG_CHECKING(what assembler to use)
1822 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1823   # Single tree build which includes gas.  We want to prefer it
1824   # over whatever linker top-level may have detected, since
1825   # we'll use what we're building after installation anyway.
1826   AC_MSG_RESULT(newly built gas)
1827   in_tree_gas=yes
1828   _gcc_COMPUTE_GAS_VERSION
1829   in_tree_gas_is_elf=no
1830   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1831      || (grep 'obj_format = multi' ../gas/Makefile \
1832          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1833   then
1834     in_tree_gas_is_elf=yes
1835   fi
1836 else
1837   AC_MSG_RESULT($gcc_cv_as)
1838   in_tree_gas=no
1839 fi
1840
1841 # Identify the linker which will work hand-in-glove with the newly
1842 # built GCC, so that we can examine its features.  This is the linker
1843 # which will be driven by the driver program.
1844 #
1845 # If build != host, and we aren't building gas in-tree, we identify a
1846 # build->target linker and hope that it will have the same features
1847 # as the host->target linker we'll be using.
1848 gcc_cv_gld_major_version=
1849 gcc_cv_gld_minor_version=
1850 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1851 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1852
1853 AS_VAR_SET_IF(gcc_cv_ld,, [
1854 if test -x "$DEFAULT_LINKER"; then
1855         gcc_cv_ld="$DEFAULT_LINKER"
1856 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1857      && test -f ../ld/Makefile \
1858      && test x$build = x$host; then
1859         gcc_cv_ld=../ld/ld-new$build_exeext
1860 elif test -x collect-ld$build_exeext; then
1861         # Build using linker in the current directory.
1862         gcc_cv_ld=./collect-ld$build_exeext
1863 elif test -x $LD_FOR_TARGET; then
1864         gcc_cv_ld="$LD_FOR_TARGET"
1865 else
1866         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1867 fi])
1868
1869 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1870 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1871 case "$ORIGINAL_LD_FOR_TARGET" in
1872   ./collect-ld | ./collect-ld$build_exeext) ;;
1873   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1874 esac
1875
1876 AC_MSG_CHECKING(what linker to use)
1877 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1878         # Single tree build which includes ld.  We want to prefer it
1879         # over whatever linker top-level may have detected, since
1880         # we'll use what we're building after installation anyway.
1881         AC_MSG_RESULT(newly built ld)
1882         in_tree_ld=yes
1883         in_tree_ld_is_elf=no
1884         if (grep 'EMUL = .*elf' ../ld/Makefile \
1885             || grep 'EMUL = .*linux' ../ld/Makefile \
1886             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1887           in_tree_ld_is_elf=yes
1888         fi
1889         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1890         do
1891 changequote(,)dnl
1892                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1893                 if test x$gcc_cv_gld_version != x; then
1894                         break
1895                 fi
1896         done
1897         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1898         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1899 changequote([,])dnl
1900 else
1901         AC_MSG_RESULT($gcc_cv_ld)
1902         in_tree_ld=no
1903 fi
1904
1905 # Figure out what nm we will be using.
1906 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1907 AS_VAR_SET_IF(gcc_cv_nm,, [
1908 if test -f $gcc_cv_binutils_srcdir/configure.in \
1909      && test -f ../binutils/Makefile \
1910      && test x$build = x$host; then
1911         gcc_cv_nm=../binutils/nm-new$build_exeext
1912 elif test -x nm$build_exeext; then
1913         gcc_cv_nm=./nm$build_exeext
1914 elif test -x $NM_FOR_TARGET; then
1915         gcc_cv_nm="$NM_FOR_TARGET"
1916 else
1917         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1918 fi])
1919
1920 AC_MSG_CHECKING(what nm to use)
1921 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1922         # Single tree build which includes binutils.
1923         AC_MSG_RESULT(newly built nm)
1924         in_tree_nm=yes
1925 else
1926         AC_MSG_RESULT($gcc_cv_nm)
1927         in_tree_nm=no
1928 fi
1929
1930 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1931 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1932 case "$ORIGINAL_NM_FOR_TARGET" in
1933   ./nm | ./nm$build_exeext) ;;
1934   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
1935 esac
1936
1937
1938 # Figure out what objdump we will be using.
1939 AS_VAR_SET_IF(gcc_cv_objdump,, [
1940 if test -f $gcc_cv_binutils_srcdir/configure.in \
1941      && test -f ../binutils/Makefile \
1942      && test x$build = x$host; then
1943         # Single tree build which includes binutils.
1944         gcc_cv_objdump=../binutils/objdump$build_exeext
1945 elif test -x objdump$build_exeext; then
1946         gcc_cv_objdump=./objdump$build_exeext
1947 elif test -x $OBJDUMP_FOR_TARGET; then
1948         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
1949 else
1950         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
1951 fi])
1952
1953 AC_MSG_CHECKING(what objdump to use)
1954 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
1955         # Single tree build which includes binutils.
1956         AC_MSG_RESULT(newly built objdump)
1957 elif test x$gcc_cv_objdump = x; then
1958         AC_MSG_RESULT(not found)
1959 else
1960         AC_MSG_RESULT($gcc_cv_objdump)
1961 fi
1962
1963 # Figure out what assembler alignment features are present.
1964 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1965  [2,6,0],,
1966 [.balign 4
1967 .p2align 2],,
1968 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1969   [Define if your assembler supports .balign and .p2align.])])
1970
1971 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1972  [2,8,0],,
1973  [.p2align 4,,7],,
1974 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1975   [Define if your assembler supports specifying the maximum number
1976    of bytes to skip when using the GAS .p2align command.])])
1977
1978 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
1979  [2,8,0],,
1980  [.literal16],,
1981 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
1982   [Define if your assembler supports .literal16.])])
1983
1984 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1985  [elf,2,9,0],,
1986  [conftest_label1: .word 0
1987 .subsection -1
1988 conftest_label2: .word 0
1989 .previous],
1990  [if test x$gcc_cv_nm != x; then
1991     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1992     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1993     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1994     then :
1995     else gcc_cv_as_subsection_m1=yes
1996     fi
1997     rm -f conftest.nm1 conftest.nm2
1998   fi],
1999  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2000   [Define if your assembler supports .subsection and .subsection -1 starts
2001    emitting at the beginning of your section.])])
2002
2003 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2004  [2,2,0],,
2005  [      .weak foobar],,
2006 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2007
2008 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2009  [2,17,0],,
2010  [      .weakref foobar, barfnot],,
2011 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2012
2013 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2014  [2,15,91],,
2015  [      .SPACE $TEXT$
2016         .NSUBSPA $CODE$,COMDAT],,
2017 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2018
2019 # .hidden needs to be supported in both the assembler and the linker,
2020 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2021 # This is irritatingly difficult to feature test for; we have to check the
2022 # date string after the version number.  If we've got an in-tree
2023 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2024 # to be safe.
2025 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2026 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2027  [elf,2,13,0],,
2028 [       .hidden foobar
2029 foobar:])
2030
2031 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2032 [if test $in_tree_ld = yes ; then
2033   gcc_cv_ld_hidden=no
2034   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2035      && test $in_tree_ld_is_elf = yes; then
2036      gcc_cv_ld_hidden=yes
2037   fi
2038 else
2039   gcc_cv_ld_hidden=yes
2040   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2041   if echo "$ld_ver" | grep GNU > /dev/null; then
2042 changequote(,)dnl
2043     ld_vers=`echo $ld_ver | sed -n \
2044         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2045         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2046         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2047         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2048         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2049         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[       ].*$,\1,p' \
2050         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[   -].*$,\1,p'`
2051     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2052     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2053     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2054     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2055     if test 0"$ld_date" -lt 20020404; then
2056       if test -n "$ld_date"; then
2057         # If there was date string, but was earlier than 2002-04-04, fail
2058         gcc_cv_ld_hidden=no
2059       elif test -z "$ld_vers"; then
2060         # If there was no date string nor ld version number, something is wrong
2061         gcc_cv_ld_hidden=no
2062       else
2063         test -z "$ld_vers_patch" && ld_vers_patch=0
2064         if test "$ld_vers_major" -lt 2; then
2065           gcc_cv_ld_hidden=no
2066         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2067           gcc_cv_ld_hidden="no"
2068         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2069           gcc_cv_ld_hidden=no
2070         fi
2071       fi
2072 changequote([,])dnl
2073     fi
2074   else
2075     case "${target}" in
2076       hppa64*-*-hpux* | ia64*-*-hpux*)
2077         gcc_cv_ld_hidden=yes
2078         ;;
2079       *)
2080         gcc_cv_ld_hidden=no
2081         ;;
2082     esac
2083   fi
2084 fi])
2085 libgcc_visibility=no
2086 AC_SUBST(libgcc_visibility)
2087 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2088 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2089   libgcc_visibility=yes
2090   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2091   [Define if your assembler and linker support .hidden.])
2092 fi
2093
2094 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2095 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2096   [elf,2,11,0],,
2097 [       .data
2098         .uleb128 L2 - L1
2099 L1:
2100         .uleb128 1280
2101         .sleb128 -1010
2102 L2:],
2103  [# GAS versions before 2.11 do not support uleb128,
2104   # despite appearing to.
2105   # ??? There exists an elf-specific test that will crash
2106   # the assembler.  Perhaps it's better to figure out whether
2107   # arbitrary sections are supported and try the test.
2108   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2109   if echo "$as_ver" | grep GNU > /dev/null; then
2110 changequote(,)dnl
2111     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2112     as_major=`echo $as_ver | sed 's/\..*//'`
2113     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2114 changequote([,])dnl
2115     if test $as_major -eq 2 && test $as_minor -lt 11
2116     then :
2117     else gcc_cv_as_leb128=yes
2118     fi
2119   fi],
2120   [AC_DEFINE(HAVE_AS_LEB128, 1,
2121     [Define if your assembler supports .sleb128 and .uleb128.])])
2122
2123 # GAS versions up to and including 2.11.0 may mis-optimize
2124 # .eh_frame data.
2125 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2126   [elf,2,12,0],,
2127 [       .text
2128 .LFB1:
2129         .4byte  0
2130 .L1:
2131         .4byte  0
2132 .LFE1:
2133         .section        .eh_frame,"aw",@progbits
2134 __FRAME_BEGIN__:
2135         .4byte  .LECIE1-.LSCIE1
2136 .LSCIE1:
2137         .4byte  0x0
2138         .byte   0x1
2139         .ascii "z\0"
2140         .byte   0x1
2141         .byte   0x78
2142         .byte   0x1a
2143         .byte   0x0
2144         .byte   0x4
2145         .4byte  1
2146         .p2align 1
2147 .LECIE1:
2148 .LSFDE1:
2149         .4byte  .LEFDE1-.LASFDE1
2150 .LASFDE1:
2151         .4byte  .LASFDE1-__FRAME_BEGIN__
2152         .4byte  .LFB1
2153         .4byte  .LFE1-.LFB1
2154         .byte   0x4
2155         .4byte  .LFE1-.LFB1
2156         .byte   0x4
2157         .4byte  .L1-.LFB1
2158 .LEFDE1:],
2159 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2160 cat > conftest.lit <<EOF
2161  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2162  0010 01000000 12000000 18000000 00000000  ................
2163  0020 08000000 04080000 0044               .........D      @&t@
2164 EOF
2165 cat > conftest.big <<EOF
2166  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2167  0010 00000001 00000012 00000018 00000000  ................
2168  0020 00000008 04000000 0844               .........D      @&t@
2169 EOF
2170   # If the assembler didn't choke, and we can objdump,
2171   # and we got the correct data, then succeed.
2172   # The text in the here-document typically retains its unix-style line
2173   # endings, while the output of objdump will use host line endings.
2174   # Therefore, use diff -b for the comparisons.
2175   if test x$gcc_cv_objdump != x \
2176   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2177      | tail -3 > conftest.got \
2178   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2179     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2180   then
2181     gcc_cv_as_eh_frame=yes
2182   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2183     gcc_cv_as_eh_frame=buggy
2184   else
2185     # Uh oh, what do we do now?
2186     gcc_cv_as_eh_frame=no
2187   fi])
2188
2189 if test $gcc_cv_as_eh_frame = buggy; then
2190   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2191   [Define if your assembler mis-optimizes .eh_frame data.])
2192 fi
2193
2194 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2195  [elf,2,12,0], [--fatal-warnings],
2196  [.section .rodata.str, "aMS", @progbits, 1])
2197 if test $gcc_cv_as_shf_merge = no; then
2198   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2199     [elf,2,12,0], [--fatal-warnings],
2200     [.section .rodata.str, "aMS", %progbits, 1])
2201 fi
2202 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2203   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2204 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2205
2206 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2207  [elf,2,16,0], [--fatal-warnings],
2208  [.section .text,"axG",@progbits,.foo,comdat])
2209 if test $gcc_cv_as_comdat_group = yes; then
2210   gcc_cv_as_comdat_group_percent=no
2211 else
2212  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2213    [elf,2,16,0], [--fatal-warnings],
2214    [.section .text,"axG",%progbits,.foo,comdat])
2215 fi
2216 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2217   comdat_group=yes
2218   if test 0"$ld_date" -lt 20050308; then
2219     if test -n "$ld_date"; then
2220       # If there was date string, but was earlier than 2005-03-08, fail
2221       comdat_group=no
2222     elif test "$ld_vers_major" -lt 2; then
2223       comdat_group=no
2224     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2225       comdat_group=no
2226     fi
2227   fi
2228 else
2229   # assume linkers other than GNU ld don't support COMDAT group
2230   comdat_group=no
2231 fi
2232 if test $comdat_group = no; then
2233   gcc_cv_as_comdat_group=no
2234   gcc_cv_as_comdat_group_percent=no
2235 fi
2236 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2237   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2238 [Define 0/1 if your assembler and linker support COMDAT groups.])
2239
2240 # Thread-local storage - the check is heavily parametrized.
2241 conftest_s=
2242 tls_first_major=
2243 tls_first_minor=
2244 tls_as_opt=
2245 case "$target" in
2246 changequote(,)dnl
2247   alpha*-*-*)
2248     conftest_s='
2249         .section ".tdata","awT",@progbits
2250 foo:    .long   25
2251         .text
2252         ldq     $27,__tls_get_addr($29)         !literal!1
2253         lda     $16,foo($29)                    !tlsgd!1
2254         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2255         ldq     $27,__tls_get_addr($29)         !literal!2
2256         lda     $16,foo($29)                    !tlsldm!2
2257         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2258         ldq     $1,foo($29)                     !gotdtprel
2259         ldah    $2,foo($29)                     !dtprelhi
2260         lda     $3,foo($2)                      !dtprello
2261         lda     $4,foo($29)                     !dtprel
2262         ldq     $1,foo($29)                     !gottprel
2263         ldah    $2,foo($29)                     !tprelhi
2264         lda     $3,foo($2)                      !tprello
2265         lda     $4,foo($29)                     !tprel'
2266         tls_first_major=2
2267         tls_first_minor=13
2268         tls_as_opt=--fatal-warnings
2269         ;;
2270   frv*-*-*)
2271     conftest_s='
2272         .section ".tdata","awT",@progbits
2273 x:      .long   25
2274         .text
2275         call    #gettlsoff(x)'
2276         tls_first_major=2
2277         tls_first_minor=14
2278         ;;
2279   hppa*-*-linux*)
2280     conftest_s='
2281 t1:     .reg    %r20
2282 t2:     .reg    %r21
2283 gp:     .reg    %r19
2284         .section ".tdata","awT",@progbits
2285 foo:    .long   25
2286         .text
2287         .align  4
2288         addil LT%foo-$tls_gdidx$,gp
2289         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2290         b __tls_get_addr
2291         nop
2292         addil LT%foo-$tls_ldidx$,gp
2293         b __tls_get_addr
2294         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2295         addil LR%foo-$tls_dtpoff$,%ret0
2296         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2297         mfctl %cr27,%t1
2298         addil LT%foo-$tls_ieoff$,gp
2299         ldw RT%foo-$tls_ieoff$(%r1),%t2
2300         add %t1,%t2,%t3
2301         mfctl %cr27,%t1
2302         addil LR%foo-$tls_leoff$,%t1
2303         ldo RR%foo-$tls_leoff$(%r1),%t2'
2304         tls_first_major=2
2305         tls_first_minor=15
2306         tls_as_opt=--fatal-warnings
2307         ;;
2308   arm*-*-*)
2309     conftest_s='
2310         .section ".tdata","awT",%progbits
2311 foo:    .long   25
2312         .text
2313 .word foo(gottpoff)
2314 .word foo(tpoff)
2315 .word foo(tlsgd)
2316 .word foo(tlsldm)
2317 .word foo(tlsldo)'
2318         tls_first_major=2
2319         tls_first_minor=17
2320         ;;
2321   i[34567]86-*-*)
2322     conftest_s='
2323         .section ".tdata","awT",@progbits
2324 foo:    .long   25
2325         .text
2326         movl    %gs:0, %eax
2327         leal    foo@TLSGD(,%ebx,1), %eax
2328         leal    foo@TLSLDM(%ebx), %eax
2329         leal    foo@DTPOFF(%eax), %edx
2330         movl    foo@GOTTPOFF(%ebx), %eax
2331         subl    foo@GOTTPOFF(%ebx), %eax
2332         addl    foo@GOTNTPOFF(%ebx), %eax
2333         movl    foo@INDNTPOFF, %eax
2334         movl    $foo@TPOFF, %eax
2335         subl    $foo@TPOFF, %eax
2336         leal    foo@NTPOFF(%ecx), %eax'
2337         tls_first_major=2
2338         tls_first_minor=14
2339         tls_as_opt=--fatal-warnings
2340         ;;
2341   x86_64-*-*)
2342     conftest_s='
2343         .section ".tdata","awT",@progbits
2344 foo:    .long   25
2345         .text
2346         movq    %fs:0, %rax
2347         leaq    foo@TLSGD(%rip), %rdi
2348         leaq    foo@TLSLD(%rip), %rdi
2349         leaq    foo@DTPOFF(%rax), %rdx
2350         movq    foo@GOTTPOFF(%rip), %rax
2351         movq    $foo@TPOFF, %rax'
2352         tls_first_major=2
2353         tls_first_minor=14
2354         tls_as_opt=--fatal-warnings
2355         ;;
2356   ia64-*-*)
2357     conftest_s='
2358         .section ".tdata","awT",@progbits
2359 foo:    data8   25
2360         .text
2361         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2362         addl    r17 = @ltoff(@dtprel(foo#)), gp
2363         addl    r18 = @ltoff(@tprel(foo#)), gp
2364         addl    r19 = @dtprel(foo#), gp
2365         adds    r21 = @dtprel(foo#), r13
2366         movl    r23 = @dtprel(foo#)
2367         addl    r20 = @tprel(foo#), gp
2368         adds    r22 = @tprel(foo#), r13
2369         movl    r24 = @tprel(foo#)'
2370         tls_first_major=2
2371         tls_first_minor=13
2372         tls_as_opt=--fatal-warnings
2373         ;;
2374   mips*-*-*)
2375     conftest_s='
2376         .section .tdata,"awT",@progbits
2377 x:
2378         .word 2
2379         .text
2380         addiu $4, $28, %tlsgd(x)
2381         addiu $4, $28, %tlsldm(x)
2382         lui $4, %dtprel_hi(x)
2383         addiu $4, $4, %dtprel_lo(x)
2384         lw $4, %gottprel(x)($28)
2385         lui $4, %tprel_hi(x)
2386         addiu $4, $4, %tprel_lo(x)'
2387         tls_first_major=2
2388         tls_first_minor=16
2389         tls_as_opt='-32 --fatal-warnings'
2390         ;;
2391   powerpc-*-*)
2392     conftest_s='
2393         .section ".tdata","awT",@progbits
2394         .align 2
2395 ld0:    .space 4
2396 ld1:    .space 4
2397 x1:     .space 4
2398 x2:     .space 4
2399 x3:     .space 4
2400         .text
2401         addi 3,31,ld0@got@tlsgd
2402         bl __tls_get_addr
2403         addi 3,31,x1@got@tlsld
2404         bl __tls_get_addr
2405         addi 9,3,x1@dtprel
2406         addis 9,3,x2@dtprel@ha
2407         addi 9,9,x2@dtprel@l
2408         lwz 9,x3@got@tprel(31)
2409         add 9,9,x@tls
2410         addi 9,2,x1@tprel
2411         addis 9,2,x2@tprel@ha
2412         addi 9,9,x2@tprel@l'
2413         tls_first_major=2
2414         tls_first_minor=14
2415         tls_as_opt="-a32 --fatal-warnings"
2416         ;;
2417   powerpc64-*-*)
2418     conftest_s='
2419         .section ".tdata","awT",@progbits
2420         .align 3
2421 ld0:    .space 8
2422 ld1:    .space 8
2423 x1:     .space 8
2424 x2:     .space 8
2425 x3:     .space 8
2426         .text
2427         addi 3,2,ld0@got@tlsgd
2428         bl .__tls_get_addr
2429         nop
2430         addi 3,2,ld1@toc
2431         bl .__tls_get_addr
2432         nop
2433         addi 3,2,x1@got@tlsld
2434         bl .__tls_get_addr
2435         nop
2436         addi 9,3,x1@dtprel
2437         bl .__tls_get_addr
2438         nop
2439         addis 9,3,x2@dtprel@ha
2440         addi 9,9,x2@dtprel@l
2441         bl .__tls_get_addr
2442         nop
2443         ld 9,x3@got@dtprel(2)
2444         add 9,9,3
2445         bl .__tls_get_addr
2446         nop'
2447         tls_first_major=2
2448         tls_first_minor=14
2449         tls_as_opt="-a64 --fatal-warnings"
2450         ;;
2451   s390-*-*)
2452     conftest_s='
2453         .section ".tdata","awT",@progbits
2454 foo:    .long   25
2455         .text
2456         .long   foo@TLSGD
2457         .long   foo@TLSLDM
2458         .long   foo@DTPOFF
2459         .long   foo@NTPOFF
2460         .long   foo@GOTNTPOFF
2461         .long   foo@INDNTPOFF
2462         l       %r1,foo@GOTNTPOFF(%r12)
2463         l       %r1,0(%r1):tls_load:foo
2464         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2465         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2466         tls_first_major=2
2467         tls_first_minor=14
2468         tls_as_opt="-m31 --fatal-warnings"
2469         ;;
2470   s390x-*-*)
2471     conftest_s='
2472         .section ".tdata","awT",@progbits
2473 foo:    .long   25
2474         .text
2475         .quad   foo@TLSGD
2476         .quad   foo@TLSLDM
2477         .quad   foo@DTPOFF
2478         .quad   foo@NTPOFF
2479         .quad   foo@GOTNTPOFF
2480         lg      %r1,foo@GOTNTPOFF(%r12)
2481         larl    %r1,foo@INDNTPOFF
2482         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2483         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2484         tls_first_major=2
2485         tls_first_minor=14
2486         tls_as_opt="-m64 -Aesame --fatal-warnings"
2487         ;;
2488   sh-*-* | sh[34]-*-*)
2489     conftest_s='
2490         .section ".tdata","awT",@progbits
2491 foo:    .long   25
2492         .text
2493         .long   foo@TLSGD
2494         .long   foo@TLSLDM
2495         .long   foo@DTPOFF
2496         .long   foo@GOTTPOFF
2497         .long   foo@TPOFF'
2498         tls_first_major=2
2499         tls_first_minor=13
2500         tls_as_opt=--fatal-warnings
2501         ;;
2502   sparc*-*-*)
2503     case "$target" in
2504       sparc*-sun-solaris2.[56789]*)
2505         # TLS was introduced in the Solaris 9 4/04 release but
2506         # we do not enable it by default on Solaris 9 either.
2507         if test "x$enable_tls" = xyes ; then
2508           on_solaris=yes
2509         else
2510           enable_tls=no;
2511         fi
2512         ;;
2513       sparc*-sun-solaris2.*)
2514         on_solaris=yes
2515         ;;
2516       *)
2517         on_solaris=no
2518         ;;
2519     esac
2520     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2521       conftest_s='
2522         .section ".tdata",#alloc,#write,#tls
2523 foo:    .long   25
2524         .text
2525         sethi   %tgd_hi22(foo), %o0
2526         add     %o0, %tgd_lo10(foo), %o1
2527         add     %l7, %o1, %o0, %tgd_add(foo)
2528         call    __tls_get_addr, %tgd_call(foo)
2529         sethi   %tldm_hi22(foo), %l1
2530         add     %l1, %tldm_lo10(foo), %l2
2531         add     %l7, %l2, %o0, %tldm_add(foo)
2532         call    __tls_get_addr, %tldm_call(foo)
2533         sethi   %tldo_hix22(foo), %l3
2534         xor     %l3, %tldo_lox10(foo), %l4
2535         add     %o0, %l4, %l5, %tldo_add(foo)
2536         sethi   %tie_hi22(foo), %o3
2537         add     %o3, %tie_lo10(foo), %o3
2538         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2539         add     %g7, %o2, %o4, %tie_add(foo)
2540         sethi   %tle_hix22(foo), %l1
2541         xor     %l1, %tle_lox10(foo), %o5
2542         ld      [%g7 + %o5], %o1'
2543         tls_first_major=0
2544         tls_first_minor=0
2545     else
2546       conftest_s='
2547         .section ".tdata","awT",@progbits
2548 foo:    .long   25
2549         .text
2550         sethi   %tgd_hi22(foo), %o0
2551         add     %o0, %tgd_lo10(foo), %o1
2552         add     %l7, %o1, %o0, %tgd_add(foo)
2553         call    __tls_get_addr, %tgd_call(foo)
2554         sethi   %tldm_hi22(foo), %l1
2555         add     %l1, %tldm_lo10(foo), %l2
2556         add     %l7, %l2, %o0, %tldm_add(foo)
2557         call    __tls_get_addr, %tldm_call(foo)
2558         sethi   %tldo_hix22(foo), %l3
2559         xor     %l3, %tldo_lox10(foo), %l4
2560         add     %o0, %l4, %l5, %tldo_add(foo)
2561         sethi   %tie_hi22(foo), %o3
2562         add     %o3, %tie_lo10(foo), %o3
2563         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2564         add     %g7, %o2, %o4, %tie_add(foo)
2565         sethi   %tle_hix22(foo), %l1
2566         xor     %l1, %tle_lox10(foo), %o5
2567         ld      [%g7 + %o5], %o1'
2568         tls_first_major=2
2569         tls_first_minor=14
2570         tls_as_opt="-32 --fatal-warnings"
2571       fi
2572         ;;
2573 changequote([,])dnl
2574 esac
2575 set_have_as_tls=no
2576 if test "x$enable_tls" = xno ; then
2577   : # TLS explicitly disabled.
2578 elif test "x$enable_tls" = xyes ; then
2579   set_have_as_tls=yes # TLS explicitly enabled.
2580 elif test -z "$tls_first_major"; then
2581   : # If we don't have a check, assume no support.
2582 else
2583   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2584   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2585   [set_have_as_tls=yes])
2586 fi
2587 if test $set_have_as_tls = yes ; then
2588   AC_DEFINE(HAVE_AS_TLS, 1,
2589             [Define if your assembler supports thread-local storage.])
2590 fi
2591
2592 # Target-specific assembler checks.
2593
2594 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2595 gcc_cv_ld_static_dynamic=no
2596 if test $in_tree_ld = yes ; then
2597   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2598     gcc_cv_ld_static_dynamic=yes
2599   fi
2600 elif test x$gcc_cv_ld != x; then
2601         # Check if linker supports -Bstatic/-Bdynamic option
2602         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2603           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2604                 gcc_cv_ld_static_dynamic=yes
2605         fi
2606 fi
2607 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2608         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2609 [Define if your linker supports -Bstatic/-Bdynamic option.])
2610 fi
2611 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2612
2613 if test x"$demangler_in_ld" = xyes; then
2614   AC_MSG_CHECKING(linker --demangle support)
2615   gcc_cv_ld_demangle=no
2616   if test $in_tree_ld = yes; then
2617     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2618       gcc_cv_ld_demangle=yes
2619     fi
2620   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2621     # Check if the GNU linker supports --demangle option
2622     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2623       gcc_cv_ld_demangle=yes
2624     fi
2625   fi
2626   if test x"$gcc_cv_ld_demangle" = xyes; then
2627     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2628 [Define if your linker supports --demangle option.])
2629   fi
2630   AC_MSG_RESULT($gcc_cv_ld_demangle)
2631 fi
2632
2633 case "$target" in
2634   # All TARGET_ABI_OSF targets.
2635   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2636     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2637         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2638 [       .set nomacro
2639         .text
2640         extbl   $3, $2, $3      !lituse_bytoff!1
2641         ldq     $2, a($29)      !literal!1
2642         ldq     $4, b($29)      !literal!2
2643         ldq_u   $3, 0($2)       !lituse_base!1
2644         ldq     $27, f($29)     !literal!5
2645         jsr     $26, ($27), f   !lituse_jsr!5
2646         ldah    $29, 0($26)     !gpdisp!3
2647         lda     $0, c($29)      !gprel
2648         ldah    $1, d($29)      !gprelhigh
2649         lda     $1, d($1)       !gprellow
2650         lda     $29, 0($29)     !gpdisp!3],,
2651     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2652   [Define if your assembler supports explicit relocations.])])
2653     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2654         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2655 [       .set nomacro
2656         .text
2657         ldq     $27, a($29)     !literal!1
2658         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2659     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2660   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2661     ;;
2662
2663   cris-*-*)
2664     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2665       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2666       [-no-mul-bug-abort], [.text],,
2667       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2668                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2669     ;;
2670
2671   sparc*-*-*)
2672     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2673       [.register %g2, #scratch],,
2674       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2675                 [Define if your assembler supports .register.])])
2676
2677     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2678       [-relax], [.text],,
2679       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2680                 [Define if your assembler supports -relax option.])])
2681
2682     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2683       gcc_cv_as_sparc_ua_pcrel,,
2684       [-K PIC],
2685 [.text
2686 foo:
2687         nop
2688 .data
2689 .align 4
2690 .byte 0
2691 .uaword %r_disp32(foo)],
2692       [if test x$gcc_cv_ld != x \
2693        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2694          gcc_cv_as_sparc_ua_pcrel=yes
2695        fi
2696        rm -f conftest],
2697       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2698                 [Define if your assembler and linker support unaligned PC relative relocs.])
2699
2700       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2701         gcc_cv_as_sparc_ua_pcrel_hidden,,
2702         [-K PIC],
2703 [.data
2704 .align 4
2705 .byte 0x31
2706 .uaword %r_disp32(foo)
2707 .byte 0x32, 0x33, 0x34
2708 .global foo
2709 .hidden foo
2710 foo:
2711 .skip 4],
2712         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2713          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2714          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2715             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2716             if $gcc_cv_objdump -R conftest 2> /dev/null \
2717                | grep 'DISP32' > /dev/null 2>&1; then
2718                 :
2719             else
2720                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2721             fi
2722          fi
2723          rm -f conftest],
2724          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2725                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2726     ]) # unaligned pcrel relocs
2727
2728     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2729       gcc_cv_as_sparc_offsetable_lo10,,
2730       [-xarch=v9],
2731 [.text
2732         or %g1, %lo(ab) + 12, %g1
2733         or %g1, %lo(ab + 12), %g1],
2734       [if test x$gcc_cv_objdump != x \
2735        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2736           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2737          gcc_cv_as_sparc_offsetable_lo10=yes
2738        fi],
2739        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2740                  [Define if your assembler supports offsetable %lo().])])
2741     ;;
2742
2743 changequote(,)dnl
2744   i[34567]86-*-* | x86_64-*-*)
2745 changequote([,])dnl
2746     case $target_os in
2747       cygwin* | pe | mingw32*)
2748         # Used for DWARF 2 in PE
2749         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2750           gcc_cv_as_ix86_pe_secrel32,
2751           [2,15,91],,
2752 [.text
2753 foo:    nop
2754 .data
2755         .secrel32 foo],
2756           [if test x$gcc_cv_ld != x \
2757            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2758              gcc_cv_as_ix86_pe_secrel32=yes
2759            fi
2760            rm -f conftest],
2761           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2762             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2763         ;;
2764     esac
2765
2766     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2767        gcc_cv_as_ix86_filds_fists,
2768       [2,9,0],, [filds mem; fists mem],,
2769       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2770         [Define if your assembler uses the new HImode fild and fist notation.])])
2771
2772     gcc_GAS_CHECK_FEATURE([cmov syntax],
2773       gcc_cv_as_ix86_cmov_sun_syntax,,,
2774       [cmovl.l %edx, %eax],,
2775       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2776         [Define if your assembler supports the Sun syntax for cmov.])])
2777
2778     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2779       gcc_cv_as_ix86_ffreep,,,
2780       [ffreep %st(1)],,
2781       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2782         [Define if your assembler supports the ffreep mnemonic.])])
2783
2784     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
2785       gcc_cv_as_ix86_sahf,,,
2786       [sahf],,
2787       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
2788         [Define if your assembler supports the sahf mnemonic.])])
2789
2790     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2791       gcc_cv_as_ix86_diff_sect_delta,,,
2792       [.section .rodata
2793 .L1:
2794         .long .L2-.L1
2795         .long .L3-.L1
2796         .text
2797 .L3:    nop
2798 .L2:    nop],,
2799       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2800         [Define if your assembler supports the subtraction of symbols in different sections.])])
2801
2802     # This one is used unconditionally by i386.[ch]; it is to be defined
2803     # to 1 if the feature is present, 0 otherwise.
2804     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2805         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2806 [       .text
2807 .L0:
2808         nop
2809         .data
2810         .long .L0@GOTOFF])
2811     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2812       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2813       [Define true if the assembler supports '.long foo@GOTOFF'.])
2814     ;;
2815
2816   ia64*-*-*)
2817     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2818         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2819 [       .text
2820         addl r15 = @ltoffx(x#), gp
2821         ;;
2822         ld8.mov r16 = [[r15]], x#],,
2823     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2824           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2825
2826     ;;
2827
2828   powerpc*-*-*)
2829     case $target in
2830       *-*-aix*) conftest_s='    .machine "pwr5"
2831         .csect .text[[PR]]
2832         mfcr 3,128';;
2833       *-*-darwin*)
2834         gcc_GAS_CHECK_FEATURE([.machine directive support],
2835           gcc_cv_as_machine_directive,,,
2836           [     .machine ppc7400])
2837         if test x$gcc_cv_as_machine_directive != xyes; then
2838           echo "*** This target requires an assembler supporting \".machine\"" >&2
2839           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2840           test x$build = x$target && exit 1
2841         fi
2842         conftest_s='    .text
2843         mfcr r3,128';;
2844       *) conftest_s='   .machine power4
2845         .text
2846         mfcr 3,128';;
2847     esac
2848
2849     gcc_GAS_CHECK_FEATURE([mfcr field support],
2850       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2851       [$conftest_s],,
2852       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2853           [Define if your assembler supports mfcr field.])])
2854
2855     case $target in
2856       *-*-aix*) conftest_s='    .machine "pwr5"
2857         .csect .text[[PR]]
2858         popcntb 3,3';;
2859       *) conftest_s='   .machine power5
2860         .text
2861         popcntb 3,3';;
2862     esac
2863
2864     gcc_GAS_CHECK_FEATURE([popcntb support],
2865       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2866       [$conftest_s],,
2867       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2868           [Define if your assembler supports popcntb field.])])
2869
2870     case $target in
2871       *-*-aix*) conftest_s='    .machine "pwr5x"
2872         .csect .text[[PR]]
2873         frin 1,1';;
2874       *) conftest_s='   .machine power5
2875         .text
2876         frin 1,1';;
2877     esac
2878
2879     gcc_GAS_CHECK_FEATURE([fp round support],
2880       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2881       [$conftest_s],,
2882       [AC_DEFINE(HAVE_AS_FPRND, 1,
2883           [Define if your assembler supports fprnd.])])
2884
2885     case $target in
2886       *-*-aix*) conftest_s='    .machine "pwr6"
2887         .csect .text[[PR]]
2888         mffgpr 1,3';;
2889       *) conftest_s='   .machine power6
2890         .text
2891         mffgpr 1,3';;
2892     esac
2893
2894     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2895       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2896       [$conftest_s],,
2897       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2898           [Define if your assembler supports mffgpr and mftgpr.])])
2899
2900     case $target in
2901       *-*-aix*) conftest_s='    .csect .text[[PR]]
2902 LCF..0:
2903         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2904       *-*-darwin*)
2905         conftest_s='    .text
2906 LCF0:
2907         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2908       *) conftest_s='   .text
2909 .LCF0:
2910         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2911     esac
2912
2913     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2914       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2915       [$conftest_s],,
2916       [AC_DEFINE(HAVE_AS_REL16, 1,
2917           [Define if your assembler supports R_PPC_REL16 relocs.])])
2918
2919     case $target in
2920       *-*-aix*) conftest_s='    .machine "pwr6"
2921         .csect .text[[PR]]
2922         cmpb 3,4,5';;
2923       *) conftest_s='   .machine power6
2924         .text
2925         cmpb 3,4,5';;
2926     esac
2927
2928     gcc_GAS_CHECK_FEATURE([compare bytes support],
2929       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
2930       [$conftest_s],,
2931       [AC_DEFINE(HAVE_AS_CMPB, 1,
2932           [Define if your assembler supports cmpb.])])
2933
2934     case $target in
2935       *-*-aix*) conftest_s='    .machine "pwr6"
2936         .csect .text[[PR]]
2937         dadd 1,2,3';;
2938       *) conftest_s='   .machine power6
2939         .text
2940         dadd 1,2,3';;
2941     esac
2942
2943     gcc_GAS_CHECK_FEATURE([decimal float support],
2944       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
2945       [$conftest_s],,
2946       [AC_DEFINE(HAVE_AS_DFP, 1,
2947           [Define if your assembler supports DFP instructions.])])
2948
2949     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
2950       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
2951       [.gnu_attribute 4,1],,
2952       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
2953           [Define if your assembler supports .gnu_attribute.])])
2954     ;;
2955
2956   mips*-*-*)
2957     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2958       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2959 [       lw $4,%gp_rel(foo)($4)],,
2960       [if test x$target_cpu_default = x
2961        then target_cpu_default=MASK_EXPLICIT_RELOCS
2962        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2963        fi])
2964     gcc_GAS_CHECK_FEATURE([-mno-shared support],
2965       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
2966       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
2967                  [Define if the assembler understands -mno-shared.])])
2968
2969     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
2970       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
2971       [.gnu_attribute 4,1],,
2972       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
2973           [Define if your assembler supports .gnu_attribute.])])
2974
2975     gcc_GAS_CHECK_FEATURE([.dtprelword support],
2976       gcc_cv_as_mips_dtprelword, [2,18,0],,
2977       [.section .tdata,"awT",@progbits
2978 x:
2979         .word 2
2980         .text
2981         .dtprelword x+0x8000],,
2982       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
2983           [Define if your assembler supports .dtprelword.])])
2984     ;;
2985 esac
2986
2987 # Mips and HP-UX need the GNU assembler.
2988 # Linux on IA64 might be able to use the Intel assembler.
2989
2990 case "$target" in
2991   mips*-*-* | *-*-hpux* )
2992     if test x$gas_flag = xyes \
2993        || test x"$host" != x"$build" \
2994        || test ! -x "$gcc_cv_as" \
2995        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2996       :
2997     else
2998       echo "*** This configuration requires the GNU assembler" >&2
2999       exit 1
3000     fi
3001     ;;
3002 esac
3003
3004 # ??? Not all targets support dwarf2 debug_line, even within a version
3005 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3006 # info to the output file.  So, as supported targets are added to gas 2.11,
3007 # add some instruction here to (also) show we expect this might work.
3008 # ??? Once 2.11 is released, probably need to add first known working
3009 # version to the per-target configury.
3010 case "$target" in
3011   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3012   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
3013   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-* | score*-*-* | spu-*-*)
3014     insn="nop"
3015     ;;
3016   ia64*-*-* | s390*-*-*)
3017     insn="nop 0"
3018     ;;
3019   mmix-*-*)
3020     insn="swym 0"
3021     ;;
3022 esac
3023 if test x"$insn" != x; then
3024  conftest_s="\
3025         .file 1 \"conftest.s\"
3026         .loc 1 3 0
3027         $insn"
3028  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3029   gcc_cv_as_dwarf2_debug_line,
3030   [elf,2,11,0],, [$conftest_s],
3031   [if test x$gcc_cv_objdump != x \
3032    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3033       | grep debug_line > /dev/null 2>&1; then
3034      gcc_cv_as_dwarf2_debug_line=yes
3035    fi])
3036
3037 # The .debug_line file table must be in the exact order that
3038 # we specified the files, since these indices are also used
3039 # by DW_AT_decl_file.  Approximate this test by testing if
3040 # the assembler bitches if the same index is assigned twice.
3041  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3042   gcc_cv_as_dwarf2_file_buggy,,,
3043 [       .file 1 "foo.s"
3044         .file 1 "bar.s"])
3045
3046  if test $gcc_cv_as_dwarf2_debug_line = yes \
3047  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3048         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3049   [Define if your assembler supports dwarf2 .file/.loc directives,
3050    and preserves file table indices exactly as given.])
3051  fi
3052
3053  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3054   gcc_cv_as_gdwarf2_flag,
3055   [elf,2,11,0], [--gdwarf2], [$insn],,
3056   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3057 [Define if your assembler supports the --gdwarf2 option.])])
3058
3059  gcc_GAS_CHECK_FEATURE([--gstabs option],
3060   gcc_cv_as_gstabs_flag,
3061   [elf,2,11,0], [--gstabs], [$insn],
3062   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3063    # and warns about it, but still exits successfully.  So check for
3064    # this.
3065    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3066    then :
3067    else gcc_cv_as_gstabs_flag=yes
3068    fi],
3069   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3070 [Define if your assembler supports the --gstabs option.])])
3071 fi
3072
3073 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3074  [gcc_cv_as_line_zero],
3075  [gcc_cv_as_line_zero=no
3076   if test $in_tree_gas = yes; then
3077     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3078   elif test "x$gcc_cv_as" != x; then
3079     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3080     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3081        test "x`cat conftest.out`" = x
3082     then
3083       gcc_cv_as_line_zero=yes
3084     else
3085       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3086       cat conftest.s >&AS_MESSAGE_LOG_FD
3087       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3088       cat conftest.out >&AS_MESSAGE_LOG_FD
3089     fi
3090     rm -f conftest.o conftest.s conftest.out
3091   fi])
3092 if test "x$gcc_cv_as_line_zero" = xyes; then
3093   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3094 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3095 fi
3096
3097 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3098 gcc_cv_ld_ro_rw_mix=unknown
3099 if test $in_tree_ld = yes ; then
3100   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3101      && test $in_tree_ld_is_elf = yes; then
3102     gcc_cv_ld_ro_rw_mix=read-write
3103   fi
3104 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3105   echo '.section myfoosect, "a"' > conftest1.s
3106   echo '.section myfoosect, "aw"' > conftest2.s
3107   echo '.byte 1' >> conftest2.s
3108   echo '.section myfoosect, "a"' > conftest3.s
3109   echo '.byte 0' >> conftest3.s
3110   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3111      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3112      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3113      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3114         conftest2.o conftest3.o > /dev/null 2>&1; then
3115     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3116                          | sed -e '/myfoosect/!d' -e N`
3117     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3118       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3119         gcc_cv_ld_ro_rw_mix=read-only
3120       else
3121         gcc_cv_ld_ro_rw_mix=read-write
3122       fi
3123     fi
3124   fi
3125 changequote(,)dnl
3126   rm -f conftest.* conftest[123].*
3127 changequote([,])dnl
3128 fi
3129 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3130         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3131   [Define if your linker links a mix of read-only
3132    and read-write sections into a read-write section.])
3133 fi
3134 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3135
3136 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3137 gcc_cv_ld_eh_frame_hdr=no
3138 if test $in_tree_ld = yes ; then
3139   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3140      && test $in_tree_ld_is_elf = yes; then
3141     gcc_cv_ld_eh_frame_hdr=yes
3142   fi
3143 elif test x$gcc_cv_ld != x; then
3144         # Check if linker supports --eh-frame-hdr option
3145         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3146                 gcc_cv_ld_eh_frame_hdr=yes
3147         fi
3148 fi
3149 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3150 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3151         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3152 [Define if your linker supports --eh-frame-hdr option.])
3153 fi
3154 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3155
3156 AC_MSG_CHECKING(linker position independent executable support)
3157 gcc_cv_ld_pie=no
3158 if test $in_tree_ld = yes ; then
3159   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3160      && test $in_tree_ld_is_elf = yes; then
3161     gcc_cv_ld_pie=yes
3162   fi
3163 elif test x$gcc_cv_ld != x; then
3164         # Check if linker supports -pie option
3165         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3166                 gcc_cv_ld_pie=yes
3167         fi
3168 fi
3169 if test x"$gcc_cv_ld_pie" = xyes; then
3170         AC_DEFINE(HAVE_LD_PIE, 1,
3171 [Define if your linker supports -pie option.])
3172 fi
3173 AC_MSG_RESULT($gcc_cv_ld_pie)
3174
3175 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3176 gcc_cv_ld_eh_gc_sections=no
3177 if test $in_tree_ld = yes ; then
3178   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3179      && test $in_tree_ld_is_elf = yes; then
3180     gcc_cv_ld_eh_gc_sections=yes
3181   fi
3182 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3183   cat > conftest.s <<EOF
3184         .section        .text
3185 .globl _start
3186         .type _start, @function
3187 _start:
3188         .long foo
3189         .size _start, .-_start
3190         .section        .text.foo,"ax",@progbits
3191         .type foo, @function
3192 foo:
3193         .long 0
3194         .size foo, .-foo
3195         .section        .gcc_except_table.foo,"a",@progbits
3196 .L0:
3197         .long 0
3198         .section        .eh_frame,"a",@progbits
3199         .long .L0
3200 EOF
3201   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3202     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3203          | grep "gc-sections option ignored" > /dev/null; then
3204       gcc_cv_ld_eh_gc_sections=no
3205     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3206       gcc_cv_ld_eh_gc_sections=yes
3207       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3208       if test x$gcc_cv_as_comdat_group != xyes; then
3209         gcc_cv_ld_eh_gc_sections=no
3210         cat > conftest.s <<EOF
3211         .section        .text
3212 .globl _start
3213         .type _start, @function
3214 _start:
3215         .long foo
3216         .size _start, .-_start
3217         .section        .gnu.linkonce.t.foo,"ax",@progbits
3218         .type foo, @function
3219 foo:
3220         .long 0
3221         .size foo, .-foo
3222         .section        .gcc_except_table.foo,"a",@progbits
3223 .L0:
3224         .long 0
3225         .section        .eh_frame,"a",@progbits
3226         .long .L0
3227 EOF
3228         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3229           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3230                | grep "gc-sections option ignored" > /dev/null; then
3231             gcc_cv_ld_eh_gc_sections=no
3232           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3233             gcc_cv_ld_eh_gc_sections=yes
3234           fi
3235         fi
3236       fi
3237     fi
3238   fi
3239   rm -f conftest.s conftest.o conftest
3240 fi
3241 case "$target" in
3242   hppa*-*-linux*)
3243     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3244     gcc_cv_ld_eh_gc_sections=no
3245     ;;
3246 esac
3247 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3248         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3249   [Define if your linker supports garbage collection of
3250    sections in presence of EH frames.])
3251 fi
3252 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3253
3254 # --------
3255 # UNSORTED
3256 # --------
3257
3258 AC_CACHE_CHECK(linker --as-needed support,
3259 gcc_cv_ld_as_needed,
3260 [gcc_cv_ld_as_needed=no
3261 if test $in_tree_ld = yes ; then
3262   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3263      && test $in_tree_ld_is_elf = yes; then
3264     gcc_cv_ld_as_needed=yes
3265   fi
3266 elif test x$gcc_cv_ld != x; then
3267         # Check if linker supports --as-needed and --no-as-needed options
3268         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3269                 gcc_cv_ld_as_needed=yes
3270         fi
3271 fi
3272 ])
3273 if test x"$gcc_cv_ld_as_needed" = xyes; then
3274         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3275 [Define if your linker supports --as-needed and --no-as-needed options.])
3276 fi
3277
3278 case "$target:$tm_file" in
3279   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3280     AC_CACHE_CHECK(linker support for omitting dot symbols,
3281     gcc_cv_ld_no_dot_syms,
3282     [gcc_cv_ld_no_dot_syms=no
3283     if test $in_tree_ld = yes ; then
3284       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3285         gcc_cv_ld_no_dot_syms=yes
3286       fi
3287     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3288       cat > conftest1.s <<EOF
3289         .text
3290         bl .foo
3291 EOF
3292       cat > conftest2.s <<EOF
3293         .section ".opd","aw"
3294         .align 3
3295         .globl foo
3296         .type foo,@function
3297 foo:
3298         .quad .LEfoo,.TOC.@tocbase,0
3299         .text
3300 .LEfoo:
3301         blr
3302         .size foo,.-.LEfoo
3303 EOF
3304       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3305          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3306          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3307         gcc_cv_ld_no_dot_syms=yes
3308       fi
3309       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3310     fi
3311     ])
3312     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3313       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3314     [Define if your PowerPC64 linker only needs function descriptor syms.])
3315     fi
3316     ;;
3317 esac
3318
3319 AC_CACHE_CHECK(linker --sysroot support,
3320   gcc_cv_ld_sysroot,
3321   [gcc_cv_ld_sysroot=no
3322   if test $in_tree_ld = yes ; then
3323       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3324         gcc_cv_ld_sysroot=yes
3325       fi
3326   elif test x$gcc_cv_ld != x; then
3327     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3328       gcc_cv_ld_sysroot=yes
3329     fi
3330   fi])
3331 if test x"$gcc_cv_ld_sysroot" = xyes; then
3332   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3333   [Define if your linker supports --sysroot.])
3334 fi
3335
3336 if test x$with_sysroot = x && test x$host = x$target \
3337    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3338    && test "$prefix" != "NONE"; then
3339   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3340 [Define to PREFIX/include if cpp should also search that directory.])
3341 fi
3342
3343 # Test for stack protector support in target C library.
3344 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3345       gcc_cv_libc_provides_ssp,
3346       [gcc_cv_libc_provides_ssp=no
3347     case "$target" in
3348        *-*-linux*)
3349       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3350         if test "x$with_sysroot" = x; then
3351           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3352         elif test "x$with_build_sysroot" != "x"; then
3353           glibc_header_dir="${with_build_sysroot}/usr/include"
3354         elif test "x$with_sysroot" = xyes; then
3355           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3356         else
3357           glibc_header_dir="${with_sysroot}/usr/include"
3358         fi
3359       else
3360         glibc_header_dir=/usr/include
3361       fi
3362       # glibc 2.4 and later provides __stack_chk_fail and
3363       # either __stack_chk_guard, or TLS access to stack guard canary.
3364       if test -f $glibc_header_dir/features.h \
3365          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3366             $glibc_header_dir/features.h > /dev/null; then
3367         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3368            $glibc_header_dir/features.h > /dev/null; then
3369           gcc_cv_libc_provides_ssp=yes
3370         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3371              $glibc_header_dir/features.h > /dev/null \
3372              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3373              $glibc_header_dir/features.h > /dev/null; then
3374           gcc_cv_libc_provides_ssp=yes
3375         fi
3376         fi
3377         ;;
3378        *-*-darwin*)
3379          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3380            [echo "no __stack_chk_fail on this target"])
3381         ;;
3382   *) gcc_cv_libc_provides_ssp=no ;;
3383     esac])
3384
3385 if test x$gcc_cv_libc_provides_ssp = xyes; then
3386   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3387             [Define if your target C library provides stack protector support])
3388 fi
3389
3390 # Check if TFmode long double should be used by default or not.
3391 # Some glibc targets used DFmode long double, but with glibc 2.4
3392 # and later they can use TFmode.
3393 case "$target" in
3394   powerpc*-*-linux* | \
3395   powerpc*-*-gnu* | \
3396   sparc*-*-linux* | \
3397   s390*-*-linux* | \
3398   alpha*-*-linux*)
3399     AC_ARG_WITH(long-double-128,
3400 [  --with-long-double-128  Use 128-bit long double by default.],
3401       gcc_cv_target_ldbl128="$with_long_double_128",
3402       [gcc_cv_target_ldbl128=no
3403       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3404         if test "x$with_sysroot" = x; then
3405           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3406         elif test "x$with_build_sysroot" != "x"; then
3407           glibc_header_dir="${with_build_sysroot}/usr/include"
3408         elif test "x$with_sysroot" = xyes; then
3409           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3410         else
3411           glibc_header_dir="${with_sysroot}/usr/include"
3412         fi
3413       else
3414         glibc_header_dir=/usr/include
3415       fi
3416 changequote(,)dnl
3417       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3418         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3419       && gcc_cv_target_ldbl128=yes
3420 changequote([,])dnl
3421       ])
3422     ;;
3423 esac
3424 if test x$gcc_cv_target_ldbl128 = xyes; then
3425   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3426             [Define if TFmode long double should be the default])
3427 fi
3428
3429 # Find out what GC implementation we want, or may, use.
3430 AC_ARG_WITH(gc,
3431 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3432                           with the compiler],
3433 [case "$withval" in
3434   page)
3435     GGC=ggc-$withval
3436     ;;
3437   zone)
3438     GGC=ggc-$withval
3439     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3440     ;;
3441   *)
3442     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3443     ;;
3444 esac],
3445 [GGC=ggc-page])
3446 AC_SUBST(GGC)
3447 echo "Using $GGC for garbage collection."
3448
3449 # Use the system's zlib library.
3450 zlibdir=-L../zlib
3451 zlibinc="-I\$(srcdir)/../zlib"
3452 AC_ARG_WITH(system-zlib,
3453 [  --with-system-zlib      use installed libz],
3454 zlibdir=
3455 zlibinc=
3456 )
3457 AC_SUBST(zlibdir)
3458 AC_SUBST(zlibinc)
3459
3460 dnl Very limited version of automake's enable-maintainer-mode
3461
3462 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3463   dnl maintainer-mode is disabled by default
3464   AC_ARG_ENABLE(maintainer-mode,
3465 [  --enable-maintainer-mode
3466                           enable make rules and dependencies not useful
3467                           (and sometimes confusing) to the casual installer],
3468       maintainer_mode=$enableval,
3469       maintainer_mode=no)
3470
3471 AC_MSG_RESULT($maintainer_mode)
3472
3473 if test "$maintainer_mode" = "yes"; then
3474   MAINT=''
3475 else
3476   MAINT='#'
3477 fi
3478 AC_SUBST(MAINT)dnl
3479
3480 # --------------
3481 # Language hooks
3482 # --------------
3483
3484 # Make empty files to contain the specs and options for each language.
3485 # Then add #include lines to for a compiler that has specs and/or options.
3486
3487 subdirs=
3488 lang_opt_files=
3489 lang_specs_files=
3490 lang_tree_files=
3491 # These (without "all_") are set in each config-lang.in.
3492 # `language' must be a single word so is spelled singularly.
3493 all_languages=
3494 all_compilers=
3495 all_outputs='Makefile gccbug libada-mk'
3496 # List of language makefile fragments.
3497 all_lang_makefrags=
3498 # List of language subdirectory makefiles.  Deprecated.
3499 all_lang_makefiles=
3500 # Additional files for gengtype
3501 all_gtfiles="$target_gtfiles"
3502
3503 # These are the languages that are set in --enable-languages,
3504 # and are available in the GCC tree.
3505 all_selected_languages=
3506
3507 # Add the language fragments.
3508 # Languages are added via two mechanisms.  Some information must be
3509 # recorded in makefile variables, these are defined in config-lang.in.
3510 # We accumulate them and plug them into the main Makefile.
3511 # The other mechanism is a set of hooks for each of the main targets
3512 # like `clean', `install', etc.
3513
3514 language_hooks="Make-hooks"
3515
3516 for lang in ${srcdir}/*/config-lang.in
3517 do
3518 changequote(,)dnl
3519         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3520
3521         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3522         if test "x$lang_alias" = x
3523         then
3524               echo "$lang doesn't set \$language." 1>&2
3525               exit 1
3526         fi
3527         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3528         subdirs="$subdirs $subdir"
3529         case ",$enable_languages," in
3530         *,$lang_alias,*)
3531             all_selected_languages="$all_selected_languages $lang_alias"
3532             if test -f $srcdir/$subdir/lang-specs.h; then
3533                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3534             fi
3535             ;;
3536         esac
3537 changequote([,])dnl
3538
3539         language=
3540         boot_language=
3541         compilers=
3542         outputs=
3543         gtfiles=
3544         subdir_requires=
3545         . ${srcdir}/$subdir/config-lang.in
3546         if test "x$language" = x
3547         then
3548                 echo "${srcdir}/$subdir/config-lang.in doesn't set \$language." 1>&2
3549                 exit 1
3550         fi
3551
3552         ok=:
3553         case ",$enable_languages," in
3554                 *,$lang_alias,*) ;;
3555                 *)
3556                         for i in $subdir_requires; do
3557                                 test -f "${srcdir}/$i/config-lang.in" && continue
3558                                 ok=false
3559                                 break
3560                         done
3561                 ;;
3562         esac
3563         $ok || continue
3564
3565         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$subdir/Make-lang.in"
3566         if test -f $srcdir/$subdir/lang.opt; then
3567             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3568         fi
3569         if test -f $srcdir/$subdir/$subdir-tree.def; then
3570             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3571         fi
3572         if test -f ${srcdir}/$subdir/Makefile.in
3573                 then all_lang_makefiles="$subdir/Makefile"
3574         fi
3575         all_languages="$all_languages $language"
3576         all_compilers="$all_compilers $compilers"
3577         all_outputs="$all_outputs $outputs"
3578         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3579 done
3580
3581 # Pick up gtfiles for c
3582 gtfiles=
3583 . ${srcdir}/c-config-lang.in
3584 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3585
3586 check_languages=
3587 for language in $all_selected_languages
3588 do
3589         check_languages="$check_languages check-$language"
3590 done
3591
3592 # We link each language in with a set of hooks, reached indirectly via
3593 # lang.${target}.  Only do so for selected languages.
3594
3595 rm -f Make-hooks
3596 touch Make-hooks
3597 target_list="all.cross start.encap rest.encap tags \
3598         install-common install-man install-info install-pdf dvi pdf \
3599         html uninstall info man srcextra srcman srcinfo \
3600         mostlyclean clean distclean maintainer-clean"
3601
3602 for t in $target_list
3603 do
3604         x=
3605         for lang in $all_selected_languages
3606         do
3607                 x="$x $lang.$t"
3608         done
3609         echo "lang.$t: $x" >> Make-hooks
3610 done
3611
3612 # --------
3613 # UNSORTED
3614 # --------
3615
3616 # Create .gdbinit.
3617
3618 echo "dir ." > .gdbinit
3619 echo "dir ${srcdir}" >> .gdbinit
3620 if test x$gdb_needs_out_file_path = xyes
3621 then
3622         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3623 fi
3624 if test "x$subdirs" != x; then
3625         for s in $subdirs
3626         do
3627                 echo "dir ${srcdir}/$s" >> .gdbinit
3628         done
3629 fi
3630 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3631
3632 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3633 AC_SUBST(gcc_tooldir)
3634 AC_SUBST(dollar)
3635
3636 # Find a directory in which to install a shared libgcc.
3637
3638 AC_ARG_ENABLE(version-specific-runtime-libs,
3639 [  --enable-version-specific-runtime-libs
3640                           specify that runtime libraries should be
3641                           installed in a compiler-specific directory])
3642
3643 AC_ARG_WITH(slibdir,
3644 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3645 slibdir="$with_slibdir",
3646 if test "${enable_version_specific_runtime_libs+set}" = set; then
3647   slibdir='$(libsubdir)'
3648 elif test "$host" != "$target"; then
3649   slibdir='$(build_tooldir)/lib'
3650 else
3651   slibdir='$(libdir)'
3652 fi)
3653 AC_SUBST(slibdir)
3654
3655 objdir=`${PWDCMD-pwd}`
3656 AC_SUBST(objdir)
3657
3658 AC_ARG_WITH(datarootdir,
3659 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3660 datarootdir="\${prefix}/$with_datarootdir",
3661 datarootdir='$(prefix)/share')
3662 AC_SUBST(datarootdir)
3663
3664 AC_ARG_WITH(docdir,
3665 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3666 docdir="\${prefix}/$with_docdir",
3667 docdir='$(datarootdir)')
3668 AC_SUBST(docdir)
3669
3670 AC_ARG_WITH(htmldir,
3671 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3672 htmldir="\${prefix}/$with_htmldir",
3673 htmldir='$(docdir)')
3674 AC_SUBST(htmldir)
3675
3676 # Substitute configuration variables
3677 AC_SUBST(subdirs)
3678 AC_SUBST(srcdir)
3679 AC_SUBST(all_compilers)
3680 AC_SUBST(all_gtfiles)
3681 AC_SUBST(all_lang_makefrags)
3682 AC_SUBST(all_lang_makefiles)
3683 AC_SUBST(all_languages)
3684 AC_SUBST(all_selected_languages)
3685 AC_SUBST(build_exeext)
3686 AC_SUBST(build_install_headers_dir)
3687 AC_SUBST(build_xm_file_list)
3688 AC_SUBST(build_xm_include_list)
3689 AC_SUBST(build_xm_defines)
3690 AC_SUBST(check_languages)
3691 AC_SUBST(cpp_install_dir)
3692 AC_SUBST(xmake_file)
3693 AC_SUBST(tmake_file)
3694 AC_SUBST(extra_gcc_objs)
3695 AC_SUBST(extra_headers_list)
3696 AC_SUBST(extra_objs)
3697 AC_SUBST(extra_parts)
3698 AC_SUBST(extra_passes)
3699 AC_SUBST(extra_programs)
3700 AC_SUBST(float_h_file)
3701 AC_SUBST(gcc_config_arguments)
3702 AC_SUBST(gcc_gxx_include_dir)
3703 AC_SUBST(host_exeext)
3704 AC_SUBST(host_xm_file_list)
3705 AC_SUBST(host_xm_include_list)
3706 AC_SUBST(host_xm_defines)
3707 AC_SUBST(out_host_hook_obj)
3708 AC_SUBST(install)
3709 AC_SUBST(lang_opt_files)
3710 AC_SUBST(lang_specs_files)
3711 AC_SUBST(lang_tree_files)
3712 AC_SUBST(local_prefix)
3713 AC_SUBST(md_file)
3714 AC_SUBST(objc_boehm_gc)
3715 AC_SUBST(out_file)
3716 AC_SUBST(out_object_file)
3717 AC_SUBST(thread_file)
3718 AC_SUBST(tm_file_list)
3719 AC_SUBST(tm_include_list)
3720 AC_SUBST(tm_defines)
3721 AC_SUBST(tm_p_file_list)
3722 AC_SUBST(tm_p_include_list)
3723 AC_SUBST(xm_file_list)
3724 AC_SUBST(xm_include_list)
3725 AC_SUBST(xm_defines)
3726 AC_SUBST(c_target_objs)
3727 AC_SUBST(cxx_target_objs)
3728 AC_SUBST(target_cpu_default)
3729
3730 AC_SUBST_FILE(language_hooks)
3731
3732 # Echo link setup.
3733 if test x${build} = x${host} ; then
3734   if test x${host} = x${target} ; then
3735     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3736   else
3737     echo "Links are now set up to build a cross-compiler" 1>&2
3738     echo " from ${host} to ${target}." 1>&2
3739   fi
3740 else
3741   if test x${host} = x${target} ; then
3742     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3743     echo " for ${target}." 1>&2
3744   else
3745     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3746     echo " from ${host} to ${target}." 1>&2
3747   fi
3748 fi
3749
3750 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3751 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3752
3753 # Configure the subdirectories
3754 # AC_CONFIG_SUBDIRS($subdirs)
3755
3756 # Create the Makefile
3757 # and configure language subdirectories
3758 AC_CONFIG_FILES($all_outputs)
3759
3760 AC_CONFIG_COMMANDS([default],
3761 [
3762 case ${CONFIG_HEADERS} in
3763   *auto-host.h:config.in*)
3764   echo > cstamp-h ;;
3765 esac
3766 # Make sure all the subdirs exist.
3767 for d in $subdirs doc build
3768 do
3769     test -d $d || mkdir $d
3770 done
3771 ],
3772 [subdirs='$subdirs'])
3773 AC_OUTPUT