gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.64)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 AC_PROG_CXX
 280 ACX_PROG_GNAT([-I"$srcdir"/ada])
 281
 282 # autoconf is lame and doesn't give us any substitution variable for this.
 283 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 284   NO_MINUS_C_MINUS_O=yes
 285 else
 286   OUTPUT_OPTION='-o $@'
 287 fi
 288 AC_SUBST(NO_MINUS_C_MINUS_O)
 289 AC_SUBST(OUTPUT_OPTION)
 290
 291 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 292 # optimizations to be activated explicitly by the toplevel.
 293 case "$CC" in
 294   */prev-gcc/xgcc*) ;;
 295   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 296 esac
 297 AC_SUBST(CFLAGS)
 298
 299 # -------------------------
 300 # Check C compiler features
 301 # -------------------------
 302
 303 AC_USE_SYSTEM_EXTENSIONS
 304 AC_PROG_CPP
 305 AC_C_INLINE
 306
 307 # sizeof(char) is 1 by definition.
 308 AC_CHECK_SIZEOF(void *)
 309 AC_CHECK_SIZEOF(short)
 310 AC_CHECK_SIZEOF(int)
 311 AC_CHECK_SIZEOF(long)
 312 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 313 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 314 GCC_STDINT_TYPES
 315
 316 # ---------------------
 317 # Warnings and checking
 318 # ---------------------
 319
 320 # Check $CC warning features (if it's GCC).
 321 # We want to use -pedantic, but we don't want warnings about
 322 # * 'long long'
 323 # * variadic macros
 324 # * overlong strings
 325 # So, we only use -pedantic if we can disable those warnings.
 326
 327 ACX_PROG_CC_WARNING_OPTS(
 328         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wcast-qual])), [loose_warn])
 329 ACX_PROG_CC_WARNING_OPTS(
 330         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
 331         [c_loose_warn])
 332 ACX_PROG_CC_WARNING_OPTS(
 333         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
 334 ACX_PROG_CC_WARNING_OPTS(
 335         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
 336 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 337         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 338                        [-Wno-overlength-strings])), [strict_warn])
 339 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 340
 341 # The above macros do nothing if the compiler is not GCC.  However, the
 342 # Makefile has more goo to add other flags, so these variables are used
 343 # to enable warnings only for GCC.
 344 warn_cflags=
 345 warn_cxxflags=
 346 if test "x$GCC" = "xyes"; then
 347   warn_cflags='$(GCC_WARN_CFLAGS)'
 348   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
 349 fi
 350 AC_SUBST(warn_cflags)
 351 AC_SUBST(warn_cxxflags)
 352
 353 # Enable expensive internal checks
 354 is_release=
 355 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 356   is_release=yes
 357 fi
 358
 359 AC_ARG_ENABLE(checking,
 360 [  --enable-checking[=LIST]
 361                           enable expensive run-time checks.  With LIST,
 362                           enable only specific categories of checks.
 363                           Categories are: yes,no,all,none,release.
 364                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
 365                           rtlflag,rtl,runtime,tree,valgrind,types.],
 366 [ac_checking_flags="${enableval}"],[
 367 # Determine the default checks.
 368 if test x$is_release = x ; then
 369   ac_checking_flags=yes
 370 else
 371   ac_checking_flags=release
 372 fi])
 373 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 374 for check in release $ac_checking_flags
 375 do
 376         case $check in
 377         # these set all the flags to specific states
 378         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 379                         ac_fold_checking= ; ac_gc_checking=1 ;
 380                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 381                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 382                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 383                         ac_types_checking=1 ;;
 384         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 385                         ac_fold_checking= ; ac_gc_checking= ;
 386                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 387                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 388                         ac_tree_checking= ; ac_valgrind_checking= ;
 389                         ac_types_checking= ;;
 390         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 391                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 392                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 393                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 394                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 395                         ac_types_checking=1 ;;
 396         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 397                         ac_fold_checking= ; ac_gc_checking= ;
 398                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 399                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 400                         ac_tree_checking= ; ac_valgrind_checking= ;
 401                         ac_types_checking= ;;
 402         # these enable particular checks
 403         assert)         ac_assert_checking=1 ;;
 404         df)             ac_df_checking=1 ;;
 405         fold)           ac_fold_checking=1 ;;
 406         gc)             ac_gc_checking=1 ;;
 407         gcac)           ac_gc_always_collect=1 ;;
 408         gimple)         ac_gimple_checking=1 ;;
 409         misc)           ac_checking=1 ;;
 410         rtl)            ac_rtl_checking=1 ;;
 411         rtlflag)        ac_rtlflag_checking=1 ;;
 412         runtime)        ac_runtime_checking=1 ;;
 413         tree)           ac_tree_checking=1 ;;
 414         types)          ac_types_checking=1 ;;
 415         valgrind)       ac_valgrind_checking=1 ;;
 416         *)      AC_MSG_ERROR(unknown check category $check) ;;
 417         esac
 418 done
 419 IFS="$ac_save_IFS"
 420
 421 nocommon_flag=""
 422 if test x$ac_checking != x ; then
 423   AC_DEFINE(ENABLE_CHECKING, 1,
 424 [Define if you want more run-time sanity checks.  This one gets a grab
 425    bag of miscellaneous but relatively cheap checks.])
 426   nocommon_flag=-fno-common
 427 fi
 428 AC_SUBST(nocommon_flag)
 429 if test x$ac_df_checking != x ; then
 430   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 431 [Define if you want more run-time sanity checks for dataflow.])
 432 fi
 433 if test x$ac_assert_checking != x ; then
 434   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 435 [Define if you want assertions enabled.  This is a cheap check.])
 436 fi
 437 if test x$ac_gimple_checking != x ; then
 438   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 439 [Define if you want operations on GIMPLE (the basic data structure of
 440 the high-level optimizers) to be checked for dynamic type safety at
 441 runtime.  This is moderately expensive.])
 442 fi
 443 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 444 if test x$ac_runtime_checking != x ; then
 445   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 446 [Define if you want runtime assertions enabled.  This is a cheap check.])
 447 fi
 448 if test x$ac_tree_checking != x ; then
 449   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 450 [Define if you want all operations on trees (the basic data
 451    structure of the front ends) to be checked for dynamic type safety
 452    at runtime.  This is moderately expensive.  The tree browser debugging
 453    routines will also be enabled by this option.
 454    ])
 455   TREEBROWSER=tree-browser.o
 456 fi
 457 if test x$ac_types_checking != x ; then
 458   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 459 [Define if you want all gimple types to be verified after gimplifiation.
 460    This is cheap.
 461    ])
 462 fi
 463 AC_SUBST(TREEBROWSER)
 464 if test x$ac_rtl_checking != x ; then
 465   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 466 [Define if you want all operations on RTL (the basic data structure
 467    of the optimizer and back end) to be checked for dynamic type safety
 468    at runtime.  This is quite expensive.])
 469 fi
 470 if test x$ac_rtlflag_checking != x ; then
 471   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 472 [Define if you want RTL flag accesses to be checked against the RTL
 473    codes that are supported for each access macro.  This is relatively
 474    cheap.])
 475 fi
 476 if test x$ac_gc_checking != x ; then
 477   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 478 [Define if you want the garbage collector to do object poisoning and
 479    other memory allocation checks.  This is quite expensive.])
 480 fi
 481 if test x$ac_gc_always_collect != x ; then
 482   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 483 [Define if you want the garbage collector to operate in maximally
 484    paranoid mode, validating the entire heap and collecting garbage at
 485    every opportunity.  This is extremely expensive.])
 486 fi
 487 if test x$ac_fold_checking != x ; then
 488   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 489 [Define if you want fold checked that it never destructs its argument.
 490    This is quite expensive.])
 491 fi
 492 valgrind_path_defines=
 493 valgrind_command=
 494
 495 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 496 dnl # an if statement.  This was the source of very frustrating bugs
 497 dnl # in converting to autoconf 2.5x!
 498 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 499
 500 if test x$ac_valgrind_checking != x ; then
 501   # It is certainly possible that there's valgrind but no valgrind.h.
 502   # GCC relies on making annotations so we must have both.
 503   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 504   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 505     [[#include <valgrind/memcheck.h>
 506 #ifndef VALGRIND_DISCARD
 507 #error VALGRIND_DISCARD not defined
 508 #endif]])],
 509   [gcc_cv_header_valgrind_memcheck_h=yes],
 510   [gcc_cv_header_valgrind_memcheck_h=no])
 511   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 512   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 513   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 514     [[#include <memcheck.h>
 515 #ifndef VALGRIND_DISCARD
 516 #error VALGRIND_DISCARD not defined
 517 #endif]])],
 518   [gcc_cv_header_memcheck_h=yes],
 519   [gcc_cv_header_memcheck_h=no])
 520   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 521   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 522         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 523   if test "x$valgrind_path" = "x" \
 524     || (test $have_valgrind_h = no \
 525         && test $gcc_cv_header_memcheck_h = no \
 526         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 527         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 528   fi
 529   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 530   valgrind_command="$valgrind_path -q"
 531   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 532 [Define if you want to run subprograms and generated programs
 533    through valgrind (a memory checker).  This is extremely expensive.])
 534   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 535     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 536         [Define if valgrind's valgrind/memcheck.h header is installed.])
 537   fi
 538   if test $gcc_cv_header_memcheck_h = yes; then
 539     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 540         [Define if valgrind's memcheck.h header is installed.])
 541   fi
 542 fi
 543 AC_SUBST(valgrind_path_defines)
 544 AC_SUBST(valgrind_command)
 545
 546 # Enable code coverage collection
 547 AC_ARG_ENABLE(coverage,
 548 [  --enable-coverage[=LEVEL]
 549                           enable compiler's code coverage collection.
 550                           Use to measure compiler performance and locate
 551                           unused parts of the compiler. With LEVEL, specify
 552                           optimization. Values are opt, noopt,
 553                           default is noopt],
 554 [case "${enableval}" in
 555   yes|noopt)
 556     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 557     ;;
 558   opt)
 559     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 560     ;;
 561   no)
 562     # a.k.a. --disable-coverage
 563     coverage_flags=""
 564     ;;
 565   *)
 566     AC_MSG_ERROR(unknown coverage setting $enableval)
 567     ;;
 568 esac],
 569 [coverage_flags=""])
 570 AC_SUBST(coverage_flags)
 571
 572 AC_ARG_ENABLE(gather-detailed-mem-stats,
 573 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 574 [enable_gather_detailed_mem_stats=no])
 575 if test x$enable_gather_detailed_mem_stats = xyes ; then
 576   AC_DEFINE(GATHER_STATISTICS, 1,
 577         [Define to enable detailed memory allocation stats gathering.])
 578 fi
 579
 580 # -------------------------------
 581 # Miscenalleous configure options
 582 # -------------------------------
 583
 584 # See if we are building gcc with C++.
 585 AC_ARG_ENABLE(build-with-cxx,
 586 [  --enable-build-with-cxx build with C++ compiler instead of C compiler],
 587 ENABLE_BUILD_WITH_CXX=$enableval,
 588 ENABLE_BUILD_WITH_CXX=no)
 589 AC_SUBST(ENABLE_BUILD_WITH_CXX)
 590
 591 # With stabs
 592 AC_ARG_WITH(stabs,
 593 [  --with-stabs            arrange to use stabs instead of host debug format],
 594 stabs="$with_stabs",
 595 stabs=no)
 596
 597 # Determine whether or not multilibs are enabled.
 598 AC_ARG_ENABLE(multilib,
 599 [  --enable-multilib       enable library support for multiple ABIs],
 600 [], [enable_multilib=yes])
 601 AC_SUBST(enable_multilib)
 602
 603 # Enable __cxa_atexit for C++.
 604 AC_ARG_ENABLE(__cxa_atexit,
 605 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 606 [], [])
 607
 608 # Enable C extension for decimal float if target supports it.
 609 AC_ARG_ENABLE(decimal-float,
 610 [  --enable-decimal-float={no,yes,bid,dpd}
 611                         enable decimal float extension to C.  Selecting 'bid'
 612                         or 'dpd' choses which decimal floating point format
 613                         to use],
 614 [
 615   case $enable_decimal_float in
 616     yes | no | bid | dpd) ;;
 617     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 618 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 619   esac
 620 ],
 621 [
 622   case $target in
 623     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 624       enable_decimal_float=yes
 625       ;;
 626     *)
 627       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 628       enable_decimal_float=no
 629       ;;
 630   esac
 631 ])
 632
 633 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 634 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 635 [Define to 1 to enable decimal float extension to C.])
 636
 637 # x86's use BID format instead of DPD
 638 case x$enable_decimal_float in
 639   xyes)
 640     case $target in
 641       i?86*-*-linux* | x86_64*-*-linux*)
 642         enable_decimal_float=bid
 643         ;;
 644       *)
 645         enable_decimal_float=dpd
 646         ;;
 647     esac
 648     ;;
 649   xno)
 650     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 651     # dependency on libdecnumber.
 652     enable_decimal_float=dpd
 653     ;;
 654 esac
 655 AC_SUBST(enable_decimal_float)
 656
 657 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 658 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 659 [Define to 1 to specify that we are using the BID decimal floating
 660 point format instead of DPD])
 661
 662 # Enable C extension for fixed-point arithmetic.
 663 AC_ARG_ENABLE(fixed-point,
 664 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 665 [
 666 ],
 667 [
 668   case $target in
 669     mips*-*-*)
 670       case $host in
 671         mips*-sgi-irix*)
 672           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
 673           enable_fixed_point=no
 674           ;;
 675         *)
 676           enable_fixed_point=yes
 677           ;;
 678       esac
 679       ;;
 680     *)
 681       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 682       enable_fixed_point=no
 683       ;;
 684   esac
 685 ])
 686 AC_SUBST(enable_fixed_point)
 687
 688 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 689 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 690 [Define to 1 to enable fixed-point arithmetic extension to C.])
 691
 692 # Enable threads
 693 # Pass with no value to take the default
 694 # Pass with a value to specify a thread package
 695 AC_ARG_ENABLE(threads,
 696 [  --enable-threads        enable thread usage for target GCC
 697   --enable-threads=LIB    use LIB thread package for target GCC],,
 698 [enable_threads=''])
 699
 700 AC_ARG_ENABLE(tls,
 701 [  --enable-tls            enable or disable generation of tls code
 702                           overriding the assembler check for tls support],
 703 [
 704   case $enable_tls in
 705     yes | no) ;;
 706     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 707 Valid choices are 'yes' and 'no'.]) ;;
 708   esac
 709 ], [enable_tls=''])
 710
 711 AC_ARG_ENABLE(objc-gc,
 712 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 713                           the GNU Objective-C runtime],
 714 if test x$enable_objc_gc = xno; then
 715         objc_boehm_gc=''
 716 else
 717         objc_boehm_gc=1
 718 fi,
 719 objc_boehm_gc='')
 720
 721 AC_ARG_WITH(dwarf2,
 722 [  --with-dwarf2           force the default debug format to be DWARF 2],
 723 dwarf2="$with_dwarf2",
 724 dwarf2=no)
 725
 726 AC_ARG_ENABLE(shared,
 727 [  --disable-shared        don't provide a shared libgcc],
 728 [
 729   case $enable_shared in
 730   yes | no) ;;
 731   *)
 732     enable_shared=no
 733     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 734     for pkg in $enableval; do
 735       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 736         enable_shared=yes
 737       fi
 738     done
 739     IFS="$ac_save_ifs"
 740     ;;
 741   esac
 742 ], [enable_shared=yes])
 743 AC_SUBST(enable_shared)
 744
 745 AC_ARG_WITH(build-sysroot,
 746   [  --with-build-sysroot=sysroot
 747                           use sysroot as the system root during the build])
 748
 749 AC_ARG_WITH(sysroot,
 750 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 751 [
 752  case ${with_sysroot} in
 753  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 754  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 755  esac
 756
 757  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 758  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 759
 760  if test "x$prefix" = xNONE; then
 761   test_prefix=/usr/local
 762  else
 763   test_prefix=$prefix
 764  fi
 765  if test "x$exec_prefix" = xNONE; then
 766   test_exec_prefix=$test_prefix
 767  else
 768   test_exec_prefix=$exec_prefix
 769  fi
 770  case ${TARGET_SYSTEM_ROOT} in
 771  "${test_prefix}"|"${test_prefix}/"*|\
 772  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 773  '${prefix}'|'${prefix}/'*|\
 774  '${exec_prefix}'|'${exec_prefix}/'*)
 775    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 776    TARGET_SYSTEM_ROOT_DEFINE="$t"
 777    ;;
 778  esac
 779 ], [
 780  TARGET_SYSTEM_ROOT=
 781  TARGET_SYSTEM_ROOT_DEFINE=
 782  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 783 ])
 784 AC_SUBST(TARGET_SYSTEM_ROOT)
 785 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 786 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 787
 788 AC_ARG_WITH(specs,
 789   [AS_HELP_STRING([--with-specs=SPECS],
 790                   [add SPECS to driver command-line processing])],
 791   [CONFIGURE_SPECS=$withval],
 792   [CONFIGURE_SPECS=]
 793 )
 794 AC_SUBST(CONFIGURE_SPECS)
 795
 796 # Build with intermodule optimisations
 797 AC_ARG_ENABLE(intermodule,
 798 [  --enable-intermodule    build the compiler in one step],
 799 [case ${enable_intermodule} in
 800   yes) onestep="-onestep";;
 801   *) onestep="";;
 802 esac],
 803 [onestep=""])
 804 AC_SUBST(onestep)
 805
 806 ACX_PKGVERSION([GCC])
 807 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 808
 809 # Sanity check enable_languages in case someone does not run the toplevel
 810 # configure # script.
 811 AC_ARG_ENABLE(languages,
 812 [  --enable-languages=LIST specify which front-ends to build],
 813 [case ,${enable_languages}, in
 814        ,,|,yes,)
 815                 # go safe -- we cannot be much sure without the toplevel
 816                 # configure's
 817                 # analysis of which target libs are present and usable
 818                 enable_languages=c
 819                 ;;
 820          *,all,*)
 821                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 822                 ;;
 823         *,c,*)
 824                 ;;
 825         *)
 826                 enable_languages=c,${enable_languages}
 827                 ;;
 828 esac],
 829 [enable_languages=c])
 830
 831 AC_ARG_WITH(multilib-list,
 832 [  --with-multilib-list    Select multilibs (SH only)],
 833 :,
 834 with_multilib_list=default)
 835
 836 # -------------------------
 837 # Checks for other programs
 838 # -------------------------
 839
 840 AC_PROG_MAKE_SET
 841
 842 # Find some useful tools
 843 AC_PROG_AWK
 844 # We need awk to create options.c and options.h.
 845 # Bail out if it's missing.
 846 case ${AWK} in
 847   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 848 esac
 849
 850 gcc_AC_PROG_LN_S
 851 ACX_PROG_LN($LN_S)
 852 AC_PROG_RANLIB
 853 case "${host}" in
 854 *-*-darwin*)
 855   # By default, the Darwin ranlib will not treat common symbols as
 856   # definitions when  building the archive table of contents.  Other
 857   # ranlibs do that; pass an option to the Darwin ranlib that makes
 858   # it behave similarly.
 859   ranlib_flags="-c"
 860   ;;
 861 *)
 862   ranlib_flags=""
 863 esac
 864 AC_SUBST(ranlib_flags)
 865
 866 gcc_AC_PROG_INSTALL
 867
 868 # See if cmp has --ignore-initial.
 869 gcc_AC_PROG_CMP_IGNORE_INITIAL
 870
 871 # See if we have the mktemp command.
 872 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 873
 874 # See if makeinfo has been installed and is modern enough
 875 # that we can use it.
 876 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 877   [GNU texinfo.* \([0-9][0-9.]*\)],
 878   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 879 if test $gcc_cv_prog_makeinfo_modern = no; then
 880   AC_MSG_WARN([
 881 *** Makeinfo is missing or too old.
 882 *** Info documentation will not be built.])
 883   BUILD_INFO=
 884 else
 885   BUILD_INFO=info
 886 fi
 887 AC_SUBST(BUILD_INFO)
 888
 889 # Is pod2man recent enough to regenerate manpages?
 890 AC_MSG_CHECKING([for recent Pod::Man])
 891 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 892   AC_MSG_RESULT(yes)
 893   GENERATED_MANPAGES=generated-manpages
 894 else
 895   AC_MSG_RESULT(no)
 896   GENERATED_MANPAGES=
 897 fi
 898 AC_SUBST(GENERATED_MANPAGES)
 899
 900 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 901
 902 # How about lex?
 903 dnl Don't use AC_PROG_LEX; we insist on flex.
 904 dnl LEXLIB is not useful in gcc.
 905 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 906
 907 # Bison?
 908 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 909
 910 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 911 # check for build == host before using them.
 912
 913 # NM
 914 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 915   && test -d ../binutils ; then
 916   NM='$(objdir)/../binutils/nm-new'
 917 else
 918   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 919 fi
 920
 921 # AR
 922 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 923   && test -d ../binutils ; then
 924   AR='$(objdir)/../binutils/ar'
 925 else
 926   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 927 fi
 928
 929
 930 # --------------------
 931 # Checks for C headers
 932 # --------------------
 933
 934 # Need to reject headers which give warnings, so that the -Werror bootstrap
 935 # works later. *sigh*  This needs to come before all header checks.
 936 AC_PROG_CPP_WERROR
 937
 938 AC_HEADER_STDC
 939 AC_HEADER_TIME
 940 ACX_HEADER_STRING
 941 AC_HEADER_SYS_WAIT
 942 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 943                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 944                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 945                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 946
 947 # Check for thread headers.
 948 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 949 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 950
 951 # These tests can't be done till we know if we have limits.h.
 952 gcc_AC_C_CHAR_BIT
 953 AC_C_BIGENDIAN
 954
 955 # --------
 956 # UNSORTED
 957 # --------
 958
 959
 960 # These libraries may be used by collect2.
 961 # We may need a special search path to get them linked.
 962 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 963 [save_LIBS="$LIBS"
 964 for libs in '' -lld -lmld \
 965                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 966                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 967 do
 968         LIBS="$libs"
 969         AC_TRY_LINK_FUNC(ldopen,
 970                 [gcc_cv_collect2_libs="$libs"; break])
 971 done
 972 LIBS="$save_LIBS"
 973 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 974 case $gcc_cv_collect2_libs in
 975         "none required")        ;;
 976         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 977 esac
 978 AC_SUBST(COLLECT2_LIBS)
 979
 980 # When building Ada code on Alpha, we need exc_resume which is usually in
 981 # -lexc.  So test for it.
 982 save_LIBS="$LIBS"
 983 LIBS=
 984 AC_SEARCH_LIBS(exc_resume, exc)
 985 GNAT_LIBEXC="$LIBS"
 986 LIBS="$save_LIBS"
 987 AC_SUBST(GNAT_LIBEXC)
 988
 989 # Some systems put ldexp and frexp in libm instead of libc; assume
 990 # they're both in the same place.  jcf-dump needs them.
 991 save_LIBS="$LIBS"
 992 LIBS=
 993 AC_SEARCH_LIBS(ldexp, m)
 994 LDEXP_LIB="$LIBS"
 995 LIBS="$save_LIBS"
 996 AC_SUBST(LDEXP_LIB)
 997
 998 # Use <inttypes.h> only if it exists,
 999 # doesn't clash with <sys/types.h>, and declares intmax_t.
1000 AC_MSG_CHECKING(for inttypes.h)
1001 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1002 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1003 [[#include <sys/types.h>
1004 #include <inttypes.h>]],
1005   [[intmax_t i = -1;]])],
1006   [gcc_cv_header_inttypes_h=yes],
1007   [gcc_cv_header_inttypes_h=no])])
1008 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1009 if test $gcc_cv_header_inttypes_h = yes; then
1010   AC_DEFINE(HAVE_INTTYPES_H, 1,
1011         [Define if you have a working <inttypes.h> header file.])
1012 fi
1013
1014 dnl Disabled until we have a complete test for buggy enum bitfields.
1015 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1016
1017 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1018   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1019   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1020   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1021   putchar_unlocked putc_unlocked)
1022 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1023         sysconf strsignal getrusage nl_langinfo \
1024         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1025         gcc_UNLOCKED_FUNCS)
1026
1027 save_CPPFLAGS="$CPPFLAGS"
1028 save_LIBS="$LIBS"
1029 LIBS="$LIBS $LIBELFLIBS"
1030 AC_CHECK_FUNCS(elf_getshdrstrndx,,
1031   [AC_CHECK_FUNCS(elf_getshstrndx,
1032     [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1033 #include <libelf.h>
1034 int main()
1035 {
1036   return elf_getshstrndx (NULL, 0) == 0;
1037 }]])], AC_DEFINE(HAVE_ELF_GETSHSTRNDX_GABI, 1,
1038         [Define if elf_getshstrndx has gABI conformant return values.]))])]
1039   )
1040 LIBS="$save_LIBS"
1041 CPPFLAGS="$save_CPPFLAGS"
1042
1043 if test x$ac_cv_func_mbstowcs = xyes; then
1044   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1045 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1046 int main()
1047 {
1048   mbstowcs(0, "", 0);
1049   return 0;
1050 }]])],
1051     [gcc_cv_func_mbstowcs_works=yes],
1052     [gcc_cv_func_mbstowcs_works=no],
1053     [gcc_cv_func_mbstowcs_works=yes])])
1054   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1055     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1056   [Define this macro if mbstowcs does not crash when its
1057    first argument is NULL.])
1058   fi
1059 fi
1060
1061 AC_CHECK_TYPE(ssize_t, int)
1062 AC_CHECK_TYPE(caddr_t, char *)
1063
1064 gcc_AC_FUNC_MMAP_BLACKLIST
1065
1066 case "${host}" in
1067 *-*-*vms*)
1068   # Under VMS, vfork works very differently than on Unix. The standard test
1069   # won't work, and it isn't easily adaptable. It makes more sense to
1070   # just force it.
1071   ac_cv_func_vfork_works=yes
1072   ;;
1073 esac
1074 AC_FUNC_FORK
1075
1076 AM_ICONV
1077 # Until we have in-tree GNU iconv:
1078 LIBICONV_DEP=
1079 AC_SUBST(LIBICONV_DEP)
1080
1081 AM_LC_MESSAGES
1082
1083 AM_LANGINFO_CODESET
1084
1085 # We will need to find libiberty.h and ansidecl.h
1086 saved_CFLAGS="$CFLAGS"
1087 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1088 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1089         strsignal strstr strverscmp \
1090         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1091         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1092 #include "ansidecl.h"
1093 #include "system.h"])
1094
1095 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1096 #include "ansidecl.h"
1097 #include "system.h"
1098 #ifdef HAVE_SYS_RESOURCE_H
1099 #include <sys/resource.h>
1100 #endif
1101 ])
1102
1103 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1104 #include "ansidecl.h"
1105 #include "system.h"
1106 #ifdef HAVE_SYS_RESOURCE_H
1107 #include <sys/resource.h>
1108 #endif
1109 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1110 [Define to `long' if <sys/resource.h> doesn't define.])])
1111
1112 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1113 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1114 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1115 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1116 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1117 #include "ansidecl.h"
1118 #include "system.h"
1119 #ifdef HAVE_LDFCN_H
1120 #undef FREAD
1121 #undef FWRITE
1122 #include <ldfcn.h>
1123 #endif
1124 ])
1125
1126 gcc_AC_CHECK_DECLS(times, , ,[
1127 #include "ansidecl.h"
1128 #include "system.h"
1129 #ifdef HAVE_SYS_TIMES_H
1130 #include <sys/times.h>
1131 #endif
1132 ])
1133
1134 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1135 #include "ansidecl.h"
1136 #include "system.h"
1137 #include <signal.h>
1138 ])
1139
1140 # More time-related stuff.
1141 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1142 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1143 #include "ansidecl.h"
1144 #include "system.h"
1145 #ifdef HAVE_SYS_TIMES_H
1146 #include <sys/times.h>
1147 #endif
1148 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1149 if test $ac_cv_struct_tms = yes; then
1150   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1151   [Define if <sys/times.h> defines struct tms.])
1152 fi
1153
1154 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1155 # revisit after autoconf 2.50.
1156 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1157 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1158 #include "ansidecl.h"
1159 #include "system.h"
1160 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1161 if test $gcc_cv_type_clock_t = yes; then
1162   AC_DEFINE(HAVE_CLOCK_T, 1,
1163   [Define if <time.h> defines clock_t.])
1164 fi
1165
1166 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1167 CFLAGS="$saved_CFLAGS"
1168
1169 gcc_AC_INITFINI_ARRAY
1170
1171 # mkdir takes a single argument on some systems.
1172 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1173
1174 # File extensions
1175 manext='.1'
1176 objext='.o'
1177 AC_SUBST(manext)
1178 AC_SUBST(objext)
1179
1180 # With Setjmp/Longjmp based exception handling.
1181 AC_ARG_ENABLE(sjlj-exceptions,
1182 [  --enable-sjlj-exceptions
1183                           arrange to use setjmp/longjmp exception handling],
1184 [case $target in
1185   *-*-hpux10*)
1186     if test $enableval != yes; then
1187       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1188       enableval=yes
1189     fi
1190     ;;
1191 esac
1192 force_sjlj_exceptions=yes],
1193 [case $target in
1194   *-*-hpux10*)
1195     force_sjlj_exceptions=yes
1196     enableval=yes
1197     ;;
1198   *)
1199     force_sjlj_exceptions=no
1200     ;;
1201 esac])
1202 if test $force_sjlj_exceptions = yes; then
1203   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1204   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1205     [Define 0/1 to force the choice for exception handling model.])
1206 fi
1207
1208 # For platforms with the unwind ABI which includes an unwind library,
1209 # libunwind, we can choose to use the system libunwind.
1210 # config.gcc also contains tests of with_system_libunwind.
1211 GCC_CHECK_UNWIND_GETIPINFO
1212
1213 # --------------------------------------------------------
1214 # Build, host, and target specific configuration fragments
1215 # --------------------------------------------------------
1216
1217 # Collect build-machine-specific information.
1218 . ${srcdir}/config.build
1219
1220 # Collect host-machine-specific information.
1221 . ${srcdir}/config.host
1222
1223 target_gtfiles=
1224
1225 # Collect target-machine-specific information.
1226 . ${srcdir}/config.gcc
1227
1228 extra_objs="${host_extra_objs} ${extra_objs}"
1229 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1230
1231 # Default the target-machine variables that were not explicitly set.
1232 if test x"$tm_file" = x
1233 then tm_file=$cpu_type/$cpu_type.h; fi
1234
1235 if test x"$extra_headers" = x
1236 then extra_headers=; fi
1237
1238 if test x$md_file = x
1239 then md_file=$cpu_type/$cpu_type.md; fi
1240
1241 if test x$out_file = x
1242 then out_file=$cpu_type/$cpu_type.c; fi
1243
1244 if test x"$tmake_file" = x
1245 then tmake_file=$cpu_type/t-$cpu_type
1246 fi
1247
1248 if test x"$dwarf2" = xyes
1249 then tm_file="$tm_file tm-dwarf2.h"
1250 fi
1251
1252 # Say what files are being used for the output code and MD file.
1253 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1254 echo "Using \`$srcdir/config/$md_file' as machine description file."
1255
1256 # If any of the xm_file variables contain nonexistent files, warn
1257 # about them and drop them.
1258
1259 bx=
1260 for x in $build_xm_file; do
1261   if    test -f $srcdir/config/$x
1262   then      bx="$bx $x"
1263   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1264   fi
1265 done
1266 build_xm_file="$bx"
1267
1268 hx=
1269 for x in $host_xm_file; do
1270   if    test -f $srcdir/config/$x
1271   then      hx="$hx $x"
1272   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1273   fi
1274 done
1275 host_xm_file="$hx"
1276
1277 tx=
1278 for x in $xm_file; do
1279   if    test -f $srcdir/config/$x
1280   then      tx="$tx $x"
1281   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1282   fi
1283 done
1284 xm_file="$tx"
1285
1286 count=a
1287 for f in $tm_file; do
1288         count=${count}x
1289 done
1290 if test $count = ax; then
1291         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1292 else
1293         echo "Using the following target machine macro files:"
1294         for f in $tm_file; do
1295                 echo "  $srcdir/config/$f"
1296         done
1297 fi
1298
1299 if test x$need_64bit_hwint = xyes; then
1300         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1301 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1302 fi
1303
1304 if test x$use_long_long_for_widest_fast_int = xyes; then
1305         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1306 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1307 efficiently supported by the host hardware.])
1308 fi
1309
1310 count=a
1311 for f in $host_xm_file; do
1312         count=${count}x
1313 done
1314 if test $count = a; then
1315         :
1316 elif test $count = ax; then
1317         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1318 else
1319         echo "Using the following host machine macro files:"
1320         for f in $host_xm_file; do
1321                 echo "  $srcdir/config/$f"
1322         done
1323 fi
1324 echo "Using ${out_host_hook_obj} for host machine hooks."
1325
1326 if test "$host_xm_file" != "$build_xm_file"; then
1327         count=a
1328         for f in $build_xm_file; do
1329                 count=${count}x
1330         done
1331         if test $count = a; then
1332                 :
1333         elif test $count = ax; then
1334                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1335         else
1336                 echo "Using the following build machine macro files:"
1337                 for f in $build_xm_file; do
1338                         echo "  $srcdir/config/$f"
1339                 done
1340         fi
1341 fi
1342
1343 case ${host} in
1344   powerpc*-*-darwin*)
1345     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1346       gcc_cv_mcontext_underscores,
1347       AC_COMPILE_IFELSE([
1348 #include <sys/cdefs.h>
1349 #include <sys/signal.h>
1350 #include <ucontext.h>
1351 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1352 ],
1353         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1354       if test $gcc_cv_mcontext_underscores = yes; then
1355         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1356           [mcontext_t fields start with __])
1357       fi
1358     ;;
1359 esac
1360
1361 # ---------
1362 # Threading
1363 # ---------
1364
1365 # Check if a valid thread package
1366 case ${enable_threads} in
1367   "" | no)
1368     # No threads
1369     target_thread_file='single'
1370     ;;
1371   yes)
1372     # default
1373     target_thread_file='single'
1374     ;;
1375   aix | dce | gnat | irix | posix | posix95 | rtems | \
1376   single | solaris | vxworks | win32 | mipssde)
1377     target_thread_file=${enable_threads}
1378     ;;
1379   *)
1380     echo "${enable_threads} is an unknown thread package" 1>&2
1381     exit 1
1382     ;;
1383 esac
1384
1385 if test x${thread_file} = x; then
1386   # No thread file set by target-specific clauses in config.gcc,
1387   # so use file chosen by default logic above
1388   thread_file=${target_thread_file}
1389 fi
1390
1391 # Make gthr-default.h if we have a thread file.
1392 gthread_flags=
1393 if test $thread_file != single; then
1394   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1395   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1396     rm -f gthr-default.h-t
1397   else
1398     mv -f gthr-default.h-t gthr-default.h
1399   fi
1400   gthread_flags=-DHAVE_GTHR_DEFAULT
1401 fi
1402 AC_SUBST(gthread_flags)
1403
1404 # --------
1405 # UNSORTED
1406 # --------
1407
1408 use_cxa_atexit=no
1409 if test x$enable___cxa_atexit = xyes || \
1410    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1411   if test x$host = x$target; then
1412     case $host in
1413       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1414       # keyed to flag_use_cxa_atexit
1415       *-*-mingw32*)
1416         use_cxa_atexit=yes
1417         ;;
1418       *)
1419         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1420           [echo "__cxa_atexit can't be enabled on this target"])
1421         ;;
1422     esac
1423   else
1424     # We can't check for __cxa_atexit when building a cross, so assume
1425     # it is available
1426     use_cxa_atexit=yes
1427   fi
1428   if test x$use_cxa_atexit = xyes; then
1429     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1430       [Define if you want to use __cxa_atexit, rather than atexit, to
1431       register C++ destructors for local statics and global objects.
1432       This is essential for fully standards-compliant handling of
1433       destructors, but requires __cxa_atexit in libc.])
1434   fi
1435 fi
1436
1437 # Look for a file containing extra machine modes.
1438 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1439   extra_modes_file='$(srcdir)'/config/${extra_modes}
1440   AC_SUBST(extra_modes_file)
1441   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1442   [Define to the name of a file containing a list of extra machine modes
1443    for this architecture.])
1444 fi
1445
1446 # Convert extra_options into a form suitable for Makefile use.
1447 extra_opt_files=
1448 for f in $extra_options; do
1449   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1450 done
1451 AC_SUBST(extra_opt_files)
1452
1453 # auto-host.h is the file containing items generated by autoconf and is
1454 # the first file included by config.h.
1455 # If host=build, it is correct to have bconfig include auto-host.h
1456 # as well.  If host!=build, we are in error and need to do more
1457 # work to find out the build config parameters.
1458 if test x$host = x$build
1459 then
1460         build_auto=auto-host.h
1461 else
1462         # We create a subdir, then run autoconf in the subdir.
1463         # To prevent recursion we set host and build for the new
1464         # invocation of configure to the build for this invocation
1465         # of configure.
1466         tempdir=build.$$
1467         rm -rf $tempdir
1468         mkdir $tempdir
1469         cd $tempdir
1470         case ${srcdir} in
1471         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1472         *) realsrcdir=../${srcdir};;
1473         esac
1474         saved_CFLAGS="${CFLAGS}"
1475         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1476         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1477         ${realsrcdir}/configure \
1478                 --enable-languages=${enable_languages-all} \
1479                 --target=$target_alias --host=$build_alias --build=$build_alias
1480         CFLAGS="${saved_CFLAGS}"
1481
1482         # We just finished tests for the build machine, so rename
1483         # the file auto-build.h in the gcc directory.
1484         mv auto-host.h ../auto-build.h
1485         cd ..
1486         rm -rf $tempdir
1487         build_auto=auto-build.h
1488 fi
1489 AC_SUBST(build_subdir)
1490
1491 tm_file="${tm_file} defaults.h"
1492 tm_p_file="${tm_p_file} tm-preds.h"
1493 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1494 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1495 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1496 # put this back in temporarily.
1497 xm_file="auto-host.h ansidecl.h ${xm_file}"
1498
1499 # --------
1500 # UNSORTED
1501 # --------
1502
1503 changequote(,)dnl
1504 # Compile in configure arguments.
1505 if test -f configargs.h ; then
1506         # Being re-configured.
1507         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1508         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1509 else
1510         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1511 fi
1512
1513 # Double all backslashes and backslash all quotes to turn
1514 # gcc_config_arguments into a C string.
1515 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1516 $gcc_config_arguments
1517 EOF
1518 gcc_config_arguments_str=`cat conftest.out`
1519 rm -f conftest.out
1520
1521 cat > configargs.h <<EOF
1522 /* Generated automatically. */
1523 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1524 static const char thread_model[] = "$thread_file";
1525
1526 static const struct {
1527   const char *name, *value;
1528 } configure_default_options[] = $configure_default_options;
1529 EOF
1530 changequote([,])dnl
1531
1532 changequote(,)dnl
1533 gcc_BASEVER=`cat $srcdir/BASE-VER`
1534 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1535 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1536 if test -f $srcdir/REVISION ; then
1537         gcc_REVISION=`cat $srcdir/REVISION`
1538 else
1539         gcc_REVISION=""
1540 fi
1541 cat > plugin-version.h <<EOF
1542 #include "configargs.h"
1543
1544 static char basever[] = "$gcc_BASEVER";
1545 static char datestamp[] = "$gcc_DATESTAMP";
1546 static char devphase[] = "$gcc_DEVPHASE";
1547 static char revision[] = "$gcc_REVISION";
1548
1549 /* FIXME plugins: We should make the version information more precise.
1550    One way to do is to add a checksum. */
1551
1552 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1553                                                 devphase, revision,
1554                                                 configuration_arguments};
1555 EOF
1556 changequote([,])dnl
1557
1558 # Internationalization
1559 ZW_GNU_GETTEXT_SISTER_DIR
1560
1561 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1562 # -liconv on the link line twice.
1563 case "$LIBINTL" in *$LIBICONV*)
1564         LIBICONV= ;;
1565 esac
1566
1567 AC_ARG_ENABLE(secureplt,
1568 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1569 [], [])
1570
1571 AC_ARG_ENABLE(leading-mingw64-underscores,
1572   AS_HELP_STRING([--enable-leading-mingw64-underscores],
1573                  [Enable leading underscores on 64 bit mingw targets]),
1574   [],[])
1575 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
1576   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
1577     [Define if we should use leading underscore on 64 bit mingw targets])])
1578
1579 AC_ARG_ENABLE(cld,
1580 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1581 [enable_cld=no])
1582
1583 # Windows32 Registry support for specifying GCC installation paths.
1584 AC_ARG_ENABLE(win32-registry,
1585 [  --disable-win32-registry
1586                           disable lookup of installation paths in the
1587                           Registry on Windows hosts
1588   --enable-win32-registry enable registry lookup (default)
1589   --enable-win32-registry=KEY
1590                           use KEY instead of GCC version as the last portion
1591                           of the registry key],,)
1592
1593 case $host_os in
1594   win32 | pe | cygwin* | mingw32* | uwin*)
1595     if test "x$enable_win32_registry" != xno; then
1596       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1597     fi
1598
1599     if test "x$enable_win32_registry" != xno; then
1600       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1601   [Define to 1 if installation paths should be looked up in the Windows
1602    Registry. Ignored on non-Windows hosts.])
1603
1604       if test "x$enable_win32_registry" != xyes \
1605          && test "x$enable_win32_registry" != x; then
1606         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1607   [Define to be the last component of the Windows registry key under which
1608    to look for installation paths.  The full key used will be
1609    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1610    The default is the GCC version number.])
1611       fi
1612     fi
1613   ;;
1614 esac
1615
1616 # Get an absolute path to the GCC top-level source directory
1617 holddir=`${PWDCMD-pwd}`
1618 cd $srcdir
1619 topdir=`${PWDCMD-pwd}`
1620 cd $holddir
1621
1622 # Conditionalize the makefile for this host machine.
1623 xmake_file=
1624 for f in ${host_xmake_file}
1625 do
1626         if test -f ${srcdir}/config/$f
1627         then
1628                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1629         fi
1630 done
1631
1632 # Conditionalize the makefile for this target machine.
1633 tmake_file_=
1634 for f in ${tmake_file}
1635 do
1636         if test -f ${srcdir}/config/$f
1637         then
1638                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1639         fi
1640 done
1641 tmake_file="${tmake_file_}"
1642
1643 out_object_file=`basename $out_file .c`.o
1644
1645 tm_file_list="options.h"
1646 tm_include_list="options.h"
1647 for f in $tm_file; do
1648   case $f in
1649     ./* )
1650        f=`echo $f | sed 's/^..//'`
1651        tm_file_list="${tm_file_list} $f"
1652        tm_include_list="${tm_include_list} $f"
1653        ;;
1654     defaults.h )
1655        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1656        tm_include_list="${tm_include_list} $f"
1657        ;;
1658     * )
1659        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1660        tm_include_list="${tm_include_list} config/$f"
1661        ;;
1662   esac
1663 done
1664
1665 tm_p_file_list=
1666 tm_p_include_list=
1667 for f in $tm_p_file; do
1668   case $f in
1669     tm-preds.h )
1670        tm_p_file_list="${tm_p_file_list} $f"
1671        tm_p_include_list="${tm_p_include_list} $f"
1672        ;;
1673     * )
1674        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1675        tm_p_include_list="${tm_p_include_list} config/$f"
1676   esac
1677 done
1678
1679 xm_file_list=
1680 xm_include_list=
1681 for f in $xm_file; do
1682   case $f in
1683     ansidecl.h )
1684        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1685        xm_include_list="${xm_include_list} $f"
1686        ;;
1687     auto-host.h )
1688        xm_file_list="${xm_file_list} $f"
1689        xm_include_list="${xm_include_list} $f"
1690        ;;
1691     * )
1692        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1693        xm_include_list="${xm_include_list} config/$f"
1694        ;;
1695   esac
1696 done
1697
1698 host_xm_file_list=
1699 host_xm_include_list=
1700 for f in $host_xm_file; do
1701   case $f in
1702     ansidecl.h )
1703        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1704        host_xm_include_list="${host_xm_include_list} $f"
1705        ;;
1706     auto-host.h )
1707        host_xm_file_list="${host_xm_file_list} $f"
1708        host_xm_include_list="${host_xm_include_list} $f"
1709        ;;
1710     * )
1711        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1712        host_xm_include_list="${host_xm_include_list} config/$f"
1713        ;;
1714   esac
1715 done
1716
1717 build_xm_file_list=
1718 for f in $build_xm_file; do
1719   case $f in
1720     ansidecl.h )
1721        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1722        build_xm_include_list="${build_xm_include_list} $f"
1723        ;;
1724     auto-build.h | auto-host.h )
1725        build_xm_file_list="${build_xm_file_list} $f"
1726        build_xm_include_list="${build_xm_include_list} $f"
1727        ;;
1728     * )
1729        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1730        build_xm_include_list="${build_xm_include_list} config/$f"
1731        ;;
1732   esac
1733 done
1734
1735 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1736 # cross-compiler which does not use the native headers and libraries.
1737 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1738 CROSS=                                          AC_SUBST(CROSS)
1739 ALL=all.internal                                AC_SUBST(ALL)
1740 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1741
1742 if test "x$with_build_sysroot" != x; then
1743   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1744 else
1745   # This value is used, even on a native system, because
1746   # CROSS_SYSTEM_HEADER_DIR is just
1747   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1748   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1749 fi
1750
1751 if test x$host != x$target
1752 then
1753         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1754         ALL=all.cross
1755         SYSTEM_HEADER_DIR=$build_system_header_dir
1756         case "$host","$target" in
1757         # Darwin crosses can use the host system's libraries and headers,
1758         # because of the fat library support.  Of course, it must be the
1759         # same version of Darwin on both sides.  Allow the user to
1760         # just say --target=foo-darwin without a version number to mean
1761         # "the version on this system".
1762             *-*-darwin*,*-*-darwin*)
1763                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1764                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1765                 if test $hostos = $targetos -o $targetos = darwin ; then
1766                     CROSS=
1767                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1768                     with_headers=yes
1769                 fi
1770                 ;;
1771
1772             i?86-*-*,x86_64-*-* \
1773             | powerpc*-*-*,powerpc64*-*-*)
1774                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1775         esac
1776 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1777         SYSTEM_HEADER_DIR=$build_system_header_dir
1778 fi
1779
1780 # If this is a cross-compiler that does not
1781 # have its own set of headers then define
1782 # inhibit_libc
1783
1784 # If this is using newlib, without having the headers available now,
1785 # then define inhibit_libc in LIBGCC2_CFLAGS.
1786 # This prevents libgcc2 from containing any code which requires libc
1787 # support.
1788 : ${inhibit_libc=false}
1789 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1790        test x$with_newlib = xyes ; } &&
1791      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1792        inhibit_libc=true
1793 fi
1794 AC_SUBST(inhibit_libc)
1795
1796 # When building gcc with a cross-compiler, we need to adjust things so
1797 # that the generator programs are still built with the native compiler.
1798 # Also, we cannot run fixincludes.
1799
1800 # These are the normal (build=host) settings:
1801 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1802 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1803 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1804 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1805
1806 # And these apply if build != host, or we are generating coverage data
1807 if test x$build != x$host || test "x$coverage_flags" != x
1808 then
1809     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1810     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1811 fi
1812
1813 # Expand extra_headers to include complete path.
1814 # This substitutes for lots of t-* files.
1815 extra_headers_list=
1816 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1817 for file in ${extra_headers} ; do
1818   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1819 done
1820
1821 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1822 if test x"$use_gcc_tgmath" = xyes
1823 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1824 fi
1825
1826 # Define collect2 in Makefile.
1827 case $host_can_use_collect2 in
1828   no) collect2= ;;
1829   *) collect2='collect2$(exeext)' ;;
1830 esac
1831 AC_SUBST([collect2])
1832
1833 # Add a definition of USE_COLLECT2 if system wants one.
1834 case $use_collect2 in
1835   no) use_collect2= ;;
1836   "") ;;
1837   *)
1838     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1839     xm_defines="${xm_defines} USE_COLLECT2"
1840     case $host_can_use_collect2 in
1841       no)
1842         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1843         ;;
1844     esac
1845     ;;
1846 esac
1847
1848 # ---------------------------
1849 # Assembler & linker features
1850 # ---------------------------
1851
1852 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1853 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1854 # However when ld-new is first executed from the build tree, libtool will
1855 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1856 # to the build tree.  While doing this we need to use the previous-stage
1857 # linker, or we have an infinite loop.  The presence of a shell script as
1858 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1859 # the gcc/collect-ld script.  So we need to know how libtool works, or
1860 # exec-tool will fail.
1861
1862 m4_defun([_LT_CONFIG_COMMANDS], [])
1863 AC_PROG_LIBTOOL
1864 AC_SUBST(objdir)
1865 AC_SUBST(enable_fast_install)
1866
1867 # Identify the assembler which will work hand-in-glove with the newly
1868 # built GCC, so that we can examine its features.  This is the assembler
1869 # which will be driven by the driver program.
1870 #
1871 # If build != host, and we aren't building gas in-tree, we identify a
1872 # build->target assembler and hope that it will have the same features
1873 # as the host->target assembler we'll be using.
1874 gcc_cv_gas_major_version=
1875 gcc_cv_gas_minor_version=
1876 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1877
1878 m4_pattern_allow([AS_FOR_TARGET])dnl
1879 AS_VAR_SET_IF(gcc_cv_as,, [
1880 if test -x "$DEFAULT_ASSEMBLER"; then
1881         gcc_cv_as="$DEFAULT_ASSEMBLER"
1882 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1883      && test -f ../gas/Makefile \
1884      && test x$build = x$host; then
1885         gcc_cv_as=../gas/as-new$build_exeext
1886 elif test -x as$build_exeext; then
1887         # Build using assembler in the current directory.
1888         gcc_cv_as=./as$build_exeext
1889 elif test -x $AS_FOR_TARGET; then
1890         gcc_cv_as="$AS_FOR_TARGET"
1891 else
1892         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1893 fi])
1894
1895 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1896 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1897 case "$ORIGINAL_AS_FOR_TARGET" in
1898   ./as | ./as$build_exeext) ;;
1899   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1900 esac
1901
1902 AC_MSG_CHECKING(what assembler to use)
1903 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1904   # Single tree build which includes gas.  We want to prefer it
1905   # over whatever linker top-level may have detected, since
1906   # we'll use what we're building after installation anyway.
1907   AC_MSG_RESULT(newly built gas)
1908   in_tree_gas=yes
1909   _gcc_COMPUTE_GAS_VERSION
1910   in_tree_gas_is_elf=no
1911   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1912      || (grep 'obj_format = multi' ../gas/Makefile \
1913          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1914   then
1915     in_tree_gas_is_elf=yes
1916   fi
1917 else
1918   AC_MSG_RESULT($gcc_cv_as)
1919   in_tree_gas=no
1920 fi
1921
1922 # Identify the linker which will work hand-in-glove with the newly
1923 # built GCC, so that we can examine its features.  This is the linker
1924 # which will be driven by the driver program.
1925 #
1926 # If build != host, and we aren't building gas in-tree, we identify a
1927 # build->target linker and hope that it will have the same features
1928 # as the host->target linker we'll be using.
1929 gcc_cv_gld_major_version=
1930 gcc_cv_gld_minor_version=
1931 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1932 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1933
1934 AS_VAR_SET_IF(gcc_cv_ld,, [
1935 if test -x "$DEFAULT_LINKER"; then
1936         gcc_cv_ld="$DEFAULT_LINKER"
1937 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1938      && test -f ../ld/Makefile \
1939      && test x$build = x$host; then
1940         gcc_cv_ld=../ld/ld-new$build_exeext
1941 elif test -x collect-ld$build_exeext; then
1942         # Build using linker in the current directory.
1943         gcc_cv_ld=./collect-ld$build_exeext
1944 elif test -x $LD_FOR_TARGET; then
1945         gcc_cv_ld="$LD_FOR_TARGET"
1946 else
1947         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1948 fi])
1949
1950 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
1951 PLUGIN_LD=`basename $gcc_cv_ld`
1952 AC_ARG_WITH(plugin-ld,
1953 [  --with-plugin-ld=[[ARG]]  specify the plugin linker],
1954 [if test x"$withval" != x; then
1955    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
1956    PLUGIN_LD="$withval"
1957  fi])
1958 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
1959 AC_DEFINE_UNQUOTED(PLUGIN_LD, "$PLUGIN_LD", [Specify plugin linker])
1960
1961 # Check to see if we are using gold instead of ld
1962 AC_MSG_CHECKING(whether we are using gold)
1963 ld_is_gold=no
1964 if test x$gcc_cv_ld != x; then
1965   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
1966      | grep "GNU gold" > /dev/null; then
1967     ld_is_gold=yes
1968   fi
1969 fi
1970 AC_MSG_RESULT($ld_is_gold)
1971
1972 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1973 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1974 case "$ORIGINAL_LD_FOR_TARGET" in
1975   ./collect-ld | ./collect-ld$build_exeext) ;;
1976   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1977 esac
1978
1979 AC_MSG_CHECKING(what linker to use)
1980 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1981         # Single tree build which includes ld.  We want to prefer it
1982         # over whatever linker top-level may have detected, since
1983         # we'll use what we're building after installation anyway.
1984         AC_MSG_RESULT(newly built ld)
1985         in_tree_ld=yes
1986         in_tree_ld_is_elf=no
1987         if (grep 'EMUL = .*elf' ../ld/Makefile \
1988             || grep 'EMUL = .*linux' ../ld/Makefile \
1989             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1990           in_tree_ld_is_elf=yes
1991         fi
1992         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1993         do
1994 changequote(,)dnl
1995                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1996                 if test x$gcc_cv_gld_version != x; then
1997                         break
1998                 fi
1999         done
2000         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
2001         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
2002 changequote([,])dnl
2003 else
2004         AC_MSG_RESULT($gcc_cv_ld)
2005         in_tree_ld=no
2006 fi
2007
2008 # Figure out what nm we will be using.
2009 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
2010 AS_VAR_SET_IF(gcc_cv_nm,, [
2011 if test -f $gcc_cv_binutils_srcdir/configure.in \
2012      && test -f ../binutils/Makefile \
2013      && test x$build = x$host; then
2014         gcc_cv_nm=../binutils/nm-new$build_exeext
2015 elif test -x nm$build_exeext; then
2016         gcc_cv_nm=./nm$build_exeext
2017 elif test -x $NM_FOR_TARGET; then
2018         gcc_cv_nm="$NM_FOR_TARGET"
2019 else
2020         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
2021 fi])
2022
2023 AC_MSG_CHECKING(what nm to use)
2024 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2025         # Single tree build which includes binutils.
2026         AC_MSG_RESULT(newly built nm)
2027         in_tree_nm=yes
2028 else
2029         AC_MSG_RESULT($gcc_cv_nm)
2030         in_tree_nm=no
2031 fi
2032
2033 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2034 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2035 case "$ORIGINAL_NM_FOR_TARGET" in
2036   ./nm | ./nm$build_exeext) ;;
2037   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2038 esac
2039
2040
2041 # Figure out what objdump we will be using.
2042 AS_VAR_SET_IF(gcc_cv_objdump,, [
2043 if test -f $gcc_cv_binutils_srcdir/configure.in \
2044      && test -f ../binutils/Makefile \
2045      && test x$build = x$host; then
2046         # Single tree build which includes binutils.
2047         gcc_cv_objdump=../binutils/objdump$build_exeext
2048 elif test -x objdump$build_exeext; then
2049         gcc_cv_objdump=./objdump$build_exeext
2050 elif test -x $OBJDUMP_FOR_TARGET; then
2051         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2052 else
2053         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2054 fi])
2055
2056 AC_MSG_CHECKING(what objdump to use)
2057 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2058         # Single tree build which includes binutils.
2059         AC_MSG_RESULT(newly built objdump)
2060 elif test x$gcc_cv_objdump = x; then
2061         AC_MSG_RESULT(not found)
2062 else
2063         AC_MSG_RESULT($gcc_cv_objdump)
2064 fi
2065
2066 # Figure out what readelf we will be using.
2067 AS_VAR_SET_IF(gcc_cv_readelf,, [
2068 if test -f $gcc_cv_binutils_srcdir/configure.in \
2069      && test -f ../binutils/Makefile \
2070      && test x$build = x$host; then
2071         # Single tree build which includes binutils.
2072         gcc_cv_readelf=../binutils/readelf$build_exeext
2073 elif test -x readelf$build_exeext; then
2074         gcc_cv_readelf=./readelf$build_exeext
2075 else
2076         AC_PATH_PROG(gcc_cv_readelf, readelf)
2077 fi])
2078
2079 AC_MSG_CHECKING(what readelf to use)
2080 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2081         # Single tree build which includes binutils.
2082         AC_MSG_RESULT(newly built readelf)
2083 elif test x$gcc_cv_readelf = x; then
2084         AC_MSG_RESULT(not found)
2085 else
2086         AC_MSG_RESULT($gcc_cv_readelf)
2087 fi
2088
2089 # Figure out what assembler alignment features are present.
2090 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2091  [2,6,0],,
2092 [.balign 4
2093 .p2align 2],,
2094 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2095   [Define if your assembler supports .balign and .p2align.])])
2096
2097 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2098  [2,8,0],,
2099  [.p2align 4,,7],,
2100 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2101   [Define if your assembler supports specifying the maximum number
2102    of bytes to skip when using the GAS .p2align command.])])
2103
2104 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2105  [2,8,0],,
2106  [.literal16],,
2107 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2108   [Define if your assembler supports .literal16.])])
2109
2110 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2111  [elf,2,9,0],,
2112  [conftest_label1: .word 0
2113 .subsection -1
2114 conftest_label2: .word 0
2115 .previous],
2116  [if test x$gcc_cv_nm != x; then
2117     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2118     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2119     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2120     then :
2121     else gcc_cv_as_subsection_m1=yes
2122     fi
2123     rm -f conftest.nm1 conftest.nm2
2124   fi],
2125  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2126   [Define if your assembler supports .subsection and .subsection -1 starts
2127    emitting at the beginning of your section.])])
2128
2129 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2130  [2,2,0],,
2131  [      .weak foobar],,
2132 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2133
2134 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2135  [2,17,0],,
2136  [      .weakref foobar, barfnot],,
2137 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2138
2139 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2140  [2,15,91],,
2141  [      .SPACE $TEXT$
2142         .NSUBSPA $CODE$,COMDAT],,
2143 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2144
2145 # .hidden needs to be supported in both the assembler and the linker,
2146 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2147 # This is irritatingly difficult to feature test for; we have to check the
2148 # date string after the version number.  If we've got an in-tree
2149 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2150 # to be safe.
2151 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2152 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2153  [elf,2,13,0],,
2154 [       .hidden foobar
2155 foobar:],[
2156 # Solaris 9/x86 as incorrectly emits an alias for a hidden symbol with
2157 # STV_HIDDEN, so disable .hidden support if so.
2158 case "${target}" in
2159   i?86-*-solaris2*)
2160     if test x$gcc_cv_as != x && test x$gcc_cv_objdump != x; then
2161       cat > conftest.s <<EOF
2162 .globl hidden
2163         .hidden hidden
2164 hidden:
2165 .globl default
2166         .set    default,hidden
2167 EOF
2168       if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
2169         && $gcc_cv_objdump -t conftest.o 2>/dev/null | \
2170         grep '\.hidden default' > /dev/null; then
2171         gcc_cv_as_hidden=no
2172       else
2173         gcc_cv_as_hidden=yes
2174       fi
2175     else
2176       # Assume bug is present if objdump is missing.
2177       gcc_cv_as_hidden=no
2178     fi
2179     ;;
2180   *)
2181     gcc_cv_as_hidden=yes
2182     ;;
2183 esac])
2184
2185 changequote(,)dnl
2186 if test $in_tree_ld != yes ; then
2187   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2188   if test x"$ld_is_gold" = xyes; then
2189     gcc_cv_ld_hidden=yes
2190   elif echo "$ld_ver" | grep GNU > /dev/null; then
2191     ld_vers=`echo $ld_ver | sed -n \
2192         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2193     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2194     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2195     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2196     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2197   else
2198     case "${target}" in
2199       *-*-solaris2*)
2200         #
2201         # Solaris 2 ld -V output looks like this for a regular version:
2202         #
2203         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1699
2204         #
2205         # but test versions add stuff at the end:
2206         #
2207         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1701:onnv-ab196087-6931056-03/25/10
2208         #
2209         ld_ver=`$gcc_cv_ld -V 2>&1`
2210         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2211           ld_vers=`echo $ld_ver | sed -n \
2212             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2213           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2214           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2215         fi
2216         ;;
2217     esac
2218   fi
2219 fi
2220 changequote([,])dnl
2221
2222 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2223 [[if test $in_tree_ld = yes ; then
2224   gcc_cv_ld_hidden=no
2225   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2226      && test $in_tree_ld_is_elf = yes; then
2227      gcc_cv_ld_hidden=yes
2228   fi
2229 else
2230   gcc_cv_ld_hidden=yes
2231   if echo "$ld_ver" | grep GNU > /dev/null; then
2232     if test 0"$ld_date" -lt 20020404; then
2233       if test -n "$ld_date"; then
2234         # If there was date string, but was earlier than 2002-04-04, fail
2235         gcc_cv_ld_hidden=no
2236       elif test -z "$ld_vers"; then
2237         # If there was no date string nor ld version number, something is wrong
2238         gcc_cv_ld_hidden=no
2239       else
2240         test -z "$ld_vers_patch" && ld_vers_patch=0
2241         if test "$ld_vers_major" -lt 2; then
2242           gcc_cv_ld_hidden=no
2243         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2244           gcc_cv_ld_hidden="no"
2245         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2246           gcc_cv_ld_hidden=no
2247         fi
2248       fi
2249     fi
2250   else
2251     case "${target}" in
2252       hppa64*-*-hpux* | ia64*-*-hpux*)
2253         gcc_cv_ld_hidden=yes
2254         ;;
2255       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2256         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
2257         # .symbolic was only added in Solaris 9 12/02.
2258         gcc_cv_ld_hidden=yes
2259         ;;
2260       *)
2261         gcc_cv_ld_hidden=no
2262         ;;
2263     esac
2264   fi
2265 fi]])
2266 libgcc_visibility=no
2267 AC_SUBST(libgcc_visibility)
2268 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2269 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2270   libgcc_visibility=yes
2271   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2272   [Define if your assembler and linker support .hidden.])
2273 fi
2274
2275 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2276 gcc_cv_ld_ro_rw_mix=unknown
2277 if test $in_tree_ld = yes ; then
2278   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2279      && test $in_tree_ld_is_elf = yes; then
2280     gcc_cv_ld_ro_rw_mix=read-write
2281   fi
2282 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2283   echo '.section myfoosect, "a"' > conftest1.s
2284   echo '.section myfoosect, "aw"' > conftest2.s
2285   echo '.byte 1' >> conftest2.s
2286   echo '.section myfoosect, "a"' > conftest3.s
2287   echo '.byte 0' >> conftest3.s
2288   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2289      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2290      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2291      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2292         conftest2.o conftest3.o > /dev/null 2>&1; then
2293     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2294                          | sed -e '/myfoosect/!d' -e N`
2295     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2296       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2297         gcc_cv_ld_ro_rw_mix=read-only
2298       else
2299         gcc_cv_ld_ro_rw_mix=read-write
2300       fi
2301     fi
2302   fi
2303 changequote(,)dnl
2304   rm -f conftest.* conftest[123].*
2305 changequote([,])dnl
2306 fi
2307 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2308         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2309   [Define if your linker links a mix of read-only
2310    and read-write sections into a read-write section.])
2311 fi
2312 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2313
2314 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2315 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2316   [elf,2,11,0],,
2317 [       .data
2318         .uleb128 L2 - L1
2319 L1:
2320         .uleb128 1280
2321         .sleb128 -1010
2322 L2:],
2323 [[# GAS versions before 2.11 do not support uleb128,
2324   # despite appearing to.
2325   # ??? There exists an elf-specific test that will crash
2326   # the assembler.  Perhaps it's better to figure out whether
2327   # arbitrary sections are supported and try the test.
2328   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2329   if echo "$as_ver" | grep GNU > /dev/null; then
2330     as_vers=`echo $as_ver | sed -n \
2331         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2332     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2333     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2334     if test $as_major -eq 2 && test $as_minor -lt 11
2335     then :
2336     else gcc_cv_as_leb128=yes
2337     fi
2338   fi]],
2339   [AC_DEFINE(HAVE_AS_LEB128, 1,
2340     [Define if your assembler supports .sleb128 and .uleb128.])])
2341
2342 # Check if we have assembler support for unwind directives.
2343 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2344   ,,
2345 [       .text
2346         .cfi_startproc
2347         .cfi_offset 0, 0
2348         .cfi_same_value 1
2349         .cfi_def_cfa 1, 2
2350         .cfi_escape 1, 2, 3, 4, 5
2351         .cfi_endproc],
2352 [case "$target" in
2353   *-*-solaris*)
2354     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2355     # read-only and read-write sections, we need to make sure that the
2356     # assembler used emits read-write .eh_frame sections.
2357     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2358       if test "x$gcc_cv_objdump" != x; then
2359         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2360                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2361           gcc_cv_as_cfi_directive=no
2362         else
2363           case "$target" in
2364             i?86-*-solaris2.1[[0-9]]*)
2365               # On Solaris/x86, make sure that GCC and gas agree on using
2366               # read-only .eh_frame sections for 64-bit.
2367               if $gcc_cv_as --64 -o conftest.o conftest.s > /dev/null 2>&1 && \
2368                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2369                         sed -e /.eh_frame/!d -e N | \
2370                         grep READONLY > /dev/null; then
2371                 gcc_cv_as_cfi_directive=yes
2372               else
2373                 gcc_cv_as_cfi_directive=no
2374               fi
2375               ;;
2376             *)
2377               gcc_cv_as_cfi_directive=yes
2378               ;;
2379           esac
2380         fi
2381       else
2382         # no objdump, err on the side of caution
2383         gcc_cv_as_cfi_directive=no
2384       fi
2385     else
2386       gcc_cv_as_cfi_directive=yes
2387     fi
2388     ;;
2389   *-*-*)
2390     gcc_cv_as_cfi_directive=yes
2391     ;;
2392 esac])
2393 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_readelf != x; then
2394 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2395   ,,
2396 [       .text
2397         .cfi_startproc
2398         .cfi_adjust_cfa_offset 64
2399         .skip 75040, 0
2400         .cfi_adjust_cfa_offset 128
2401         .cfi_endproc],
2402 [[
2403 if $gcc_cv_readelf -wf conftest.o 2>/dev/null \
2404     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2405    gcc_cv_as_cfi_advance_working=yes
2406 fi
2407 ]])
2408 else
2409   # no readelf, err on the side of caution
2410   gcc_cv_as_cfi_advance_working=no
2411 fi
2412 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2413   [`if test $gcc_cv_as_cfi_directive = yes \
2414        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2415   [Define 0/1 if your assembler supports CFI directives.])
2416
2417 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2418   gcc_cv_as_cfi_personality_directive, ,,
2419 [       .text
2420         .cfi_startproc
2421         .cfi_personality 0, symbol
2422         .cfi_endproc])
2423 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2424   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2425     then echo 1; else echo 0; fi`],
2426   [Define 0/1 if your assembler supports .cfi_personality.])
2427
2428 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2429   gcc_cv_as_cfi_sections_directive, ,,
2430 [       .text
2431         .cfi_sections .debug_frame, .eh_frame
2432         .cfi_startproc
2433         .cfi_endproc])
2434 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2435   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2436     then echo 1; else echo 0; fi`],
2437   [Define 0/1 if your assembler supports .cfi_sections.])
2438
2439 # GAS versions up to and including 2.11.0 may mis-optimize
2440 # .eh_frame data.
2441 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2442   [elf,2,12,0],,
2443 [       .text
2444 .LFB1:
2445         .4byte  0
2446 .L1:
2447         .4byte  0
2448 .LFE1:
2449         .section        .eh_frame,"aw",@progbits
2450 __FRAME_BEGIN__:
2451         .4byte  .LECIE1-.LSCIE1
2452 .LSCIE1:
2453         .4byte  0x0
2454         .byte   0x1
2455         .ascii "z\0"
2456         .byte   0x1
2457         .byte   0x78
2458         .byte   0x1a
2459         .byte   0x0
2460         .byte   0x4
2461         .4byte  1
2462         .p2align 1
2463 .LECIE1:
2464 .LSFDE1:
2465         .4byte  .LEFDE1-.LASFDE1
2466 .LASFDE1:
2467         .4byte  .LASFDE1-__FRAME_BEGIN__
2468         .4byte  .LFB1
2469         .4byte  .LFE1-.LFB1
2470         .byte   0x4
2471         .4byte  .LFE1-.LFB1
2472         .byte   0x4
2473         .4byte  .L1-.LFB1
2474 .LEFDE1:],
2475 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2476 cat > conftest.lit <<EOF
2477  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2478  0010 01000000 12000000 18000000 00000000  ................
2479  0020 08000000 04080000 0044               .........D      @&t@
2480 EOF
2481 cat > conftest.big <<EOF
2482  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2483  0010 00000001 00000012 00000018 00000000  ................
2484  0020 00000008 04000000 0844               .........D      @&t@
2485 EOF
2486   # If the assembler didn't choke, and we can objdump,
2487   # and we got the correct data, then succeed.
2488   # The text in the here-document typically retains its unix-style line
2489   # endings, while the output of objdump will use host line endings.
2490   # Therefore, use diff -b for the comparisons.
2491   if test x$gcc_cv_objdump != x \
2492   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2493      | tail -3 > conftest.got \
2494   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2495     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2496   then
2497     gcc_cv_as_eh_frame=yes
2498   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2499     gcc_cv_as_eh_frame=buggy
2500   else
2501     # Uh oh, what do we do now?
2502     gcc_cv_as_eh_frame=no
2503   fi])
2504
2505 if test $gcc_cv_as_eh_frame = buggy; then
2506   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2507   [Define if your assembler mis-optimizes .eh_frame data.])
2508 fi
2509
2510 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2511  [elf,2,12,0], [--fatal-warnings],
2512  [.section .rodata.str, "aMS", @progbits, 1])
2513 if test $gcc_cv_as_shf_merge = no; then
2514   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2515     [elf,2,12,0], [--fatal-warnings],
2516     [.section .rodata.str, "aMS", %progbits, 1])
2517 fi
2518 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2519   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2520 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2521
2522 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2523  [elf,2,16,0], [--fatal-warnings],
2524  [.section .text,"axG",@progbits,.foo,comdat])
2525 if test $gcc_cv_as_comdat_group = yes; then
2526   gcc_cv_as_comdat_group_percent=no
2527 else
2528  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2529    [elf,2,16,0], [--fatal-warnings],
2530    [.section .text,"axG",%progbits,.foo,comdat])
2531 fi
2532 if test x"$ld_is_gold" = xyes; then
2533   comdat_group=yes
2534 elif test $in_tree_ld = yes ; then
2535   comdat_group=no
2536   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2537      && test $in_tree_ld_is_elf = yes; then
2538      comdat_group=yes
2539   fi
2540 elif echo "$ld_ver" | grep GNU > /dev/null; then
2541   comdat_group=yes
2542   if test 0"$ld_date" -lt 20050308; then
2543     if test -n "$ld_date"; then
2544       # If there was date string, but was earlier than 2005-03-08, fail
2545       comdat_group=no
2546     elif test "$ld_vers_major" -lt 2; then
2547       comdat_group=no
2548     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2549       comdat_group=no
2550     fi
2551   fi
2552 else
2553 changequote(,)dnl
2554   case "${target}" in
2555     *-*-solaris2.1[1-9]*)
2556       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
2557       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
2558       # version 1.688.
2559       #
2560       # FIXME: Maybe need to refine later when COMDAT group support with
2561       # Sun as is implemented.
2562       if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 1688; then
2563         comdat_group=yes
2564       else
2565         comdat_group=no
2566       fi
2567       ;;
2568     *)
2569       # Assume linkers other than GNU ld don't support COMDAT group.
2570       comdat_group=no
2571       ;;
2572   esac
2573 changequote([,])dnl
2574 fi
2575 # Allow overriding the automatic COMDAT group tests above.
2576 AC_ARG_ENABLE(comdat,
2577   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
2578   [comdat_group="$enable_comdat"])
2579 if test $comdat_group = no; then
2580   gcc_cv_as_comdat_group=no
2581   gcc_cv_as_comdat_group_percent=no
2582 fi
2583 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2584   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2585 [Define 0/1 if your assembler and linker support COMDAT groups.])
2586
2587 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2588  gcc_cv_as_discriminator,
2589  [2,19,51],,
2590 [       .text
2591         .file 1 "conf.c"
2592         .loc 1 1 0 discriminator 1],,
2593 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2594   [Define if your assembler supports the .loc discriminator sub-directive.])])
2595
2596 # Thread-local storage - the check is heavily parameterized.
2597 conftest_s=
2598 tls_first_major=
2599 tls_first_minor=
2600 tls_as_opt=
2601 case "$target" in
2602 changequote(,)dnl
2603   alpha*-*-*)
2604     conftest_s='
2605         .section ".tdata","awT",@progbits
2606 foo:    .long   25
2607         .text
2608         ldq     $27,__tls_get_addr($29)         !literal!1
2609         lda     $16,foo($29)                    !tlsgd!1
2610         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2611         ldq     $27,__tls_get_addr($29)         !literal!2
2612         lda     $16,foo($29)                    !tlsldm!2
2613         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2614         ldq     $1,foo($29)                     !gotdtprel
2615         ldah    $2,foo($29)                     !dtprelhi
2616         lda     $3,foo($2)                      !dtprello
2617         lda     $4,foo($29)                     !dtprel
2618         ldq     $1,foo($29)                     !gottprel
2619         ldah    $2,foo($29)                     !tprelhi
2620         lda     $3,foo($2)                      !tprello
2621         lda     $4,foo($29)                     !tprel'
2622         tls_first_major=2
2623         tls_first_minor=13
2624         tls_as_opt=--fatal-warnings
2625         ;;
2626   cris-*-*|crisv32-*-*)
2627     conftest_s='
2628         .section ".tdata","awT",@progbits
2629 x:      .long   25
2630         .text
2631         move.d x:IE,$r10
2632         nop'
2633         tls_first_major=2
2634         tls_first_minor=20
2635         tls_as_opt=--fatal-warnings
2636         ;;
2637   frv*-*-*)
2638     conftest_s='
2639         .section ".tdata","awT",@progbits
2640 x:      .long   25
2641         .text
2642         call    #gettlsoff(x)'
2643         tls_first_major=2
2644         tls_first_minor=14
2645         ;;
2646   hppa*-*-linux*)
2647     conftest_s='
2648 t1:     .reg    %r20
2649 t2:     .reg    %r21
2650 gp:     .reg    %r19
2651         .section ".tdata","awT",@progbits
2652 foo:    .long   25
2653         .text
2654         .align  4
2655         addil LT%foo-$tls_gdidx$,gp
2656         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2657         b __tls_get_addr
2658         nop
2659         addil LT%foo-$tls_ldidx$,gp
2660         b __tls_get_addr
2661         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2662         addil LR%foo-$tls_dtpoff$,%ret0
2663         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2664         mfctl %cr27,%t1
2665         addil LT%foo-$tls_ieoff$,gp
2666         ldw RT%foo-$tls_ieoff$(%r1),%t2
2667         add %t1,%t2,%t3
2668         mfctl %cr27,%t1
2669         addil LR%foo-$tls_leoff$,%t1
2670         ldo RR%foo-$tls_leoff$(%r1),%t2'
2671         tls_first_major=2
2672         tls_first_minor=15
2673         tls_as_opt=--fatal-warnings
2674         ;;
2675   arm*-*-*)
2676     conftest_s='
2677         .section ".tdata","awT",%progbits
2678 foo:    .long   25
2679         .text
2680 .word foo(gottpoff)
2681 .word foo(tpoff)
2682 .word foo(tlsgd)
2683 .word foo(tlsldm)
2684 .word foo(tlsldo)'
2685         tls_first_major=2
2686         tls_first_minor=17
2687         ;;
2688   i[34567]86-*-*)
2689     case "$target" in
2690       i[34567]86-*-solaris2.[89]*)
2691         # TLS was introduced in the Solaris 9 4/04 release but
2692         # we do not enable it by default on Solaris 9 either.
2693         if test "x$enable_tls" = xyes ; then
2694           on_solaris=yes
2695         else
2696           enable_tls=no;
2697         fi
2698         ;;
2699       i[34567]86-*-solaris2.*)
2700         on_solaris=yes
2701         ;;
2702       *)
2703         on_solaris=no
2704         ;;
2705     esac
2706     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2707       conftest_s='
2708         .section .tdata,"awt",@progbits'
2709       tls_first_major=0
2710       tls_first_minor=0
2711 changequote([,])dnl
2712       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
2713 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
2714 changequote(,)dnl
2715     else
2716       conftest_s='
2717         .section ".tdata","awT",@progbits'
2718       tls_first_major=2
2719       tls_first_minor=14
2720       tls_as_opt="--fatal-warnings"
2721     fi
2722     conftest_s="$conftest_s
2723 foo:    .long   25
2724         .text
2725         movl    %gs:0, %eax
2726         leal    foo@tlsgd(,%ebx,1), %eax
2727         leal    foo@tlsldm(%ebx), %eax
2728         leal    foo@dtpoff(%eax), %edx
2729         movl    foo@gottpoff(%ebx), %eax
2730         subl    foo@gottpoff(%ebx), %eax
2731         addl    foo@gotntpoff(%ebx), %eax
2732         movl    foo@indntpoff, %eax
2733         movl    \$foo@tpoff, %eax
2734         subl    \$foo@tpoff, %eax
2735         leal    foo@ntpoff(%ecx), %eax"
2736     ;;
2737   x86_64-*-*)
2738     conftest_s='
2739         .section ".tdata","awT",@progbits
2740 foo:    .long   25
2741         .text
2742         movq    %fs:0, %rax
2743         leaq    foo@TLSGD(%rip), %rdi
2744         leaq    foo@TLSLD(%rip), %rdi
2745         leaq    foo@DTPOFF(%rax), %rdx
2746         movq    foo@GOTTPOFF(%rip), %rax
2747         movq    $foo@TPOFF, %rax'
2748         tls_first_major=2
2749         tls_first_minor=14
2750         tls_as_opt=--fatal-warnings
2751         ;;
2752   ia64-*-*)
2753     conftest_s='
2754         .section ".tdata","awT",@progbits
2755 foo:    data8   25
2756         .text
2757         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2758         addl    r17 = @ltoff(@dtprel(foo#)), gp
2759         addl    r18 = @ltoff(@tprel(foo#)), gp
2760         addl    r19 = @dtprel(foo#), gp
2761         adds    r21 = @dtprel(foo#), r13
2762         movl    r23 = @dtprel(foo#)
2763         addl    r20 = @tprel(foo#), gp
2764         adds    r22 = @tprel(foo#), r13
2765         movl    r24 = @tprel(foo#)'
2766         tls_first_major=2
2767         tls_first_minor=13
2768         tls_as_opt=--fatal-warnings
2769         ;;
2770   mips*-*-*)
2771     conftest_s='
2772         .section .tdata,"awT",@progbits
2773 x:
2774         .word 2
2775         .text
2776         addiu $4, $28, %tlsgd(x)
2777         addiu $4, $28, %tlsldm(x)
2778         lui $4, %dtprel_hi(x)
2779         addiu $4, $4, %dtprel_lo(x)
2780         lw $4, %gottprel(x)($28)
2781         lui $4, %tprel_hi(x)
2782         addiu $4, $4, %tprel_lo(x)'
2783         tls_first_major=2
2784         tls_first_minor=16
2785         tls_as_opt='-32 --fatal-warnings'
2786         ;;
2787   m68k-*-*)
2788     conftest_s='
2789         .section .tdata,"awT",@progbits
2790 x:
2791         .word 2
2792         .text
2793 foo:
2794         move.l x@TLSGD(%a5),%a0
2795         move.l x@TLSLDM(%a5),%a0
2796         move.l x@TLSLDO(%a5),%a0
2797         move.l x@TLSIE(%a5),%a0
2798         move.l x@TLSLE(%a5),%a0'
2799         tls_first_major=2
2800         tls_first_minor=19
2801         tls_as_opt='--fatal-warnings'
2802         ;;
2803   powerpc-*-*)
2804     conftest_s='
2805         .section ".tdata","awT",@progbits
2806         .align 2
2807 ld0:    .space 4
2808 ld1:    .space 4
2809 x1:     .space 4
2810 x2:     .space 4
2811 x3:     .space 4
2812         .text
2813         addi 3,31,ld0@got@tlsgd
2814         bl __tls_get_addr
2815         addi 3,31,x1@got@tlsld
2816         bl __tls_get_addr
2817         addi 9,3,x1@dtprel
2818         addis 9,3,x2@dtprel@ha
2819         addi 9,9,x2@dtprel@l
2820         lwz 9,x3@got@tprel(31)
2821         add 9,9,x@tls
2822         addi 9,2,x1@tprel
2823         addis 9,2,x2@tprel@ha
2824         addi 9,9,x2@tprel@l'
2825         tls_first_major=2
2826         tls_first_minor=14
2827         tls_as_opt="-a32 --fatal-warnings"
2828         ;;
2829   powerpc64-*-*)
2830     conftest_s='
2831         .section ".tdata","awT",@progbits
2832         .align 3
2833 ld0:    .space 8
2834 ld1:    .space 8
2835 x1:     .space 8
2836 x2:     .space 8
2837 x3:     .space 8
2838         .text
2839         addi 3,2,ld0@got@tlsgd
2840         bl .__tls_get_addr
2841         nop
2842         addi 3,2,ld1@toc
2843         bl .__tls_get_addr
2844         nop
2845         addi 3,2,x1@got@tlsld
2846         bl .__tls_get_addr
2847         nop
2848         addi 9,3,x1@dtprel
2849         bl .__tls_get_addr
2850         nop
2851         addis 9,3,x2@dtprel@ha
2852         addi 9,9,x2@dtprel@l
2853         bl .__tls_get_addr
2854         nop
2855         ld 9,x3@got@dtprel(2)
2856         add 9,9,3
2857         bl .__tls_get_addr
2858         nop'
2859         tls_first_major=2
2860         tls_first_minor=14
2861         tls_as_opt="-a64 --fatal-warnings"
2862         ;;
2863   s390-*-*)
2864     conftest_s='
2865         .section ".tdata","awT",@progbits
2866 foo:    .long   25
2867         .text
2868         .long   foo@TLSGD
2869         .long   foo@TLSLDM
2870         .long   foo@DTPOFF
2871         .long   foo@NTPOFF
2872         .long   foo@GOTNTPOFF
2873         .long   foo@INDNTPOFF
2874         l       %r1,foo@GOTNTPOFF(%r12)
2875         l       %r1,0(%r1):tls_load:foo
2876         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2877         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2878         tls_first_major=2
2879         tls_first_minor=14
2880         tls_as_opt="-m31 --fatal-warnings"
2881         ;;
2882   s390x-*-*)
2883     conftest_s='
2884         .section ".tdata","awT",@progbits
2885 foo:    .long   25
2886         .text
2887         .quad   foo@TLSGD
2888         .quad   foo@TLSLDM
2889         .quad   foo@DTPOFF
2890         .quad   foo@NTPOFF
2891         .quad   foo@GOTNTPOFF
2892         lg      %r1,foo@GOTNTPOFF(%r12)
2893         larl    %r1,foo@INDNTPOFF
2894         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2895         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2896         tls_first_major=2
2897         tls_first_minor=14
2898         tls_as_opt="-m64 -Aesame --fatal-warnings"
2899         ;;
2900   sh-*-* | sh[34]-*-*)
2901     conftest_s='
2902         .section ".tdata","awT",@progbits
2903 foo:    .long   25
2904         .text
2905         .long   foo@TLSGD
2906         .long   foo@TLSLDM
2907         .long   foo@DTPOFF
2908         .long   foo@GOTTPOFF
2909         .long   foo@TPOFF'
2910         tls_first_major=2
2911         tls_first_minor=13
2912         tls_as_opt=--fatal-warnings
2913         ;;
2914   sparc*-*-*)
2915     case "$target" in
2916       sparc*-sun-solaris2.[89]*)
2917         # TLS was introduced in the Solaris 9 4/04 release but
2918         # we do not enable it by default on Solaris 9 either.
2919         if test "x$enable_tls" = xyes ; then
2920           on_solaris=yes
2921         else
2922           enable_tls=no;
2923         fi
2924         ;;
2925       sparc*-sun-solaris2.*)
2926         on_solaris=yes
2927         ;;
2928       *)
2929         on_solaris=no
2930         ;;
2931     esac
2932     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2933       conftest_s='
2934         .section ".tdata",#alloc,#write,#tls
2935 foo:    .long   25
2936         .text
2937         sethi   %tgd_hi22(foo), %o0
2938         add     %o0, %tgd_lo10(foo), %o1
2939         add     %l7, %o1, %o0, %tgd_add(foo)
2940         call    __tls_get_addr, %tgd_call(foo)
2941         sethi   %tldm_hi22(foo), %l1
2942         add     %l1, %tldm_lo10(foo), %l2
2943         add     %l7, %l2, %o0, %tldm_add(foo)
2944         call    __tls_get_addr, %tldm_call(foo)
2945         sethi   %tldo_hix22(foo), %l3
2946         xor     %l3, %tldo_lox10(foo), %l4
2947         add     %o0, %l4, %l5, %tldo_add(foo)
2948         sethi   %tie_hi22(foo), %o3
2949         add     %o3, %tie_lo10(foo), %o3
2950         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2951         add     %g7, %o2, %o4, %tie_add(foo)
2952         sethi   %tle_hix22(foo), %l1
2953         xor     %l1, %tle_lox10(foo), %o5
2954         ld      [%g7 + %o5], %o1'
2955         tls_first_major=0
2956         tls_first_minor=0
2957     else
2958       conftest_s='
2959         .section ".tdata","awT",@progbits
2960 foo:    .long   25
2961         .text
2962         sethi   %tgd_hi22(foo), %o0
2963         add     %o0, %tgd_lo10(foo), %o1
2964         add     %l7, %o1, %o0, %tgd_add(foo)
2965         call    __tls_get_addr, %tgd_call(foo)
2966         sethi   %tldm_hi22(foo), %l1
2967         add     %l1, %tldm_lo10(foo), %l2
2968         add     %l7, %l2, %o0, %tldm_add(foo)
2969         call    __tls_get_addr, %tldm_call(foo)
2970         sethi   %tldo_hix22(foo), %l3
2971         xor     %l3, %tldo_lox10(foo), %l4
2972         add     %o0, %l4, %l5, %tldo_add(foo)
2973         sethi   %tie_hi22(foo), %o3
2974         add     %o3, %tie_lo10(foo), %o3
2975         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2976         add     %g7, %o2, %o4, %tie_add(foo)
2977         sethi   %tle_hix22(foo), %l1
2978         xor     %l1, %tle_lox10(foo), %o5
2979         ld      [%g7 + %o5], %o1'
2980         tls_first_major=2
2981         tls_first_minor=14
2982         tls_as_opt="-32 --fatal-warnings"
2983       fi
2984         ;;
2985   xtensa*-*-*)
2986     conftest_s='
2987         .section ".tdata","awT",@progbits
2988 foo:    .long   25
2989         .text
2990         movi    a8, foo@TLSFUNC
2991         movi    a10, foo@TLSARG
2992         callx8.tls a8, foo@TLSCALL'
2993         tls_first_major=2
2994         tls_first_minor=19
2995         ;;
2996 changequote([,])dnl
2997 esac
2998 set_have_as_tls=no
2999 if test "x$enable_tls" = xno ; then
3000   : # TLS explicitly disabled.
3001 elif test "x$enable_tls" = xyes ; then
3002   set_have_as_tls=yes # TLS explicitly enabled.
3003 elif test -z "$tls_first_major"; then
3004   : # If we don't have a check, assume no support.
3005 else
3006   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
3007   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
3008   [set_have_as_tls=yes])
3009 fi
3010 if test $set_have_as_tls = yes ; then
3011   AC_DEFINE(HAVE_AS_TLS, 1,
3012             [Define if your assembler supports thread-local storage.])
3013 fi
3014
3015 # Target-specific assembler checks.
3016
3017 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
3018 gcc_cv_ld_static_dynamic=no
3019 if test $in_tree_ld = yes ; then
3020   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
3021     gcc_cv_ld_static_dynamic=yes
3022   fi
3023 elif test x$gcc_cv_ld != x; then
3024         # Check if linker supports -Bstatic/-Bdynamic option
3025         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
3026           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
3027                 gcc_cv_ld_static_dynamic=yes
3028         fi
3029 fi
3030 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
3031         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
3032 [Define if your linker supports -Bstatic/-Bdynamic option.])
3033 fi
3034 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
3035
3036 if test x"$demangler_in_ld" = xyes; then
3037   AC_MSG_CHECKING(linker --demangle support)
3038   gcc_cv_ld_demangle=no
3039   if test $in_tree_ld = yes; then
3040     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
3041       gcc_cv_ld_demangle=yes
3042     fi
3043   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
3044     # Check if the GNU linker supports --demangle option
3045     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
3046       gcc_cv_ld_demangle=yes
3047     fi
3048   fi
3049   if test x"$gcc_cv_ld_demangle" = xyes; then
3050     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
3051 [Define if your linker supports --demangle option.])
3052   fi
3053   AC_MSG_RESULT($gcc_cv_ld_demangle)
3054 fi
3055
3056 case "$target" in
3057   # All TARGET_ABI_OSF targets.
3058   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
3059     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3060         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3061 [       .set nomacro
3062         .text
3063         extbl   $3, $2, $3      !lituse_bytoff!1
3064         ldq     $2, a($29)      !literal!1
3065         ldq     $4, b($29)      !literal!2
3066         ldq_u   $3, 0($2)       !lituse_base!1
3067         ldq     $27, f($29)     !literal!5
3068         jsr     $26, ($27), f   !lituse_jsr!5
3069         ldah    $29, 0($26)     !gpdisp!3
3070         lda     $0, c($29)      !gprel
3071         ldah    $1, d($29)      !gprelhigh
3072         lda     $1, d($1)       !gprellow
3073         lda     $29, 0($29)     !gpdisp!3],,
3074     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3075   [Define if your assembler supports explicit relocations.])])
3076     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3077         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3078 [       .set nomacro
3079         .text
3080         ldq     $27, a($29)     !literal!1
3081         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3082     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3083   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3084     ;;
3085
3086   cris-*-*)
3087     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3088       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3089       [-no-mul-bug-abort], [.text],,
3090       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3091                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3092     ;;
3093
3094   sparc*-*-*)
3095     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3096       [.register %g2, #scratch],,
3097       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3098                 [Define if your assembler supports .register.])])
3099
3100     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3101       [-relax], [.text],,
3102       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3103                 [Define if your assembler supports -relax option.])])
3104
3105     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3106       gcc_cv_as_sparc_gotdata_op,,
3107       [-K PIC],
3108 [.text
3109 foo:
3110         nop
3111 bar:
3112         sethi %gdop_hix22(foo), %g1
3113         xor    %g1, %gdop_lox10(foo), %g1
3114         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3115       [if test x$gcc_cv_ld != x \
3116        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3117          if $gcc_cv_ld -v | grep GNU >/dev/null 2>&1; then
3118            if test x$gcc_cv_objdump != x; then
3119              if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3120                 | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3121                gcc_cv_as_sparc_gotdata_op=no
3122              else
3123                gcc_cv_as_sparc_gotdata_op=yes
3124              fi
3125            fi
3126          else
3127            gcc_cv_as_sparc_gotdata_op=yes
3128          fi
3129        fi
3130        rm -f conftest],
3131       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3132                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3133
3134     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3135       gcc_cv_as_sparc_ua_pcrel,,
3136       [-K PIC],
3137 [.text
3138 foo:
3139         nop
3140 .data
3141 .align 4
3142 .byte 0
3143 .uaword %r_disp32(foo)],
3144       [if test x$gcc_cv_ld != x \
3145        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3146          gcc_cv_as_sparc_ua_pcrel=yes
3147        fi
3148        rm -f conftest],
3149       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3150                 [Define if your assembler and linker support unaligned PC relative relocs.])
3151
3152       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3153         gcc_cv_as_sparc_ua_pcrel_hidden,,
3154         [-K PIC],
3155 [.data
3156 .align 4
3157 .byte 0x31
3158 .uaword %r_disp32(foo)
3159 .byte 0x32, 0x33, 0x34
3160 .global foo
3161 .hidden foo
3162 foo:
3163 .skip 4],
3164         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3165          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3166          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3167             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3168             if $gcc_cv_objdump -R conftest 2> /dev/null \
3169                | grep 'DISP32' > /dev/null 2>&1; then
3170                 :
3171             else
3172                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3173             fi
3174          fi
3175          rm -f conftest],
3176          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3177                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3178     ]) # unaligned pcrel relocs
3179
3180     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3181       gcc_cv_as_sparc_offsetable_lo10,,
3182       [-xarch=v9],
3183 [.text
3184         or %g1, %lo(ab) + 12, %g1
3185         or %g1, %lo(ab + 12), %g1],
3186       [if test x$gcc_cv_objdump != x \
3187        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3188           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3189          gcc_cv_as_sparc_offsetable_lo10=yes
3190        fi],
3191        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3192                  [Define if your assembler supports offsetable %lo().])])
3193     ;;
3194
3195 changequote(,)dnl
3196   i[34567]86-*-* | x86_64-*-*)
3197 changequote([,])dnl
3198     case $target_os in
3199       cygwin*)
3200         # Full C++ conformance when using a shared libstdc++-v3 requires some
3201         # support from the Cygwin DLL, which in more recent versions exports
3202         # wrappers to aid in interposing and redirecting operators new, delete,
3203         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3204         # are configuring for a version of Cygwin that exports the wrappers.
3205         if test x$host = x$target; then
3206           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3207         else
3208           # Can't check presence of libc functions during cross-compile, so
3209           # we just have to assume we're building for an up-to-date target.
3210           gcc_ac_cygwin_dll_wrappers=yes
3211         fi
3212         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3213           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3214           [Define if you want to generate code by default that assumes that the
3215            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3216     esac
3217     case $target_os in
3218       cygwin* | pe | mingw32*)
3219         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3220         # definition is used unconditionally to initialise the default state of
3221         # the target option variable that governs usage of the feature.
3222         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3223          [2,19,52],,[.comm foo,1,32])
3224         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3225           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3226           [Define if your assembler supports specifying the alignment
3227            of objects allocated using the GAS .comm command.])
3228         # Used for DWARF 2 in PE
3229         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3230           gcc_cv_as_ix86_pe_secrel32,
3231           [2,15,91],,
3232 [.text
3233 foo:    nop
3234 .data
3235         .secrel32 foo],
3236           [if test x$gcc_cv_ld != x \
3237            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
3238              gcc_cv_as_ix86_pe_secrel32=yes
3239            fi
3240            rm -f conftest],
3241           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
3242             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
3243         # Test if the assembler supports the extended form of the .section
3244         # directive that specifies section alignment.  LTO support uses this,
3245         # but normally only after installation, so we warn but don't fail the
3246         # configure if LTO is enabled but the assembler does not support it.
3247         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
3248           [2,20,1],-fatal-warnings,[.section lto_test,"dr0"])
3249         if test x$gcc_cv_as_section_has_align != xyes; then
3250           case ",$enable_languages," in
3251             *,lto,*)
3252               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
3253               ;;
3254           esac
3255         fi
3256         ;;
3257     esac
3258
3259     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
3260        gcc_cv_as_ix86_filds,,,
3261        [filds mem; fists mem],,
3262        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
3263          [Define if your assembler uses filds and fists mnemonics.])])
3264
3265     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3266        gcc_cv_as_ix86_fildq,,,
3267        [fildq mem; fistpq mem],,
3268        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3269          [Define if your assembler uses fildq and fistq mnemonics.])])
3270
3271     gcc_GAS_CHECK_FEATURE([cmov syntax],
3272       gcc_cv_as_ix86_cmov_sun_syntax,,,
3273       [cmovl.l %edx, %eax],,
3274       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3275         [Define if your assembler supports the Sun syntax for cmov.])])
3276
3277     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3278       gcc_cv_as_ix86_ffreep,,,
3279       [ffreep %st(1)],,
3280       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3281         [Define if your assembler supports the ffreep mnemonic.])])
3282
3283     gcc_GAS_CHECK_FEATURE([.quad directive],
3284       gcc_cv_as_ix86_quad,,,
3285       [.quad 0],,
3286       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
3287         [Define if your assembler supports the .quad directive.])])
3288
3289     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3290       gcc_cv_as_ix86_sahf,,,
3291       [.code64
3292        sahf],,
3293       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3294         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
3295
3296     gcc_GAS_CHECK_FEATURE([swap suffix],
3297       gcc_cv_as_ix86_swap,,,
3298       [movl.s %esp, %ebp],,
3299       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
3300         [Define if your assembler supports the swap suffix.])])
3301
3302     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3303       gcc_cv_as_ix86_diff_sect_delta,,,
3304       [.section .rodata
3305 .L1:
3306         .long .L2-.L1
3307         .long .L3-.L1
3308         .text
3309 .L3:    nop
3310 .L2:    nop],,
3311       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3312         [Define if your assembler supports the subtraction of symbols in different sections.])])
3313
3314     # These two are used unconditionally by i386.[ch]; it is to be defined
3315     # to 1 if the feature is present, 0 otherwise.
3316     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3317         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3318 [       .text
3319 .L0:
3320         nop
3321         .data
3322         .long .L0@GOTOFF])
3323     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3324       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3325       [Define true if the assembler supports '.long foo@GOTOFF'.])
3326
3327     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
3328         gcc_cv_as_ix86_rep_lock_prefix,,,
3329         [rep movsl
3330          lock orl $0, (%esp)])
3331     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_REP_LOCK_PREFIX,
3332       [`if test $gcc_cv_as_ix86_rep_lock_prefix = yes; then echo 1; else echo 0; fi`],
3333       [Define true if the assembler supports 'rep <insn>, lock <insn>'.])
3334
3335     ;;
3336
3337   ia64*-*-*)
3338     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3339         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3340 [       .text
3341         addl r15 = @ltoffx(x#), gp
3342         ;;
3343         ld8.mov r16 = [[r15]], x#],,
3344     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3345           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3346
3347     ;;
3348
3349   powerpc*-*-*)
3350     case $target in
3351       *-*-aix*) conftest_s='    .machine "pwr5"
3352         .csect .text[[PR]]
3353         mfcr 3,128';;
3354       *-*-darwin*)
3355         gcc_GAS_CHECK_FEATURE([.machine directive support],
3356           gcc_cv_as_machine_directive,,,
3357           [     .machine ppc7400])
3358         if test x$gcc_cv_as_machine_directive != xyes; then
3359           echo "*** This target requires an assembler supporting \".machine\"" >&2
3360           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3361           test x$build = x$target && exit 1
3362         fi
3363         conftest_s='    .text
3364         mfcr r3,128';;
3365       *) conftest_s='   .machine power4
3366         .text
3367         mfcr 3,128';;
3368     esac
3369
3370     gcc_GAS_CHECK_FEATURE([mfcr field support],
3371       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3372       [$conftest_s],,
3373       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3374           [Define if your assembler supports mfcr field.])])
3375
3376     case $target in
3377       *-*-aix*) conftest_s='    .machine "pwr5"
3378         .csect .text[[PR]]
3379         popcntb 3,3';;
3380       *) conftest_s='   .machine power5
3381         .text
3382         popcntb 3,3';;
3383     esac
3384
3385     gcc_GAS_CHECK_FEATURE([popcntb support],
3386       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3387       [$conftest_s],,
3388       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3389           [Define if your assembler supports popcntb field.])])
3390
3391     case $target in
3392       *-*-aix*) conftest_s='    .machine "pwr5x"
3393         .csect .text[[PR]]
3394         frin 1,1';;
3395       *) conftest_s='   .machine power5
3396         .text
3397         frin 1,1';;
3398     esac
3399
3400     gcc_GAS_CHECK_FEATURE([fp round support],
3401       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3402       [$conftest_s],,
3403       [AC_DEFINE(HAVE_AS_FPRND, 1,
3404           [Define if your assembler supports fprnd.])])
3405
3406     case $target in
3407       *-*-aix*) conftest_s='    .machine "pwr6"
3408         .csect .text[[PR]]
3409         mffgpr 1,3';;
3410       *) conftest_s='   .machine power6
3411         .text
3412         mffgpr 1,3';;
3413     esac
3414
3415     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3416       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
3417       [$conftest_s],,
3418       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3419           [Define if your assembler supports mffgpr and mftgpr.])])
3420
3421     case $target in
3422       *-*-aix*) conftest_s='    .csect .text[[PR]]
3423 LCF..0:
3424         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3425       *-*-darwin*)
3426         conftest_s='    .text
3427 LCF0:
3428         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3429       *) conftest_s='   .text
3430 .LCF0:
3431         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3432     esac
3433
3434     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3435       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3436       [$conftest_s],,
3437       [AC_DEFINE(HAVE_AS_REL16, 1,
3438           [Define if your assembler supports R_PPC_REL16 relocs.])])
3439
3440     case $target in
3441       *-*-aix*) conftest_s='    .machine "pwr6"
3442         .csect .text[[PR]]
3443         cmpb 3,4,5';;
3444       *) conftest_s='   .machine power6
3445         .text
3446         cmpb 3,4,5';;
3447     esac
3448
3449     gcc_GAS_CHECK_FEATURE([compare bytes support],
3450       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
3451       [$conftest_s],,
3452       [AC_DEFINE(HAVE_AS_CMPB, 1,
3453           [Define if your assembler supports cmpb.])])
3454
3455     case $target in
3456       *-*-aix*) conftest_s='    .machine "pwr6"
3457         .csect .text[[PR]]
3458         dadd 1,2,3';;
3459       *) conftest_s='   .machine power6
3460         .text
3461         dadd 1,2,3';;
3462     esac
3463
3464     gcc_GAS_CHECK_FEATURE([decimal float support],
3465       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
3466       [$conftest_s],,
3467       [AC_DEFINE(HAVE_AS_DFP, 1,
3468           [Define if your assembler supports DFP instructions.])])
3469
3470     case $target in
3471       *-*-aix*) conftest_s='    .machine "pwr7"
3472         .csect .text[[PR]]
3473         lxvd2x 1,2,3';;
3474       *) conftest_s='   .machine power7
3475         .text
3476         lxvd2x 1,2,3';;
3477     esac
3478
3479     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3480       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
3481       [$conftest_s],,
3482       [AC_DEFINE(HAVE_AS_VSX, 1,
3483           [Define if your assembler supports VSX instructions.])])
3484
3485     case $target in
3486       *-*-aix*) conftest_s='    .machine "pwr7"
3487         .csect .text[[PR]]
3488         popcntd 3,3';;
3489       *) conftest_s='   .machine power7
3490         .text
3491         popcntd 3,3';;
3492     esac
3493
3494     gcc_GAS_CHECK_FEATURE([popcntd support],
3495       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
3496       [$conftest_s],,
3497       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
3498           [Define if your assembler supports POPCNTD instructions.])])
3499
3500     case $target in
3501       *-*-aix*) conftest_s='    .csect .text[[PR]]
3502         lwsync';;
3503       *) conftest_s='   .text
3504         lwsync';;
3505     esac
3506
3507     gcc_GAS_CHECK_FEATURE([lwsync support],
3508       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
3509       [$conftest_s],,
3510       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
3511           [Define if your assembler supports LWSYNC instructions.])])
3512
3513     case $target in
3514       *-*-aix*) conftest_s='    .machine "476"
3515         .csect .text[[PR]]
3516         dci 0';;
3517       *) conftest_s='   .machine "476"
3518         .text
3519         dci 0';;
3520     esac
3521
3522     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
3523       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
3524       [$conftest_s],,
3525       [AC_DEFINE(HAVE_AS_DCI, 1,
3526           [Define if your assembler supports the DCI/ICI instructions.])])
3527
3528     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3529       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3530       [.gnu_attribute 4,1],,
3531       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3532           [Define if your assembler supports .gnu_attribute.])])
3533
3534     gcc_GAS_CHECK_FEATURE([tls marker support],
3535       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3536       [ bl __tls_get_addr(x@tlsgd)],,
3537       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3538           [Define if your assembler supports arg info for __tls_get_addr.])])
3539
3540     case $target in
3541       *-*-aix*)
3542         gcc_GAS_CHECK_FEATURE([.ref support],
3543           gcc_cv_as_aix_ref, [2.21.0],,
3544           [     .csect stuff[[rw]]
3545              stuff:
3546                 .long 1
3547                 .extern sym
3548                 .ref sym
3549           ],,
3550           [AC_DEFINE(HAVE_AS_REF, 1,
3551             [Define if your assembler supports .ref])])
3552         ;;
3553     esac
3554     ;;
3555
3556   mips*-*-*)
3557     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3558       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3559 [       lw $4,%gp_rel(foo)($4)],,
3560       [if test x$target_cpu_default = x
3561        then target_cpu_default=MASK_EXPLICIT_RELOCS
3562        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3563        fi])
3564     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3565       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3566       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3567                  [Define if the assembler understands -mno-shared.])])
3568
3569     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3570       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3571       [.gnu_attribute 4,1],,
3572       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3573           [Define if your assembler supports .gnu_attribute.])])
3574
3575     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3576       gcc_cv_as_mips_dtprelword, [2,18,0],,
3577       [.section .tdata,"awT",@progbits
3578 x:
3579         .word 2
3580         .text
3581         .dtprelword x+0x8000],,
3582       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3583           [Define if your assembler supports .dtprelword.])])
3584
3585     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
3586     gcc_cv_as_ld_jalr_reloc=no
3587     if test $gcc_cv_as_mips_explicit_relocs = yes; then
3588       if test $in_tree_ld = yes ; then
3589         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
3590            && test $in_tree_ld_is_elf = yes; then
3591           gcc_cv_as_ld_jalr_reloc=yes
3592         fi
3593       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
3594         echo '  .ent x' > conftest.s
3595         echo 'x:        ld $2,%got_disp(y)($3)' >> conftest.s
3596         echo '  ld $25,%call16(y)($28)' >> conftest.s
3597         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
3598         echo '1:        jalr $25' >> conftest.s
3599         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
3600         echo '1:        jalr $25' >> conftest.s
3601         echo '  .end x' >> conftest.s
3602         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
3603            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
3604           if $gcc_cv_objdump -d conftest.so | grep jalr >/dev/null 2>&1 \
3605              && $gcc_cv_objdump -d conftest.so | grep "bal.*<x>" >/dev/null 2>&1; then
3606             gcc_cv_as_ld_jalr_reloc=yes
3607           fi
3608         fi
3609         rm -f conftest.*
3610       fi
3611     fi
3612     if test $gcc_cv_as_ld_jalr_reloc = yes; then
3613       if test x$target_cpu_default = x; then
3614         target_cpu_default=MASK_RELAX_PIC_CALLS
3615       else
3616         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
3617       fi
3618     fi
3619     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
3620
3621     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
3622       [gcc_cv_ld_mips_personality_relaxation],
3623       [gcc_cv_ld_mips_personality_relaxation=no
3624        if test $in_tree_ld = yes ; then
3625          if test "$gcc_cv_gld_major_version" -eq 2 \
3626                  -a "$gcc_cv_gld_minor_version" -ge 21 \
3627                  -o "$gcc_cv_gld_major_version" -gt 2; then
3628            gcc_cv_ld_mips_personality_relaxation=yes
3629          fi
3630        elif test x$gcc_cv_as != x \
3631                  -a x$gcc_cv_ld != x \
3632                  -a x$gcc_cv_readelf != x ; then
3633          cat > conftest.s <<EOF
3634         .cfi_startproc
3635         .cfi_personality 0x80,indirect_ptr
3636         .ent test
3637 test:
3638         nop
3639         .end test
3640         .cfi_endproc
3641
3642         .section .data,"aw",@progbits
3643 indirect_ptr:
3644         .dc.a personality
3645 EOF
3646          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
3647             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
3648            if $gcc_cv_readelf -d conftest 2>&1 \
3649               | grep TEXTREL > /dev/null 2>&1; then
3650              :
3651            elif $gcc_cv_readelf --relocs conftest 2>&1 \
3652                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
3653              :
3654            else
3655              gcc_cv_ld_mips_personality_relaxation=yes
3656            fi
3657          fi
3658        fi
3659        rm -f conftest.s conftest.o conftest])
3660     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
3661             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
3662       [Define if your linker can relax absolute .eh_frame personality
3663 pointers into PC-relative form.])
3664     fi
3665     ;;
3666 esac
3667
3668 # Mips and HP-UX need the GNU assembler.
3669 # Linux on IA64 might be able to use the Intel assembler.
3670
3671 case "$target" in
3672   mips*-*-* | *-*-hpux* )
3673     if test x$gas_flag = xyes \
3674        || test x"$host" != x"$build" \
3675        || test ! -x "$gcc_cv_as" \
3676        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3677       :
3678     else
3679       echo "*** This configuration requires the GNU assembler" >&2
3680       exit 1
3681     fi
3682     ;;
3683 esac
3684
3685 # ??? Not all targets support dwarf2 debug_line, even within a version
3686 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3687 # info to the output file.  So, as supported targets are added to gas 2.11,
3688 # add some instruction here to (also) show we expect this might work.
3689 # ??? Once 2.11 is released, probably need to add first known working
3690 # version to the per-target configury.
3691 case "$target" in
3692   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3693   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3694   | xstormy16*-*-* | cris-*-* | crisv32-*-* | xtensa*-*-* | bfin-*-* | score*-*-* \
3695   | spu-*-* | fido*-*-* | m32c-*-*)
3696     insn="nop"
3697     ;;
3698   ia64*-*-* | s390*-*-*)
3699     insn="nop 0"
3700     ;;
3701   mmix-*-*)
3702     insn="swym 0"
3703     ;;
3704 esac
3705 if test x"$insn" != x; then
3706  conftest_s="\
3707         .file 1 \"conftest.s\"
3708         .loc 1 3 0
3709         $insn"
3710  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3711   gcc_cv_as_dwarf2_debug_line,
3712   [elf,2,11,0],, [$conftest_s],
3713   [if test x$gcc_cv_objdump != x \
3714    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3715       | grep debug_line > /dev/null 2>&1; then
3716      gcc_cv_as_dwarf2_debug_line=yes
3717    fi])
3718
3719 # The .debug_line file table must be in the exact order that
3720 # we specified the files, since these indices are also used
3721 # by DW_AT_decl_file.  Approximate this test by testing if
3722 # the assembler bitches if the same index is assigned twice.
3723  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3724   gcc_cv_as_dwarf2_file_buggy,,,
3725 [       .file 1 "foo.s"
3726         .file 1 "bar.s"])
3727
3728  if test $gcc_cv_as_dwarf2_debug_line = yes \
3729  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3730         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3731   [Define if your assembler supports dwarf2 .file/.loc directives,
3732    and preserves file table indices exactly as given.])
3733  fi
3734
3735  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3736   gcc_cv_as_gdwarf2_flag,
3737   [elf,2,11,0], [--gdwarf2], [$insn],,
3738   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3739 [Define if your assembler supports the --gdwarf2 option.])])
3740
3741  gcc_GAS_CHECK_FEATURE([--gstabs option],
3742   gcc_cv_as_gstabs_flag,
3743   [elf,2,11,0], [--gstabs], [$insn],
3744   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3745    # and warns about it, but still exits successfully.  So check for
3746    # this.
3747    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3748    then :
3749    else gcc_cv_as_gstabs_flag=yes
3750    fi],
3751   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3752 [Define if your assembler supports the --gstabs option.])])
3753
3754  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3755   gcc_cv_as_debug_prefix_map_flag,
3756   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3757   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3758 [Define if your assembler supports the --debug-prefix-map option.])])
3759 fi
3760
3761 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
3762  ,,
3763 [.lcomm bar,4,16],,
3764 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
3765   [Define if your assembler supports .lcomm with an alignment field.])])
3766
3767 AC_ARG_ENABLE(gnu-unique-object,
3768  [  --enable-gnu-unique-object  enable the use of the @gnu_unique_object ELF extension on
3769                                 glibc systems],
3770  [case $enable_gnu_unique_object in
3771     yes | no) ;;
3772     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
3773 Valid choices are 'yes' and 'no'.]) ;;
3774   esac],
3775  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
3776    [elf,2,19,52],,
3777    [.type foo, @gnu_unique_object],,
3778 # Also check for ld.so support, i.e. glibc 2.11 or higher.
3779    [[if test x$host = x$build -a x$host = x$target &&
3780        glibcver=`ldd --version 2>/dev/null | sed 's/.* //;q'`; then
3781       glibcmajor=`expr "$glibcver" : "\([0-9]*\)"`
3782       glibcminor=`expr "$glibcver" : "[2-9]*\.\([0-9]*\)"`
3783       glibcnum=`expr $glibcmajor \* 1000 + $glibcminor`
3784       if test "$glibcnum" -ge 2011 ; then
3785         enable_gnu_unique_object=yes
3786       fi
3787     fi]])])
3788 if test x$enable_gnu_unique_object = xyes; then
3789   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
3790    [Define if your assembler supports @gnu_unique_object.])
3791 fi
3792
3793 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3794  [gcc_cv_as_line_zero],
3795  [gcc_cv_as_line_zero=no
3796   if test $in_tree_gas = yes; then
3797     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3798   elif test "x$gcc_cv_as" != x; then
3799     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3800     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3801        test "x`cat conftest.out`" = x
3802     then
3803       gcc_cv_as_line_zero=yes
3804     else
3805       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3806       cat conftest.s >&AS_MESSAGE_LOG_FD
3807       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3808       cat conftest.out >&AS_MESSAGE_LOG_FD
3809     fi
3810     rm -f conftest.o conftest.s conftest.out
3811   fi])
3812 if test "x$gcc_cv_as_line_zero" = xyes; then
3813   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3814 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3815 fi
3816
3817 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3818 gcc_cv_ld_eh_frame_hdr=no
3819 if test $in_tree_ld = yes ; then
3820   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3821      && test $in_tree_ld_is_elf = yes; then
3822     gcc_cv_ld_eh_frame_hdr=yes
3823   fi
3824 elif test x$gcc_cv_ld != x; then
3825         # Check if linker supports --eh-frame-hdr option
3826         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3827                 gcc_cv_ld_eh_frame_hdr=yes
3828         fi
3829 fi
3830 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3831 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3832         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3833 [Define if your linker supports --eh-frame-hdr option.])
3834 fi
3835 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3836
3837 AC_MSG_CHECKING(linker position independent executable support)
3838 gcc_cv_ld_pie=no
3839 if test $in_tree_ld = yes ; then
3840   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3841      && test $in_tree_ld_is_elf = yes; then
3842     gcc_cv_ld_pie=yes
3843   fi
3844 elif test x$gcc_cv_ld != x; then
3845         # Check if linker supports -pie option
3846         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3847                 gcc_cv_ld_pie=yes
3848         fi
3849 fi
3850 if test x"$gcc_cv_ld_pie" = xyes; then
3851         AC_DEFINE(HAVE_LD_PIE, 1,
3852 [Define if your linker supports -pie option.])
3853 fi
3854 AC_MSG_RESULT($gcc_cv_ld_pie)
3855
3856 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3857 gcc_cv_ld_eh_gc_sections=no
3858 if test $in_tree_ld = yes ; then
3859   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3860      && test $in_tree_ld_is_elf = yes; then
3861     gcc_cv_ld_eh_gc_sections=yes
3862   fi
3863 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3864   cat > conftest.s <<EOF
3865         .section        .text
3866 .globl _start
3867         .type _start, @function
3868 _start:
3869         .long foo
3870         .size _start, .-_start
3871         .section        .text.foo,"ax",@progbits
3872         .type foo, @function
3873 foo:
3874         .long 0
3875         .size foo, .-foo
3876         .section        .gcc_except_table.foo,"a",@progbits
3877 .L0:
3878         .long 0
3879         .section        .eh_frame,"a",@progbits
3880         .long .L0
3881 EOF
3882   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3883     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3884          | grep "gc-sections option ignored" > /dev/null; then
3885       gcc_cv_ld_eh_gc_sections=no
3886     elif $gcc_cv_objdump -h conftest 2> /dev/null \
3887          | grep gcc_except_table > /dev/null; then
3888       gcc_cv_ld_eh_gc_sections=yes
3889       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3890       if test x$gcc_cv_as_comdat_group != xyes; then
3891         gcc_cv_ld_eh_gc_sections=no
3892         cat > conftest.s <<EOF
3893         .section        .text
3894 .globl _start
3895         .type _start, @function
3896 _start:
3897         .long foo
3898         .size _start, .-_start
3899         .section        .gnu.linkonce.t.foo,"ax",@progbits
3900         .type foo, @function
3901 foo:
3902         .long 0
3903         .size foo, .-foo
3904         .section        .gcc_except_table.foo,"a",@progbits
3905 .L0:
3906         .long 0
3907         .section        .eh_frame,"a",@progbits
3908         .long .L0
3909 EOF
3910         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3911           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3912                | grep "gc-sections option ignored" > /dev/null; then
3913             gcc_cv_ld_eh_gc_sections=no
3914           elif $gcc_cv_objdump -h conftest 2> /dev/null \
3915                | grep gcc_except_table > /dev/null; then
3916             gcc_cv_ld_eh_gc_sections=yes
3917           fi
3918         fi
3919       fi
3920     fi
3921   fi
3922   rm -f conftest.s conftest.o conftest
3923 fi
3924 case "$target" in
3925   hppa*-*-linux*)
3926     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3927     gcc_cv_ld_eh_gc_sections=no
3928     ;;
3929 esac
3930 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3931         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3932   [Define if your linker supports garbage collection of
3933    sections in presence of EH frames.])
3934 fi
3935 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3936
3937 # --------
3938 # UNSORTED
3939 # --------
3940
3941 AC_CACHE_CHECK(linker --as-needed support,
3942 gcc_cv_ld_as_needed,
3943 [gcc_cv_ld_as_needed=no
3944 if test $in_tree_ld = yes ; then
3945   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3946      && test $in_tree_ld_is_elf = yes; then
3947     gcc_cv_ld_as_needed=yes
3948   fi
3949 elif test x$gcc_cv_ld != x; then
3950         # Check if linker supports --as-needed and --no-as-needed options
3951         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3952                 gcc_cv_ld_as_needed=yes
3953         fi
3954 fi
3955 ])
3956 if test x"$gcc_cv_ld_as_needed" = xyes; then
3957         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3958 [Define if your linker supports --as-needed and --no-as-needed options.])
3959 fi
3960
3961 case "$target:$tm_file" in
3962   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3963     AC_CACHE_CHECK(linker support for omitting dot symbols,
3964     gcc_cv_ld_no_dot_syms,
3965     [gcc_cv_ld_no_dot_syms=no
3966     if test $in_tree_ld = yes ; then
3967       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3968         gcc_cv_ld_no_dot_syms=yes
3969       fi
3970     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3971       cat > conftest1.s <<EOF
3972         .text
3973         bl .foo
3974 EOF
3975       cat > conftest2.s <<EOF
3976         .section ".opd","aw"
3977         .align 3
3978         .globl foo
3979         .type foo,@function
3980 foo:
3981         .quad .LEfoo,.TOC.@tocbase,0
3982         .text
3983 .LEfoo:
3984         blr
3985         .size foo,.-.LEfoo
3986 EOF
3987       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3988          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3989          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3990         gcc_cv_ld_no_dot_syms=yes
3991       fi
3992       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3993     fi
3994     ])
3995     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3996       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3997     [Define if your PowerPC64 linker only needs function descriptor syms.])
3998     fi
3999     ;;
4000 esac
4001
4002 AC_CACHE_CHECK(linker --build-id support,
4003   gcc_cv_ld_buildid,
4004   [gcc_cv_ld_buildid=no
4005   if test $in_tree_ld = yes ; then
4006     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4007        "$gcc_cv_gld_minor_version" -ge 18 -o \
4008        "$gcc_cv_gld_major_version" -gt 2 \
4009        && test $in_tree_ld_is_elf = yes; then
4010       gcc_cv_ld_buildid=yes
4011     fi
4012   elif test x$gcc_cv_ld != x; then
4013     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
4014       gcc_cv_ld_buildid=yes
4015     fi
4016   fi])
4017 if test x"$gcc_cv_ld_buildid" = xyes; then
4018   AC_DEFINE(HAVE_LD_BUILDID, 1,
4019   [Define if your linker supports --build-id.])
4020 fi
4021
4022 AC_ARG_ENABLE(linker-build-id,
4023 [  --enable-linker-build-id
4024                           compiler will always pass --build-id to linker],
4025 [],
4026 enable_linker_build_id=no)
4027
4028 if test x"$enable_linker_build_id" = xyes; then
4029   if test x"$gcc_cv_ld_buildid" = xyes; then
4030     AC_DEFINE(ENABLE_LD_BUILDID, 1,
4031     [Define if gcc should always pass --build-id to linker.])
4032   else
4033     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
4034   fi
4035 fi
4036
4037 AC_CACHE_CHECK(linker --sysroot support,
4038   gcc_cv_ld_sysroot,
4039   [gcc_cv_ld_sysroot=no
4040   if test $in_tree_ld = yes ; then
4041       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
4042         gcc_cv_ld_sysroot=yes
4043       fi
4044   elif test x$gcc_cv_ld != x; then
4045     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
4046       gcc_cv_ld_sysroot=yes
4047     fi
4048   fi])
4049 if test x"$gcc_cv_ld_sysroot" = xyes; then
4050   AC_DEFINE(HAVE_LD_SYSROOT, 1,
4051   [Define if your linker supports --sysroot.])
4052 fi
4053
4054 if test x$with_sysroot = x && test x$host = x$target \
4055    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
4056    && test "$prefix" != "NONE"; then
4057   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
4058 [Define to PREFIX/include if cpp should also search that directory.])
4059 fi
4060
4061 # Test for stack protector support in target C library.
4062 AC_CACHE_CHECK(__stack_chk_fail in target C library,
4063       gcc_cv_libc_provides_ssp,
4064       [gcc_cv_libc_provides_ssp=no
4065     case "$target" in
4066        *-*-linux* | *-*-kfreebsd*-gnu | *-*-knetbsd*-gnu)
4067       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
4068         if test "x$with_headers" != x; then
4069           glibc_header_dir=$with_headers
4070         elif test "x$with_sysroot" = x; then
4071           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
4072         elif test "x$with_build_sysroot" != "x"; then
4073           glibc_header_dir="${with_build_sysroot}/usr/include"
4074         elif test "x$with_sysroot" = xyes; then
4075           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
4076         else
4077           glibc_header_dir="${with_sysroot}/usr/include"
4078         fi
4079       else
4080         glibc_header_dir=/usr/include
4081       fi
4082       [# glibc 2.4 and later provides __stack_chk_fail and
4083       # either __stack_chk_guard, or TLS access to stack guard canary.
4084       if test -f $glibc_header_dir/features.h \
4085          && $EGREP '^[  ]*#[    ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
4086             $glibc_header_dir/features.h > /dev/null; then
4087         if $EGREP '^[   ]*#[    ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
4088            $glibc_header_dir/features.h > /dev/null; then
4089           gcc_cv_libc_provides_ssp=yes
4090         elif $EGREP '^[         ]*#[    ]*define[       ]+__GLIBC__[    ]+2' \
4091              $glibc_header_dir/features.h > /dev/null \
4092              && $EGREP '^[      ]*#[    ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
4093              $glibc_header_dir/features.h > /dev/null; then
4094           gcc_cv_libc_provides_ssp=yes
4095         elif $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC__[   ]+1' \
4096              $glibc_header_dir/features.h > /dev/null && \
4097              test -f $glibc_header_dir/bits/uClibc_config.h && \
4098              $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
4099              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
4100           gcc_cv_libc_provides_ssp=yes
4101         fi
4102       fi]
4103         ;;
4104        *-*-gnu*)
4105          # Avoid complicated tests (see
4106          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
4107          # simply assert that glibc does provide this, which is true for all
4108          # realistically usable GNU/Hurd configurations.
4109          gcc_cv_libc_provides_ssp=yes;;
4110        *-*-darwin* | *-*-freebsd*)
4111          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
4112            [echo "no __stack_chk_fail on this target"])
4113         ;;
4114   *) gcc_cv_libc_provides_ssp=no ;;
4115     esac])
4116
4117 if test x$gcc_cv_libc_provides_ssp = xyes; then
4118   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
4119             [Define if your target C library provides stack protector support])
4120 fi
4121
4122 # Check if TFmode long double should be used by default or not.
4123 # Some glibc targets used DFmode long double, but with glibc 2.4
4124 # and later they can use TFmode.
4125 case "$target" in
4126   powerpc*-*-linux* | \
4127   powerpc*-*-gnu* | \
4128   sparc*-*-linux* | \
4129   s390*-*-linux* | \
4130   alpha*-*-linux*)
4131     AC_ARG_WITH(long-double-128,
4132 [  --with-long-double-128  Use 128-bit long double by default.],
4133       gcc_cv_target_ldbl128="$with_long_double_128",
4134       [[gcc_cv_target_ldbl128=no
4135       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
4136         if test "x$with_sysroot" = x; then
4137           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
4138         elif test "x$with_build_sysroot" != "x"; then
4139           glibc_header_dir="${with_build_sysroot}/usr/include"
4140         elif test "x$with_sysroot" = xyes; then
4141           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
4142         else
4143           glibc_header_dir="${with_sysroot}/usr/include"
4144         fi
4145       else
4146         glibc_header_dir=/usr/include
4147       fi
4148       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
4149         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
4150       && gcc_cv_target_ldbl128=yes
4151       ]])
4152     ;;
4153 esac
4154 if test x$gcc_cv_target_ldbl128 = xyes; then
4155   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
4156             [Define if TFmode long double should be the default])
4157 fi
4158
4159 # Find out what GC implementation we want, or may, use.
4160 AC_ARG_WITH(gc,
4161 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
4162                           with the compiler],
4163 [case "$withval" in
4164   page)
4165     GGC=ggc-$withval
4166     ;;
4167   zone)
4168     GGC=ggc-$withval
4169     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
4170     ;;
4171   *)
4172     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
4173     ;;
4174 esac],
4175 [GGC=ggc-page])
4176 AC_SUBST(GGC)
4177 echo "Using $GGC for garbage collection."
4178
4179 # Libraries to use on the host.  This will normally be set by the top
4180 # level Makefile.  Here we simply capture the value for our Makefile.
4181 if test -z "${HOST_LIBS+set}"; then
4182   HOST_LIBS=
4183 fi
4184 AC_SUBST(HOST_LIBS)
4185
4186 # Use the system's zlib library.
4187 zlibdir=-L../zlib
4188 zlibinc="-I\$(srcdir)/../zlib"
4189 AC_ARG_WITH(system-zlib,
4190 [  --with-system-zlib      use installed libz],
4191 zlibdir=
4192 zlibinc=
4193 )
4194 AC_SUBST(zlibdir)
4195 AC_SUBST(zlibinc)
4196
4197 dnl Very limited version of automake's enable-maintainer-mode
4198
4199 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
4200   dnl maintainer-mode is disabled by default
4201   AC_ARG_ENABLE(maintainer-mode,
4202 [  --enable-maintainer-mode
4203                           enable make rules and dependencies not useful
4204                           (and sometimes confusing) to the casual installer],
4205       maintainer_mode=$enableval,
4206       maintainer_mode=no)
4207
4208 AC_MSG_RESULT($maintainer_mode)
4209
4210 if test "$maintainer_mode" = "yes"; then
4211   MAINT=''
4212 else
4213   MAINT='#'
4214 fi
4215 AC_SUBST(MAINT)dnl
4216
4217 # --------------
4218 # Language hooks
4219 # --------------
4220
4221 # Make empty files to contain the specs and options for each language.
4222 # Then add #include lines to for a compiler that has specs and/or options.
4223
4224 subdirs=
4225 lang_opt_files=
4226 lang_specs_files=
4227 lang_tree_files=
4228 # These (without "all_") are set in each config-lang.in.
4229 # `language' must be a single word so is spelled singularly.
4230 all_languages=
4231 all_compilers=
4232 all_outputs='Makefile gccbug'
4233 # List of language makefile fragments.
4234 all_lang_makefrags=
4235 # Additional files for gengtype
4236 all_gtfiles="$target_gtfiles"
4237
4238 # These are the languages that are set in --enable-languages,
4239 # and are available in the GCC tree.
4240 all_selected_languages=
4241
4242 # Add the language fragments.
4243 # Languages are added via two mechanisms.  Some information must be
4244 # recorded in makefile variables, these are defined in config-lang.in.
4245 # We accumulate them and plug them into the main Makefile.
4246 # The other mechanism is a set of hooks for each of the main targets
4247 # like `clean', `install', etc.
4248
4249 language_hooks="Make-hooks"
4250
4251 for lang in ${srcdir}/*/config-lang.in
4252 do
4253 changequote(,)dnl
4254         test "$lang" = "${srcdir}/*/config-lang.in" && continue
4255
4256         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
4257         if test "x$lang_alias" = x
4258         then
4259               echo "$lang doesn't set \$language." 1>&2
4260               exit 1
4261         fi
4262         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
4263         subdirs="$subdirs $subdir"
4264
4265         # $gcc_subdir is where the gcc integration files are to be found
4266         # for a language, both for internal compiler purposes (compiler
4267         # sources implementing front-end to GCC tree converters), and for
4268         # build infrastructure purposes (Make-lang.in, etc.)
4269         #
4270         # This will be <subdir> (relative to $srcdir) if a line like
4271         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
4272         # is found in <langdir>/config-lang.in, and will remain <langdir>
4273         # otherwise.
4274         #
4275         # Except for the language alias (fetched above), the regular
4276         # "config-lang.in" contents are always retrieved from $gcc_subdir,
4277         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
4278         # only this and the language alias.
4279
4280         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
4281         if [ "$gcc_subdir" = "" ]; then
4282            gcc_subdir="$subdir"
4283         fi
4284
4285         case ",$enable_languages," in
4286         *,$lang_alias,*)
4287             all_selected_languages="$all_selected_languages $lang_alias"
4288             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
4289                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
4290             fi
4291             ;;
4292         esac
4293 changequote([,])dnl
4294
4295         language=
4296         boot_language=
4297         compilers=
4298         outputs=
4299         gtfiles=
4300         subdir_requires=
4301         . ${srcdir}/$gcc_subdir/config-lang.in
4302         if test "x$language" = x
4303         then
4304                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
4305                 exit 1
4306         fi
4307
4308         ok=:
4309         case ",$enable_languages," in
4310                 *,$lang_alias,*) ;;
4311                 *)
4312                         for i in $subdir_requires; do
4313                                 test -f "${srcdir}/$i/config-lang.in" && continue
4314                                 ok=false
4315                                 break
4316                         done
4317                 ;;
4318         esac
4319         $ok || continue
4320
4321         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
4322         if test -f $srcdir/$gcc_subdir/lang.opt; then
4323             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
4324         fi
4325         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
4326             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
4327         fi
4328         all_languages="$all_languages $language"
4329         all_compilers="$all_compilers $compilers"
4330         all_outputs="$all_outputs $outputs"
4331         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
4332         case ",$enable_languages," in
4333                 *,lto,*)
4334                     AC_DEFINE(ENABLE_LTO, 1, [Define to enable LTO support.])
4335                     enable_lto=yes
4336                     AC_SUBST(enable_lto)
4337                     # LTO needs to speak the platform's object file format, and has a
4338                     # number of implementations of the required binary file access APIs.
4339                     # ELF is the most common, and default.  We only link libelf if ELF
4340                     # is indeed the selected format.
4341                     LTO_BINARY_READER=${lto_binary_reader}
4342                     LTO_USE_LIBELF=-lelf
4343                     if test "x$lto_binary_reader" != "xlto-elf" ; then
4344                       LTO_USE_LIBELF=
4345                     fi
4346                     AC_SUBST(LTO_BINARY_READER)
4347                     AC_SUBST(LTO_USE_LIBELF)
4348                     ;;
4349                 *) ;;
4350         esac
4351 done
4352
4353 # Pick up gtfiles for c
4354 gtfiles=
4355 . ${srcdir}/c-config-lang.in
4356 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
4357
4358 check_languages=
4359 for language in $all_selected_languages
4360 do
4361         check_languages="$check_languages check-$language"
4362 done
4363
4364 # We link each language in with a set of hooks, reached indirectly via
4365 # lang.${target}.  Only do so for selected languages.
4366
4367 rm -f Make-hooks
4368 touch Make-hooks
4369 target_list="all.cross start.encap rest.encap tags \
4370         install-common install-man install-info install-pdf install-html dvi \
4371         pdf html uninstall info man srcextra srcman srcinfo \
4372         mostlyclean clean distclean maintainer-clean install-plugin"
4373
4374 for t in $target_list
4375 do
4376         x=
4377         for lang in $all_selected_languages
4378         do
4379                 x="$x $lang.$t"
4380         done
4381         echo "lang.$t: $x" >> Make-hooks
4382 done
4383
4384 # --------
4385 # UNSORTED
4386 # --------
4387
4388 # Create .gdbinit.
4389
4390 echo "dir ." > .gdbinit
4391 echo "dir ${srcdir}" >> .gdbinit
4392 if test x$gdb_needs_out_file_path = xyes
4393 then
4394         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
4395 fi
4396 if test "x$subdirs" != x; then
4397         for s in $subdirs
4398         do
4399                 echo "dir ${srcdir}/$s" >> .gdbinit
4400         done
4401 fi
4402 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
4403
4404 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
4405 AC_SUBST(gcc_tooldir)
4406 AC_SUBST(dollar)
4407
4408 # Find a directory in which to install a shared libgcc.
4409
4410 AC_ARG_ENABLE(version-specific-runtime-libs,
4411 [  --enable-version-specific-runtime-libs
4412                           specify that runtime libraries should be
4413                           installed in a compiler-specific directory])
4414
4415 AC_ARG_WITH(slibdir,
4416 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
4417 slibdir="$with_slibdir",
4418 if test "${enable_version_specific_runtime_libs+set}" = set; then
4419   slibdir='$(libsubdir)'
4420 elif test "$host" != "$target"; then
4421   slibdir='$(build_tooldir)/lib'
4422 else
4423   slibdir='$(libdir)'
4424 fi)
4425 AC_SUBST(slibdir)
4426
4427 # Substitute configuration variables
4428 AC_SUBST(subdirs)
4429 AC_SUBST(srcdir)
4430 AC_SUBST(all_compilers)
4431 AC_SUBST(all_gtfiles)
4432 AC_SUBST(all_lang_makefrags)
4433 AC_SUBST(all_languages)
4434 AC_SUBST(all_selected_languages)
4435 AC_SUBST(build_exeext)
4436 AC_SUBST(build_install_headers_dir)
4437 AC_SUBST(build_xm_file_list)
4438 AC_SUBST(build_xm_include_list)
4439 AC_SUBST(build_xm_defines)
4440 AC_SUBST(build_file_translate)
4441 AC_SUBST(check_languages)
4442 AC_SUBST(cpp_install_dir)
4443 AC_SUBST(xmake_file)
4444 AC_SUBST(tmake_file)
4445 AC_SUBST(TM_ENDIAN_CONFIG)
4446 AC_SUBST(TM_MULTILIB_CONFIG)
4447 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
4448 AC_SUBST(extra_gcc_objs)
4449 AC_SUBST(extra_headers_list)
4450 AC_SUBST(extra_objs)
4451 AC_SUBST(extra_parts)
4452 AC_SUBST(extra_passes)
4453 AC_SUBST(extra_programs)
4454 AC_SUBST(float_h_file)
4455 AC_SUBST(gcc_config_arguments)
4456 AC_SUBST(gcc_gxx_include_dir)
4457 AC_SUBST(host_exeext)
4458 AC_SUBST(host_xm_file_list)
4459 AC_SUBST(host_xm_include_list)
4460 AC_SUBST(host_xm_defines)
4461 AC_SUBST(out_host_hook_obj)
4462 AC_SUBST(install)
4463 AC_SUBST(lang_opt_files)
4464 AC_SUBST(lang_specs_files)
4465 AC_SUBST(lang_tree_files)
4466 AC_SUBST(local_prefix)
4467 AC_SUBST(md_file)
4468 AC_SUBST(objc_boehm_gc)
4469 AC_SUBST(out_file)
4470 AC_SUBST(out_object_file)
4471 AC_SUBST(thread_file)
4472 AC_SUBST(tm_file_list)
4473 AC_SUBST(tm_include_list)
4474 AC_SUBST(tm_defines)
4475 AC_SUBST(tm_p_file_list)
4476 AC_SUBST(tm_p_include_list)
4477 AC_SUBST(xm_file_list)
4478 AC_SUBST(xm_include_list)
4479 AC_SUBST(xm_defines)
4480 AC_SUBST(use_gcc_stdint)
4481 AC_SUBST(c_target_objs)
4482 AC_SUBST(cxx_target_objs)
4483 AC_SUBST(fortran_target_objs)
4484 AC_SUBST(target_cpu_default)
4485
4486 AC_SUBST_FILE(language_hooks)
4487
4488 # Echo link setup.
4489 if test x${build} = x${host} ; then
4490   if test x${host} = x${target} ; then
4491     echo "Links are now set up to build a native compiler for ${target}." 1>&2
4492   else
4493     echo "Links are now set up to build a cross-compiler" 1>&2
4494     echo " from ${host} to ${target}." 1>&2
4495   fi
4496 else
4497   if test x${host} = x${target} ; then
4498     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
4499     echo " for ${target}." 1>&2
4500   else
4501     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
4502     echo " from ${host} to ${target}." 1>&2
4503   fi
4504 fi
4505
4506 AC_ARG_VAR(GMPLIBS,[How to link GMP])
4507 AC_ARG_VAR(GMPINC,[How to find GMP include files])
4508
4509 AC_ARG_VAR(PPLLIBS,[How to link PPL])
4510 AC_ARG_VAR(PPLINC,[How to find PPL include files])
4511
4512 AC_ARG_VAR(CLOOGLIBS,[How to link CLOOG])
4513 AC_ARG_VAR(CLOOGINC,[How to find CLOOG include files])
4514 if test "x${CLOOGLIBS}" != "x" ; then
4515    AC_DEFINE(HAVE_cloog, 1, [Define if cloog is in use.])
4516 fi
4517
4518 AC_ARG_VAR(LIBELFLIBS,[How to link libelf])
4519 AC_ARG_VAR(LIBELFINC,[How to find libelf include files])
4520 if test "x${LIBELFLIBS}" != "x" ; then
4521    AC_DEFINE(HAVE_libelf, 1, [Define if libelf is in use.])
4522 fi
4523
4524 # Check for plugin support
4525 AC_ARG_ENABLE(plugin,
4526 [  --enable-plugin         enable plugin support],
4527 enable_plugin=$enableval,
4528 enable_plugin=yes; default_plugin=yes)
4529
4530 pluginlibs=
4531 if test x"$enable_plugin" = x"yes"; then
4532
4533   case "${host}" in
4534     *-*-darwin*)
4535       export_sym_check="$gcc_cv_nm -g"
4536     ;;
4537     *)
4538       export_sym_check="$gcc_cv_objdump -T"
4539     ;;
4540   esac
4541   AC_MSG_CHECKING([for exported symbols])
4542   echo "int main() {return 0;} int foobar() {return 0;}" > conftest.c
4543   ${CC} ${CFLAGS} ${LDFLAGS} conftest.c -o conftest > /dev/null 2>&1
4544   if $export_sym_check conftest | grep foobar > /dev/null; then
4545     : # No need to use a flag
4546   else
4547     AC_MSG_CHECKING([for -rdynamic])
4548     ${CC} ${CFLAGS} ${LDFLAGS} -rdynamic conftest.c -o conftest > /dev/null 2>&1
4549     if $export_sym_check conftest | grep foobar > /dev/null; then
4550       plugin_rdynamic=yes
4551       pluginlibs="-rdynamic"
4552     else
4553       plugin_rdynamic=no
4554       enable_plugin=no
4555     fi
4556     AC_MSG_RESULT([$plugin_rdynamic])
4557   fi
4558
4559   # Check -ldl
4560   saved_LIBS="$LIBS"
4561   AC_SEARCH_LIBS([dlopen], [dl])
4562   if test x"$ac_cv_search_dlopen" = x"-ldl"; then
4563     pluginlibs="$pluginlibs -ldl"
4564   fi
4565   LIBS="$saved_LIBS"
4566
4567   # Check that we can build shared objects with -fPIC -shared
4568   saved_LDFLAGS="$LDFLAGS"
4569   case "${host}" in
4570     *-*-darwin*)
4571       LDFLAGS="$LDFLAGS -fPIC -shared -undefined dynamic_lookup"
4572     ;;
4573     *)
4574       LDFLAGS="$LDFLAGS -fPIC -shared"
4575     ;;
4576   esac
4577   AC_MSG_CHECKING([for -fPIC -shared])
4578   AC_TRY_LINK(
4579     [extern int X;],[return X == 0;],
4580     [AC_MSG_RESULT([yes]); have_pic_shared=yes],
4581     [AC_MSG_RESULT([no]); have_pic_shared=no])
4582   if test x"$have_pic_shared" != x"yes" -o x"$ac_cv_search_dlopen" = x"no"; then
4583     pluginlibs=
4584     enable_plugin=no
4585   fi
4586   LDFLAGS="$saved_LDFLAGS"
4587
4588   # If plugin support had been requested but not available, fail.
4589   if test x"$enable_plugin" = x"no" ; then
4590     if test x"$default_plugin" != x"yes"; then
4591       AC_MSG_ERROR([
4592 Building GCC with plugin support requires a host that supports
4593 -fPIC, -shared, -ldl and -rdynamic.])
4594     fi
4595   fi
4596 fi
4597
4598 AC_SUBST(pluginlibs)
4599 AC_SUBST(enable_plugin)
4600 if test x"$enable_plugin" = x"yes"; then
4601   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
4602 fi
4603
4604 # Configure the subdirectories
4605 # AC_CONFIG_SUBDIRS($subdirs)
4606
4607 # Create the Makefile
4608 # and configure language subdirectories
4609 AC_CONFIG_FILES($all_outputs)
4610
4611 AC_CONFIG_COMMANDS([default],
4612 [
4613 case ${CONFIG_HEADERS} in
4614   *auto-host.h:config.in*)
4615   echo > cstamp-h ;;
4616 esac
4617 # Make sure all the subdirs exist.
4618 for d in $subdirs doc build
4619 do
4620     test -d $d || mkdir $d
4621 done
4622 ],
4623 [subdirs='$subdirs'])
4624 AC_OUTPUT