gcc/ada/sem_attr.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ A T T R                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- You should have received a copy of the GNU General Public License along  --
  19 -- with this program; see file COPYING3.  If not see                        --
  20 -- <http://www.gnu.org/licenses/>.                                          --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  Attribute handling is isolated in a separate package to ease the addition
  28 --  of implementation defined attributes. Logically this processing belongs
  29 --  in chapter 4. See Sem_Ch4 for a description of the relation of the
  30 --  Analyze and Resolve routines for expression components.
  31
  32 --  This spec also documents all GNAT implementation defined pragmas
  33
  34 with Exp_Tss; use Exp_Tss;
  35 with Namet;   use Namet;
  36 with Snames;  use Snames;
  37 with Types;   use Types;
  38
  39 package Sem_Attr is
  40
  41    -----------------------------------------
  42    -- Implementation Dependent Attributes --
  43    -----------------------------------------
  44
  45    --  This section describes the implementation dependent attributes
  46    --  provided in GNAT, as well as constructing an array of flags
  47    --  indicating which attributes these are.
  48
  49    Attribute_Impl_Def : Attribute_Class_Array := Attribute_Class_Array'(
  50
  51       ------------------
  52       -- Abort_Signal --
  53       ------------------
  54
  55       Attribute_Abort_Signal => True,
  56       --  Standard'Abort_Signal (Standard is the only allowed prefix) provides
  57       --  the entity for the special exception used to signal task abort or
  58       --  asynchronous transfer of control. Normally this attribute should only
  59       --  be used in the tasking runtime (it is highly peculiar, and completely
  60       --  outside the normal semantics of Ada, for a user program to intercept
  61       --  the abort exception).
  62
  63       ------------------
  64       -- Address_Size --
  65       ------------------
  66
  67       Attribute_Address_Size => True,
  68       --  Standard'Address_Size (Standard is the only allowed prefix) is
  69       --  a static constant giving the number of bits in an Address. It
  70       --  is used primarily for constructing the definition of Memory_Size
  71       --  in package Standard, but may be freely used in user programs.
  72       --  This is a static attribute.
  73
  74       ---------------
  75       -- Asm_Input --
  76       ---------------
  77
  78       Attribute_Asm_Input => True,
  79       --  Used only in conjunction with the Asm subprograms in package
  80       --  Machine_Code to construct machine instructions. See documentation
  81       --  in package Machine_Code in file s-maccod.ads.
  82
  83       ----------------
  84       -- Asm_Output --
  85       ----------------
  86
  87       Attribute_Asm_Output => True,
  88       --  Used only in conjunction with the Asm subprograms in package
  89       --  Machine_Code to construct machine instructions. See documentation
  90       --  in package Machine_Code in file s-maccod.ads.
  91
  92       ---------------
  93       -- AST_Entry --
  94       ---------------
  95
  96       Attribute_AST_Entry => True,
  97       --  E'Ast_Entry, where E is a task entry, yields a value of the
  98       --  predefined type System.DEC.AST_Handler, that enables the given
  99       --  entry to be called when an AST occurs. If the name to which the
 100       --  attribute applies has not been specified with the pragma AST_Entry,
 101       --  the attribute returns the value No_Ast_Handler, and no AST occurs.
 102       --  If the entry is for a task that is not callable (T'Callable False),
 103       --  the exception program error is raised. If an AST occurs for an
 104       --  entry of a task that is terminated, the program is erroneous.
 105       --
 106       --  The attribute AST_Entry is supported only in OpenVMS versions
 107       --  of GNAT. It will be rejected as illegal in other GNAT versions.
 108
 109       ---------
 110       -- Bit --
 111       ---------
 112
 113       Attribute_Bit => True,
 114       --  Obj'Bit, where Obj is any object, yields the bit offset within the
 115       --  storage unit (byte) that contains the first bit of storage allocated
 116       --  for the object. The attribute value is of type Universal_Integer,
 117       --  and is always a non-negative number not exceeding the value of
 118       --  System.Storage_Unit.
 119       --
 120       --  For an object that is a variable or a constant allocated in a
 121       --  register, the value is zero. (The use of this attribute does not
 122       --  force the allocation of a variable to memory).
 123       --
 124       --  For an object that is a formal parameter, this attribute applies to
 125       --  either the matching actual parameter or to a copy of the matching
 126       --  actual parameter.
 127       --
 128       --  For an access object the value is zero. Note that Obj.all'Bit is
 129       --  subject to an Access_Check for the designated object. Similarly
 130       --  for a record component X.C'Bit is subject to a discriminant check
 131       --  and X(I).Bit and X(I1..I2)'Bit are subject to index checks.
 132       --
 133       --  This attribute is designed to be compatible with the DEC Ada
 134       --  definition and implementation of the Bit attribute.
 135
 136       ------------------
 137       -- Code_Address --
 138       ------------------
 139
 140       Attribute_Code_Address => True,
 141       --  The reference subp'Code_Address, where subp is a subprogram entity,
 142       --  gives the address of the first generated instruction for the sub-
 143       --  program. This is often, but not always the same as the 'Address
 144       --  value, which is the address to be used in a call. The differences
 145       --  occur in the case of a nested procedure (where Address yields the
 146       --  address of the trampoline code used to load the static link), and on
 147       --  some systems which use procedure descriptors (in which case Address
 148       --  yields the address of the descriptor).
 149
 150       -----------------------
 151       -- Default_Bit_Order --
 152       -----------------------
 153
 154       Attribute_Default_Bit_Order => True,
 155       --  Standard'Default_Bit_Order (Standard is the only permissible prefix),
 156       --  provides the value System.Default_Bit_Order as a Pos value (0 for
 157       --  High_Order_First, 1 for Low_Order_First). This is used to construct
 158       --  the definition of Default_Bit_Order in package System. This is a
 159       --  static attribute.
 160
 161       ---------------
 162       -- Elab_Body --
 163       ---------------
 164
 165       Attribute_Elab_Body => True,
 166       --  This attribute can only be applied to a program unit name. It returns
 167       --  the entity for the corresponding elaboration procedure for elabor-
 168       --  ating the body of the referenced unit. This is used in the main
 169       --  generated elaboration procedure by the binder, and is not normally
 170       --  used in any other context, but there may be specialized situations in
 171       --  which it is useful to be able to call this elaboration procedure from
 172       --  Ada code, e.g. if it is necessary to do selective reelaboration to
 173       --  fix some error.
 174
 175       ---------------
 176       -- Elab_Spec --
 177       ---------------
 178
 179       Attribute_Elab_Spec => True,
 180       --  This attribute can only be applied to a program unit name. It
 181       --  returns the entity for the corresponding elaboration procedure
 182       --  for elaborating the spec of the referenced unit. This is used
 183       --  in the main generated elaboration procedure by the binder, and
 184       --  is not normally used in any other context, but there may be
 185       --  specialized situations in which it is useful to be able to
 186       --  call this elaboration procedure from Ada code, e.g. if it
 187       --  is necessary to do selective reelaboration to fix some error.
 188
 189       ----------------
 190       -- Elaborated --
 191       ----------------
 192
 193       Attribute_Elaborated => True,
 194       --  Lunit'Elaborated, where Lunit is a library unit, yields a boolean
 195       --  value indicating whether or not the body of the designated library
 196       --  unit has been elaborated yet.
 197
 198       --------------
 199       -- Enum_Rep --
 200       --------------
 201
 202       Attribute_Enum_Rep => True,
 203       --  For every enumeration subtype S, S'Enum_Rep denotes a function
 204       --  with the following specification:
 205       --
 206       --    function S'Enum_Rep (Arg : S'Base) return universal_integer;
 207       --
 208       --  The function returns the representation value for the given
 209       --  enumeration value. This will be equal to the 'Pos value in the
 210       --  absence of an enumeration representation clause. This is a static
 211       --  attribute (i.e. the result is static if the argument is static).
 212
 213       --------------
 214       -- Enum_Val --
 215       --------------
 216
 217       Attribute_Enum_Val => True,
 218       --  For every enumeration subtype S, S'Enum_Val denotes a function
 219       --  with the following specification:
 220       --
 221       --    function S'Enum_Val (Arg : universal_integer) return S'Base;
 222       --
 223       --  This function performs the inverse transformation to Enum_Rep. Given
 224       --  a representation value for the type, it returns the corresponding
 225       --  enumeration value. Constraint_Error is raised if no value of the
 226       --  enumeration type corresponds to the given integer value.
 227
 228       -----------------
 229       -- Fixed_Value --
 230       -----------------
 231
 232       Attribute_Fixed_Value => True,
 233       --  For every fixed-point type S, S'Fixed_Value denotes a function
 234       --  with the following specification:
 235       --
 236       --    function S'Fixed_Value (Arg : universal_integer) return S;
 237       --
 238       --  The value returned is the fixed-point value V such that
 239       --
 240       --    V = Arg * S'Small
 241       --
 242       --  The effect is thus equivalent to first converting the argument to
 243       --  the integer type used to represent S, and then doing an unchecked
 244       --  conversion to the fixed-point type. This attribute is primarily
 245       --  intended for use in implementation of the input-output functions for
 246       --  fixed-point values.
 247
 248       -----------------------
 249       -- Has_Discriminants --
 250       -----------------------
 251
 252       Attribute_Has_Discriminants => True,
 253       --  Gtyp'Has_Discriminants, where Gtyp is a generic formal type, yields
 254       --  a Boolean value indicating whether or not the actual instantiation
 255       --  type has discriminants.
 256
 257       ---------
 258       -- Img --
 259       ---------
 260
 261       Attribute_Img => True,
 262       --  The 'Img function is defined for any prefix, P, that denotes an
 263       --  object of scalar type T. P'Img is equivalent to T'Image (P). This
 264       --  is convenient for debugging. For example:
 265       --
 266       --     Put_Line ("X = " & X'Img);
 267       --
 268       --  has the same meaning as the more verbose:
 269       --
 270       --     Put_Line ("X = " & Temperature_Type'Image (X));
 271       --
 272       --  where Temperature_Type is the subtype of the object X.
 273
 274       -------------------
 275       -- Integer_Value --
 276       -------------------
 277
 278       Attribute_Integer_Value => True,
 279       --  For every integer type S, S'Integer_Value denotes a function
 280       --  with the following specification:
 281       --
 282       --    function S'Integer_Value (Arg : universal_fixed) return S;
 283       --
 284       --  The value returned is the integer value V, such that
 285       --
 286       --    Arg = V * fixed-type'Small
 287       --
 288       --  The effect is thus equivalent to first doing an unchecked convert
 289       --  from the fixed-point type to its corresponding implementation type,
 290       --  and then converting the result to the target integer type. This
 291       --  attribute is primarily intended for use in implementation of the
 292       --  standard input-output functions for fixed-point values.
 293
 294       Attribute_Invalid_Value => True,
 295       --  For every scalar type, S'Invalid_Value designates an undefined value
 296       --  of the type. If possible this value is an invalid value, and in fact
 297       --  is identical to the value that would be set if Initialize_Scalars
 298       --  mode were in effect (including the behavior of its value on
 299       --  environment variables or binder switches). The intended use is
 300       --  to set a value where initialization is required (e.g. as a result of
 301       --  the coding standards in use), but logically no initialization is
 302       --  needed, and the value should never be accessed.
 303
 304       ------------------
 305       -- Machine_Size --
 306       ------------------
 307
 308       Attribute_Machine_Size => True,
 309       --  This attribute is identical to the Object_Size attribute. It is
 310       --  provided for compatibility with the DEC attribute of this name.
 311
 312       -----------------------
 313       -- Maximum_Alignment --
 314       -----------------------
 315
 316       Attribute_Maximum_Alignment => True,
 317       --  Standard'Maximum_Alignment (Standard is the only permissible prefix)
 318       --  provides the maximum useful alignment value for the target. This
 319       --  is a static value that can be used to specify the alignment for an
 320       --  object, guaranteeing that it is properly aligned in all cases. The
 321       --  time this is useful is when an external object is imported and its
 322       --  alignment requirements are unknown. This is a static attribute.
 323
 324       --------------------
 325       -- Mechanism_Code --
 326       --------------------
 327
 328       Attribute_Mechanism_Code => True,
 329       --  function'Mechanism_Code yields an integer code for the mechanism
 330       --  used for the result of function, and subprogram'Mechanism_Code (n)
 331       --  yields the mechanism used for formal parameter number n (a static
 332       --  integer value, 1 = first parameter). The code returned is:
 333       --
 334       --     1 = by copy (value)
 335       --     2 = by reference
 336       --     3 = by descriptor (default descriptor type)
 337       --     4 = by descriptor (UBS  unaligned bit string)
 338       --     5 = by descriptor (UBSB aligned bit string with arbitrary bounds)
 339       --     6 = by descriptor (UBA  unaligned bit array)
 340       --     7 = by descriptor (S    string, also scalar access type parameter)
 341       --     8 = by descriptor (SB   string with arbitrary bounds)
 342       --     9 = by descriptor (A    contiguous array)
 343       --    10 = by descriptor (NCA  non-contiguous array)
 344
 345       --------------------
 346       -- Null_Parameter --
 347       --------------------
 348
 349       Attribute_Null_Parameter => True,
 350       --  A reference T'Null_Parameter denotes an (imaginary) object of type or
 351       --  subtype T allocated at (machine) address zero. The attribute is
 352       --  allowed only as the default expression of a formal parameter, or as
 353       --  an actual expression of a subprogram call. In either case, the
 354       --  subprogram must be imported.
 355       --
 356       --  The identity of the object is represented by the address zero in the
 357       --  argument list, independent of the passing mechanism (explicit or
 358       --  default).
 359       --
 360       --  The reason that this capability is needed is that for a record or
 361       --  other composite object passed by reference, there is no other way of
 362       --  specifying that a zero address should be passed.
 363
 364       -----------------
 365       -- Object_Size --
 366       -----------------
 367
 368       Attribute_Object_Size => True,
 369       --  Type'Object_Size is the same as Type'Size for all types except
 370       --  fixed-point types and discrete types. For fixed-point types and
 371       --  discrete types, this attribute gives the size used for default
 372       --  allocation of objects and components of the size. See section in
 373       --  Einfo ("Handling of type'Size values") for further details.
 374
 375       -------------------------
 376       -- Passed_By_Reference --
 377       -------------------------
 378
 379       Attribute_Passed_By_Reference => True,
 380       --  T'Passed_By_Reference for any subtype T returns a boolean value that
 381       --  is true if the type is normally passed by reference and false if the
 382       --  type is normally passed by copy in calls. For scalar types, the
 383       --  result is always False and is static. For non-scalar types, the
 384       --  result is non-static (since it is computed by Gigi).
 385
 386       ------------------
 387       -- Range_Length --
 388       ------------------
 389
 390       Attribute_Range_Length => True,
 391       --  T'Range_Length for any discrete type T yields the number of values
 392       --  represented by the subtype (zero for a null range). The result is
 393       --  static for static subtypes. Note that Range_Length applied to the
 394       --  index subtype of a one dimensional array always gives the same result
 395       --  as Range applied to the array itself. The result is of type universal
 396       --  integer.
 397
 398       ---------
 399       -- Ref --
 400       ---------
 401
 402       Attribute_Ref => True,
 403       --  System.Address'Ref (Address is the only permissible prefix) is
 404       --  equivalent to System'To_Address, provided for compatibility with
 405       --  other compilers.
 406
 407       ------------------
 408       -- Storage_Unit --
 409       ------------------
 410
 411       Attribute_Storage_Unit => True,
 412       --  Standard'Storage_Unit (Standard is the only permissible prefix)
 413       --  provides the value System.Storage_Unit, and is intended primarily
 414       --  for constructing this definition in package System (see note above
 415       --  in Default_Bit_Order description). The is a static attribute.
 416
 417       ---------------
 418       -- Stub_Type --
 419       ---------------
 420
 421       Attribute_Stub_Type => True,
 422       --  The GNAT implementation of remote access-to-classwide types is
 423       --  organised as described in AARM E.4(20.t): a value of an RACW type
 424       --  (designating a remote object) is represented as a normal access
 425       --  value, pointing to a "stub" object which in turn contains the
 426       --  necessary information to contact the designated remote object. A
 427       --  call on any dispatching operation of such a stub object does the
 428       --  remote call, if necessary, using the information in the stub object
 429       --  to locate the target partition, etc.
 430       --
 431       --  For a prefix T that denotes a remote access-to-classwide type,
 432       --  T'Stub_Type denotes the type of the corresponding stub objects.
 433       --
 434       --  By construction, the layout of T'Stub_Type is identical to that of
 435       --  System.Partition_Interface.RACW_Stub_Type (see implementation notes
 436       --  in body of Exp_Dist).
 437
 438       -----------------
 439       -- Target_Name --
 440       -----------------
 441
 442       Attribute_Target_Name => True,
 443       --  Standard'Target_Name yields the string identifying the target for the
 444       --  compilation, taken from Sdefault.Target_Name.
 445
 446       ----------------
 447       -- To_Address --
 448       ----------------
 449
 450       Attribute_To_Address => True,
 451       --  System'To_Address (System is the only permissible prefix) is a
 452       --  function that takes any integer value, and converts it into an
 453       --  address value. The semantics is to first convert the integer value to
 454       --  type Integer_Address according to normal conversion rules, and then
 455       --  to convert this to an address using the same semantics as the
 456       --  System.Storage_Elements.To_Address function. The important difference
 457       --  is that this is a static attribute so it can be used in
 458       --  initializations in preelaborate packages.
 459
 460       ----------------
 461       -- Type_Class --
 462       ----------------
 463
 464       Attribute_Type_Class => True,
 465       --  T'Type_Class for any type or subtype T yields the value of the type
 466       --  class for the full type of T. If T is a generic formal type, then the
 467       --  value is the value for the corresponding actual subtype. The value of
 468       --  this attribute is of type System.Aux_DEC.Type_Class, which has the
 469       --  following definition:
 470       --
 471       --    type Type_Class is
 472       --      (Type_Class_Enumeration,
 473       --       Type_Class_Integer,
 474       --       Type_Class_Fixed_Point,
 475       --       Type_Class_Floating_Point,
 476       --       Type_Class_Array,
 477       --       Type_Class_Record,
 478       --       Type_Class_Access,
 479       --       Type_Class_Task,
 480       --       Type_Class_Address);
 481       --
 482       --  Protected types yield the value Type_Class_Task, which thus applies
 483       --  to all concurrent types. This attribute is designed to be compatible
 484       --  with the DEC Ada attribute of the same name.
 485       --
 486       --  Note: if pragma Extend_System is used to merge the definitions of
 487       --  Aux_DEC into System, then the type Type_Class can be referenced
 488       --  as an entity within System, as can its enumeration literals.
 489
 490       -----------------
 491       -- UET_Address --
 492       -----------------
 493
 494       Attribute_UET_Address => True,
 495       --  Unit'UET_Address, where Unit is a program unit, yields the address
 496       --  of the unit exception table for the specified unit. This is only
 497       --  used in the internal implementation of exception handling. See the
 498       --  implementation of unit Ada.Exceptions for details on its use.
 499
 500       ------------------------------
 501       -- Universal_Literal_String --
 502       ------------------------------
 503
 504       Attribute_Universal_Literal_String => True,
 505       --  The prefix of 'Universal_Literal_String must be a named number.
 506       --  The static result is the string consisting of the characters of
 507       --  the number as defined in the original source. This allows the
 508       --  user program to access the actual text of named numbers without
 509       --  intermediate conversions and without the need to enclose the
 510       --  strings in quotes (which would preclude their use as numbers).
 511
 512       -------------------------
 513       -- Unrestricted_Access --
 514       -------------------------
 515
 516       Attribute_Unrestricted_Access => True,
 517       --  The Unrestricted_Access attribute is similar to Access except that
 518       --  all accessibility and aliased view checks are omitted. This is very
 519       --  much a user-beware attribute. Basically its status is very similar
 520       --  to Address, for which it is a desirable replacement where the value
 521       --  desired is an access type. In other words, its effect is identical
 522       --  to first taking 'Address and then doing an unchecked conversion to
 523       --  a desired access type. Note that in GNAT, but not necessarily in
 524       --  other implementations, the use of static chains for inner level
 525       --  subprograms means that Unrestricted_Access applied to a subprogram
 526       --  yields a value that can be called as long as the subprogram is in
 527       --  scope (normal Ada 95 accessibility rules restrict this usage).
 528
 529       ---------------
 530       -- VADS_Size --
 531       ---------------
 532
 533       Attribute_VADS_Size => True,
 534       --  Typ'VADS_Size yields the Size value typically yielded by some Ada 83
 535       --  compilers. The differences between VADS_Size and Size is that for
 536       --  scalar types for which no Size has been specified, VADS_Size yields
 537       --  the Object_Size rather than the Value_Size. For example, while
 538       --  Natural'Size is typically 31, the value of Natural'VADS_Size is 32.
 539       --  For all other types, Size and VADS_Size yield the same value.
 540
 541       ----------------
 542       -- Value_Size --
 543       ----------------
 544
 545       Attribute_Value_Size => True,
 546       --  Type'Value_Size is the number of bits required to represent value of
 547       --  the given subtype. It is the same as Type'Size, but, unlike Size, may
 548       --  be set for non-first subtypes. See section in Einfo ("Handling of
 549       --  type'Size values") for further details.
 550
 551       ---------------
 552       -- Word_Size --
 553       ---------------
 554
 555       Attribute_Word_Size => True,
 556       --  Standard'Word_Size (Standard is the only permissible prefix)
 557       --  provides the value System.Word_Size, and is intended primarily
 558       --  for constructing this definition in package System (see note above
 559       --  in Default_Bit_Order description). This is a static attribute.
 560
 561       others => False);
 562
 563    -----------------
 564    -- Subprograms --
 565    -----------------
 566
 567    procedure Analyze_Attribute (N : Node_Id);
 568    --  Performs bottom up semantic analysis of an attribute. Note that the
 569    --  parser has already checked that type returning attributes appear only
 570    --  in appropriate contexts (i.e. in subtype marks, or as prefixes for
 571    --  other attributes).
 572
 573    function Name_Implies_Lvalue_Prefix (Nam : Name_Id) return Boolean;
 574    --  Determine whether the name of an attribute reference categorizes its
 575    --  prefix as an lvalue. The following attributes fall under this bracket
 576    --  by directly or indirectly modifying their prefixes.
 577    --     Access
 578    --     Address
 579    --     Input
 580    --     Read
 581    --     Unchecked_Access
 582    --     Unrestricted_Access
 583
 584    procedure Resolve_Attribute (N : Node_Id; Typ : Entity_Id);
 585    --  Performs type resolution of attribute. If the attribute yields a
 586    --  universal value, mark its type as that of the context. On the other
 587    --  hand, if the context itself is universal (as in T'Val (T'Pos (X)), mark
 588    --  the type as being the largest type of that class that can be used at
 589    --  run-time. This is correct since either the value gets folded (in which
 590    --  case it doesn't matter what type of the class we give if, since the
 591    --  folding uses universal arithmetic anyway) or it doesn't get folded (in
 592    --  which case it is going to be dealt with at runtime, and the largest type
 593    --  is right).
 594
 595    function Stream_Attribute_Available
 596      (Typ          : Entity_Id;
 597       Nam          : TSS_Name_Type;
 598       Partial_View : Entity_Id := Empty) return Boolean;
 599    --  For a limited type Typ, return True iff the given attribute is
 600    --  available. For Ada 05, availability is defined by 13.13.2(36/1). For Ada
 601    --  95, an attribute is considered to be available if it has been specified
 602    --  using an attribute definition clause for the type, or for its full view,
 603    --  or for an ancestor of either. Parameter Partial_View is used only
 604    --  internally, when checking for an attribute definition clause that is not
 605    --  visible (Ada 95 only).
 606
 607 end Sem_Attr;