libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12 sinclude(../config/gthr.m4)
  13 sinclude(../config/sjlj.m4)
  14
  15 AC_PREREQ(2.64)
  16 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  17 AC_CONFIG_SRCDIR([static-object.mk])
  18
  19 # The libgcc should not depend on any header files
  20 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  21   [m4_divert_text([DEFAULTS],
  22     [ac_includes_default='/* none */'])])
  23
  24 AC_ARG_WITH(target-subdir,
  25 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  26 AC_ARG_WITH(cross-host,
  27 [  --with-cross-host=HOST           Configuring with a cross compiler])
  28 AC_ARG_WITH(ld,
  29 [  --with-ld               arrange to use the specified ld (full pathname)])
  30
  31 if test "${srcdir}" = "."; then
  32   if test -n "${with_build_subdir}"; then
  33     libgcc_topdir="${srcdir}/../.."
  34     with_target_subdir=
  35   elif test -z "${with_target_subdir}"; then
  36     libgcc_topdir="${srcdir}/.."
  37   else
  38     if test "${with_target_subdir}" != "."; then
  39       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  40     else
  41       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  42     fi
  43   fi
  44 else
  45   libgcc_topdir="${srcdir}/.."
  46 fi
  47 AC_SUBST(libgcc_topdir)
  48 AC_CONFIG_AUX_DIR($libgcc_topdir)
  49 AC_CONFIG_HEADER(auto-target.h:config.in)
  50
  51 AC_ARG_ENABLE(shared,
  52 [  --disable-shared        don't provide a shared libgcc],
  53 [
  54   case $enable_shared in
  55   yes | no) ;;
  56   *)
  57     enable_shared=no
  58     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  59     for pkg in $enableval; do
  60       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  61         enable_shared=yes
  62       fi
  63     done
  64     IFS="$ac_save_ifs"
  65     ;;
  66   esac
  67 ], [enable_shared=yes])
  68 AC_SUBST(enable_shared)
  69
  70 AC_ARG_ENABLE(vtable-verify,
  71 [  --enable-vtable-verify    Enable vtable verification feature ],
  72 [case "$enableval" in
  73  yes) enable_vtable_verify=yes ;;
  74  no)  enable_vtable_verify=no ;;
  75  *)   enable_vtable_verify=no;;
  76  esac],
  77 [enable_vtable_verify=no])
  78 AC_SUBST(enable_vtable_verify)
  79
  80 AC_ARG_WITH(aix-soname,
  81 [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
  82     [shared library versioning (aka "SONAME") variant to provide on AIX])],
  83 [case "${host}:${enable_shared}" in
  84  power*-*-aix[[5-9]]*:yes)
  85    AC_MSG_CHECKING([which variant of shared library versioning to provide for shared libgcc])
  86    case ${withval} in
  87      aix|svr4|both) ;;
  88      *) AC_MSG_ERROR([Unknown argument to --with-aix-soname]);;
  89    esac
  90    AC_MSG_RESULT($withval)
  91    ;;
  92  *) with_aix_soname=aix ;;
  93  esac
  94 ], [with_aix_soname=aix])
  95 AC_SUBST(with_aix_soname)
  96
  97 GCC_PICFLAG
  98 AC_SUBST(PICFLAG)
  99
 100 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 101 AC_ARG_ENABLE(version-specific-runtime-libs,
 102 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
 103 [case "$enableval" in
 104  yes) version_specific_libs=yes ;;
 105  no)  version_specific_libs=no ;;
 106  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 107  esac],
 108 [version_specific_libs=no])
 109 AC_MSG_RESULT($version_specific_libs)
 110
 111 AC_ARG_WITH(slibdir,
 112 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
 113 slibdir="$with_slibdir",
 114 if test "${version_specific_libs}" = yes; then
 115   slibdir='$(libsubdir)'
 116 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
 117   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 118 else
 119   slibdir='$(libdir)'
 120 fi)
 121 AC_SUBST(slibdir)
 122
 123 # Command-line options.
 124 # Very limited version of AC_MAINTAINER_MODE.
 125 AC_ARG_ENABLE([maintainer-mode],
 126   [AC_HELP_STRING([--enable-maintainer-mode],
 127                  [enable make rules and dependencies not useful (and
 128                   sometimes confusing) to the casual installer])],
 129   [case ${enable_maintainer_mode} in
 130      yes) MAINT='' ;;
 131      no) MAINT='#' ;;
 132      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 133    esac
 134    maintainer_mode=${enableval}],
 135   [MAINT='#'])
 136 AC_SUBST([MAINT])dnl
 137
 138 AC_PROG_INSTALL
 139
 140 AC_PROG_AWK
 141 # We need awk; bail out if it's missing.
 142 case ${AWK} in
 143   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 144 esac
 145
 146 AC_CANONICAL_HOST
 147 ACX_NONCANONICAL_HOST
 148 ACX_NONCANONICAL_TARGET
 149 GCC_TOPLEV_SUBDIRS
 150
 151 # Calculate toolexeclibdir
 152 # Also toolexecdir, though it's only used in toolexeclibdir
 153 case ${version_specific_libs} in
 154   yes)
 155     # Need the gcc compiler version to know where to install libraries
 156     # and header files if --enable-version-specific-runtime-libs option
 157     # is selected.
 158     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 159     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 160     ;;
 161   no)
 162     if test -n "$with_cross_host" &&
 163        test x"$with_cross_host" != x"no"; then
 164       # Install a library built with a cross compiler in tooldir, not libdir.
 165       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 166       toolexeclibdir='$(toolexecdir)/lib'
 167     else
 168       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 169       toolexeclibdir='$(libdir)'
 170     fi
 171     multi_os_directory=`$CC -print-multi-os-directory`
 172     case $multi_os_directory in
 173       .) ;; # Avoid trailing /.
 174       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 175     esac
 176     ;;
 177 esac
 178 AC_SUBST(toolexecdir)
 179 AC_SUBST(toolexeclibdir)
 180
 181 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 182 dnl to call AC_CHECK_PROG.
 183 AC_CHECK_TOOL(AR, ar)
 184 AC_CHECK_TOOL(LIPO, lipo, :)
 185 AC_CHECK_TOOL(NM, nm)
 186 AC_CHECK_TOOL(RANLIB, ranlib, :)
 187 AC_CHECK_TOOL(STRIP, strip, :)
 188 AC_PROG_LN_S
 189
 190 GCC_NO_EXECUTABLES
 191 AC_PROG_CC
 192 AC_PROG_CPP_WERROR
 193
 194 AC_CHECK_SIZEOF([double])
 195 AC_CHECK_SIZEOF([long double])
 196 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 197 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 198 AC_SUBST(double_type_size)
 199 AC_SUBST(long_double_type_size)
 200
 201 AC_CHECK_HEADERS(inttypes.h stdint.h stdlib.h ftw.h \
 202         unistd.h sys/stat.h sys/types.h \
 203         string.h strings.h memory.h)
 204 AC_HEADER_STDC
 205
 206 # Check for decimal float support.
 207 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 208                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 209 #include <fenv.h>
 210 ]], [[
 211 _Decimal32 x;
 212 int fe_except =
 213   FE_INVALID|FE_DIVBYZERO|FE_OVERFLOW|FE_UNDERFLOW|FE_INEXACT;
 214 ]])],
 215                                   [libgcc_cv_dfp=yes],
 216                                   [libgcc_cv_dfp=no])])
 217 decimal_float=$libgcc_cv_dfp
 218 AC_SUBST(decimal_float)
 219
 220 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 221
 222 # Check for fixed-point support.
 223 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 224                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 225                                   [libgcc_cv_fixed_point=no])])
 226 fixed_point=$libgcc_cv_fixed_point
 227 AC_SUBST(fixed_point)
 228
 229 # For platforms with the unwind ABI which includes an unwind library,
 230 # libunwind, we can choose to use the system libunwind.
 231 # config.gcc also contains tests of with_system_libunwind.
 232 GCC_CHECK_UNWIND_GETIPINFO
 233
 234 # Check if the compiler is configured for setjmp/longjmp exceptions.
 235 GCC_CHECK_SJLJ_EXCEPTIONS
 236
 237 AC_ARG_ENABLE([explicit-exception-frame-registration],
 238   [AC_HELP_STRING([--enable-explicit-exception-frame-registration],
 239      [register exception tables explicitly at module start, for use
 240       e.g. for compatibility with installations without PT_GNU_EH_FRAME support])],
 241 [
 242 force_explicit_eh_registry=
 243 if test "$enable_explicit_exception_frame_registration" = yes; then
 244   if test $ac_cv_sjlj_exceptions = yes; then
 245     AC_MSG_ERROR([Can't --enable-explicit-exception-frame-registration
 246                   with setjmp/longjmp exceptions])
 247   fi
 248   force_explicit_eh_registry=-DUSE_EH_FRAME_REGISTRY_ALWAYS
 249 fi
 250 ])
 251 AC_SUBST([force_explicit_eh_registry])
 252
 253 AC_LIB_PROG_LD_GNU
 254
 255 AC_MSG_CHECKING([for thread model used by GCC])
 256 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 257 AC_MSG_RESULT([$target_thread_file])
 258
 259 # Check for assembler CFI support.
 260 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 261                [AC_COMPILE_IFELSE(
 262 [asm("\n\
 263         .text\n\
 264         .cfi_startproc\n\
 265         .cfi_personality 0, symbol\n\
 266         .cfi_endproc");],
 267   [libgcc_cv_cfi=yes],
 268   [libgcc_cv_cfi=no])])
 269
 270 # Check 32bit or 64bit.  In the case of MIPS, this really determines the
 271 # word size rather than the address size.
 272 cat > conftest.c <<EOF
 273 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__)) \
 274     || defined(__mips64)
 275 host_address=64
 276 #else
 277 host_address=32
 278 #endif
 279 EOF
 280 eval `${CC-cc} -E conftest.c | grep host_address=`
 281 rm -f conftest.c
 282
 283 case ${host} in
 284 mips*-*-*)
 285   AC_CACHE_CHECK([whether the target is hard-float],
 286                  [libgcc_cv_mips_hard_float],
 287                  [AC_COMPILE_IFELSE(
 288     [#ifndef __mips_hard_float
 289      #error FOO
 290      #endif],
 291     [libgcc_cv_mips_hard_float=yes],
 292     [libgcc_cv_mips_hard_float=no])])
 293 esac
 294
 295 # Determine the version of glibc, if any, used on the target.
 296 AC_MSG_CHECKING([for target glibc version])
 297 AC_ARG_WITH([glibc-version],
 298   [AS_HELP_STRING([--with-glibc-version=M.N],
 299     [assume GCC used with glibc version M.N or later])], [
 300 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
 301   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
 302   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
 303 else
 304   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
 305 fi], [
 306 AC_COMPUTE_INT([glibc_version_major], [__GLIBC__],
 307                                       [#include <features.h>],
 308                                       [glibc_version_major=0])
 309 AC_COMPUTE_INT([glibc_version_minor], [__GLIBC_MINOR__],
 310                                       [#include <features.h>],
 311                                       [glibc_version_minor=0])])
 312 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
 313
 314 # Determine floating-point type for powerpc*-*-linux*.
 315 # Single-precision-only FPRs are not a supported configuration for
 316 # this target, so are not allowed for in this test.
 317 case ${host} in
 318 powerpc*-*-linux*)
 319   cat > conftest.c <<EOF
 320 #ifdef __powerpc64__
 321 ppc_fp_type=64
 322 #elif defined _SOFT_FLOAT
 323 ppc_fp_type=soft
 324 #elif defined _SOFT_DOUBLE
 325 ppc_fp_type=e500v1
 326 #elif defined __NO_FPRS__
 327 ppc_fp_type=e500v2
 328 #else
 329 ppc_fp_type=hard
 330 #endif
 331 EOF
 332 eval `${CC-cc} -E conftest.c | grep ppc_fp_type=`
 333 rm -f conftest.c
 334 # glibc 2.19 and later provide all the soft-fp functions, with proper
 335 # interactions with <fenv.h> exception and rounding mode handling, so
 336 # make libgcc's versions into compat symbols if a recent enough glibc
 337 # version is being used.
 338 ppc_fp_compat=
 339 case ${ppc_fp_type} in
 340 soft|e500v1|e500v2)
 341   if test $glibc_version_major -gt 2 \
 342     || ( test $glibc_version_major -eq 2 \
 343         && test $glibc_version_minor -ge 19 ); then
 344     ppc_fp_compat="t-softfp-compat"
 345   fi
 346   ;;
 347 esac
 348 ;;
 349 esac
 350
 351 # Collect host-machine-specific information.
 352 . ${srcdir}/config.host
 353
 354 # Used for constructing correct paths for offload compilers.
 355 accel_dir_suffix=
 356 real_host_noncanonical=${host_noncanonical}
 357 if test x"$enable_as_accelerator_for" != x; then
 358   accel_dir_suffix=/accel/${target_noncanonical}
 359   real_host_noncanonical=${enable_as_accelerator_for}
 360 fi
 361 AC_SUBST(accel_dir_suffix)
 362 AC_SUBST(real_host_noncanonical)
 363
 364 if test x"$enable_offload_targets" != x; then
 365   extra_parts="${extra_parts} crtoffloadbegin.o crtoffloadend.o"
 366 fi
 367
 368 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 369 # This is after config.host so we can augment tmake_file.
 370 # Link with -nostartfiles -nodefaultlibs since neither are present while
 371 # building libgcc.
 372 case ${host} in
 373 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 374   cat > conftest.s <<EOF
 375         .section        .eh_frame,"a",@unwind
 376         .zero   4
 377         .section        .jcr,"aw",@progbits
 378         .zero   8
 379 EOF
 380   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 381       tmake_file="${tmake_file} i386/t-crtstuff"
 382   fi
 383   ;;
 384 esac
 385
 386 # Check if xtensa target is configured for windowed ABI and thus needs to use
 387 # custom unwind code.
 388 # This is after config.host so we can augment tmake_file.
 389 case ${host} in
 390 xtensa*-*)
 391   cat > conftest.c <<EOF
 392         #ifdef __XTENSA_CALL0_ABI__
 393         #error
 394         #endif
 395 EOF
 396   if AC_TRY_COMMAND(${CC-cc} -E -o conftest.i conftest.c 1>&AS_MESSAGE_LOG_FD); then
 397       tmake_file="${tmake_file} xtensa/t-windowed"
 398   fi
 399   ;;
 400 esac
 401
 402 # Check for visibility support.  This is after config.host so that
 403 # we can check for asm_hidden_op.
 404 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 405     libgcc_cv_hidden_visibility_attribute, [
 406         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 407         libgcc_cv_hidden_visibility_attribute=no
 408         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 409             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 410                 libgcc_cv_hidden_visibility_attribute=yes
 411             fi
 412         fi
 413         rm -f conftest.*
 414     ])
 415
 416 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 417     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 418 else
 419     vis_hide=
 420 fi
 421 AC_SUBST(vis_hide)
 422
 423 # See if we have thread-local storage.  We can only test assembler
 424 # since link-time and run-time tests require the newly built
 425 # gcc, which can't be used to build executable due to that libgcc
 426 # is yet to be built here.
 427 GCC_CHECK_CC_TLS
 428 set_have_cc_tls=
 429 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 430   set_have_cc_tls="-DHAVE_CC_TLS"
 431 fi
 432 AC_SUBST(set_have_cc_tls)
 433
 434 # See if we have emulated thread-local storage.
 435 GCC_CHECK_EMUTLS
 436 set_use_emutls=
 437 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 438   set_use_emutls="-DUSE_EMUTLS"
 439 fi
 440 AC_SUBST(set_use_emutls)
 441
 442 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 443 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 444   [[void ip (void) __attribute__ ((constructor (1)));]])],
 445   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 446 if test $libgcc_cv_init_priority = yes; then
 447   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 448   [Define if the compiler supports init priority.])
 449 fi
 450
 451 # Conditionalize the sfp-machine.h header for this target machine.
 452 if test -z "${sfp_machine_header}"; then
 453         sfp_machine_header=$cpu_type/sfp-machine.h
 454         if test -f ${srcdir}/config/${sfp_machine_header}; then
 455                 :
 456         else
 457                 sfp_machine_header=no-sfp-machine.h
 458         fi
 459 fi
 460 AC_SUBST(sfp_machine_header)
 461
 462 # Conditionalize the makefile for this target machine.
 463 tmake_file_=
 464 for f in ${tmake_file}
 465 do
 466         if test -f ${srcdir}/config/$f
 467         then
 468                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 469         fi
 470 done
 471 tmake_file="${tmake_file_}"
 472 AC_SUBST(tmake_file)
 473
 474 # Likewise export definitions for libgcc_tm.h
 475 tm_file_=
 476 for f in ${tm_file}
 477 do
 478         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 479 done
 480 tm_file="${tm_file_}"
 481 AC_SUBST(tm_file)
 482 AC_SUBST(tm_defines)
 483
 484 # Map from thread model to thread header.
 485 GCC_AC_THREAD_HEADER([$target_thread_file])
 486
 487 # Substitute configuration variables
 488 AC_SUBST(cpu_type)
 489 AC_SUBST(extra_parts)
 490 AC_SUBST(asm_hidden_op)
 491 AC_CONFIG_LINKS([enable-execute-stack.c:$enable_execute_stack])
 492 AC_CONFIG_LINKS([unwind.h:$unwind_header])
 493 AC_CONFIG_LINKS([md-unwind-support.h:config/$md_unwind_header])
 494 AC_CONFIG_LINKS([sfp-machine.h:config/$sfp_machine_header])
 495 AC_CONFIG_LINKS([gthr-default.h:$thread_header])
 496
 497 # We need multilib support.
 498 AC_CONFIG_FILES([Makefile])
 499 AC_CONFIG_COMMANDS([default],
 500   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 501 if test -n "$CONFIG_FILES"; then
 502   # FIXME: We shouldn't need to set ac_file
 503   ac_file=Makefile
 504   . ${libgcc_topdir}/config-ml.in
 505 fi]],
 506 [[srcdir=${srcdir}
 507 host=${host}
 508 with_target_subdir=${with_target_subdir}
 509 with_multisubdir=${with_multisubdir}
 510 ac_configure_args="--enable-multilib ${ac_configure_args}"
 511 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 512 libgcc_topdir=${libgcc_topdir}
 513 CC="${CC}"
 514 ]])
 515 AC_OUTPUT