libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 # We use these options to decide which functions to include.
   9 AC_ARG_WITH(target-subdir,
  10   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  11                  [configure in a subdirectory]))
  12
  13 # We may get other options which we don't document:
  14 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  15
  16 # When building with srcdir == objdir, links to the source files will
  17 # be created in directories within the target_subdir.  We have to
  18 # adjust toplevel_srcdir accordingly, so that configure finds
  19 # install-sh and other auxiliary files that live in the top-level
  20 # source directory.
  21 if test "${srcdir}" = "."; then
  22   if test -z "${with_target_subdir}"; then
  23     toprel=".."
  24   else
  25     if test "${with_target_subdir}" != "."; then
  26       toprel="${with_multisrctop}../.."
  27     else
  28       toprel="${with_multisrctop}.."
  29     fi
  30   fi
  31 else
  32   toprel=".."
  33 fi
  34
  35 libgcj_basedir=$srcdir/$toprel/./libjava
  36 AC_SUBST(libgcj_basedir)
  37
  38 AC_CANONICAL_SYSTEM
  39 _GCC_TOPLEV_NONCANONICAL_BUILD
  40 _GCC_TOPLEV_NONCANONICAL_TARGET
  41
  42 AC_SUBST(target_noncanonical)
  43
  44 # This works around the fact that libtool configuration may change LD
  45 # for this particular configuration, but some shells, instead of
  46 # keeping the changes in LD private, export them just because LD is
  47 # exported.
  48 ORIGINAL_LD_FOR_MULTILIBS=$LD
  49
  50 AC_PROG_LN_S
  51
  52 # This works around an automake problem.
  53 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  54 AC_SUBST(mkinstalldirs)
  55
  56 AC_ARG_WITH(cross-host,
  57   AS_HELP_STRING([--with-cross-host=HOST],
  58                  [configure with a cross compiler from HOST]))
  59
  60 AC_ARG_WITH(newlib,
  61   AS_HELP_STRING([--with-newlib],
  62                  [configure with newlib]))
  63
  64 AC_ARG_ENABLE(version-specific-runtime-libs,
  65   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  67     [case "$enableval" in
  68       yes) version_specific_libs=yes ;;
  69       no)  version_specific_libs=no ;;
  70       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71      esac],
  72     [version_specific_libs=no]
  73 )
  74
  75 # Default to --enable-multilib
  76 AC_ARG_ENABLE(multilib,
  77   AS_HELP_STRING([--enable-multilib],
  78                  [build many library versions (default)]),
  79 [case "${enableval}" in
  80   yes) multilib=yes ;;
  81   no)  multilib=no ;;
  82   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  83  esac], [multilib=yes])dnl
  84
  85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  86 GCC_NO_EXECUTABLES
  87
  88 # (1) We use an abnormal CXX (without library references), so we
  89 # must cache it under a different name.
  90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  91 # the non-multilib-adjusted value will be used in multilibs.
  92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  93 # (4) As another side effect, automake doesn't automatically include them
  94 # in Makefile.in.
  95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  97 # used in later tests.  This may not be necessary in libjava; I don't know.
  98 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
  99 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 100 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 101 save_CXXFLAGS="$CXXFLAGS"
 102 CXXFLAGS="$CXXFLAGS -fno-builtin"
 103 AC_PROG_CC
 104 AC_PROG_CXX
 105 CXXFLAGS="$save_CXXFLAGS"
 106 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 107 AC_SUBST(CFLAGS)
 108 AC_SUBST(CXXFLAGS)
 109 AC_SUBST(LDFLAGS)
 110
 111 AM_INIT_AUTOMAKE([1.9.0])
 112
 113 AC_CHECK_TOOL(AS, as)
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116
 117 AC_PROG_INSTALL
 118
 119 AM_MAINTAINER_MODE
 120
 121 AC_EXEEXT
 122
 123 # configure.host sets the following important variables
 124 #       libgcj_cflags    - host specific C compiler flags
 125 #       libgcj_cxxflags  - host specific C++ compiler flags
 126 #       libgcj_javaflags - host specific Java compiler flags
 127
 128 libgcj_cflags=
 129 libgcj_cxxflags=
 130 libgcj_javaflags=
 131
 132 . ${srcdir}/configure.host
 133
 134 LIBGCJ_CFLAGS="${libgcj_cflags}"
 135 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 136 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 137 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 138 AC_SUBST(LIBGCJ_CFLAGS)
 139 AC_SUBST(LIBGCJ_CXXFLAGS)
 140 AC_SUBST(LIBGCJ_JAVAFLAGS)
 141 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 142
 143 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 144
 145 # Only use libltdl for non-newlib builds.
 146 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 147    AC_LIBLTDL_CONVENIENCE
 148    AC_LIBTOOL_DLOPEN
 149    DIRLTDL=libltdl
 150    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 151    # Sigh.  Libtool's macro doesn't do the right thing.
 152    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 153    # FIXME: this is a hack.
 154    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 155    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 156 fi
 157 AC_SUBST(INCLTDL)
 158 AC_SUBST(LIBLTDL)
 159 AC_SUBST(DIRLTDL)
 160 AC_PROG_LIBTOOL
 161 AM_PROG_GCJ
 162 AM_PROG_CC_C_O
 163 AC_CONFIG_SUBDIRS(libltdl)
 164
 165 # The -no-testsuite modules omit the test subdir.
 166 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 167
 168 # Should the runtime set system properties by examining the
 169 # environment variable GCJ_PROPERTIES?
 170 AC_ARG_ENABLE(getenv-properties,
 171   AS_HELP_STRING([--disable-getenv-properties],
 172                  [don't set system properties from GCJ_PROPERTIES]))
 173
 174 # Whether GCJ_PROPERTIES is used depends on the target.
 175 if test -z "$enable_getenv_properties"; then
 176    enable_getenv_properties=${enable_getenv_properties_default-yes}
 177 fi
 178 if test "$enable_getenv_properties" = no; then
 179    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 180      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 181 fi
 182
 183 # Whether we should use arguments to main()
 184 if test -z "$enable_main_args"; then
 185    enable_main_args=${enable_main_args_default-yes}
 186 fi
 187 if test "$enable_main_args" = no; then
 188    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 189 fi
 190
 191
 192 # Should we use hashtable-based synchronization?
 193 # Currently works only for Linux X86/ia64
 194 # Typically faster and more space-efficient
 195 AC_ARG_ENABLE(hash-synchronization,
 196   AS_HELP_STRING([--enable-hash-synchronization],
 197                  [use global hash table for monitor locks]))
 198
 199 if test -z "$enable_hash_synchronization"; then
 200    enable_hash_synchronization=$enable_hash_synchronization_default
 201 fi
 202
 203 AC_ARG_WITH(java-home,
 204   AS_HELP_STRING([--with-java-home=DIRECTORY],
 205                  [value of java.home system property]),
 206                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 207 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 208 AC_SUBST(JAVA_HOME)
 209
 210 # What is the native OS API for MinGW?
 211 AC_ARG_WITH(win32-nlsapi,
 212   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 213                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 214 [case "${withval}" in
 215   ansi) with_win32_nlsapi=ansi ;;
 216   unicows) with_win32_nlsapi=unicows ;;
 217   unicode) with_win32_nlsapi=unicode ;;
 218   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 219 esac],[with_win32_nlsapi=ansi])
 220
 221 case "${with_win32_nlsapi}" in
 222   unicows | unicode)
 223     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 224       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 225     ;;
 226 esac
 227
 228 # configure.host sets slow_pthread_self if the synchronization code should
 229 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 230 if test "${slow_pthread_self}" = "yes"; then
 231   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 232     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 233 fi
 234
 235
 236 # See if the user has requested runtime debugging.
 237 LIBGCJDEBUG="false"
 238 AC_SUBST(LIBGCJDEBUG)
 239 AC_ARG_ENABLE(libgcj-debug,
 240   AS_HELP_STRING([--enable-libgcj-debug],
 241                  [enable runtime debugging code]),
 242   [if test "$enable_libgcj_debug" = yes; then
 243     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 244     LIBGCJDEBUG="true"
 245   fi])
 246
 247 # Check for gc debugging.  This option is handled both here and in the GC.
 248 AC_ARG_ENABLE(gc-debug,
 249    AS_HELP_STRING([--enable-gc-debug],
 250                   [include full support for pointer backtracing etc.]),
 251 [ if test "$enable_gc_debug" = "yes"; then
 252     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 253               [Define if we want to use debug calls into the garbage collector.])
 254   fi])
 255
 256 # See if the user has the interpreter included.
 257 AC_ARG_ENABLE(interpreter,
 258   AS_HELP_STRING([--enable-interpreter],
 259                  [enable interpreter]),
 260   [if test "$enable_interpreter" = yes; then
 261     # This can also be set in configure.host.
 262     libgcj_interpreter=yes
 263   elif test "$enable_interpreter" = no; then
 264     libgcj_interpreter=no
 265   fi])
 266
 267 if test "$libgcj_interpreter" = yes; then
 268    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 269 fi
 270 INTERPRETER="$libgcj_interpreter"
 271 AC_SUBST(INTERPRETER)
 272
 273 AC_MSG_CHECKING([for exception model to use])
 274 AC_LANG_PUSH(C++)
 275 AC_ARG_ENABLE(sjlj-exceptions,
 276   AS_HELP_STRING([--enable-sjlj-exceptions],
 277                  [force use of builtin_setjmp for exceptions]),
 278 [:],
 279 [dnl Botheration.  Now we've got to detect the exception model.
 280 dnl Link tests against libgcc.a are problematic since -- at least
 281 dnl as of this writing -- we've not been given proper -L bits for
 282 dnl single-tree newlib and libgloss.
 283 dnl
 284 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 285 dnl conftest files before we got a change to grep them first.
 286 cat > conftest.$ac_ext << EOF
 287 [#]line __oline__ "configure"
 288 struct S { ~S(); };
 289 void bar();
 290 void foo()
 291 {
 292   S s;
 293   bar();
 294 }
 295 EOF
 296 old_CXXFLAGS="$CXXFLAGS"
 297 CXXFLAGS=-S
 298 if AC_TRY_EVAL(ac_compile); then
 299   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 300     enable_sjlj_exceptions=yes
 301   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 302     enable_sjlj_exceptions=no
 303   fi
 304 fi
 305 CXXFLAGS="$old_CXXFLAGS"
 306 rm -f conftest*])
 307 if test x$enable_sjlj_exceptions = xyes; then
 308   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 309         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 310   ac_exception_model_name=sjlj
 311 elif test x$enable_sjlj_exceptions = xno; then
 312   ac_exception_model_name="call frame"
 313 else
 314   AC_MSG_ERROR([unable to detect exception model])
 315 fi
 316 AC_LANG_POP(C++)
 317 AC_MSG_RESULT($ac_exception_model_name)
 318
 319 # If we are non using SJLJ exceptions, and this host does not have support
 320 # for unwinding from a signal handler, enable checked dereferences and divides.
 321 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 322   CHECKREFSPEC=-fcheck-references
 323   DIVIDESPEC=-fuse-divide-subroutine
 324   EXCEPTIONSPEC=
 325 fi
 326
 327 # See if the user wants to disable java.net.  This is the mildly
 328 # ugly way that we admit that target-side configuration sucks.
 329 AC_ARG_ENABLE(java-net,
 330   AS_HELP_STRING([--disable-java-net],
 331                  [disable java.net]))
 332
 333 # Whether java.net is built by default can depend on the target.
 334 if test -z "$enable_java_net"; then
 335    enable_java_net=${enable_java_net_default-yes}
 336 fi
 337 if test "$enable_java_net" = no; then
 338    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 339 fi
 340
 341 # See if the user wants to configure without libffi.  Some
 342 # architectures don't support it, and default values are set in
 343 # configure.host.
 344 AC_ARG_WITH(libffi,
 345   AS_HELP_STRING([--without-libffi],
 346                  [don't use libffi]),
 347   [:],
 348   [with_libffi=${with_libffi_default-yes}])
 349
 350 LIBFFI=
 351 LIBFFIINCS=
 352 if test "$with_libffi" != no; then
 353    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 354    LIBFFI=../libffi/libffi_convenience.la
 355    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 356 fi
 357 AC_SUBST(LIBFFI)
 358 AC_SUBST(LIBFFIINCS)
 359
 360 # See if the user wants to disable JVMPI support.
 361 AC_ARG_ENABLE(jvmpi,
 362   AS_HELP_STRING([--disable-jvmpi],
 363                  [disable JVMPI support]))
 364
 365 if test "$enable_jvmpi" != no; then
 366     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 367 fi
 368
 369 # If the target is an eCos system, use the appropriate eCos
 370 # I/O routines.
 371 # FIXME: this should not be a local option but a global target
 372 # system; at present there is no eCos target.
 373 TARGET_ECOS=${PROCESS-"no"}
 374 AC_ARG_WITH(ecos,
 375 [  --with-ecos             enable runtime eCos target support],
 376 TARGET_ECOS="$with_ecos"
 377 )
 378
 379 supply_backtrace=no
 380
 381 PLATFORM_INNER_NAT_HDRS=
 382 case "$TARGET_ECOS" in
 383    no) case "$host" in
 384       *mingw*)
 385             PLATFORM=Win32
 386             PLATFORMNET=Win32
 387             PLATFORMH=win32.h
 388         CHECK_FOR_BROKEN_MINGW_LD
 389       ;;
 390       *)
 391             PLATFORM=Posix
 392             PLATFORMNET=Posix
 393             PLATFORMH=posix.h
 394             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 395       ;;
 396       esac
 397       ;;
 398    *)
 399       PLATFORM=Ecos
 400       PLATFORMNET=NoNet
 401       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 402       PLATFORMH=posix.h
 403       ;;
 404 esac
 405 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 406 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 407
 408 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 409                                       [Define if you have int32_t and uint32_t.]))
 410 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 411                                         [Define if you have int32_t and uint32_t.]))
 412 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 413                                           [Define if you have u_int32_t]))
 414 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 415                                            [Define if you have u_int32_t]))
 416
 417 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 418 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix)
 419 AM_CONDITIONAL(USING_ECOS_PLATFORM, test "$PLATFORM" = Ecos)
 420
 421 case "$host" in
 422   *-darwin*) DARWIN_CRT=true ;;
 423   *) DARWIN_CRT=false ;;
 424 esac
 425 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 426
 427 # These may not be defined in a non-ANS conformant embedded system.
 428 # FIXME: Should these case a runtime exception in that case?
 429 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 430                                   [Define is you have 'mktime' in <time.h>]))
 431 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 432                                   [Define is you have 'localtime' in <time.h>]))
 433
 434 # Create the subdirectory for natFile.cc, or the attempt
 435 # to create the link will fail.
 436 test -d java || mkdir java
 437 test -d java/io || mkdir java/io
 438 test -d gnu || mkdir gnu
 439 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 440
 441 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 442 test -d java/lang || mkdir java/lang
 443 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 444 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 445
 446 # Likewise for natInetAddress.cc and natNetworkInterface.cc.
 447 test -d java/net || mkdir java/net
 448 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 449 AC_CONFIG_LINKS(java/net/natNetworkInterface.cc:java/net/natNetworkInterface${PLATFORMNET}.cc)
 450
 451 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 452 test -d gnu/java || mkdir gnu/java
 453 test -d gnu/java/net || mkdir gnu/java/net
 454 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 455 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 456
 457 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 458 test -d gnu/java/nio || mkdir gnu/java/nio
 459 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 460 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 461 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 462 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 463
 464 case "${host}" in
 465     *mingw*)
 466       SYSTEMSPEC="-lgdi32 -lws2_32"
 467       if test "${with_win32_nlsapi}" = "unicows"; then
 468         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 469       fi
 470     ;;
 471     *)
 472       SYSTEMSPEC=
 473     ;;
 474 esac
 475 AC_SUBST(SYSTEMSPEC)
 476
 477 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 478 AC_SUBST(LIBGCJTESTSPEC)
 479
 480 AC_ARG_WITH(system-zlib,
 481   AS_HELP_STRING([--with-system-zlib],
 482                  [use installed libz]))
 483 ZLIBSPEC=
 484 AC_SUBST(ZLIBSPEC)
 485 ZLIBTESTSPEC=
 486 AC_SUBST(ZLIBTESTSPEC)
 487
 488 AC_PATH_XTRA
 489
 490 # Determine which AWT peer libraries to build
 491 AC_ARG_ENABLE(java-awt,
 492   AS_HELP_STRING([--enable-java-awt],
 493                  [list of AWT peer implementations to be built]))
 494
 495 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 496 use_xlib_awt=""
 497 use_gtk_awt=""
 498 # The default toolkit to use is the first one specified.
 499 TOOLKIT=
 500 AC_SUBST(TOOLKIT)
 501
 502 for peer in $peerlibs ; do
 503   case $peer in
 504     xlib)
 505       if test "$no_x" = yes; then
 506         echo "*** xlib peers requested but no X library available" 1>&2
 507         exit 1
 508       else
 509         use_xlib_awt="yes"
 510         if test -z "$TOOLKIT"; then
 511            TOOLKIT=gnu.awt.xlib.XToolkit
 512         fi
 513       fi
 514       ;;
 515     gtk)
 516       if test "$no_x" = yes; then
 517          echo "*** gtk peers requested but no X library available" 1>&2
 518          exit 1
 519       else
 520          use_gtk_awt=yes
 521          if test -z "$TOOLKIT"; then
 522             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 523          fi
 524          test -d jniinclude || mkdir jniinclude
 525       fi
 526       ;;
 527     no)
 528       use_xlib_awt=
 529       use_gtk_awt=
 530       break
 531       ;;
 532     *)
 533       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 534       exit 1
 535   esac
 536 done
 537
 538 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 539 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 540
 541 # determine whether to enable the cairo GTK Graphics2D backend
 542 AC_ARG_ENABLE(gtk-cairo,
 543   AS_HELP_STRING([--enable-gtk-cairo],
 544                  [build the cairo Graphics2D implementation on GTK]))
 545 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 546 if test "x${enable_gtk_cairo}" = xyes
 547 then
 548         PKG_CHECK_MODULES(CAIRO, cairo)
 549         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 550 fi
 551 AC_SUBST(CAIRO_LIBS)
 552 AC_SUBST(CAIRO_CFLAGS)
 553 AC_SUBST(PANGOFT2_LIBS)
 554 AC_SUBST(PANGOFT2_CFLAGS)
 555
 556 # FIXME: this should be _libs on some hosts.
 557 libsubdir=.libs
 558
 559 # Allow the GC to be disabled.  Can be useful when debugging.
 560 AC_MSG_CHECKING([for garbage collector to use])
 561 AC_ARG_ENABLE(java-gc,
 562   AS_HELP_STRING([--enable-java-gc=TYPE],
 563                  [choose garbage collector (default is boehm)]),
 564   [GC=$enableval],
 565   [GC=boehm])
 566 GCLIBS=
 567 GCINCS=
 568 GCDEPS=
 569 GCSPEC=
 570 JC1GCSPEC=
 571 GCTESTSPEC=
 572 case "$GC" in
 573  boehm)
 574     AC_MSG_RESULT(boehm)
 575     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 576     JC1GCSPEC='-fuse-boehm-gc'
 577     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 578     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 579     GCOBJS=boehm.lo
 580     GCHDR=boehm-gc.h
 581     # The POSIX thread support needs to know this.
 582     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 583     ;;
 584  no)
 585     AC_MSG_RESULT(none)
 586     GCHDR=no-gc.h
 587     ;;
 588  *)
 589     AC_MSG_ERROR([unrecognized collector "$GC"])
 590     ;;
 591 esac
 592 AC_SUBST(GCLIBS)
 593 AC_SUBST(GCINCS)
 594 AC_SUBST(GCDEPS)
 595 AC_SUBST(GCSPEC)
 596 AC_SUBST(JC1GCSPEC)
 597 AC_SUBST(GCTESTSPEC)
 598 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 599 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 600 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 601
 602
 603 AC_MSG_CHECKING([for thread model used by GCC])
 604 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 605 AC_MSG_RESULT([$THREADS])
 606
 607 case "$THREADS" in
 608  no | none | single)
 609     THREADS=none
 610     ;;
 611  posix | posix95 | pthreads)
 612     THREADS=posix
 613     case "$host" in
 614      *-*-linux*)
 615         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 616         ;;
 617     esac
 618     ;;
 619  win32)
 620     ;;
 621  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 622     AC_MSG_ERROR(thread package $THREADS not yet supported)
 623     ;;
 624  *)
 625     AC_MSG_ERROR($THREADS is an unknown thread package)
 626     ;;
 627 esac
 628
 629 THREADCXXFLAGS=
 630 THREADLDFLAGS=
 631 THREADLIBS=
 632 THREADINCS=
 633 THREADDEPS=
 634 THREADH=
 635 THREADSPEC=
 636 case "$THREADS" in
 637  posix)
 638     case "$host" in
 639      *-*-cygwin*)
 640         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 641         ;;
 642      *-*-freebsd[[1234]]*)
 643         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 644         # merely adds pthread_* functions) but it does have a -pthread switch
 645         # which is required at link-time to select -lc_r *instead* of -lc.
 646         THREADLDFLAGS=-pthread
 647         # Don't set THREADSPEC here as might be expected since -pthread is
 648         # not processed when found within a spec file, it must come from
 649         # the command line.  For now, the user must provide the -pthread
 650         # switch to link code compiled with gcj.  In future, consider adding
 651         # support for weak references to pthread_* functions ala gthr.h API.
 652         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 653         ;;
 654      *-*-freebsd*)
 655         # FreeBSD 5 implements a model much closer to other modern UNIX
 656         # which support threads.  However, it still does not support
 657         # -lpthread.
 658         THREADLDFLAGS=-pthread
 659         THREADSPEC=-lc_r
 660         ;;
 661      alpha*-dec-osf*)
 662         THREADCXXFLAGS=-pthread
 663         # boehm-gc needs some functions from librt, so link that too.
 664         THREADLIBS='-lpthread -lrt'
 665         THREADSPEC='-lpthread -lrt'
 666         ;;
 667      *)
 668         THREADLIBS=-lpthread
 669         THREADSPEC=-lpthread
 670         ;;
 671     esac
 672     THREADH=posix-threads.h
 673     # MIT pthreads doesn't seem to have the mutexattr functions.
 674     # But for now we don't check for it.  We just assume you aren't
 675     # using MIT pthreads.
 676     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 677
 678     # If we're using the Boehm GC, then we happen to know that it
 679     # defines _REENTRANT, so we don't bother.  Eww.
 680     if test "$GC" != boehm; then
 681        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 682     fi
 683     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 684     ;;
 685
 686  win32)
 687     THREADH=win32-threads.h
 688     ;;
 689
 690  none)
 691     THREADH=no-threads.h
 692     ;;
 693 esac
 694 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 695 AC_SUBST(THREADLIBS)
 696 AC_SUBST(THREADINCS)
 697 AC_SUBST(THREADDEPS)
 698 AC_SUBST(THREADSPEC)
 699 AC_SUBST(THREADLDFLAGS)
 700 AC_SUBST(THREADCXXFLAGS)
 701 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 702 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 703 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 704
 705 if test -d sysdep; then true; else mkdir sysdep; fi
 706 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 707
 708 HASH_SYNC_SPEC=
 709 # Hash synchronization is only useful with posix threads right now.
 710 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 711    HASH_SYNC_SPEC=-fhash-synchronization
 712    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 713 fi
 714 AC_SUBST(HASH_SYNC_SPEC)
 715
 716
 717 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 718
 719 # We're in the tree with gcc, and need to include some of its headers.
 720 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 721
 722 TL_AC_GCC_VERSION([$srcdir/..])
 723
 724 # Figure out where generated headers like libgcj-config.h get installed.
 725 tool_include_dir='$(libdir)/gcc/$(target_noncanonical)/'${gcc_version}/include
 726 AC_SUBST(tool_include_dir)
 727
 728 if test "x${with_newlib}" = "xyes"; then
 729    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 730    # may not work correctly, because the compiler may not be able to
 731    # link executables.
 732
 733    # We assume newlib.  This lets us hard-code the functions we know
 734    # we'll have.
 735    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 736    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 737    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 738    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 739    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 740    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 741    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 742    # This is only for POSIX threads.
 743    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 744    # We also assume we are using gcc, which provides alloca.
 745    AC_DEFINE(HAVE_ALLOCA)
 746
 747    # Assume we do not have getuid and friends.
 748    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 749    PLATFORMNET=NoNet
 750 else
 751    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 752                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 753                    access stat mkdir rename rmdir unlink realpath utime chmod \
 754                    nl_langinfo setlocale \
 755                    inet_pton uname inet_ntoa \
 756                    fork execvp pipe sigaction ftruncate])
 757    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 758    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 759    AC_CHECK_FUNC(backtrace, [
 760      case "$host" in
 761        ia64-*-linux*)
 762          # Has broken backtrace()
 763          ;;
 764        mips*-*-linux*)
 765          # Has broken backtrace(), but we supply our own.
 766          if test -d sysdep; then true; else mkdir -p sysdep; fi
 767          supply_backtrace=yes
 768          AC_DEFINE(HAVE_BACKTRACE, 1,
 769            [Define if your platform has a working backtrace() function.])
 770          ;;
 771        *)
 772          AC_DEFINE(HAVE_BACKTRACE, 1,
 773            [Define if your platform has a working backtrace() function.])
 774          ;;
 775      esac
 776    ], [
 777      case "$host" in
 778        *mingw*)
 779          # Has backtrace() defined in libgcj itself
 780          AC_DEFINE(HAVE_BACKTRACE, 1,
 781            [Define if your platform has a working backtrace() function.])
 782          ;;
 783      esac
 784    ])
 785
 786    AC_CHECK_LIB(dl, dladdr, [
 787      if test "x${disable_dladdr}" = "xyes"; then
 788        #Broken dladdr().
 789        true
 790      else
 791        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 792      fi
 793    ])
 794    if test x"$build" = x"$host"; then
 795      AC_CHECK_FILES(/proc/self/exe, [
 796        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 797    else
 798      case $host in
 799      *-linux*)
 800        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 801        ;;
 802      esac
 803    fi
 804
 805    AM_ICONV
 806    AM_LC_MESSAGES
 807    AC_STRUCT_TIMEZONE
 808
 809    AC_CHECK_FUNCS(gethostbyname_r, [
 810      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 811        [Define if you have the 'gethostbyname_r' function.])
 812      # There are two different kinds of gethostbyname_r.
 813      # We look for the one that returns `int'.
 814      # Hopefully this check is robust enough.
 815      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 816        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 817
 818      case " $GCINCS " in
 819      *" -D_REENTRANT "*) ;;
 820      *)
 821         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 822         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 823         [libjava_cv_gethostbyname_r_needs_reentrant],
 824         [ AC_LANG_PUSH(C++)
 825           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 826             [[gethostbyname_r("", 0, 0);]])],
 827             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 828                 CPPFLAGS_SAVE="$CPPFLAGS"
 829                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 830                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 831                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 832                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 833                 CPPFLAGS="$CPPFLAGS_SAVE"
 834           ])
 835           AC_LANG_POP(C++)
 836         ])
 837         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 838           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 839         fi
 840      ;;
 841      esac
 842
 843      AC_CACHE_CHECK([for struct hostent_data],
 844         [libjava_cv_struct_hostent_data], [dnl
 845         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 846 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 847 # define _REENTRANT 1
 848 #endif
 849 #include <netdb.h>]], [[struct hostent_data data;]])],
 850           [libjava_cv_struct_hostent_data=yes],
 851           [libjava_cv_struct_hostent_data=no])])
 852      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 853        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 854          [Define if struct hostent_data is defined in netdb.h])
 855      fi
 856    ])
 857
 858    # FIXME: libjava source code expects to find a prototype for
 859    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 860    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 861    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 862    # linkage check is enough, yet C++ code requires proper prototypes.)
 863    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 864    AC_CHECK_FUNCS(gethostbyaddr_r, [
 865      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 866        [Define if you have the 'gethostbyaddr_r' function.])
 867      # There are two different kinds of gethostbyaddr_r.
 868      # We look for the one that returns `int'.
 869      # Hopefully this check is robust enough.
 870      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 871        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 872          [Define if gethostbyaddr_r returns 'int'.])])])])
 873
 874    AC_CHECK_FUNCS(gethostname, [
 875      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 876        [Define if you have the 'gethostname' function.])
 877      AC_EGREP_HEADER(gethostname, unistd.h, [
 878        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 879          [Define if gethostname is declared in <unistd.h>.])])])
 880
 881    AC_CHECK_FUNCS(usleep, [
 882      AC_EGREP_HEADER(usleep, unistd.h, [
 883        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 884           [Define if usleep is declared in <unistd.h>.])])])
 885
 886    # Look for these functions in the thread library, but only bother
 887    # if using POSIX threads.
 888    if test "$THREADS" = posix; then
 889       save_LIBS="$LIBS"
 890       LIBS="$LIBS $THREADLIBS"
 891       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 892       # E.g., Solaris.
 893       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 894
 895       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 896       # Solaris 7 the name librt is preferred.
 897       AC_CHECK_FUNCS(sched_yield, , [
 898         AC_CHECK_LIB(rt, sched_yield, [
 899           AC_DEFINE(HAVE_SCHED_YIELD)
 900           THREADLIBS="$THREADLIBS -lrt"
 901           THREADSPEC="$THREADSPEC -lrt"], [
 902           AC_CHECK_LIB(posix4, sched_yield, [
 903             AC_DEFINE(HAVE_SCHED_YIELD)
 904             THREADLIBS="$THREADLIBS -lposix4"
 905             THREADSPEC="$THREADSPEC -lposix4"])])])
 906       LIBS="$save_LIBS"
 907
 908       # We can save a little space at runtime if the mutex has m_count
 909       # or __m_count.  This is a nice hack for Linux.
 910       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 911           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 912         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
 913              [Define if pthread_mutex_t has m_count member.]), [
 914         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 915             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 916           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
 917             [Define if pthread_mutex_t has __m_count member.]))])
 918    fi
 919
 920    # We require a way to get the time.
 921    time_found=no
 922    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 923    if test "$time_found" = no; then
 924       AC_MSG_ERROR([no function found to get the time])
 925    fi
 926
 927    AC_CHECK_FUNCS(memmove)
 928
 929    # We require memcpy.
 930    memcpy_found=no
 931    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 932    if test "$memcpy_found" = no; then
 933       AC_MSG_ERROR([memcpy is required])
 934    fi
 935
 936    AC_CHECK_LIB(dl, dlopen, [
 937        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
 938
 939    # Some library-finding code we stole from Tcl.
 940    #--------------------------------------------------------------------
 941    #    Check for the existence of the -lsocket and -lnsl libraries.
 942    #    The order here is important, so that they end up in the right
 943    #    order in the command line generated by make.  Here are some
 944    #    special considerations:
 945    #    1. Use "connect" and "accept" to check for -lsocket, and
 946    #       "gethostbyname" to check for -lnsl.
 947    #    2. Use each function name only once:  can't redo a check because
 948    #       autoconf caches the results of the last check and won't redo it.
 949    #    3. Use -lnsl and -lsocket only if they supply procedures that
 950    #       aren't already present in the normal libraries.  This is because
 951    #       IRIX 5.2 has libraries, but they aren't needed and they're
 952    #       bogus:  they goof up name resolution if used.
 953    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 954    #       To get around this problem, check for both libraries together
 955    #       if -lsocket doesn't work by itself.
 956    #--------------------------------------------------------------------
 957
 958    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 959     [gcj_cv_lib_sockets=
 960      gcj_checkBoth=0
 961      unset ac_cv_func_connect
 962      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 963      if test "$gcj_checkSocket" = 1; then
 964          unset ac_cv_func_connect
 965          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 966                       gcj_checkBoth=1)
 967      fi
 968      if test "$gcj_checkBoth" = 1; then
 969          gcj_oldLibs=$LIBS
 970          LIBS="$LIBS -lsocket -lnsl"
 971          unset ac_cv_func_accept
 972          AC_CHECK_FUNC(accept,
 973                        [gcj_checkNsl=0
 974                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 975          unset ac_cv_func_accept
 976          LIBS=$gcj_oldLibs
 977      fi
 978      unset ac_cv_func_gethostbyname
 979      gcj_oldLibs=$LIBS
 980      LIBS="$LIBS $gcj_cv_lib_sockets"
 981      AC_CHECK_FUNC(gethostbyname, ,
 982                    [AC_CHECK_LIB(nsl, main,
 983                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 984      unset ac_cv_func_gethostbyname
 985      LIBS=$gcj_oldLIBS
 986    ])
 987    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 988
 989    if test "$with_system_zlib" = yes; then
 990       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
 991    fi
 992
 993    # Test for Gtk stuff, if asked for.
 994    if test "$use_gtk_awt" = yes; then
 995       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
 996       AC_SUBST(GTK_CFLAGS)
 997       AC_SUBST(GTK_LIBS)
 998
 999       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1000       AC_SUBST(GLIB_CFLAGS)
1001       AC_SUBST(GLIB_LIBS)
1002
1003       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1004       AC_SUBST(LIBART_CFLAGS)
1005       AC_SUBST(LIBART_LIBS)
1006
1007       # We require the XTest Extension to support java.awt.Robot.
1008       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1009                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1010                    [${X_LIBS}])
1011    fi
1012
1013    # On Solaris, and maybe other architectures, the Boehm collector
1014    # requires -ldl.
1015    if test "$GC" = boehm; then
1016       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1017    fi
1018 fi
1019 AM_CONDITIONAL(SUPPLY_BACKTRACE, test "$supply_backtrace" = yes)
1020
1021 if test -z "${with_multisubdir}"; then
1022    builddotdot=.
1023 else
1024    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
1025 fi
1026
1027 NATIVE=yes
1028
1029 # Which gcj do we use?
1030 which_gcj=default
1031 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
1032 if test -n "${with_cross_host}"; then
1033   # We are being configured with a cross compiler. We can't
1034   # use ac_exeext, because that is for the target platform.
1035   NATIVE=no
1036   cross_host_exeext=
1037   case "${with_cross_host}" in
1038      *mingw* | *cygwin*)
1039          cross_host_exeext=.exe
1040      ;;
1041   esac
1042   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
1043      if test x"$build_noncanonical" = x"$with_cross_host"; then
1044         # Ordinary cross (host!=target and host=build)
1045         which_gcj=built
1046      else
1047         # Canadian cross (host!=target and host!=build)
1048         which_gcj=cross
1049      fi
1050   else
1051      which_gcj=cross
1052   fi
1053 else
1054   # We are being configured with a native or crossed-native compiler
1055   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
1056      if test x"$build" = x"$host"; then
1057         # True native build (host=target and host=build)
1058         which_gcj=built
1059      else
1060         # Crossed-native build (host=target and host!=build)
1061         which_gcj=cross
1062      fi
1063   else
1064      which_gcj=path
1065   fi
1066 fi
1067 case "${which_gcj}" in
1068    built)
1069       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
1070       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
1071       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/fastjar/fastjar'
1072    ;;
1073    cross)
1074       if test "x${with_newlib}" = "xyes"; then
1075          # FIXME (comment): Why is this needed?
1076          GCC_UNWIND_INCLUDE=
1077          GCJ="${target_noncanonical}-gcj"
1078       else
1079          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
1080       fi
1081       ZIP='$(target_noncanonical)-fastjar'
1082       GCJH='$(target_noncanonical)-gcjh'
1083    ;;
1084    path)
1085       GCJ="gcj -B`${PWDCMD-pwd}`/"
1086       ## In this case, gcj is found outside the build tree.  However, zip is
1087       ## found in the build tree.
1088       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1089       GCJH=gcjh
1090    ;;
1091 esac
1092
1093 AC_SUBST(GCJH)
1094 AC_SUBST(ZIP)
1095
1096 # Create it, so that compile/link tests don't fail
1097 test -f libgcj.spec || touch libgcj.spec
1098
1099 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1100 case $build in
1101     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1102     *)         CLASSPATH_SEPARATOR=':' ;;
1103 esac
1104 AC_SUBST(CLASSPATH_SEPARATOR)
1105
1106 # We must search the source tree for java.lang, since we still don't
1107 # have libgcj.jar nor java/lang/*.class
1108 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1109 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1110
1111 # Since some classes depend on this one, we need its source available
1112 # before we can do any GCJ compilation test :-(
1113 if test ! -f gnu/classpath/Configuration.java; then
1114   test -d gnu || mkdir gnu
1115   test -d gnu/classpath || mkdir gnu/classpath
1116   sed -e 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
1117       -e 's,@TOOLKIT@,$TOOLKIT,' \
1118         < $srcdir/gnu/classpath/Configuration.java.in \
1119         > gnu/classpath/Configuration.java
1120   # We do not want to redirect the output of the grep below to /dev/null,
1121   # but we add /dev/null to the input list so that grep will print the
1122   # filename of Configuration.java in case it finds any matches.
1123   if grep @ gnu/classpath/Configuration.java /dev/null; then
1124     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1125   fi
1126 fi
1127
1128 LT_AC_PROG_GCJ
1129
1130 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1131
1132 AC_COMPILE_CHECK_SIZEOF(void *)
1133
1134 AC_C_BIGENDIAN_CROSS
1135
1136 ZLIBS=
1137 SYS_ZLIBS=
1138 ZINCS=
1139
1140 if test -z "$ZLIBSPEC"; then
1141    # Use zlib from the GCC tree.
1142    ZINCS='-I$(top_srcdir)/../zlib'
1143    ZLIBS=../zlib/libzgcj_convenience.la
1144 else
1145    # System's zlib.
1146    SYS_ZLIBS="$ZLIBSPEC"
1147 fi
1148 AC_SUBST(ZLIBS)
1149 AC_SUBST(SYS_ZLIBS)
1150 AC_SUBST(ZINCS)
1151 AC_SUBST(DIVIDESPEC)
1152 AC_SUBST(CHECKREFSPEC)
1153 AC_SUBST(EXCEPTIONSPEC)
1154 AC_SUBST(IEEESPEC)
1155
1156 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1157 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1158 AC_SUBST(GCC_UNWIND_INCLUDE)
1159
1160 # Process the option "--enable-version-specific-runtime-libs"
1161 # Calculate toolexeclibdir
1162 case ${version_specific_libs} in
1163   yes)
1164     # Need the gcc compiler version to know where to install libraries
1165     # and header files if --enable-version-specific-runtime-libs option
1166     # is selected.
1167     includedir='${libdir}/gcc/${target_noncanonical}/'$gcc_version/include/
1168     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1169     toolexecmainlibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1170     toolexeclibdir=$toolexecmainlibdir
1171     ;;
1172   no)
1173     if test -n "$with_cross_host" &&
1174        test x"$with_cross_host" != x"no"; then
1175       # Install a library built with a cross compiler in tooldir, not libdir.
1176       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1177       toolexecmainlibdir='$(toolexecdir)/lib'
1178     else
1179       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1180       toolexecmainlibdir='$(libdir)'
1181     fi
1182     multi_os_directory=`$CC -print-multi-os-directory`
1183     case $multi_os_directory in
1184       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1185       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1186     esac
1187     ;;
1188 esac
1189 AC_SUBST(toolexecdir)
1190 AC_SUBST(toolexecmainlibdir)
1191 AC_SUBST(toolexeclibdir)
1192
1193 # Determine gcj version number.
1194 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1195 GCJVERSION=$gcjversion
1196 AC_SUBST(GCJVERSION)
1197 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1198
1199 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1200 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1201
1202 TL_AC_GXX_INCLUDE_DIR
1203
1204 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1205 # On that system, sys/ioctl.h will not include sys/filio.h unless
1206 # BSD_COMP is defined; just including sys/filio.h is simpler.
1207 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1208 # for now.  If you change this, you also must update natFile.cc.
1209 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1210                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1211                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1212                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1213                   dirent.h])
1214 AC_CHECK_HEADERS(inttypes.h, [
1215     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1216     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1217 ])
1218 AC_HEADER_SYS_WAIT
1219
1220 AC_CHECK_TYPE([ssize_t], [int])
1221
1222 AC_MSG_CHECKING([for in_addr_t])
1223 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1224 #if STDC_HEADERS
1225 #include <stdlib.h>
1226 #include <stddef.h>
1227 #endif
1228 #if HAVE_NETINET_IN_H
1229 #include <netinet/in.h>
1230 #endif]], [[in_addr_t foo;]])],
1231   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1232      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1233    AC_MSG_RESULT(yes)],
1234   [AC_MSG_RESULT(no)])
1235
1236 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1237 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1238   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1239      [Define if struct ip_mreq is defined in netinet/in.h.])
1240    AC_MSG_RESULT(yes)],
1241   [AC_MSG_RESULT(no)])
1242
1243 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1244 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1245   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1246      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1247    AC_MSG_RESULT(yes)],
1248   [AC_MSG_RESULT(no)])
1249
1250 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1251 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1252   [AC_DEFINE(HAVE_INET6, 1,
1253      [Define if inet6 structures are defined in netinet/in.h.])
1254    AC_MSG_RESULT(yes)],
1255   [AC_MSG_RESULT(no)])
1256
1257 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1258 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1259 #include <sys/types.h>
1260 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1261   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1262    AC_MSG_RESULT(yes)],
1263   [AC_MSG_RESULT(no)])
1264
1265 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1266 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1267   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1268    AC_MSG_RESULT(yes)],
1269   [AC_MSG_RESULT(no)
1270    AC_MSG_CHECKING([for global timezone variable])
1271    dnl FIXME: we don't want a link check here because that won't work
1272    dnl when cross-compiling.  So instead we make an assumption that
1273    dnl the header file will mention timezone if it exists.
1274    dnl Don't find the win32 function timezone
1275    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1276      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1277       AC_MSG_RESULT(yes)],
1278      [AC_MSG_RESULT(no)
1279        AC_MSG_CHECKING([for global _timezone variable])
1280        dnl FIXME: As above, don't want link check
1281        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1282          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1283             [Define if your platform has the global _timezone variable.])
1284           AC_MSG_RESULT(yes)],
1285           [AC_MSG_RESULT(no)])])])
1286
1287 AC_FUNC_ALLOCA
1288 AC_FUNC_MMAP
1289
1290 AC_CHECK_PROGS(PERL, perl, false)
1291
1292 SYSDEP_SOURCES=
1293 SIGNAL_HANDLER_AUX=
1294
1295 case "${host}" in
1296  i?86-*-linux*)
1297     SIGNAL_HANDLER=include/i386-signal.h
1298     ;;
1299  sparc*-sun-solaris*)
1300     SIGNAL_HANDLER=include/sparc-signal.h
1301     ;;
1302 # ia64-*)
1303 #    SYSDEP_SOURCES=sysdep/ia64.c
1304 #    test -d sysdep || mkdir sysdep
1305 #    ;;
1306  hppa*-*-linux*)
1307     SIGNAL_HANDLER=include/pa-signal.h
1308     ;;
1309  ia64-*-linux*)
1310     SIGNAL_HANDLER=include/dwarf2-signal.h
1311     ;;
1312  powerpc*-*-linux*)
1313     SIGNAL_HANDLER=include/powerpc-signal.h
1314     ;;
1315  alpha*-*-linux*)
1316     SIGNAL_HANDLER=include/dwarf2-signal.h
1317     ;;
1318  s390*-*-linux*)
1319     SIGNAL_HANDLER=include/s390-signal.h
1320     ;;
1321  x86_64*-*-linux*)
1322     SIGNAL_HANDLER=include/x86_64-signal.h
1323     SIGNAL_HANDLER_AUX=include/i386-signal.h
1324     ;;
1325  sparc*-*-linux*)
1326     SIGNAL_HANDLER=include/dwarf2-signal.h
1327     ;;
1328  sh*-*-linux*)
1329     SIGNAL_HANDLER=include/sh-signal.h
1330     ;;
1331  *mingw*)
1332     SIGNAL_HANDLER=include/win32-signal.h
1333     ;;
1334  mips*-*-linux*)
1335     SIGNAL_HANDLER=include/mips-signal.h
1336     ;;
1337  *-*-darwin*)
1338     SIGNAL_HANDLER=include/darwin-signal.h
1339     ;;
1340  *)
1341     SIGNAL_HANDLER=include/default-signal.h
1342     ;;
1343 esac
1344
1345 # If we're using sjlj exceptions, forget what we just learned.
1346 if test "$enable_sjlj_exceptions" = yes; then
1347    SIGNAL_HANDLER=include/default-signal.h
1348    SIGNAL_HANDLER_AUX=
1349 fi
1350
1351 # Define here any compiler flags that you need in order to make backtrace() work.
1352 BACKTRACESPEC=
1353 case "${host}" in
1354  x86_64*-*-linux*|i?86-*)
1355     BACKTRACESPEC=-fno-omit-frame-pointer
1356     ;;
1357 esac
1358 AC_SUBST(BACKTRACESPEC)
1359
1360 AC_SUBST(SYSDEP_SOURCES)
1361
1362 if test -z "$SIGNAL_HANDLER_AUX"; then
1363   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1364 fi
1365
1366 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1367                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1368
1369 if test "${multilib}" = "yes"; then
1370   multilib_arg="--enable-multilib"
1371 else
1372   multilib_arg=
1373 fi
1374
1375
1376
1377 here=`${PWDCMD-pwd}`
1378 AC_SUBST(here)
1379
1380 # We get this from the environment.
1381 AC_SUBST(GCJFLAGS)
1382
1383 AC_CONFIG_FILES([
1384 Makefile
1385 libgcj.pc
1386 libgcj.spec
1387 libgcj-test.spec
1388 gnu/classpath/Configuration.java
1389 gcj/Makefile
1390 include/Makefile
1391 testsuite/Makefile
1392 external/Makefile
1393 external/sax/Makefile
1394 external/w3c_dom/Makefile
1395 ])
1396
1397 AC_CONFIG_COMMANDS([default],
1398 [# Only add multilib support code if we just rebuilt top-level Makefile.
1399 case " $CONFIG_FILES " in
1400  *" Makefile "*)
1401    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1402    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1403    ;;
1404 esac
1405 for ac_multi_file in $CONFIG_FILES; do
1406   case $ac_multi_file in
1407   */Makefile)
1408     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1409   esac
1410 done
1411 ],
1412 srcdir=${srcdir}
1413 host=${host}
1414 target=${target}
1415 with_multisubdir=${with_multisubdir}
1416 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1417 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1418 libgcj_basedir=${libgcj_basedir}
1419 CC="${CC}"
1420 CXX="${CXX}"
1421 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1422 )
1423
1424 AC_OUTPUT