libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([GNU OpenMP Runtime Library], 1.0,,[libgomp])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  14    [Specify that runtime libraries should be installed in a compiler-specific directory],
  15    permit yes|no)
  16 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  17
  18 AC_MSG_CHECKING([for --enable-linux-futex])
  19 LIBGOMP_ENABLE(linux-futex, default, ,
  20   [Use the Linux futex system call],
  21   permit yes|no|default)
  22 AC_MSG_RESULT($enable_linux_futex)
  23
  24 # We would like our source tree to be readonly. However when releases or
  25 # pre-releases are generated, the flex/bison generated files as well as the
  26 # various formats of manuals need to be included along with the rest of the
  27 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  28 # just that.
  29 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  30 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  31    [put copies of generated files in source dir intended for creating source
  32     tarballs for users without texinfo bison or flex.],
  33    permit yes|no)
  34 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  35 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  36
  37
  38 # -------
  39 # -------
  40
  41 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  42 #
  43 # You will slowly go insane if you do not grok the following fact:  when
  44 # building this library, the top-level /target/ becomes the library's /host/.
  45 #
  46 # configure then causes --target to default to --host, exactly like any
  47 # other package using autoconf.  Therefore, 'target' and 'host' will
  48 # always be the same.  This makes sense both for native and cross compilers
  49 # just think about it for a little while.  :-)
  50 #
  51 # Also, if this library is being configured as part of a cross compiler, the
  52 # top-level configure script will pass the "real" host as $with_cross_host.
  53 #
  54 # Do not delete or change the following two lines.  For why, see
  55 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  56 AC_CANONICAL_SYSTEM
  57 target_alias=${target_alias-$host_alias}
  58
  59 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  60 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  61 #  1.9.0:  minimum required version
  62 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  63 #              of other PACKAGE_* variables will, however, and there's nothing
  64 #              we can do about that; they come from AC_INIT).
  65 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  66 #            file in the top srcdir, etc, etc), so stop complaining.
  67 #  -Wall:  turns on all automake warnings...
  68 #  -Wno-portability:  ...except this one, since GNU make is required.
  69 #  -Wno-override: ... and this one, since we do want this in testsuite.
  70 AM_INIT_AUTOMAKE([1.9.0 foreign -Wall -Wno-portability -Wno-override])
  71 AM_ENABLE_MULTILIB(, ..)
  72
  73 # Calculate toolexeclibdir
  74 # Also toolexecdir, though it's only used in toolexeclibdir
  75 case ${enable_version_specific_runtime_libs} in
  76   yes)
  77     # Need the gcc compiler version to know where to install libraries
  78     # and header files if --enable-version-specific-runtime-libs option
  79     # is selected.
  80     toolexecdir='$(libdir)/gcc/$(target_alias)'
  81     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  82     ;;
  83   no)
  84     if test -n "$with_cross_host" &&
  85        test x"$with_cross_host" != x"no"; then
  86       # Install a library built with a cross compiler in tooldir, not libdir.
  87       toolexecdir='$(exec_prefix)/$(target_alias)'
  88       toolexeclibdir='$(toolexecdir)/lib'
  89     else
  90       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  91       toolexeclibdir='$(libdir)'
  92     fi
  93     multi_os_directory=`$CC -print-multi-os-directory`
  94     case $multi_os_directory in
  95       .) ;; # Avoid trailing /.
  96       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  97     esac
  98     ;;
  99 esac
 100 AC_SUBST(toolexecdir)
 101 AC_SUBST(toolexeclibdir)
 102
 103 # Check the compiler.
 104 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 105 # We must force CC to /not/ be precious variables; otherwise
 106 # the wrong, non-multilib-adjusted value will be used in multilibs.
 107 # As a side effect, we have to subst CFLAGS ourselves.
 108
 109 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 110 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 111 AC_PROG_CC
 112 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 113
 114 AC_SUBST(CFLAGS)
 115
 116 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 117 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 118 # in both places for now and restore CFLAGS at the end of config.
 119 save_CFLAGS="$CFLAGS"
 120
 121 # Add -Wall -Werror if we are using GCC.
 122 if test "x$GCC" = "xyes"; then
 123   XCFLAGS="$XCFLAGS -Wall -Werror"
 124 fi
 125
 126 # Find other programs we need.
 127 AC_CHECK_TOOL(AR, ar)
 128 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 129 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 130 AC_PROG_MAKE_SET
 131 AC_PROG_INSTALL
 132
 133 # See if makeinfo has been installed and is modern enough
 134 # that we can use it.
 135 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 136                    [GNU texinfo.* \([0-9][0-9.]*\)],
 137                    [4.[4-9]*])
 138 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 139
 140
 141 # Configure libtool
 142 AM_PROG_LIBTOOL
 143 AC_SUBST(enable_shared)
 144 AC_SUBST(enable_static)
 145
 146 AM_MAINTAINER_MODE
 147
 148 # We need gfortran to compile parts of the library
 149 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 150 #AC_PROG_FC(gfortran)
 151 FC="$GFORTRAN"
 152 AC_PROG_FC(gfortran)
 153 FCFLAGS="$FCFLAGS -Wall"
 154
 155 # For libtool versioning info, format is CURRENT:REVISION:AGE
 156 libtool_VERSION=1:0:0
 157 AC_SUBST(libtool_VERSION)
 158
 159 # Check header files.
 160 AC_STDC_HEADERS
 161 AC_HEADER_TIME
 162 AC_CHECK_HEADERS(unistd.h semaphore.h sys/loadavg.h sys/time.h)
 163
 164 GCC_HEADER_STDINT(gstdint.h)
 165
 166 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 167 # In case the pthread.h system header is not found, this test will fail.
 168 XPCFLAGS=""
 169 CFLAGS="$CFLAGS -pthread"
 170 AC_LINK_IFELSE(
 171  [AC_LANG_PROGRAM(
 172   [#include <pthread.h>
 173    void *g(void *d) { return NULL; }],
 174   [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 175  [XPCFLAGS=" -Wc,-pthread"],
 176  [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 177   AC_LINK_IFELSE(
 178    [AC_LANG_PROGRAM(
 179     [#include <pthread.h>
 180      void *g(void *d) { return NULL; }],
 181     [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 182    [],
 183    [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 184
 185 # Check for functions needed.
 186 AC_CHECK_FUNCS(getloadavg clock_gettime)
 187
 188 # Check for broken semaphore implementation on darwin.
 189 # sem_init returns: sem_init error: Function not implemented.
 190 case "$host" in
 191   *-darwin*)
 192     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 193         Define if the POSIX Semaphores do not work on your system.)
 194     ;;
 195   *-linux*)
 196     case "$enable_linux_futex" in
 197       default)
 198         # If headers don't have gettid/futex syscalls definition, then
 199         # default to no, otherwise there will be compile time failures.
 200         # Otherwise, default to yes.  If we don't detect we are
 201         # compiled/linked against NPTL and not cross-compiling, check
 202         # if programs are run by default against NPTL and if not, issue
 203         # a warning.
 204         enable_linux_futex=no
 205         AC_LINK_IFELSE(
 206          [AC_LANG_PROGRAM(
 207           [#include <sys/syscall.h>
 208            int lk;],
 209           [syscall (SYS_gettid); syscall (SYS_futex, &lk, 0, 0, 0);])],
 210           [AC_LINK_IFELSE(
 211            [AC_LANG_PROGRAM(
 212             [#ifndef _GNU_SOURCE
 213              #define _GNU_SOURCE 1
 214              #endif
 215              #include <pthread.h>
 216              pthread_t th; void *status;],
 217             [pthread_tryjoin_np (th, &status);])],[enable_linux_futex=yes],
 218             [if test x$cross_compiling = xno; then
 219                if getconf GNU_LIBPTHREAD_VERSION 2>/dev/null \
 220                   | LC_ALL=C grep -i NPTL > /dev/null 2>/dev/null; then
 221                  AC_MSG_WARN([The kernel might not support futex or gettid syscalls.
 222 If so, please configure with --disable-linux-futex])
 223                fi
 224              fi
 225              enable_linux_futex=yes])])
 226         ;;
 227       yes)
 228         AC_LINK_IFELSE(
 229          [AC_LANG_PROGRAM(
 230           [#include <sys/syscall.h>
 231            int lk;],
 232           [syscall (SYS_gettid); syscall (SYS_futex, &lk, 0, 0, 0);])],[],
 233           [AC_MSG_ERROR([SYS_gettid and SYS_futex required for --enable-linux-futex])])
 234         ;;
 235     esac
 236     ;;
 237 esac
 238
 239 # Check for pthread_{,attr_}[sg]etaffinity_np.
 240 AC_LINK_IFELSE(
 241  [AC_LANG_PROGRAM(
 242   [#define _GNU_SOURCE
 243    #include <pthread.h>],
 244   [cpu_set_t cpuset;
 245    pthread_attr_t attr;
 246    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 247    if (CPU_ISSET (0, &cpuset))
 248      CPU_SET (1, &cpuset);
 249    else
 250      CPU_ZERO (&cpuset);
 251    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 252    pthread_attr_init (&attr);
 253    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 254    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 255   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 256 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 257
 258 # At least for glibc, clock_gettime is in librt.  But don't pull that
 259 # in if it still doesn't give us the function we want.
 260 if test $ac_cv_func_clock_gettime = no; then
 261   AC_CHECK_LIB(rt, clock_gettime,
 262     [LIBS="-lrt $LIBS"
 263      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 264                [Define to 1 if you have the `clock_gettime' function.])])
 265 fi
 266
 267 # See if we support thread-local storage.
 268 GCC_CHECK_TLS
 269
 270 # See what sort of export controls are availible.
 271 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 272 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 273 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 274 LIBGOMP_ENABLE_SYMVERS
 275
 276 # Get target configury.
 277 . ${srcdir}/configure.tgt
 278 CFLAGS="$save_CFLAGS $XCFLAGS"
 279
 280 # Check for __sync_val_compare_and_swap, but only after the target has
 281 # had a chance to set XCFLAGS.
 282 LIBGOMP_CHECK_SYNC_BUILTINS
 283
 284 XCFLAGS="$XCFLAGS$XPCFLAGS"
 285
 286 AC_SUBST(config_path)
 287 AC_SUBST(XCFLAGS)
 288 AC_SUBST(XLDFLAGS)
 289
 290 # Cleanup and exit.
 291 CFLAGS="$save_CFLAGS"
 292 AC_CACHE_SAVE
 293
 294 if test ${multilib} = yes; then
 295   multilib_arg="--enable-multilib"
 296 else
 297   multilib_arg=
 298 fi
 299
 300 # Set up the set of libraries that we need to link against for libgomp.
 301 # Note that the GOMP_SELF_SPEC in gcc.c will force -pthread for -fopenmp,
 302 # which will force linkage against -lpthread (or equivalent for the system).
 303 # That's not 100% ideal, but about the best we can do easily.
 304 if test $enable_shared = yes; then
 305   link_gomp="-lgomp %{static: $LIBS}"
 306 else
 307   link_gomp="-lgomp $LIBS"
 308 fi
 309 AC_SUBST(link_gomp)
 310
 311 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 312
 313 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 314 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 315 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 316 # need to copy this macro to our acinclude.m4.
 317 save_CFLAGS="$CFLAGS"
 318 for i in $config_path; do
 319   if test -f $srcdir/config/$i/omp-lock.h; then
 320     CFLAGS="$CFLAGS -include $srcdir/config/$i/omp-lock.h"
 321     break
 322   fi
 323 done
 324
 325 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 326   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 327 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 328 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 329 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 330
 331 # If the lock fits in an integer, then arrange for Fortran to use that
 332 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 333 # Except that we don't have a way at present to multi-lib the installed
 334 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 335 # actual target.
 336 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 337 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 338 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 339   OMP_LOCK_KIND=8
 340 fi
 341 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 342   OMP_NEST_LOCK_KIND=8
 343 fi
 344
 345 AC_SUBST(OMP_LOCK_SIZE)
 346 AC_SUBST(OMP_LOCK_ALIGN)
 347 AC_SUBST(OMP_NEST_LOCK_SIZE)
 348 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 349 AC_SUBST(OMP_LOCK_KIND)
 350 AC_SUBST(OMP_NEST_LOCK_KIND)
 351 CFLAGS="$save_CFLAGS"
 352
 353 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 354 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 355 AC_OUTPUT