gcc/ada/s-casi16.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                   GNU ADA RUNTIME LIBRARY COMPONENTS                     --
   4 --                                                                          --
   5 --        S Y S T E M . C O M P A R E _ A R R A Y _ S I G N E D _ 16        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Address_Operations; use System.Address_Operations;
  35
  36 with Unchecked_Conversion;
  37
  38 package body System.Compare_Array_Signed_16 is
  39
  40    type Word is mod 2 ** 32;
  41    --  Used to process operands by words
  42
  43    type Half is range -(2 ** 15) .. (2 ** 15) - 1;
  44    for Half'Size use 16;
  45    --  Used to process operands by half words
  46
  47    type Uhalf is record
  48       H : Half;
  49    end record;
  50    pragma Pack (Uhalf);
  51    for Uhalf'Alignment use 1;
  52    --  Used to process operands when unaligned
  53
  54    type WP is access Word;
  55    type HP is access Half;
  56    type UP is access Uhalf;
  57
  58    function W is new Unchecked_Conversion (Address, WP);
  59    function H is new Unchecked_Conversion (Address, HP);
  60    function U is new Unchecked_Conversion (Address, UP);
  61
  62    -----------------------
  63    -- Compare_Array_S16 --
  64    -----------------------
  65
  66    function Compare_Array_S16
  67      (Left      : System.Address;
  68       Right     : System.Address;
  69       Left_Len  : Natural;
  70       Right_Len : Natural) return Integer
  71    is
  72       Clen : Natural := Natural'Min (Left_Len, Right_Len);
  73       --  Number of elements left to compare
  74
  75       L : Address := Left;
  76       R : Address := Right;
  77       --  Pointers to next elements to compare
  78
  79    begin
  80       --  Go by words if possible
  81
  82       if ModA (OrA (Left, Right), 4) = 0 then
  83          while Clen > 1
  84            and then W (L).all = W (R).all
  85          loop
  86             Clen := Clen - 2;
  87             L := AddA (L, 4);
  88             R := AddA (R, 4);
  89          end loop;
  90       end if;
  91
  92       --  Case of going by aligned half words
  93
  94       if ModA (OrA (Left, Right), 2) = 0 then
  95          while Clen /= 0 loop
  96             if H (L).all /= H (R).all then
  97                if H (L).all > H (R).all then
  98                   return +1;
  99                else
 100                   return -1;
 101                end if;
 102             end if;
 103
 104             Clen := Clen - 1;
 105             L := AddA (L, 2);
 106             R := AddA (R, 2);
 107          end loop;
 108
 109       --  Case of going by unaligned half words
 110
 111       else
 112          while Clen /= 0 loop
 113             if U (L).H /= U (R).H then
 114                if U (L).H > U (R).H then
 115                   return +1;
 116                else
 117                   return -1;
 118                end if;
 119             end if;
 120
 121             Clen := Clen - 1;
 122             L := AddA (L, 2);
 123             R := AddA (R, 2);
 124          end loop;
 125       end if;
 126
 127       --  Here if common section equal, result decided by lengths
 128
 129       if Left_Len = Right_Len then
 130          return 0;
 131       elsif Left_Len > Right_Len then
 132          return +1;
 133       else
 134          return -1;
 135       end if;
 136    end Compare_Array_S16;
 137
 138 end System.Compare_Array_Signed_16;