gcc/ada/s-imgbiu.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                       S Y S T E M . I M G _ B I U                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --     Copyright (C) 1992,1993,1994,1995 Free Software Foundation, Inc.     --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Unsigned_Types; use System.Unsigned_Types;
  35
  36 package body System.Img_BIU is
  37
  38    -----------------------------
  39    -- Set_Image_Based_Integer --
  40    -----------------------------
  41
  42    procedure Set_Image_Based_Integer
  43      (V : Integer;
  44       B : Natural;
  45       W : Integer;
  46       S : out String;
  47       P : in out Natural)
  48    is
  49       Start : Natural;
  50
  51    begin
  52       --  Positive case can just use the unsigned circuit directly
  53
  54       if V >= 0 then
  55          Set_Image_Based_Unsigned (Unsigned (V), B, W, S, P);
  56
  57       --  Negative case has to set a minus sign. Note also that we have to be
  58       --  careful not to generate overflow with the largest negative number.
  59
  60       else
  61          P := P + 1;
  62          S (P) := ' ';
  63          Start := P;
  64
  65          declare
  66             pragma Suppress (Overflow_Check);
  67             pragma Suppress (Range_Check);
  68          begin
  69             Set_Image_Based_Unsigned (Unsigned (-V), B, W - 1, S, P);
  70          end;
  71
  72          --  Set minus sign in last leading blank location. Because of the
  73          --  code above, there must be at least one such location.
  74
  75          while S (Start + 1) = ' ' loop
  76             Start := Start + 1;
  77          end loop;
  78
  79          S (Start) := '-';
  80       end if;
  81
  82    end Set_Image_Based_Integer;
  83
  84    ------------------------------
  85    -- Set_Image_Based_Unsigned --
  86    ------------------------------
  87
  88    procedure Set_Image_Based_Unsigned
  89      (V : Unsigned;
  90       B : Natural;
  91       W : Integer;
  92       S : out String;
  93       P : in out Natural)
  94    is
  95       Start : constant Natural := P;
  96       F, T  : Natural;
  97       BU    : constant Unsigned := Unsigned (B);
  98       Hex   : constant array
  99                 (Unsigned range 0 .. 15) of Character := "0123456789ABCDEF";
 100
 101       procedure Set_Digits (T : Unsigned);
 102       --  Set digits of absolute value of T
 103
 104       procedure Set_Digits (T : Unsigned) is
 105       begin
 106          if T >= BU then
 107             Set_Digits (T / BU);
 108             P := P + 1;
 109             S (P) := Hex (T mod BU);
 110          else
 111             P := P + 1;
 112             S (P) := Hex (T);
 113          end if;
 114       end Set_Digits;
 115
 116    --  Start of processing for Set_Image_Based_Unsigned
 117
 118    begin
 119
 120       if B >= 10 then
 121          P := P + 1;
 122          S (P) := '1';
 123       end if;
 124
 125       P := P + 1;
 126       S (P) := Character'Val (Character'Pos ('0') + B mod 10);
 127
 128       P := P + 1;
 129       S (P) := '#';
 130
 131       Set_Digits (V);
 132
 133       P := P + 1;
 134       S (P) := '#';
 135
 136       --  Add leading spaces if required by width parameter
 137
 138       if P - Start < W then
 139          F := P;
 140          P := Start + W;
 141          T := P;
 142
 143          while F > Start loop
 144             S (T) := S (F);
 145             T := T - 1;
 146             F := F - 1;
 147          end loop;
 148
 149          for J in Start + 1 .. T loop
 150             S (J) := ' ';
 151          end loop;
 152       end if;
 153
 154    end Set_Image_Based_Unsigned;
 155
 156 end System.Img_BIU;