gcc/ada/a-comlin.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                     A D A . C O M M A N D _ L I N E                      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2003 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System;                 use System;
  35
  36 package body Ada.Command_Line is
  37
  38    function Arg_Count return Natural;
  39    pragma Import (C, Arg_Count, "__gnat_arg_count");
  40
  41    procedure Fill_Arg (A : System.Address; Arg_Num : Integer);
  42    pragma Import (C, Fill_Arg, "__gnat_fill_arg");
  43
  44    function Len_Arg (Arg_Num : Integer) return Integer;
  45    pragma Import (C, Len_Arg, "__gnat_len_arg");
  46
  47    -----------------------
  48    -- Local Subprograms --
  49    -----------------------
  50
  51    function Initialized return Boolean;
  52    --  Checks to ensure that gnat_argc and gnat_argv have been properly
  53    --  initialized.  Returns false if not, or if argv / argc are
  54    --  unsupported on the target (e.g. VxWorks).
  55
  56    --------------
  57    -- Argument --
  58    --------------
  59
  60    function Argument (Number : in Positive) return String is
  61       Num : Positive;
  62
  63    begin
  64       if Number > Argument_Count then
  65          raise Constraint_Error;
  66       end if;
  67
  68       if Remove_Args = null then
  69          Num := Number;
  70       else
  71          Num := Remove_Args (Number);
  72       end if;
  73
  74       declare
  75          Arg : aliased String (1 .. Len_Arg (Num));
  76
  77       begin
  78          Fill_Arg (Arg'Address, Num);
  79          return Arg;
  80       end;
  81    end Argument;
  82
  83    --------------------
  84    -- Argument_Count --
  85    --------------------
  86
  87    function Argument_Count return Natural is
  88    begin
  89       if not Initialized then
  90          --  RM A.15 (11)
  91          return 0;
  92       end if;
  93
  94       if Remove_Args = null then
  95          return Arg_Count - 1;
  96       else
  97          return Remove_Count;
  98       end if;
  99    end Argument_Count;
 100
 101    -----------------
 102    -- Initialized --
 103    -----------------
 104
 105    function Initialized return Boolean is
 106       gnat_argv : System.Address;
 107       pragma Import (C, gnat_argv, "gnat_argv");
 108
 109    begin
 110       return gnat_argv /= System.Null_Address;
 111    end Initialized;
 112
 113    ------------------
 114    -- Command_Name --
 115    ------------------
 116
 117    function Command_Name return String is
 118    begin
 119       if not Initialized then
 120          return "";
 121       end if;
 122
 123       declare
 124          Arg : aliased String (1 .. Len_Arg (0));
 125
 126       begin
 127          Fill_Arg (Arg'Address, 0);
 128          return Arg;
 129       end;
 130    end Command_Name;
 131
 132 end Ada.Command_Line;