libcpp/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT(cpplib, [ ], gcc-bugs@gcc.gnu.org, cpplib)
   6 AC_CONFIG_SRCDIR(ucnid.h)
   7 AC_CONFIG_MACRO_DIR(../config)
   8 AC_CANONICAL_SYSTEM
   9
  10 # Checks for programs.
  11 AC_PROG_MAKE_SET
  12 AC_PROG_INSTALL
  13 AC_PROG_CC
  14 AC_PROG_CXX
  15 AC_PROG_RANLIB
  16
  17 AC_USE_SYSTEM_EXTENSIONS
  18 AC_SYS_LARGEFILE
  19
  20 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
  21 AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
  22 AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
  23 AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
  24
  25 # Figure out what compiler warnings we can enable.
  26 # See config/warnings.m4 for details.
  27
  28 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wno-narrowing -Wwrite-strings \
  29                           -Wmissing-format-attribute], [warn])
  30 ACX_PROG_CC_WARNING_OPTS([-Wstrict-prototypes -Wmissing-prototypes \
  31                           -Wold-style-definition -Wc++-compat], [c_warn])
  32 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])
  33
  34 # Disable exceptions and RTTI if building with g++
  35 ACX_PROG_CC_WARNING_OPTS(
  36        m4_quote(m4_do([-fno-exceptions -fno-rtti])), [noexception_flags])
  37
  38 # Only enable with --enable-werror-always until existing warnings are
  39 # corrected.
  40 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  41
  42 # Dependency checking.
  43 ZW_CREATE_DEPDIR
  44 AC_LANG_PUSH([C++])
  45 AC_COMPILE_IFELSE([[int i;]], [],
  46                   [AC_MSG_ERROR([C++ compiler missing or inoperational])])
  47 AC_LANG_POP([C++])
  48 ZW_PROG_COMPILER_DEPENDENCIES([CXX])
  49
  50 # Checks for header files.
  51 AC_HEADER_TIME
  52 ACX_HEADER_STRING
  53
  54 AC_CHECK_HEADERS(locale.h fcntl.h limits.h stddef.h \
  55         stdlib.h strings.h string.h sys/file.h unistd.h)
  56
  57 # Checks for typedefs, structures, and compiler characteristics.
  58 AC_C_BIGENDIAN
  59 AC_C_CONST
  60 AC_C_INLINE
  61 AC_FUNC_OBSTACK
  62 AC_TYPE_OFF_T
  63 AC_TYPE_SIZE_T
  64 AC_TYPE_SSIZE_T
  65 AC_TYPE_UINTPTR_T
  66 AC_CHECK_TYPE(ptrdiff_t, int)
  67 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
  68 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
  69 AC_STRUCT_TM
  70 AC_CHECK_SIZEOF(int)
  71 AC_CHECK_SIZEOF(long)
  72 define(libcpp_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
  73   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
  74   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
  75   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
  76   putchar_unlocked putc_unlocked)
  77 AC_CHECK_FUNCS(libcpp_UNLOCKED_FUNCS)
  78 AC_CHECK_DECLS([abort, asprintf, basename(char *), errno, getopt, vasprintf])
  79 AC_CHECK_DECLS(m4_split(m4_normalize(libcpp_UNLOCKED_FUNCS)))
  80
  81 # Checks for library functions.
  82 AC_FUNC_ALLOCA
  83 AC_HEADER_STDC
  84 AM_LANGINFO_CODESET
  85 ZW_GNU_GETTEXT_SISTER_DIR
  86
  87 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
  88 [AC_TRY_COMPILE([
  89 #include <sys/types.h>
  90 ],
  91 [if ((uchar *)0) return 0;
  92  if (sizeof(uchar)) return 0;],
  93 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
  94 if test $ac_cv_type_uchar = yes; then
  95   AC_DEFINE(HAVE_UCHAR, 1,
  96   [Define if <sys/types.h> defines \`uchar'.])
  97 fi
  98
  99 # g++ on Solaris 10+ defines _XOPEN_SOURCE=600, which exposes a different
 100 # iconv() prototype.
 101 AC_LANG_PUSH([C++])
 102 AM_ICONV
 103 AC_LANG_POP([C++])
 104
 105 # More defines and substitutions.
 106 PACKAGE="$PACKAGE_TARNAME"
 107 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Define to the name of this package.])
 108 AC_SUBST(PACKAGE)
 109
 110 if test "x$enable_nls" != xno; then
 111   USED_CATALOGS='$(CATALOGS)'
 112 else
 113   USED_CATALOGS=
 114 fi
 115 AC_SUBST(USED_CATALOGS)
 116
 117 AC_ARG_ENABLE(maintainer-mode,
 118 [  --enable-maintainer-mode enable rules only needed by maintainers],,
 119 enable_maintainer_mode=no)
 120
 121 if test "x$enable_maintainer_mode" = xno; then
 122   MAINT='#'
 123 else
 124   MAINT=
 125 fi
 126 AC_SUBST(MAINT)
 127
 128 # Enable expensive internal checks
 129 is_release=
 130 if test -f $srcdir/../gcc/DEV-PHASE \
 131    && test x"`cat $srcdir/../gcc/DEV-PHASE`" != xexperimental; then
 132   is_release=yes
 133 fi
 134
 135 AC_ARG_ENABLE(checking,
 136 [AS_HELP_STRING([[--enable-checking[=LIST]]],
 137                 [enable expensive run-time checks.  With LIST,
 138                  enable only specific categories of checks.
 139                  Categories are: yes,no,all,none,release.
 140                  Flags are: misc,valgrind or other strings])],
 141 [ac_checking_flags="${enableval}"],[
 142 # Determine the default checks.
 143 if test x$is_release = x ; then
 144   ac_checking_flags=yes
 145 else
 146   ac_checking_flags=release
 147 fi])
 148 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 149 for check in release $ac_checking_flags
 150 do
 151         case $check in
 152         # these set all the flags to specific states
 153         yes|all) ac_checking=1 ; ac_valgrind_checking= ;;
 154         no|none|release) ac_checking= ; ac_valgrind_checking= ;;
 155         # these enable particular checks
 156         misc) ac_checking=1 ;;
 157         valgrind) ac_valgrind_checking=1 ;;
 158         # accept
 159         *) ;;
 160         esac
 161 done
 162 IFS="$ac_save_IFS"
 163
 164 if test x$ac_checking != x ; then
 165   AC_DEFINE(ENABLE_CHECKING, 1,
 166 [Define if you want more run-time sanity checks.])
 167 fi
 168
 169 if test x$ac_valgrind_checking != x ; then
 170   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 171 [Define if you want to workaround valgrind (a memory checker) warnings about
 172  possible memory leaks because of libcpp use of interior pointers.])
 173 fi
 174
 175 AC_ARG_ENABLE(canonical-system-headers,
 176 [  --enable-canonical-system-headers
 177                           enable or disable system headers canonicalization],
 178 [],
 179 enable_canonical_system_headers=yes)
 180 if test $enable_canonical_system_headers != no; then
 181   AC_DEFINE(ENABLE_CANONICAL_SYSTEM_HEADERS,
 182             1, [Define to enable system headers canonicalization.])
 183 fi
 184
 185 case $target in
 186   i?86-* | x86_64-*)
 187     AC_TRY_COMPILE([], [asm ("pcmpestri %0, %%xmm0, %%xmm1" : : "i"(0))],
 188       [AC_DEFINE([HAVE_SSE4], [1],
 189                  [Define to 1 if you can assemble SSE4 insns.])])
 190 esac
 191
 192 # Enable --enable-host-shared.
 193 AC_ARG_ENABLE(host-shared,
 194 [AS_HELP_STRING([--enable-host-shared],
 195                 [build host code as shared libraries])],
 196 [PICFLAG=-fPIC], [PICFLAG=])
 197 AC_SUBST(PICFLAG)
 198
 199 # Output.
 200
 201 AC_CONFIG_HEADERS(config.h:config.in, [echo timestamp > stamp-h1])
 202 AC_CONFIG_FILES(Makefile)
 203 AC_OUTPUT