gcc/ada/a-elchha.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --    A D A . E X C E P T I O N S . L A S T _ C H A N C E _ H A N D L E R   --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --           Copyright (C) 2003-2004 Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  24 -- MA 02111-1307, USA.                                                      --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- GNAT was originally developed  by the GNAT team at  New York University. --
  34 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  35 --                                                                          --
  36 ------------------------------------------------------------------------------
  37
  38 --  Default version for most targets
  39
  40 procedure Ada.Exceptions.Last_Chance_Handler
  41   (Except : Exception_Occurrence)
  42 is
  43    procedure Unhandled_Terminate;
  44    pragma No_Return (Unhandled_Terminate);
  45    pragma Import (C, Unhandled_Terminate, "__gnat_unhandled_terminate");
  46    --  Perform system dependent shutdown code
  47
  48    function Exception_Message_Length
  49      (X : Exception_Occurrence) return Natural;
  50    pragma Import (Ada, Exception_Message_Length, "__gnat_exception_msg_len");
  51
  52    procedure Append_Info_Exception_Message
  53      (X : Exception_Occurrence; Info : in out String; Ptr : in out Natural);
  54    pragma Import
  55      (Ada, Append_Info_Exception_Message, "__gnat_append_info_e_msg");
  56
  57    procedure Append_Info_Exception_Information
  58      (X : Exception_Occurrence; Info : in out String; Ptr : in out Natural);
  59    pragma Import
  60      (Ada, Append_Info_Exception_Information, "__gnat_append_info_e_info");
  61
  62    procedure To_Stderr (S : String);
  63    pragma Import (Ada, To_Stderr, "__gnat_to_stderr");
  64    --  Little routine to output string to stderr
  65
  66    Ptr   : Natural := 0;
  67    Nobuf : String (1 .. 0);
  68
  69    Nline : constant String := String'(1 => ASCII.LF);
  70    --  Convenient shortcut
  71
  72 begin
  73    --  Let's shutdown the runtime now. The rest of the procedure needs to be
  74    --  careful not to use anything that would require runtime support. In
  75    --  particular, functions returning strings are banned since the sec stack
  76    --  is no longer functional. This is particularly important to note for the
  77    --  Exception_Information output. We used to allow the tailored version to
  78    --  show up here, which turned out to be a bad idea as it might involve a
  79    --  traceback decorator the length of which we don't control. Potentially
  80    --  heavy primary/secondary stack use or dynamic allocations right before
  81    --  this point are not welcome, moving the output before the finalization
  82    --  raises order of outputs concerns, and decorators are intended to only
  83    --  be used with exception traces, which should have been issued already.
  84
  85    System.Standard_Library.Adafinal;
  86
  87    --  Check for special case of raising _ABORT_SIGNAL, which is not
  88    --  really an exception at all. We recognize this by the fact that
  89    --  it is the only exception whose name starts with underscore.
  90
  91    if Except.Id.Full_Name.all (1) = '_' then
  92       To_Stderr (Nline);
  93       To_Stderr ("Execution terminated by abort of environment task");
  94       To_Stderr (Nline);
  95
  96    --  If no tracebacks, we print the unhandled exception in the old style
  97    --  (i.e. the style used before ZCX was implemented). We do this to
  98    --  retain compatibility.
  99
 100    elsif Except.Num_Tracebacks = 0 then
 101       To_Stderr (Nline);
 102       To_Stderr ("raised ");
 103       To_Stderr (Except.Id.Full_Name.all (1 .. Except.Id.Name_Length - 1));
 104
 105       if Exception_Message_Length (Except) /= 0 then
 106          To_Stderr (" : ");
 107          Append_Info_Exception_Message (Except, Nobuf, Ptr);
 108       end if;
 109
 110       To_Stderr (Nline);
 111
 112    --  Traceback exists
 113
 114    else
 115       To_Stderr (Nline);
 116       To_Stderr ("Execution terminated by unhandled exception");
 117       To_Stderr (Nline);
 118
 119       Append_Info_Exception_Information (Except, Nobuf, Ptr);
 120    end if;
 121
 122    Unhandled_Terminate;
 123 end Ada.Exceptions.Last_Chance_Handler;