configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32 m4_include([config/cloog.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_PREREQ(2.64)
  36 AC_DISABLE_OPTION_CHECKING
  37
  38 progname=$0
  39 # if PWD already has a value, it is probably wrong.
  40 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  41
  42 # Export original configure arguments for use by sub-configures.
  43 # Quote arguments with shell meta charatcers.
  44 TOPLEVEL_CONFIGURE_ARGUMENTS=
  45 set -- "$progname" "$@"
  46 for ac_arg
  47 do
  48   case "$ac_arg" in
  49   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  50     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  51     # if the argument is of the form -foo=baz, quote the baz part only
  52     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  53   *) ;;
  54   esac
  55   # Add the quoted argument to the list.
  56   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  57 done
  58 if test "$silent" = yes; then
  59   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  60 fi
  61 # Remove the initial space we just introduced and, as these will be
  62 # expanded by make, quote '$'.
  63 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  64 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  65
  66 # Find the build, host, and target systems.
  67 ACX_NONCANONICAL_BUILD
  68 ACX_NONCANONICAL_HOST
  69 ACX_NONCANONICAL_TARGET
  70
  71 dnl Autoconf 2.5x and later will set a default program prefix if
  72 dnl --target was used, even if it was the same as --host.  Disable
  73 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  74 dnl to take effect.
  75 test "$host_noncanonical" = "$target_noncanonical" &&
  76   test "$program_prefix$program_suffix$program_transform_name" = \
  77     NONENONEs,x,x, &&
  78   program_transform_name=s,y,y,
  79
  80 AC_CANONICAL_SYSTEM
  81 AC_ARG_PROGRAM
  82
  83 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  84 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  85
  86 # Get 'install' or 'install-sh' and its variants.
  87 AC_PROG_INSTALL
  88 ACX_PROG_LN
  89 AC_PROG_LN_S
  90 AC_PROG_SED
  91 AC_PROG_AWK
  92
  93 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  94
  95 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  96 # a relative path.
  97 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  98   INSTALL="${srcpwd}/install-sh -c"
  99 fi
 100
 101 # Set srcdir to "." if that's what it is.
 102 # This is important for multilib support.
 103 pwd=`${PWDCMD-pwd}`
 104 if test "${pwd}" = "${srcpwd}" ; then
 105   srcdir=.
 106 fi
 107
 108 topsrcdir=$srcpwd
 109
 110 extra_host_args=
 111
 112 ### To add a new directory to the tree, first choose whether it is a target
 113 ### or a host dependent tool.  Then put it into the appropriate list
 114 ### (library or tools, host or target), doing a dependency sort.
 115
 116 # Subdirs will be configured in the order listed in build_configdirs,
 117 # configdirs, or target_configdirs; see the serialization section below.
 118
 119 # Dependency sorting is only needed when *configuration* must be done in
 120 # a particular order.  In all cases a dependency should be specified in
 121 # the Makefile, whether or not it's implicitly specified here.
 122
 123 # Double entries in build_configdirs, configdirs, or target_configdirs may
 124 # cause circular dependencies and break everything horribly.
 125
 126 # these library is used by various programs built for the build
 127 # environment
 128 #
 129 build_libs="build-libiberty"
 130
 131 # these tools are built for the build environment
 132 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 133
 134 # these libraries are used by various programs built for the host environment
 135 #
 136 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl cloog libelf libiconv"
 137
 138 # these tools are built for the host environment
 139 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 140 # know that we are building the simulator.
 141 # binutils, gas and ld appear in that order because it makes sense to run
 142 # "make check" in that particular order.
 143 # If --enable-gold is used, "gold" may replace "ld".
 144 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 145
 146 # libgcj represents the runtime libraries only used by gcj.
 147 libgcj="target-libffi \
 148         target-zlib \
 149         target-libjava"
 150
 151 # these libraries are built for the target environment, and are built after
 152 # the host libraries and the host tools (which may be a cross compiler)
 153 # Note that libiberty is not a target library.
 154 target_libraries="target-libgcc \
 155                 target-libbacktrace \
 156                 target-libgloss \
 157                 target-newlib \
 158                 target-libgomp \
 159                 target-libatomic \
 160                 target-libitm \
 161                 target-libstdc++-v3 \
 162                 target-libmudflap \
 163                 target-libssp \
 164                 target-libquadmath \
 165                 target-libgfortran \
 166                 target-boehm-gc \
 167                 ${libgcj} \
 168                 target-libobjc \
 169                 target-libada \
 170                 target-libgo"
 171
 172 # these tools are built using the target libraries, and are intended to
 173 # run only in the target environment
 174 #
 175 # note: any program that *uses* libraries that are in the "target_libraries"
 176 # list belongs in this list.
 177 #
 178 target_tools="target-rda"
 179
 180 ################################################################################
 181
 182 ## All tools belong in one of the four categories, and are assigned above
 183 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 184 ## is important because configure will choke if they ever get through.
 185 ## ${configdirs} is directories we build using the host tools.
 186 ## ${target_configdirs} is directories we build using the target tools.
 187 configdirs=`echo ${host_libs} ${host_tools}`
 188 target_configdirs=`echo ${target_libraries} ${target_tools}`
 189 build_configdirs=`echo ${build_libs} ${build_tools}`
 190
 191 m4_divert_text([PARSE_ARGS],
 192 [case $srcdir in
 193   *" "*)
 194 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 195     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 196 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 197     ;;
 198 esac
 199 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 200 ])
 201
 202 ################################################################################
 203
 204 srcname="gnu development package"
 205
 206 # This gets set non-empty for some net releases of packages.
 207 appdirs=""
 208
 209 # Define is_cross_compiler to save on calls to 'test'.
 210 is_cross_compiler=
 211 if test x"${host}" = x"${target}" ; then
 212   is_cross_compiler=no
 213 else
 214   is_cross_compiler=yes
 215 fi
 216
 217 # Find the build and target subdir names.
 218 GCC_TOPLEV_SUBDIRS
 219 # Be sure to cover against remnants of an in-tree build.
 220 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 221   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 222 Use a pristine source tree when building in a separate tree])
 223 fi
 224
 225 # Skipdirs are removed silently.
 226 skipdirs=
 227 # Noconfigdirs are removed loudly.
 228 noconfigdirs=""
 229
 230 use_gnu_ld=
 231 # Make sure we don't let GNU ld be added if we didn't want it.
 232 if test x$with_gnu_ld = xno ; then
 233   use_gnu_ld=no
 234   noconfigdirs="$noconfigdirs ld gold"
 235 fi
 236
 237 use_gnu_as=
 238 # Make sure we don't let GNU as be added if we didn't want it.
 239 if test x$with_gnu_as = xno ; then
 240   use_gnu_as=no
 241   noconfigdirs="$noconfigdirs gas"
 242 fi
 243
 244 use_included_zlib=
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # some tools are so dependent upon X11 that if we're not building with X,
 252 # it's not even worth trying to configure, much less build, that tool.
 253
 254 case ${with_x} in
 255   yes | "") ;; # the default value for this tree is that X11 is available
 256   no)
 257     skipdirs="${skipdirs} tk itcl libgui"
 258     # We won't be able to build gdbtk without X.
 259     enable_gdbtk=no
 260     ;;
 261   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 262 esac
 263
 264 # Some are only suitable for cross toolchains.
 265 # Remove these if host=target.
 266 cross_only="target-libgloss target-newlib target-opcodes"
 267
 268 case $is_cross_compiler in
 269   no) skipdirs="${skipdirs} ${cross_only}" ;;
 270 esac
 271
 272 # If both --with-headers and --with-libs are specified, default to
 273 # --without-newlib.
 274 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 275    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 276   if test x"${with_newlib}" = x ; then
 277     with_newlib=no
 278   fi
 279 fi
 280
 281 # Recognize --with-newlib/--without-newlib.
 282 case ${with_newlib} in
 283   no) skipdirs="${skipdirs} target-newlib" ;;
 284   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 285 esac
 286
 287 # Handle --enable-gold, --enable-ld.
 288 # --disable-gold [--enable-ld]
 289 #     Build only ld.  Default option.
 290 # --enable-gold [--enable-ld]
 291 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 292 #     as "ld.bfd" and "ld".
 293 # --enable-gold=default [--enable-ld]
 294 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 295 #     install ld as "ld.bfd".
 296 # --enable-gold[=default] --disable-ld
 297 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 298 # --enable-gold --enable-ld=default
 299 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 300 #     and ld.bfd).
 301 #     In other words, ld is default
 302 # --enable-gold=default --enable-ld=default
 303 #     Error.
 304
 305 default_ld=
 306 AC_ARG_ENABLE(gold,
 307 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 308                 [build gold @<:@ARG={default,yes,no}@:>@])],
 309 ENABLE_GOLD=$enableval,
 310 ENABLE_GOLD=no)
 311 case "${ENABLE_GOLD}" in
 312   yes|default)
 313     # Check for ELF target.
 314     is_elf=no
 315     case "${target}" in
 316       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 317       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 318       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 319       | *-*-solaris2* | *-*-nto*)
 320         case "${target}" in
 321           *-*-linux*aout* | *-*-linux*oldld*)
 322             ;;
 323           *)
 324             is_elf=yes
 325             ;;
 326         esac
 327     esac
 328
 329     if test "$is_elf" = "yes"; then
 330       # Check for target supported by gold.
 331       case "${target}" in
 332         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* | tilegx*-*-*)
 333           configdirs="$configdirs gold"
 334           if test x${ENABLE_GOLD} = xdefault; then
 335             default_ld=gold
 336           fi
 337           ENABLE_GOLD=yes
 338           ;;
 339       esac
 340     fi
 341     ;;
 342   no)
 343     ;;
 344   *)
 345     AC_MSG_ERROR([invalid --enable-gold argument])
 346     ;;
 347 esac
 348
 349 AC_ARG_ENABLE(ld,
 350 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 351                 [build ld @<:@ARG={default,yes,no}@:>@])],
 352 ENABLE_LD=$enableval,
 353 ENABLE_LD=yes)
 354
 355 case "${ENABLE_LD}" in
 356   default)
 357     if test x${default_ld} != x; then
 358       AC_MSG_ERROR([either gold or ld can be the default ld])
 359     fi
 360     ;;
 361   yes)
 362     ;;
 363   no)
 364     if test x${ENABLE_GOLD} != xyes; then
 365       AC_MSG_WARN([neither ld nor gold are enabled])
 366     fi
 367     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 368     ;;
 369   *)
 370     AC_MSG_ERROR([invalid --enable-ld argument])
 371     ;;
 372 esac
 373
 374 # Configure extra directories which are host specific
 375
 376 case "${host}" in
 377   *-cygwin*)
 378     configdirs="$configdirs libtermcap" ;;
 379 esac
 380
 381 # A target can indicate whether a language isn't supported for some reason.
 382 # Only spaces may be used in this macro; not newlines or tabs.
 383 unsupported_languages=
 384
 385 # Remove more programs from consideration, based on the host or
 386 # target this usually means that a port of the program doesn't
 387 # exist yet.
 388
 389 case "${host}" in
 390   i[[3456789]]86-*-msdosdjgpp*)
 391     noconfigdirs="$noconfigdirs tcl tk itcl"
 392     ;;
 393 esac
 394
 395
 396 AC_ARG_ENABLE(libquadmath,
 397 AS_HELP_STRING([--disable-libquadmath],
 398   [do not build libquadmath directory]),
 399 ENABLE_LIBQUADMATH=$enableval,
 400 ENABLE_LIBQUADMATH=yes)
 401 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 402   noconfigdirs="$noconfigdirs target-libquadmath"
 403 fi
 404
 405
 406 AC_ARG_ENABLE(libquadmath-support,
 407 AS_HELP_STRING([--disable-libquadmath-support],
 408   [disable libquadmath support for Fortran]),
 409 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 410 ENABLE_LIBQUADMATH_SUPPORT=yes)
 411 enable_libquadmath_support=
 412 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 413   enable_libquadmath_support=no
 414 fi
 415
 416
 417 AC_ARG_ENABLE(libada,
 418 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 419 ENABLE_LIBADA=$enableval,
 420 ENABLE_LIBADA=yes)
 421 if test "${ENABLE_LIBADA}" != "yes" ; then
 422   noconfigdirs="$noconfigdirs gnattools"
 423 fi
 424
 425 AC_ARG_ENABLE(libssp,
 426 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 427 ENABLE_LIBSSP=$enableval,
 428 ENABLE_LIBSSP=yes)
 429
 430 # Save it here so that, even in case of --enable-libgcj, if the Java
 431 # front-end isn't enabled, we still get libgcj disabled.
 432 libgcj_saved=$libgcj
 433 case $enable_libgcj in
 434 yes)
 435   # If we reset it here, it won't get added to noconfigdirs in the
 436   # target-specific build rules, so it will be forcibly enabled
 437   # (unless the Java language itself isn't enabled).
 438   libgcj=
 439   ;;
 440 no)
 441   # Make sure we get it printed in the list of not supported target libs.
 442   # Don't disable libffi, though, other languages use it.
 443   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 444   # Clear libgcj_saved so that even if java is enabled libffi won't be
 445   # built.
 446   libgcj_saved=
 447   ;;
 448 esac
 449
 450 AC_ARG_ENABLE(static-libjava,
 451 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 452                 [build static libjava @<:@default=no@:>@])],
 453 ENABLE_STATIC_LIBJAVA=$enableval,
 454 ENABLE_STATIC_LIBJAVA=no)
 455 enable_static_libjava=
 456 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 457   enable_static_libjava=yes
 458 fi
 459
 460 if test x$enable_static_libjava != xyes ; then
 461   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 462 fi
 463 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 464
 465 # Disable libmudflap on some systems.
 466 if test x$enable_libmudflap = x ; then
 467     case "${target}" in
 468     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 469         # Enable libmudflap by default in GNU and friends.
 470         ;;
 471     *-*-freebsd*)
 472         # Enable libmudflap by default in FreeBSD.
 473         ;;
 474     *)
 475         # Disable it by default everywhere else.
 476         noconfigdirs="$noconfigdirs target-libmudflap"
 477         ;;
 478     esac
 479 fi
 480
 481 # Disable libgomp on non POSIX hosted systems.
 482 if test x$enable_libgomp = x ; then
 483     # Enable libgomp by default on hosted POSIX systems.
 484     case "${target}" in
 485     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 486         ;;
 487     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 488         ;;
 489     *-*-solaris2* | *-*-hpux11*)
 490         ;;
 491     *-*-darwin* | *-*-aix*)
 492         ;;
 493     *)
 494         noconfigdirs="$noconfigdirs target-libgomp"
 495         ;;
 496     esac
 497 fi
 498
 499 # Disable libatomic on unsupported systems.
 500 if test -d ${srcdir}/libatomic; then
 501     if test x$enable_libatomic = x; then
 502         AC_MSG_CHECKING([for libatomic support])
 503         if (srcdir=${srcdir}/libatomic; \
 504                 . ${srcdir}/configure.tgt; \
 505                 test -n "$UNSUPPORTED")
 506         then
 507             AC_MSG_RESULT([no])
 508             noconfigdirs="$noconfigdirs target-libatomic"
 509         else
 510             AC_MSG_RESULT([yes])
 511         fi
 512     fi
 513 fi
 514
 515 # Disable libitm on unsupported systems.
 516 if test -d ${srcdir}/libitm; then
 517     if test x$enable_libitm = x; then
 518         AC_MSG_CHECKING([for libitm support])
 519         if (srcdir=${srcdir}/libitm; \
 520                 . ${srcdir}/configure.tgt; \
 521                 test -n "$UNSUPPORTED")
 522         then
 523             AC_MSG_RESULT([no])
 524             noconfigdirs="$noconfigdirs target-libitm"
 525         else
 526             AC_MSG_RESULT([yes])
 527         fi
 528     fi
 529 fi
 530
 531 # Disable libquadmath for some systems.
 532 case "${target}" in
 533   # libquadmath is unused on AIX and libquadmath build process use of
 534   # LD_LIBRARY_PATH can break AIX bootstrap.
 535   powerpc-*-aix* | rs6000-*-aix*)
 536     noconfigdirs="$noconfigdirs target-libquadmath"
 537     ;;
 538 esac
 539
 540 # Disable libssp for some systems.
 541 case "${target}" in
 542   avr-*-*)
 543     # No hosted I/O support.
 544     noconfigdirs="$noconfigdirs target-libssp"
 545     ;;
 546   powerpc-*-aix* | rs6000-*-aix*)
 547     noconfigdirs="$noconfigdirs target-libssp"
 548     ;;
 549   rl78-*-*)
 550     # libssp uses a misaligned load to trigger a fault, but the RL78
 551     # doesn't fault for those - instead, it gives a build-time error
 552     # for explicit misaligned loads.
 553     noconfigdirs="$noconfigdirs target-libssp"
 554     ;;
 555 esac
 556
 557 # Disable libquadmath for some systems.
 558 case "${target}" in
 559   avr-*-*)
 560     noconfigdirs="$noconfigdirs target-libquadmath"
 561     ;;
 562 esac
 563
 564 # Disable libstdc++-v3 for some systems.
 565 case "${target}" in
 566   *-*-vxworks*)
 567     # VxWorks uses the Dinkumware C++ library.
 568     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 569     ;;
 570   arm*-wince-pe*)
 571     # the C++ libraries don't build on top of CE's C libraries
 572     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 573     ;;
 574   avr-*-*)
 575     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 576     ;;
 577 esac
 578
 579 # Disable Fortran for some systems.
 580 case "${target}" in
 581   mmix-*-*)
 582     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 583     unsupported_languages="$unsupported_languages fortran"
 584     ;;
 585 esac
 586
 587 # Disable Java if libffi is not supported.
 588 case "${target}" in
 589   alpha*-*-*)
 590     ;;
 591   arm*-*-*)
 592     ;;
 593   cris-*-*)
 594     ;;
 595   frv-*-*)
 596     ;;
 597   hppa*-*-linux*)
 598     ;;
 599   hppa*-*-hpux*)
 600     ;;
 601   i?86-*-*)
 602     ;;
 603   ia64*-*-*)
 604     ;;
 605   m32r*-*-*)
 606     ;;
 607   m68k-*-*)
 608     ;;
 609   mips*-*-rtems*)
 610     ;;
 611   mips*-*-linux*)
 612     ;;
 613   powerpc*-*-linux*)
 614     ;;
 615   powerpc-*-darwin*)
 616     ;;
 617   powerpc-*-aix* | rs6000-*-aix*)
 618     ;;
 619   powerpc-*-freebsd*)
 620     ;;
 621   powerpc64-*-freebsd*)
 622     ;;
 623   powerpc*-*-rtems*)
 624     ;;
 625   s390-*-* | s390x-*-*)
 626     ;;
 627   sh-*-* | sh[[34]]*-*-*)
 628     ;;
 629   sh64-*-* | sh5*-*-*)
 630     ;;
 631   sparc*-*-*)
 632     ;;
 633   x86_64-*-*)
 634     ;;
 635   *-*-*)
 636     unsupported_languages="$unsupported_languages java"
 637     ;;
 638 esac
 639
 640 # Disable Java, libgcj or related libraries for some systems.
 641 case "${target}" in
 642   powerpc-*-darwin*)
 643     ;;
 644   i[[3456789]]86-*-darwin*)
 645     ;;
 646   x86_64-*-darwin[[912]]*)
 647     ;;
 648   *-*-darwin*)
 649     noconfigdirs="$noconfigdirs ${libgcj}"
 650     ;;
 651   *-*-netware*)
 652     noconfigdirs="$noconfigdirs ${libgcj}"
 653     ;;
 654   *-*-rtems*)
 655     noconfigdirs="$noconfigdirs ${libgcj}"
 656     ;;
 657   *-*-tpf*)
 658     noconfigdirs="$noconfigdirs ${libgcj}"
 659     ;;
 660   *-*-uclinux*)
 661     noconfigdirs="$noconfigdirs ${libgcj}"
 662     ;;
 663   *-*-vxworks*)
 664     noconfigdirs="$noconfigdirs ${libgcj}"
 665     ;;
 666   alpha*-*-*vms*)
 667     noconfigdirs="$noconfigdirs ${libgcj}"
 668     ;;
 669   arm-wince-pe)
 670     noconfigdirs="$noconfigdirs ${libgcj}"
 671     ;;
 672   arm*-*-symbianelf*)
 673     noconfigdirs="$noconfigdirs ${libgcj}"
 674     ;;
 675   bfin-*-*)
 676     noconfigdirs="$noconfigdirs target-boehm-gc"
 677     ;;
 678   cris-*-* | crisv32-*-*)
 679     unsupported_languages="$unsupported_languages java"
 680     case "${target}" in
 681       *-*-linux*)
 682         ;;
 683       *) # See PR46792 regarding target-libffi.
 684         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 685     esac
 686     ;;
 687   hppa*64*-*-linux*)
 688     # In this case, it's because the hppa64-linux target is for
 689     # the kernel only at this point and has no libc, and thus no
 690     # headers, crt*.o, etc., all of which are needed by these.
 691     unsupported_languages="$unsupported_languages java"
 692     ;;
 693   hppa*64*-*-hpux*)
 694     noconfigdirs="$noconfigdirs ${libgcj}"
 695     ;;
 696   hppa*-hp-hpux11*)
 697     ;;
 698   hppa*-*-hpux*)
 699     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 700     # build on HP-UX 10.20.
 701     noconfigdirs="$noconfigdirs ${libgcj}"
 702     ;;
 703   ia64*-*-*vms*)
 704     noconfigdirs="$noconfigdirs ${libgcj}"
 705     ;;
 706   i[[3456789]]86-w64-mingw*)
 707     noconfigdirs="$noconfigdirs ${libgcj}"
 708     ;;
 709   i[[3456789]]86-*-mingw*)
 710     noconfigdirs="$noconfigdirs ${libgcj}"
 711     ;;
 712   x86_64-*-mingw*)
 713     noconfigdirs="$noconfigdirs ${libgcj}"
 714     ;;
 715   mmix-*-*)
 716     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 717     ;;
 718   powerpc-*-aix*)
 719     # copied from rs6000-*-* entry
 720     noconfigdirs="$noconfigdirs ${libgcj}"
 721     ;;
 722   rs6000-*-aix*)
 723     noconfigdirs="$noconfigdirs ${libgcj}"
 724     ;;
 725   *-*-lynxos*)
 726     noconfigdirs="$noconfigdirs ${libgcj}"
 727     ;;
 728 esac
 729
 730 # Default libgloss CPU subdirectory.
 731 libgloss_dir="$target_cpu"
 732
 733 case "${target}" in
 734   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 735     libgloss_dir=wince
 736     ;;
 737   arm*-*-*)
 738     libgloss_dir=arm
 739     ;;
 740   cris-*-* | crisv32-*-*)
 741     libgloss_dir=cris
 742     ;;
 743   hppa*-*-*)
 744     libgloss_dir=pa
 745     ;;
 746   i[[3456789]]86-*-*)
 747     libgloss_dir=i386
 748     ;;
 749   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 750     libgloss_dir=m68hc11
 751     ;;
 752   m68*-*-* | fido-*-*)
 753     libgloss_dir=m68k
 754     ;;
 755   mips*-*-*)
 756     libgloss_dir=mips
 757     ;;
 758   powerpc*-*-*)
 759     libgloss_dir=rs6000
 760     ;;
 761   sparc*-*-*)
 762     libgloss_dir=sparc
 763     ;;
 764 esac
 765
 766 # Disable newlib and libgloss for various target OSes.
 767 case "${target}" in
 768   alpha*-dec-osf*)
 769     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 770     ;;
 771   i[[3456789]]86-*-linux*)
 772     # This section makes it possible to build newlib natively on linux.
 773     # If we are using a cross compiler then don't configure newlib.
 774     if test x${is_cross_compiler} != xno ; then
 775       noconfigdirs="$noconfigdirs target-newlib"
 776     fi
 777     noconfigdirs="$noconfigdirs target-libgloss"
 778     # If we are not using a cross compiler, do configure newlib.
 779     # Note however, that newlib will only be configured in this situation
 780     # if the --with-newlib option has been given, because otherwise
 781     # 'target-newlib' will appear in skipdirs.
 782     ;;
 783   i[[3456789]]86-*-rdos*)
 784     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 785     ;;
 786   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 787     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 788     ;;
 789   sparc-*-sunos4*)
 790     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 791     ;;
 792   *-*-aix*)
 793     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 794     ;;
 795   *-*-beos*)
 796     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 797     ;;
 798   *-*-chorusos)
 799     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 800     ;;
 801   *-*-dragonfly*)
 802     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 803     ;;
 804   *-*-freebsd*)
 805     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 806     ;;
 807   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 808     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 809     ;;
 810   *-*-lynxos*)
 811     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 812     ;;
 813   *-*-mingw*)
 814     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 815     ;;
 816   *-*-netbsd*)
 817     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 818     ;;
 819   *-*-netware*)
 820     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 821     ;;
 822   *-*-tpf*)
 823     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 824     ;;
 825   *-*-uclinux*)
 826     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 827     ;;
 828   *-*-vxworks*)
 829     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 830     ;;
 831 esac
 832
 833 case "${target}" in
 834   *-*-chorusos)
 835     ;;
 836   powerpc-*-darwin*)
 837     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 838     noconfigdirs="$noconfigdirs sim target-rda"
 839     ;;
 840   i[[3456789]]86-*-darwin*)
 841     noconfigdirs="$noconfigdirs ld gprof"
 842     noconfigdirs="$noconfigdirs sim target-rda"
 843     ;;
 844   x86_64-*-darwin[[912]]*)
 845     noconfigdirs="$noconfigdirs ld gas gprof"
 846     noconfigdirs="$noconfigdirs sim target-rda"
 847     ;;
 848   *-*-darwin*)
 849     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 850     noconfigdirs="$noconfigdirs sim target-rda"
 851     ;;
 852   *-*-dragonfly*)
 853     ;;
 854   *-*-freebsd*)
 855     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 856         && test -f /usr/local/include/gmp.h; then
 857       with_gmp=/usr/local
 858     fi
 859     ;;
 860   *-*-kaos*)
 861     # Remove unsupported stuff on all kaOS configurations.
 862     noconfigdirs="$noconfigdirs target-libgloss"
 863     ;;
 864   *-*-netbsd*)
 865     ;;
 866   *-*-netware*)
 867     ;;
 868   *-*-rtems*)
 869     noconfigdirs="$noconfigdirs target-libgloss"
 870     ;;
 871     # The tpf target doesn't support gdb yet.
 872   *-*-tpf*)
 873     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 874     ;;
 875   *-*-uclinux*)
 876     noconfigdirs="$noconfigdirs target-rda"
 877     ;;
 878   *-*-vxworks*)
 879     ;;
 880   alpha*-dec-osf*)
 881     # ld works, but does not support shared libraries.
 882     # gas doesn't generate exception information.
 883     noconfigdirs="$noconfigdirs gas ld"
 884     ;;
 885   alpha*-*-*vms*)
 886     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 887     ;;
 888   alpha*-*-*)
 889     # newlib is not 64 bit ready
 890     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 891     ;;
 892   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 893     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 894     ;;
 895   arc-*-*)
 896     noconfigdirs="$noconfigdirs target-libgloss"
 897     ;;
 898   arm-*-pe*)
 899     noconfigdirs="$noconfigdirs target-libgloss"
 900     ;;
 901   arm-*-riscix*)
 902     noconfigdirs="$noconfigdirs ld target-libgloss"
 903     ;;
 904   avr-*-rtems*)
 905     ;;
 906   avr-*-*)
 907     if test x${with_avrlibc} != xno; then
 908       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 909     fi
 910     ;;
 911   c4x-*-* | tic4x-*-*)
 912     noconfigdirs="$noconfigdirs target-libgloss"
 913     ;;
 914   tic54x-*-*)
 915     noconfigdirs="$noconfigdirs target-libgloss gdb"
 916     ;;
 917   d10v-*-*)
 918     noconfigdirs="$noconfigdirs target-libgloss"
 919     ;;
 920   d30v-*-*)
 921     noconfigdirs="$noconfigdirs gdb"
 922     ;;
 923   fr30-*-elf*)
 924     noconfigdirs="$noconfigdirs gdb"
 925     ;;
 926   moxie-*-*)
 927     noconfigdirs="$noconfigdirs gprof"
 928     ;;
 929   h8300*-*-*)
 930     noconfigdirs="$noconfigdirs target-libgloss"
 931     ;;
 932   h8500-*-*)
 933     noconfigdirs="$noconfigdirs target-libgloss"
 934     ;;
 935   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 936     ;;
 937   hppa*64*-*-linux*)
 938     ;;
 939   hppa*-*-linux*)
 940     ;;
 941   hppa*-*-*elf* | \
 942   hppa*-*-lites* | \
 943   hppa*-*-openbsd* | \
 944   hppa*64*-*-*)
 945     ;;
 946   hppa*-hp-hpux11*)
 947     noconfigdirs="$noconfigdirs ld"
 948     ;;
 949   hppa*-*-pro*)
 950     ;;
 951   hppa*-*-*)
 952     noconfigdirs="$noconfigdirs ld"
 953     ;;
 954   i960-*-*)
 955     noconfigdirs="$noconfigdirs gdb"
 956     ;;
 957   ia64*-*-elf*)
 958     # No gdb support yet.
 959     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 960     ;;
 961   ia64*-**-hpux*)
 962     # No ld support yet.
 963     noconfigdirs="$noconfigdirs libgui itcl ld"
 964     ;;
 965   ia64*-*-*vms*)
 966     # No ld support yet.
 967     noconfigdirs="$noconfigdirs libgui itcl ld"
 968     ;;
 969   i[[3456789]]86-w64-mingw*)
 970     ;;
 971   i[[3456789]]86-*-mingw*)
 972     target_configdirs="$target_configdirs target-winsup"
 973     ;;
 974   *-*-cygwin*)
 975     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 976     noconfigdirs="$noconfigdirs target-libgloss"
 977     # always build newlib if winsup directory is present.
 978     if test -d "$srcdir/winsup/cygwin"; then
 979       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 980     elif test -d "$srcdir/newlib"; then
 981       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 982     fi
 983     ;;
 984   i[[3456789]]86-*-pe)
 985     noconfigdirs="$noconfigdirs target-libgloss"
 986     ;;
 987   i[[3456789]]86-*-sco3.2v5*)
 988     # The linker does not yet know about weak symbols in COFF,
 989     # and is not configured to handle mixed ELF and COFF.
 990     noconfigdirs="$noconfigdirs ld target-libgloss"
 991     ;;
 992   i[[3456789]]86-*-sco*)
 993     noconfigdirs="$noconfigdirs gprof target-libgloss"
 994     ;;
 995   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 996     noconfigdirs="$noconfigdirs target-libgloss"
 997     ;;
 998   i[[3456789]]86-*-sysv4*)
 999     noconfigdirs="$noconfigdirs target-libgloss"
1000     ;;
1001   i[[3456789]]86-*-beos*)
1002     noconfigdirs="$noconfigdirs gdb"
1003     ;;
1004   i[[3456789]]86-*-rdos*)
1005     noconfigdirs="$noconfigdirs gdb"
1006     ;;
1007   mmix-*-*)
1008     noconfigdirs="$noconfigdirs gdb"
1009     ;;
1010   mt-*-*)
1011     noconfigdirs="$noconfigdirs sim"
1012     ;;
1013   powerpc-*-aix*)
1014     # copied from rs6000-*-* entry
1015     noconfigdirs="$noconfigdirs gprof"
1016     ;;
1017   powerpc*-*-winnt* | powerpc*-*-pe*)
1018     target_configdirs="$target_configdirs target-winsup"
1019     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1020     # always build newlib.
1021     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1022     ;;
1023     # This is temporary until we can link against shared libraries
1024   powerpcle-*-solaris*)
1025     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1026     ;;
1027   powerpc-*-beos*)
1028     noconfigdirs="$noconfigdirs gdb"
1029     ;;
1030   rs6000-*-lynxos*)
1031     noconfigdirs="$noconfigdirs gprof"
1032     ;;
1033   rs6000-*-aix*)
1034     noconfigdirs="$noconfigdirs gprof"
1035     ;;
1036   rs6000-*-*)
1037     noconfigdirs="$noconfigdirs gprof"
1038     ;;
1039   m68k-apollo-*)
1040     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1041     ;;
1042   microblaze*)
1043     noconfigdirs="$noconfigdirs gprof"
1044     ;;
1045   mips*-sde-elf* | mips*-mti-elf*)
1046     if test x$with_newlib = xyes; then
1047       noconfigdirs="$noconfigdirs gprof"
1048     fi
1049     ;;
1050   mips*-*-irix5*)
1051     noconfigdirs="$noconfigdirs gprof target-libgloss"
1052     ;;
1053   mips*-*-irix6*)
1054     noconfigdirs="$noconfigdirs gprof target-libgloss"
1055     ;;
1056   mips*-*-bsd*)
1057     noconfigdirs="$noconfigdirs gprof target-libgloss"
1058     ;;
1059   mips*-*-linux*)
1060     ;;
1061   mips*-*-*)
1062     noconfigdirs="$noconfigdirs gprof"
1063     ;;
1064   sh-*-* | sh64-*-*)
1065     case "${target}" in
1066       sh*-*-elf)
1067          ;;
1068       *)
1069          noconfigdirs="$noconfigdirs target-libgloss" ;;
1070     esac
1071     ;;
1072   sparc-*-sunos4*)
1073     if test x${is_cross_compiler} = xno ; then
1074            use_gnu_ld=no
1075     fi
1076     ;;
1077   tic6x-*-*)
1078     noconfigdirs="$noconfigdirs sim"
1079     ;;
1080   tilepro-*-* | tilegx-*-*)
1081     noconfigdirs="$noconfigdirs sim"
1082     ;;
1083   v810-*-*)
1084     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1085     ;;
1086   vax-*-*)
1087     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1088     ;;
1089 esac
1090
1091 # If we aren't building newlib, then don't build libgloss, since libgloss
1092 # depends upon some newlib header files.
1093 case "${noconfigdirs}" in
1094   *target-libgloss*) ;;
1095   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1096 esac
1097
1098 # Work in distributions that contain no compiler tools, like Autoconf.
1099 host_makefile_frag=/dev/null
1100 if test -d ${srcdir}/config ; then
1101 case "${host}" in
1102   i[[3456789]]86-*-msdosdjgpp*)
1103     host_makefile_frag="config/mh-djgpp"
1104     ;;
1105   *-cygwin*)
1106     ACX_CHECK_CYGWIN_CAT_WORKS
1107     host_makefile_frag="config/mh-cygwin"
1108     ;;
1109   *-mingw*)
1110     host_makefile_frag="config/mh-mingw"
1111     ;;
1112   hppa*-hp-hpux10*)
1113     host_makefile_frag="config/mh-pa-hpux10"
1114     ;;
1115   hppa*-hp-hpux*)
1116     host_makefile_frag="config/mh-pa"
1117     ;;
1118   hppa*-*)
1119     host_makefile_frag="config/mh-pa"
1120     ;;
1121   *-*-darwin*)
1122     host_makefile_frag="config/mh-darwin"
1123     ;;
1124   powerpc-*-aix*)
1125     host_makefile_frag="config/mh-ppc-aix"
1126     ;;
1127   rs6000-*-aix*)
1128     host_makefile_frag="config/mh-ppc-aix"
1129     ;;
1130 esac
1131 fi
1132
1133 if test "${build}" != "${host}" ; then
1134   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1135   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1136   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1137   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1138   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1139   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1140   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1141   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1142   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1143   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1144   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1145   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1146   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1147 else
1148   AR_FOR_BUILD="\$(AR)"
1149   AS_FOR_BUILD="\$(AS)"
1150   CC_FOR_BUILD="\$(CC)"
1151   CXX_FOR_BUILD="\$(CXX)"
1152   GCJ_FOR_BUILD="\$(GCJ)"
1153   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1154   GOC_FOR_BUILD="\$(GOC)"
1155   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1156   LD_FOR_BUILD="\$(LD)"
1157   NM_FOR_BUILD="\$(NM)"
1158   RANLIB_FOR_BUILD="\$(RANLIB)"
1159   WINDRES_FOR_BUILD="\$(WINDRES)"
1160   WINDMC_FOR_BUILD="\$(WINDMC)"
1161 fi
1162
1163 AC_PROG_CC
1164 AC_PROG_CXX
1165
1166 # We must set the default linker to the linker used by gcc for the correct
1167 # operation of libtool.  If LD is not defined and we are using gcc, try to
1168 # set the LD default to the ld used by gcc.
1169 if test -z "$LD"; then
1170   if test "$GCC" = yes; then
1171     case $build in
1172     *-*-mingw*)
1173       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1174     *)
1175       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1176     esac
1177     case $gcc_prog_ld in
1178     # Accept absolute paths.
1179     [[\\/]* | [A-Za-z]:[\\/]*)]
1180       LD="$gcc_prog_ld" ;;
1181     esac
1182   fi
1183 fi
1184
1185 ACX_PROG_GNAT
1186 ACX_PROG_CMP_IGNORE_INITIAL
1187
1188 AC_ARG_ENABLE([bootstrap],
1189 [AS_HELP_STRING([--enable-bootstrap],
1190                 [enable bootstrapping @<:@yes if native build@:>@])],,
1191 enable_bootstrap=default)
1192
1193 # Issue errors and warnings for invalid/strange bootstrap combinations.
1194 if test -r $srcdir/gcc/configure; then
1195   have_compiler=yes
1196 else
1197   have_compiler=no
1198 fi
1199
1200 case "$have_compiler:$host:$target:$enable_bootstrap" in
1201   *:*:*:no) ;;
1202
1203   # Default behavior.  Enable bootstrap if we have a compiler
1204   # and we are in a native configuration.
1205   yes:$build:$build:default)
1206     enable_bootstrap=yes ;;
1207
1208   *:*:*:default)
1209     enable_bootstrap=no ;;
1210
1211   # We have a compiler and we are in a native configuration, bootstrap is ok
1212   yes:$build:$build:yes)
1213     ;;
1214
1215   # Other configurations, but we have a compiler.  Assume the user knows
1216   # what he's doing.
1217   yes:*:*:yes)
1218     AC_MSG_WARN([trying to bootstrap a cross compiler])
1219     ;;
1220
1221   # No compiler: if they passed --enable-bootstrap explicitly, fail
1222   no:*:*:yes)
1223     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1224
1225   # Fail if wrong command line
1226   *)
1227     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1228     ;;
1229 esac
1230
1231 # Used for setting $lt_cv_objdir
1232 _LT_CHECK_OBJDIR
1233
1234 # Check for GMP, MPFR and MPC
1235 gmplibs="-lmpc -lmpfr -lgmp"
1236 gmpinc=
1237 have_gmp=no
1238
1239 # Specify a location for mpc
1240 # check for this first so it ends up on the link line before mpfr.
1241 AC_ARG_WITH(mpc,
1242 [AS_HELP_STRING([--with-mpc=PATH],
1243                 [specify prefix directory for installed MPC package.
1244                  Equivalent to --with-mpc-include=PATH/include
1245                  plus --with-mpc-lib=PATH/lib])])
1246 AC_ARG_WITH(mpc-include,
1247 [AS_HELP_STRING([--with-mpc-include=PATH],
1248                 [specify directory for installed MPC include files])])
1249 AC_ARG_WITH(mpc-lib,
1250 [AS_HELP_STRING([--with-mpc-lib=PATH],
1251                 [specify directory for the installed MPC library])])
1252
1253 if test "x$with_mpc" != x; then
1254   gmplibs="-L$with_mpc/lib $gmplibs"
1255   gmpinc="-I$with_mpc/include $gmpinc"
1256 fi
1257 if test "x$with_mpc_include" != x; then
1258   gmpinc="-I$with_mpc_include $gmpinc"
1259 fi
1260 if test "x$with_mpc_lib" != x; then
1261   gmplibs="-L$with_mpc_lib $gmplibs"
1262 fi
1263 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1264   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1265   gmpinc='-I$$s/mpc/src '"$gmpinc"
1266   # Do not test the mpc version.  Assume that it is sufficient, since
1267   # it is in the source tree, and the library has not been built yet
1268   # but it would be included on the link line in the version check below
1269   # hence making the test fail.
1270   have_gmp=yes
1271 fi
1272
1273 # Specify a location for mpfr
1274 # check for this first so it ends up on the link line before gmp.
1275 AC_ARG_WITH(mpfr-dir,
1276 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1277 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1278 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1279
1280 AC_ARG_WITH(mpfr,
1281 [AS_HELP_STRING([--with-mpfr=PATH],
1282                 [specify prefix directory for installed MPFR package.
1283                  Equivalent to --with-mpfr-include=PATH/include
1284                  plus --with-mpfr-lib=PATH/lib])])
1285 AC_ARG_WITH(mpfr-include,
1286 [AS_HELP_STRING([--with-mpfr-include=PATH],
1287                 [specify directory for installed MPFR include files])])
1288 AC_ARG_WITH(mpfr-lib,
1289 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1290                 [specify directory for the installed MPFR library])])
1291
1292 if test "x$with_mpfr" != x; then
1293   gmplibs="-L$with_mpfr/lib $gmplibs"
1294   gmpinc="-I$with_mpfr/include $gmpinc"
1295 fi
1296 if test "x$with_mpfr_include" != x; then
1297   gmpinc="-I$with_mpfr_include $gmpinc"
1298 fi
1299 if test "x$with_mpfr_lib" != x; then
1300   gmplibs="-L$with_mpfr_lib $gmplibs"
1301 fi
1302 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1303   # MPFR v3.1.0 moved the sources into a src sub-directory.
1304   if test -d ${srcdir}/mpfr/src; then
1305     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1306     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1307     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1308   else
1309     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1310     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1311     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1312   fi
1313   # Do not test the mpfr version.  Assume that it is sufficient, since
1314   # it is in the source tree, and the library has not been built yet
1315   # but it would be included on the link line in the version check below
1316   # hence making the test fail.
1317   have_gmp=yes
1318 fi
1319
1320 # Specify a location for gmp
1321 AC_ARG_WITH(gmp-dir,
1322 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1323 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1324 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1325
1326 AC_ARG_WITH(gmp,
1327 [AS_HELP_STRING([--with-gmp=PATH],
1328                 [specify prefix directory for the installed GMP package.
1329                  Equivalent to --with-gmp-include=PATH/include
1330                  plus --with-gmp-lib=PATH/lib])])
1331 AC_ARG_WITH(gmp-include,
1332 [AS_HELP_STRING([--with-gmp-include=PATH],
1333                 [specify directory for installed GMP include files])])
1334 AC_ARG_WITH(gmp-lib,
1335 [AS_HELP_STRING([--with-gmp-lib=PATH],
1336                 [specify directory for the installed GMP library])])
1337
1338
1339 if test "x$with_gmp" != x; then
1340   gmplibs="-L$with_gmp/lib $gmplibs"
1341   gmpinc="-I$with_gmp/include $gmpinc"
1342 fi
1343 if test "x$with_gmp_include" != x; then
1344   gmpinc="-I$with_gmp_include $gmpinc"
1345 fi
1346 if test "x$with_gmp_lib" != x; then
1347   gmplibs="-L$with_gmp_lib $gmplibs"
1348 fi
1349 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1350   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1351   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1352   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1353   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1354   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1355   # Do not test the gmp version.  Assume that it is sufficient, since
1356   # it is in the source tree, and the library has not been built yet
1357   # but it would be included on the link line in the version check below
1358   # hence making the test fail.
1359   have_gmp=yes
1360 fi
1361
1362 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1363   have_gmp=yes
1364   saved_CFLAGS="$CFLAGS"
1365   CFLAGS="$CFLAGS $gmpinc"
1366   # Check for the recommended and required versions of GMP.
1367   AC_MSG_CHECKING([for the correct version of gmp.h])
1368   AC_TRY_COMPILE([#include "gmp.h"],[
1369   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1370   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1371   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1372   choke me
1373   #endif
1374   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1375   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1376   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1377   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1378   choke me
1379   #endif
1380   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1381    [AC_MSG_RESULT([no]); have_gmp=no])
1382
1383   # If we have GMP, check the MPFR version.
1384   if test x"$have_gmp" = xyes; then
1385     # Check for the recommended and required versions of MPFR.
1386     AC_MSG_CHECKING([for the correct version of mpfr.h])
1387     AC_TRY_COMPILE([#include <gmp.h>
1388     #include <mpfr.h>],[
1389     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1390     choke me
1391     #endif
1392     ], [AC_TRY_COMPILE([#include <gmp.h>
1393     #include <mpfr.h>],[
1394     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1395     choke me
1396     #endif
1397     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1398      [AC_MSG_RESULT([no]); have_gmp=no])
1399   fi
1400
1401   # Check for the MPC header version.
1402   if test x"$have_gmp" = xyes ; then
1403     # Check for the recommended and required versions of MPC.
1404     AC_MSG_CHECKING([for the correct version of mpc.h])
1405     AC_TRY_COMPILE([#include <mpc.h>],[
1406     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1407     choke me
1408     #endif
1409     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1410     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1411     choke me
1412     #endif
1413     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1414      [AC_MSG_RESULT([no]); have_gmp=no])
1415   fi
1416
1417   # Now check the MPFR library.
1418   if test x"$have_gmp" = xyes; then
1419     saved_LIBS="$LIBS"
1420     LIBS="$LIBS $gmplibs"
1421     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1422     AC_TRY_LINK([#include <mpc.h>],[
1423     mpfr_t n;
1424     mpfr_t x;
1425     mpc_t c;
1426     int t;
1427     mpfr_init (n);
1428     mpfr_init (x);
1429     mpfr_atan2 (n, n, x, GMP_RNDN);
1430     mpfr_erfc (n, x, GMP_RNDN);
1431     mpfr_subnormalize (x, t, GMP_RNDN);
1432     mpfr_clear(n);
1433     mpfr_clear(x);
1434     mpc_init2 (c, 53);
1435     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1436     mpc_cosh (c, c, MPC_RNDNN);
1437     mpc_pow (c, c, c, MPC_RNDNN);
1438     mpc_acosh (c, c, MPC_RNDNN);
1439     mpc_clear (c);
1440     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1441     LIBS="$saved_LIBS"
1442   fi
1443
1444   CFLAGS="$saved_CFLAGS"
1445
1446 # The library versions listed in the error message below should match
1447 # the HARD-minimums enforced above.
1448   if test x$have_gmp != xyes; then
1449     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1450 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1451 their locations.  Source code for these libraries can be found at
1452 their respective hosting sites as well as at
1453 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1454 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1455 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1456 make sure that you have installed both the libraries and the header
1457 files.  They may be located in separate packages.])
1458   fi
1459 fi
1460
1461 # Flags needed for both GMP, MPFR and/or MPC.
1462 AC_SUBST(gmplibs)
1463 AC_SUBST(gmpinc)
1464 AC_SUBST(extra_mpfr_configure_flags)
1465 AC_SUBST(extra_mpc_gmp_configure_flags)
1466 AC_SUBST(extra_mpc_mpfr_configure_flags)
1467 AC_SUBST(extra_isl_gmp_configure_flags)
1468
1469 # Allow host libstdc++ to be specified for static linking with PPL.
1470 AC_ARG_WITH(host-libstdcxx,
1471 [AS_HELP_STRING([--with-host-libstdcxx=L],
1472                 [use linker arguments L to link with libstdc++
1473                  when linking with PPL])])
1474
1475 case $with_host_libstdcxx in
1476   no|yes)
1477     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1478     ;;
1479 esac
1480
1481 # Linker flags to use for stage1 or when not boostrapping.
1482 AC_ARG_WITH(stage1-ldflags,
1483 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1484 [if test "$withval" = "no" -o "$withval" = "yes"; then
1485    stage1_ldflags=
1486  else
1487    stage1_ldflags=$withval
1488  fi],
1489 [stage1_ldflags=])
1490 AC_SUBST(stage1_ldflags)
1491
1492 # Libraries to use for stage1 or when not bootstrapping.
1493 AC_ARG_WITH(stage1-libs,
1494 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1495 [if test "$withval" = "no" -o "$withval" = "yes"; then
1496    stage1_libs=
1497  else
1498    stage1_libs=$withval
1499  fi],
1500 [stage1_libs=$with_host_libstdcxx])
1501 AC_SUBST(stage1_libs)
1502
1503 # Libraries to use for stage2 and later builds.  This defaults to the
1504 # argument passed to --with-host-libstdcxx.
1505 AC_ARG_WITH(boot-libs,
1506 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1507 [if test "$withval" = "no" -o "$withval" = "yes"; then
1508    poststage1_libs=
1509  else
1510    poststage1_libs=$withval
1511  fi],
1512 [poststage1_libs=$with_host_libstdcxx])
1513 AC_SUBST(poststage1_libs)
1514
1515 # Linker flags to use for stage2 and later builds.
1516 AC_ARG_WITH(boot-ldflags,
1517 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1518                 [linker flags for stage2 and later])],
1519 [if test "$withval" = "no" -o "$withval" = "yes"; then
1520    poststage1_ldflags=
1521  else
1522    poststage1_ldflags=$withval
1523  fi],
1524 [poststage1_ldflags=
1525  # In stages 2 and 3, default to linking libstdc++ and libgcc
1526  # statically.  But if the user explicitly specified the libraries to
1527  # use, trust that they are doing what they want.
1528  if test "$poststage1_libs" = ""; then
1529    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1530  fi])
1531 AC_SUBST(poststage1_ldflags)
1532
1533 # GCC GRAPHITE dependences, ISL and CLOOG which in turn requires ISL.
1534 # Basic setup is inlined here, actual checks are in config/cloog.m4 and
1535 # config/isl.m4
1536
1537 AC_ARG_WITH(cloog,
1538   [AS_HELP_STRING(
1539     [--with-cloog=PATH],
1540     [Specify prefix directory for the installed CLooG-ISL package.
1541      Equivalent to --with-cloog-include=PATH/include
1542      plus --with-cloog-lib=PATH/lib])])
1543 AC_ARG_WITH(isl,
1544   [AS_HELP_STRING(
1545    [--with-isl=PATH],
1546    [Specify prefix directory for the installed ISL package.
1547     Equivalent to --with-isl-include=PATH/include
1548     plus --with-isl-lib=PATH/lib])])
1549
1550 # Treat either --without-cloog or --without-isl as a request to disable
1551 # GRAPHITE support and skip all following checks.
1552 if test "x$with_isl" != "xno" &&
1553    test "x$with_cloog" != "xno"; then
1554   # Check for ISL
1555   dnl Provide configure switches and initialize islinc & isllibs
1556   dnl with user input.
1557   ISL_INIT_FLAGS
1558   dnl The minimal version of ISL required for Graphite.
1559   ISL_CHECK_VERSION(0,10)
1560   dnl Only execute fail-action, if ISL has been requested.
1561   ISL_IF_FAILED([
1562     AC_MSG_ERROR([Unable to find a usable ISL.  See config.log for details.])])
1563
1564   if test "x$gcc_cv_isl" != "xno"; then
1565     # Check for CLOOG
1566     dnl Provide configure switches and initialize clooginc & clooglibs
1567     dnl with user input.
1568     CLOOG_INIT_FLAGS
1569     dnl The minimal version of CLooG required for Graphite.
1570     dnl
1571     dnl If we use CLooG-Legacy, the provided version information is
1572     dnl ignored.
1573     CLOOG_CHECK_VERSION(0,17,0)
1574
1575     dnl Only execute fail-action, if CLooG has been requested.
1576     CLOOG_IF_FAILED([
1577       AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1578   fi
1579 fi
1580
1581 # If either the ISL or the CLooG check failed, disable builds of in-tree
1582 # variants of both
1583 if test "x$with_isl" = xno ||
1584    test "x$with_cloog" = xno ||
1585    test "x$gcc_cv_cloog" = xno ||
1586    test "x$gcc_cv_isl" = xno; then
1587   noconfigdirs="$noconfigdirs cloog isl"
1588   islinc=
1589   clooginc=
1590   clooglibs=
1591 fi
1592
1593 AC_SUBST(islinc)
1594 AC_SUBST(clooglibs)
1595 AC_SUBST(clooginc)
1596
1597
1598 # Check for LTO support.
1599 AC_ARG_ENABLE(lto,
1600 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1601 enable_lto=$enableval,
1602 enable_lto=yes; default_enable_lto=yes)
1603
1604 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1605   build_lto_plugin=yes
1606 ],[if test x"$default_enable_lto" = x"yes" ; then
1607     case $target in
1608       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1609       # On other non-ELF platforms, LTO has yet to be validated.
1610       *) enable_lto=no ;;
1611     esac
1612   else
1613   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1614   # It would also be nice to check the binutils support, but we don't
1615   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1616   # warn during gcc/ subconfigure; unless you're bootstrapping with
1617   # -flto it won't be needed until after installation anyway.
1618     case $target in
1619       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1620       *) if test x"$enable_lto" = x"yes"; then
1621         AC_MSG_ERROR([LTO support is not enabled for this target.])
1622         fi
1623       ;;
1624     esac
1625   fi
1626   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1627   # Build it unless LTO was explicitly disabled.
1628   case $target in
1629     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1630     *) ;;
1631   esac
1632 ])
1633
1634
1635 # By default, C and C++ are the only stage 1 languages.
1636 stage1_languages=,c,
1637
1638 # Target libraries that we bootstrap.
1639 bootstrap_target_libs=,target-libgcc,
1640
1641 # Figure out what language subdirectories are present.
1642 # Look if the user specified --enable-languages="..."; if not, use
1643 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1644 # go away some day.
1645 # NB:  embedded tabs in this IF block -- do not untabify
1646 if test -d ${srcdir}/gcc; then
1647   if test x"${enable_languages+set}" != xset; then
1648     if test x"${LANGUAGES+set}" = xset; then
1649       enable_languages="${LANGUAGES}"
1650         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1651     else
1652       enable_languages=all
1653     fi
1654   else
1655     if test x"${enable_languages}" = x ||
1656        test x"${enable_languages}" = xyes;
1657        then
1658       echo configure.in: --enable-languages needs at least one language argument 1>&2
1659       exit 1
1660     fi
1661   fi
1662   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1663
1664   # 'f95' is the old name for the 'fortran' language. We issue a warning
1665   # and make the substitution.
1666   case ,${enable_languages}, in
1667     *,f95,*)
1668       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1669       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1670       ;;
1671   esac
1672
1673   # If bootstrapping, C++ must be enabled.
1674   case ",$enable_languages,:$enable_bootstrap" in
1675     *,c++,*:*) ;;
1676     *:yes)
1677       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1678         enable_languages="${enable_languages},c++"
1679       else
1680         AC_MSG_ERROR([bootstrapping requires c++ sources])
1681       fi
1682       ;;
1683   esac
1684
1685   # First scan to see if an enabled language requires some other language.
1686   # We assume that a given config-lang.in will list all the language
1687   # front ends it requires, even if some are required indirectly.
1688   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1689     case ${lang_frag} in
1690       ..) ;;
1691       # The odd quoting in the next line works around
1692       # an apparent bug in bash 1.12 on linux.
1693       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1694       *)
1695         # From the config-lang.in, get $language, $lang_requires, and
1696         # $lang_requires_boot_languages.
1697         language=
1698         lang_requires=
1699         lang_requires_boot_languages=
1700         . ${lang_frag}
1701         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1702           case ,${enable_languages}, in
1703             *,$other,*) ;;
1704             *,all,*) ;;
1705             *,$language,*)
1706               echo " \`$other' language required by \`$language'; enabling" 1>&2
1707               enable_languages="${enable_languages},${other}"
1708               ;;
1709           esac
1710         done
1711         for other in ${lang_requires_boot_languages} ; do
1712           if test "$other" != "c"; then
1713             case ,${enable_stage1_languages}, in
1714               *,$other,*) ;;
1715               *,all,*) ;;
1716               *)
1717                 case ,${enable_languages}, in
1718                   *,$language,*)
1719                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1720                     enable_stage1_languages="$enable_stage1_languages,${other}"
1721                     ;;
1722                 esac
1723                 ;;
1724             esac
1725           fi
1726         done
1727         ;;
1728     esac
1729   done
1730
1731   new_enable_languages=,c,
1732
1733   # If LTO is enabled, add the LTO front end.
1734   extra_host_libiberty_configure_flags=
1735   if test "$enable_lto" = "yes" ; then
1736     case ,${enable_languages}, in
1737       *,lto,*) ;;
1738       *) enable_languages="${enable_languages},lto" ;;
1739     esac
1740     if test "${build_lto_plugin}" = "yes" ; then
1741       configdirs="$configdirs lto-plugin"
1742       extra_host_libiberty_configure_flags=--enable-shared
1743     fi
1744   fi
1745   AC_SUBST(extra_host_libiberty_configure_flags)
1746
1747   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1748   potential_languages=,c,
1749
1750   enabled_target_libs=
1751   disabled_target_libs=
1752
1753   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1754     case ${lang_frag} in
1755       ..) ;;
1756       # The odd quoting in the next line works around
1757       # an apparent bug in bash 1.12 on linux.
1758       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1759       *)
1760         # From the config-lang.in, get $language, $target_libs,
1761         # $lang_dirs, $boot_language, and $build_by_default
1762         language=
1763         target_libs=
1764         lang_dirs=
1765         subdir_requires=
1766         boot_language=no
1767         build_by_default=yes
1768         . ${lang_frag}
1769         if test x${language} = x; then
1770           echo "${lang_frag} doesn't set \$language." 1>&2
1771           exit 1
1772         fi
1773
1774         if test "$language" = "c++"; then
1775           boot_language=yes
1776         fi
1777
1778         add_this_lang=no
1779         case ,${enable_languages}, in
1780           *,${language},*)
1781             # Language was explicitly selected; include it
1782             # unless it is C, which is enabled by default.
1783             if test "$language" != "c"; then
1784               add_this_lang=yes
1785             fi
1786             ;;
1787           *,all,*)
1788             # 'all' was selected, select it if it is a default language
1789             if test "$language" != "c"; then
1790               add_this_lang=${build_by_default}
1791             fi
1792             ;;
1793         esac
1794
1795         # Disable languages that need other directories if these aren't available.
1796         for i in $subdir_requires; do
1797           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1798           case ,${enable_languages}, in
1799             *,${language},*)
1800               # Specifically requested language; tell them.
1801               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1802               ;;
1803             *)
1804               # Silently disable.
1805               add_this_lang=unsupported
1806               ;;
1807           esac
1808         done
1809
1810         # Disable Ada if no preexisting GNAT is available.
1811         case ,${enable_languages},:${language}:${have_gnat} in
1812           *,${language},*:ada:no)
1813             # Specifically requested language; tell them.
1814             AC_MSG_ERROR([GNAT is required to build $language])
1815             ;;
1816           *:ada:no)
1817             # Silently disable.
1818             add_this_lang=unsupported
1819             ;;
1820         esac
1821
1822         # Disable a language that is unsupported by the target.
1823         case " $unsupported_languages " in
1824           *" $language "*)
1825             add_this_lang=unsupported
1826             ;;
1827         esac
1828
1829         case $add_this_lang in
1830           unsupported)
1831             # Remove language-dependent dirs.
1832             disabled_target_libs="$disabled_target_libs $target_libs"
1833             noconfigdirs="$noconfigdirs $lang_dirs"
1834             ;;
1835           no)
1836             # Remove language-dependent dirs; still show language as supported.
1837             disabled_target_libs="$disabled_target_libs $target_libs"
1838             noconfigdirs="$noconfigdirs $lang_dirs"
1839             potential_languages="${potential_languages}${language},"
1840             ;;
1841           yes)
1842             new_enable_languages="${new_enable_languages}${language},"
1843             potential_languages="${potential_languages}${language},"
1844             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1845             enabled_target_libs="$enabled_target_libs $target_libs"
1846             case "${boot_language}:,$enable_stage1_languages," in
1847               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1848                 # Add to (comma-separated) list of stage 1 languages.
1849                 case ",$stage1_languages," in
1850                   *,$language,* | ,yes, | ,all,) ;;
1851                   *) stage1_languages="${stage1_languages}${language}," ;;
1852                 esac
1853                 # We need to bootstrap any supporting libraries.
1854                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1855                 ;;
1856             esac
1857             ;;
1858         esac
1859         ;;
1860     esac
1861   done
1862
1863   # Add target libraries which are only needed for disabled languages
1864   # to noconfigdirs.
1865   if test -n "$disabled_target_libs"; then
1866     for dir in $disabled_target_libs; do
1867       case " $enabled_target_libs " in
1868       *" ${dir} "*) ;;
1869       *) noconfigdirs="$noconfigdirs $dir" ;;
1870       esac
1871     done
1872   fi
1873
1874   AC_ARG_ENABLE(stage1-languages,
1875   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1876                   [choose additional languages to build during
1877                   stage1.  Mostly useful for compiler development])],
1878   [case ,${enable_stage1_languages}, in
1879     ,no,|,,)
1880       # Set it to something that will have no effect in the loop below
1881       enable_stage1_languages=c ;;
1882     ,yes,)
1883       enable_stage1_languages=`echo $new_enable_languages | \
1884         sed -e "s/^,//" -e "s/,$//" ` ;;
1885     *,all,*)
1886       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1887         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1888   esac
1889
1890   # Add "good" languages from enable_stage1_languages to stage1_languages,
1891   # while "bad" languages go in missing_languages.  Leave no duplicates.
1892   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1893     case $potential_languages in
1894       *,$i,*)
1895         case $stage1_languages in
1896           *,$i,*) ;;
1897           *) stage1_languages="$stage1_languages$i," ;;
1898         esac ;;
1899       *)
1900         case $missing_languages in
1901           *,$i,*) ;;
1902           *) missing_languages="$missing_languages$i," ;;
1903         esac ;;
1904      esac
1905   done])
1906
1907   # Remove leading/trailing commas that were added for simplicity
1908   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1909   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1910   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1911   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1912
1913   if test "x$missing_languages" != x; then
1914     AC_MSG_ERROR([
1915 The following requested languages could not be built: ${missing_languages}
1916 Supported languages are: ${potential_languages}])
1917   fi
1918   if test "x$new_enable_languages" != "x$enable_languages"; then
1919     echo The following languages will be built: ${new_enable_languages}
1920     enable_languages="$new_enable_languages"
1921   fi
1922
1923   AC_SUBST(stage1_languages)
1924   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1925 fi
1926
1927 # Handle --disable-<component> generically.
1928 for dir in $configdirs $build_configdirs $target_configdirs ; do
1929   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1930   varname=`echo $dirname | sed -e s/+/_/g`
1931   if eval test x\${enable_${varname}} "=" xno ; then
1932     noconfigdirs="$noconfigdirs $dir"
1933   fi
1934 done
1935
1936 # Check for Boehm's garbage collector
1937 AC_ARG_ENABLE(objc-gc,
1938 [AS_HELP_STRING([--enable-objc-gc],
1939                 [enable use of Boehm's garbage collector with the
1940                  GNU Objective-C runtime])],
1941 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1942   *,objc,*:*:yes:*target-boehm-gc*)
1943     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1944     ;;
1945 esac])
1946
1947 # Make sure we only build Boehm's garbage collector if required.
1948 case ,${enable_languages},:${enable_objc_gc} in
1949   *,objc,*:yes)
1950     # Keep target-boehm-gc if requested for Objective-C.
1951     ;;
1952   *)
1953     # Otherwise remove target-boehm-gc depending on target-libjava.
1954     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1955       noconfigdirs="$noconfigdirs target-boehm-gc"
1956     fi
1957     ;;
1958 esac
1959
1960 # Disable libitm if we're not building C++
1961 case ,${enable_languages}, in
1962   *,c++,*) ;;
1963   *)
1964     noconfigdirs="$noconfigdirs target-libitm"
1965     ;;
1966 esac
1967
1968 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1969 # $build_configdirs and $target_configdirs.
1970 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1971
1972 notsupp=""
1973 for dir in . $skipdirs $noconfigdirs ; do
1974   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1975   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1976     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1977     if test -r $srcdir/$dirname/configure ; then
1978       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1979         true
1980       else
1981         notsupp="$notsupp $dir"
1982       fi
1983     fi
1984   fi
1985   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1986     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1987     if test -r $srcdir/$dirname/configure ; then
1988       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1989         true
1990       else
1991         notsupp="$notsupp $dir"
1992       fi
1993     fi
1994   fi
1995   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1996     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
1997     if test -r $srcdir/$dirname/configure ; then
1998       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1999         true
2000       else
2001         notsupp="$notsupp $dir"
2002       fi
2003     fi
2004   fi
2005 done
2006
2007 # Quietly strip out all directories which aren't configurable in this tree.
2008 # This relies on all configurable subdirectories being autoconfiscated, which
2009 # is now the case.
2010 build_configdirs_all="$build_configdirs"
2011 build_configdirs=
2012 for i in ${build_configdirs_all} ; do
2013   j=`echo $i | sed -e s/build-//g`
2014   if test -f ${srcdir}/$j/configure ; then
2015     build_configdirs="${build_configdirs} $i"
2016   fi
2017 done
2018
2019 configdirs_all="$configdirs"
2020 configdirs=
2021 for i in ${configdirs_all} ; do
2022   if test -f ${srcdir}/$i/configure ; then
2023     configdirs="${configdirs} $i"
2024   fi
2025 done
2026
2027 target_configdirs_all="$target_configdirs"
2028 target_configdirs=
2029 for i in ${target_configdirs_all} ; do
2030   j=`echo $i | sed -e s/target-//g`
2031   if test -f ${srcdir}/$j/configure ; then
2032     target_configdirs="${target_configdirs} $i"
2033   fi
2034 done
2035
2036 # Produce a warning message for the subdirs we can't configure.
2037 # This isn't especially interesting in the Cygnus tree, but in the individual
2038 # FSF releases, it's important to let people know when their machine isn't
2039 # supported by the one or two programs in a package.
2040
2041 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2042   # If $appdirs is non-empty, at least one of those directories must still
2043   # be configured, or we error out.  (E.g., if the gas release supports a
2044   # specified target in some subdirs but not the gas subdir, we shouldn't
2045   # pretend that all is well.)
2046   if test -n "$appdirs" ; then
2047     for dir in $appdirs ; do
2048       if test -r $dir/Makefile.in ; then
2049         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2050           appdirs=""
2051           break
2052         fi
2053         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2054           appdirs=""
2055           break
2056         fi
2057       fi
2058     done
2059     if test -n "$appdirs" ; then
2060       echo "*** This configuration is not supported by this package." 1>&2
2061       exit 1
2062     fi
2063   fi
2064   # Okay, some application will build, or we don't care to check.  Still
2065   # notify of subdirs not getting built.
2066   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2067   echo "    ${notsupp}" 1>&2
2068   echo "    (Any other directories should still work fine.)" 1>&2
2069 fi
2070
2071 case "$host" in
2072   *msdosdjgpp*)
2073     enable_gdbtk=no ;;
2074 esac
2075
2076 # To find our prefix, in gcc_cv_tool_prefix.
2077 ACX_TOOL_DIRS
2078
2079 copy_dirs=
2080
2081 AC_ARG_WITH([build-sysroot],
2082   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2083                   [use sysroot as the system root during the build])],
2084   [if test x"$withval" != x ; then
2085      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2086    fi],
2087   [SYSROOT_CFLAGS_FOR_TARGET=])
2088 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2089
2090 AC_ARG_WITH([debug-prefix-map],
2091   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2092                   [map A to B, C to D ... in debug information])],
2093   [if test x"$withval" != x; then
2094      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2095      for debug_map in $withval; do
2096        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2097      done
2098    fi],
2099   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2100 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2101
2102 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2103 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2104 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2105 # We want to ensure that TARGET libraries (which we know are built with
2106 # gcc) are built with "-O2 -g", so include those options when setting
2107 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2108 if test "x$CFLAGS_FOR_TARGET" = x; then
2109   CFLAGS_FOR_TARGET=$CFLAGS
2110   case " $CFLAGS " in
2111     *" -O2 "*) ;;
2112     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2113   esac
2114   case " $CFLAGS " in
2115     *" -g "* | *" -g3 "*) ;;
2116     *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2117   esac
2118 fi
2119 AC_SUBST(CFLAGS_FOR_TARGET)
2120
2121 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2122   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2123   case " $CXXFLAGS " in
2124     *" -O2 "*) ;;
2125     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2126   esac
2127   case " $CXXFLAGS " in
2128     *" -g "* | *" -g3 "*) ;;
2129     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2130   esac
2131 fi
2132 AC_SUBST(CXXFLAGS_FOR_TARGET)
2133
2134 AC_SUBST(LDFLAGS_FOR_TARGET)
2135
2136 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2137 # the named directory are copied to $(tooldir)/sys-include.
2138 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2139   if test x${is_cross_compiler} = xno ; then
2140     echo 1>&2 '***' --with-headers is only supported when cross compiling
2141     exit 1
2142   fi
2143   if test x"${with_headers}" != xyes ; then
2144     x=${gcc_cv_tool_prefix}
2145     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2146   fi
2147 fi
2148
2149 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2150 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2151 # are permitted.
2152 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2153   if test x${is_cross_compiler} = xno ; then
2154     echo 1>&2 '***' --with-libs is only supported when cross compiling
2155     exit 1
2156   fi
2157   if test x"${with_libs}" != xyes ; then
2158     # Copy the libraries in reverse order, so that files in the first named
2159     # library override files in subsequent libraries.
2160     x=${gcc_cv_tool_prefix}
2161     for l in ${with_libs}; do
2162       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2163     done
2164   fi
2165 fi
2166
2167 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2168 #
2169 # This is done by determining whether or not the appropriate directory
2170 # is available, and by checking whether or not specific configurations
2171 # have requested that this magic not happen.
2172 #
2173 # The command line options always override the explicit settings in
2174 # configure.in, and the settings in configure.in override this magic.
2175 #
2176 # If the default for a toolchain is to use GNU as and ld, and you don't
2177 # want to do that, then you should use the --without-gnu-as and
2178 # --without-gnu-ld options for the configure script.  Similarly, if
2179 # the default is to use the included zlib and you don't want to do that,
2180 # you should use the --with-system-zlib option for the configure script.
2181
2182 if test x${use_gnu_as} = x &&
2183    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2184   with_gnu_as=yes
2185   extra_host_args="$extra_host_args --with-gnu-as"
2186 fi
2187
2188 if test x${use_gnu_ld} = x &&
2189    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2190   with_gnu_ld=yes
2191   extra_host_args="$extra_host_args --with-gnu-ld"
2192 fi
2193
2194 if test x${use_included_zlib} = x &&
2195    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2196   :
2197 else
2198   with_system_zlib=yes
2199   extra_host_args="$extra_host_args --with-system-zlib"
2200 fi
2201
2202 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2203 # can detect this case.
2204
2205 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2206   with_newlib=yes
2207   extra_host_args="$extra_host_args --with-newlib"
2208 fi
2209
2210 # Handle ${copy_dirs}
2211 set fnord ${copy_dirs}
2212 shift
2213 while test $# != 0 ; do
2214   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2215     :
2216   else
2217     echo Copying $1 to $2
2218
2219     # Use the install script to create the directory and all required
2220     # parent directories.
2221     if test -d $2 ; then
2222       :
2223     else
2224       echo >config.temp
2225       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2226     fi
2227
2228     # Copy the directory, assuming we have tar.
2229     # FIXME: Should we use B in the second tar?  Not all systems support it.
2230     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2231
2232     # It is the responsibility of the user to correctly adjust all
2233     # symlinks.  If somebody can figure out how to handle them correctly
2234     # here, feel free to add the code.
2235
2236     echo $1 > $2/COPIED
2237   fi
2238   shift; shift
2239 done
2240
2241 # Determine a target-dependent exec_prefix that the installed
2242 # gcc will search in.  Keep this list sorted by triplet, with
2243 # the *-*-osname triplets last.
2244 md_exec_prefix=
2245 case "${target}" in
2246   i[[34567]]86-pc-msdosdjgpp*)
2247     md_exec_prefix=/dev/env/DJDIR/bin
2248     ;;
2249   *-*-hpux* | \
2250   *-*-nto-qnx* | \
2251   *-*-solaris2*)
2252     md_exec_prefix=/usr/ccs/bin
2253     ;;
2254 esac
2255
2256 extra_arflags_for_target=
2257 extra_nmflags_for_target=
2258 extra_ranlibflags_for_target=
2259 target_makefile_frag=/dev/null
2260 case "${target}" in
2261   spu-*-*)
2262     target_makefile_frag="config/mt-spu"
2263     ;;
2264   mips*-sde-elf* | mips*-mti-elf*)
2265     target_makefile_frag="config/mt-sde"
2266     ;;
2267   mipsisa*-*-elfoabi*)
2268     target_makefile_frag="config/mt-mips-elfoabi"
2269     ;;
2270   mips*-*-*linux* | mips*-*-gnu*)
2271     target_makefile_frag="config/mt-mips-gnu"
2272     ;;
2273   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2274     target_makefile_frag="config/mt-gnu"
2275     ;;
2276   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2277     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2278     # commands to handle both 32-bit and 64-bit objects.  These flags are
2279     # harmless if we're using GNU nm or ar.
2280     extra_arflags_for_target=" -X32_64"
2281     extra_nmflags_for_target=" -B -X32_64"
2282     ;;
2283 esac
2284
2285 alphaieee_frag=/dev/null
2286 case $target in
2287   alpha*-*-*)
2288     # This just makes sure to use the -mieee option to build target libs.
2289     # This should probably be set individually by each library.
2290     alphaieee_frag="config/mt-alphaieee"
2291     ;;
2292 esac
2293
2294 # If --enable-target-optspace always use -Os instead of -O2 to build
2295 # the target libraries, similarly if it is not specified, use -Os
2296 # on selected platforms.
2297 ospace_frag=/dev/null
2298 case "${enable_target_optspace}:${target}" in
2299   yes:*)
2300     ospace_frag="config/mt-ospace"
2301     ;;
2302   :d30v-*)
2303     ospace_frag="config/mt-d30v"
2304     ;;
2305   :m32r-* | :d10v-* | :fr30-*)
2306     ospace_frag="config/mt-ospace"
2307     ;;
2308   no:* | :*)
2309     ;;
2310   *)
2311     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2312     ;;
2313 esac
2314
2315 # Some systems (e.g., one of the i386-aix systems the gas testers are
2316 # using) don't handle "\$" correctly, so don't use it here.
2317 tooldir='${exec_prefix}'/${target_noncanonical}
2318 build_tooldir=${tooldir}
2319
2320 # Create a .gdbinit file which runs the one in srcdir
2321 # and tells GDB to look there for source files.
2322
2323 if test -r ${srcdir}/.gdbinit ; then
2324   case ${srcdir} in
2325     .) ;;
2326     *) cat > ./.gdbinit <<EOF
2327 # ${NO_EDIT}
2328 dir ${srcdir}
2329 dir .
2330 source ${srcdir}/.gdbinit
2331 EOF
2332     ;;
2333   esac
2334 fi
2335
2336 # Make sure that the compiler is able to generate an executable.  If it
2337 # can't, we are probably in trouble.  We don't care whether we can run the
2338 # executable--we might be using a cross compiler--we only care whether it
2339 # can be created.  At this point the main configure script has set CC.
2340 we_are_ok=no
2341 echo "int main () { return 0; }" > conftest.c
2342 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2343 if test $? = 0 ; then
2344   if test -s conftest || test -s conftest.exe ; then
2345     we_are_ok=yes
2346   fi
2347 fi
2348 case $we_are_ok in
2349   no)
2350     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2351     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2352     rm -f conftest*
2353     exit 1
2354     ;;
2355 esac
2356 rm -f conftest*
2357
2358 # Decide which environment variable is used to find dynamic libraries.
2359 case "${host}" in
2360   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2361   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2362   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2363   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2364 esac
2365
2366 # On systems where the dynamic library environment variable is PATH,
2367 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2368 # built executables to PATH.
2369 if test "$RPATH_ENVVAR" = PATH; then
2370   GCC_SHLIB_SUBDIR=/shlib
2371 else
2372   GCC_SHLIB_SUBDIR=
2373 fi
2374
2375 # Record target_configdirs and the configure arguments for target and
2376 # build configuration in Makefile.
2377 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2378 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2379
2380 # If we are building libgomp, bootstrap it.
2381 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2382   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2383 fi
2384
2385 # Determine whether gdb needs tk/tcl or not.
2386 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2387 # and in that case we want gdb to be built without tk.  Ugh!
2388 # In fact I believe gdb is the *only* package directly dependent on tk,
2389 # so we should be able to put the 'maybe's in unconditionally and
2390 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2391 # 100% sure that that's safe though.
2392
2393 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2394 case "$enable_gdbtk" in
2395   no)
2396     GDB_TK="" ;;
2397   yes)
2398     GDB_TK="${gdb_tk}" ;;
2399   *)
2400     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2401     # distro.  Eventually someone will fix this and move Insight, nee
2402     # gdbtk to a separate directory.
2403     if test -d ${srcdir}/gdb/gdbtk ; then
2404       GDB_TK="${gdb_tk}"
2405     else
2406       GDB_TK=""
2407     fi
2408     ;;
2409 esac
2410 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2411 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2412
2413 # Strip out unwanted targets.
2414
2415 # While at that, we remove Makefiles if we were started for recursive
2416 # configuration, so that the top-level Makefile reconfigures them,
2417 # like we used to do when configure itself was recursive.
2418
2419 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2420 # but now we're fixing up the Makefile ourselves with the additional
2421 # commands passed to AC_CONFIG_FILES.  Use separate variables
2422 # extrasub-{build,host,target} not because there is any reason to split
2423 # the substitutions up that way, but only to remain below the limit of
2424 # 99 commands in a script, for HP-UX sed.
2425 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2426
2427 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2428   yes:yes:*\ gold\ *:*,c++,*) ;;
2429   yes:yes:*\ gold\ *:*)
2430     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2431     ;;
2432 esac
2433
2434 # Adjust the toplevel makefile according to whether bootstrap was selected.
2435 case $enable_bootstrap in
2436   yes)
2437     bootstrap_suffix=bootstrap
2438     BUILD_CONFIG=bootstrap-debug
2439     ;;
2440   no)
2441     bootstrap_suffix=no-bootstrap
2442     BUILD_CONFIG=
2443     ;;
2444 esac
2445
2446 AC_MSG_CHECKING(for default BUILD_CONFIG)
2447
2448 AC_ARG_WITH([build-config],
2449   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2450                   [use config/NAME.mk build configuration])],
2451   [case $with_build_config in
2452    yes) with_build_config= ;;
2453    no) with_build_config= BUILD_CONFIG= ;;
2454    esac])
2455
2456 if test "x${with_build_config}" != x; then
2457   BUILD_CONFIG=$with_build_config
2458 else
2459   case $BUILD_CONFIG in
2460   bootstrap-debug)
2461     if echo "int f (void) { return 0; }" > conftest.c &&
2462        ${CC} -c conftest.c &&
2463        mv conftest.o conftest.o.g0 &&
2464        ${CC} -c -g conftest.c &&
2465        mv conftest.o conftest.o.g &&
2466        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2467       :
2468     else
2469       BUILD_CONFIG=
2470     fi
2471     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2472     ;;
2473   esac
2474 fi
2475 AC_MSG_RESULT($BUILD_CONFIG)
2476 AC_SUBST(BUILD_CONFIG)
2477
2478 extrasub_build=
2479 for module in ${build_configdirs} ; do
2480   if test -z "${no_recursion}" \
2481      && test -f ${build_subdir}/${module}/Makefile; then
2482     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2483     rm -f ${build_subdir}/${module}/Makefile
2484   fi
2485   extrasub_build="$extrasub_build
2486 /^@if build-$module\$/d
2487 /^@endif build-$module\$/d
2488 /^@if build-$module-$bootstrap_suffix\$/d
2489 /^@endif build-$module-$bootstrap_suffix\$/d"
2490 done
2491 extrasub_host=
2492 for module in ${configdirs} ; do
2493   if test -z "${no_recursion}"; then
2494     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2495       if test -f ${file}; then
2496         echo 1>&2 "*** removing ${file} to force reconfigure"
2497         rm -f ${file}
2498       fi
2499     done
2500   fi
2501   extrasub_host="$extrasub_host
2502 /^@if $module\$/d
2503 /^@endif $module\$/d
2504 /^@if $module-$bootstrap_suffix\$/d
2505 /^@endif $module-$bootstrap_suffix\$/d"
2506 done
2507 extrasub_target=
2508 for module in ${target_configdirs} ; do
2509   if test -z "${no_recursion}" \
2510      && test -f ${target_subdir}/${module}/Makefile; then
2511     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2512     rm -f ${target_subdir}/${module}/Makefile
2513   fi
2514
2515   # We only bootstrap target libraries listed in bootstrap_target_libs.
2516   case $bootstrap_target_libs in
2517     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2518     *) target_bootstrap_suffix=no-bootstrap ;;
2519   esac
2520
2521   extrasub_target="$extrasub_target
2522 /^@if target-$module\$/d
2523 /^@endif target-$module\$/d
2524 /^@if target-$module-$target_bootstrap_suffix\$/d
2525 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2526 done
2527
2528 # Do the final fixup along with target modules.
2529 extrasub_target="$extrasub_target
2530 /^@if /,/^@endif /d"
2531
2532 # Create the serialization dependencies.  This uses a temporary file.
2533
2534 AC_ARG_ENABLE([serial-configure],
2535 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2536                 [force sequential configuration of
2537                  sub-packages for the host, target or build
2538                  machine, or all sub-packages])])
2539
2540 case ${enable_serial_configure} in
2541   yes)
2542     enable_serial_build_configure=yes
2543     enable_serial_host_configure=yes
2544     enable_serial_target_configure=yes
2545     ;;
2546 esac
2547
2548 # These force 'configure's to be done one at a time, to avoid problems
2549 # with contention over a shared config.cache.
2550 rm -f serdep.tmp
2551 echo '# serdep.tmp' > serdep.tmp
2552 olditem=
2553 test "x${enable_serial_build_configure}" = xyes &&
2554 for item in ${build_configdirs} ; do
2555   case ${olditem} in
2556     "") ;;
2557     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2558   esac
2559   olditem=${item}
2560 done
2561 olditem=
2562 test "x${enable_serial_host_configure}" = xyes &&
2563 for item in ${configdirs} ; do
2564   case ${olditem} in
2565     "") ;;
2566     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2567   esac
2568   olditem=${item}
2569 done
2570 olditem=
2571 test "x${enable_serial_target_configure}" = xyes &&
2572 for item in ${target_configdirs} ; do
2573   case ${olditem} in
2574     "") ;;
2575     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2576   esac
2577   olditem=${item}
2578 done
2579 serialization_dependencies=serdep.tmp
2580 AC_SUBST_FILE(serialization_dependencies)
2581
2582 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2583 # target, nonopt, and variable assignments.  These are the ones we
2584 # might not want to pass down to subconfigures.  The exception being
2585 # --cache-file=/dev/null, which is used to turn off the use of cache
2586 # files altogether, and which should be passed on to subconfigures.
2587 # Also strip program-prefix, program-suffix, and program-transform-name,
2588 # so that we can pass down a consistent program-transform-name.
2589 baseargs=
2590 tbaseargs=
2591 keep_next=no
2592 skip_next=no
2593 eval "set -- $ac_configure_args"
2594 for ac_arg
2595 do
2596   if test X"$skip_next" = X"yes"; then
2597     skip_next=no
2598     continue
2599   fi
2600   if test X"$keep_next" = X"yes"; then
2601     case $ac_arg in
2602       *\'*)
2603         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2604     esac
2605     baseargs="$baseargs '$ac_arg'"
2606     tbaseargs="$tbaseargs '$ac_arg'"
2607     keep_next=no
2608     continue
2609   fi
2610
2611   # Handle separated arguments.  Based on the logic generated by
2612   # autoconf 2.59.
2613   case $ac_arg in
2614     *=* | --config-cache | -C | -disable-* | --disable-* \
2615       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2616       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2617       | -with-* | --with-* | -without-* | --without-* | --x)
2618       separate_arg=no
2619       ;;
2620     -*)
2621       separate_arg=yes
2622       ;;
2623     *)
2624       separate_arg=no
2625       ;;
2626   esac
2627
2628   skip_targ=no
2629   case $ac_arg in
2630 changequote(,)
2631   --with-* | --without-*)
2632     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2633
2634     case $libopt in
2635     *[-_]include)
2636       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2637       ;;
2638     *[-_]lib)
2639       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2640       ;;
2641     *)
2642       lib=$libopt
2643       ;;
2644     esac
2645 changequote([,])
2646
2647     case $lib in
2648     mpc | mpfr | gmp | cloog)
2649       # If we're processing --with-$lib, --with-$lib-include or
2650       # --with-$lib-lib, for one of the libs above, and target is
2651       # different from host, don't pass the current argument to any
2652       # target library's configure.
2653       if test x$is_cross_compiler = xyes; then
2654         skip_targ=yes
2655       fi
2656       ;;
2657     esac
2658     ;;
2659   esac
2660
2661   case "$ac_arg" in
2662     --cache-file=/dev/null | \
2663     -cache-file=/dev/null )
2664       # Handled here to avoid the test to skip args below.
2665       baseargs="$baseargs '$ac_arg'"
2666       tbaseargs="$tbaseargs '$ac_arg'"
2667       # Assert: $separate_arg should always be no.
2668       keep_next=$separate_arg
2669       ;;
2670     --no*)
2671       continue
2672       ;;
2673     --c* | \
2674     --sr* | \
2675     --ho* | \
2676     --bu* | \
2677     --t* | \
2678     --program-* | \
2679     -cache_file* | \
2680     -srcdir* | \
2681     -host* | \
2682     -build* | \
2683     -target* | \
2684     -program-prefix* | \
2685     -program-suffix* | \
2686     -program-transform-name* )
2687       skip_next=$separate_arg
2688       continue
2689       ;;
2690     -*)
2691       # An option.  Add it.
2692       case $ac_arg in
2693         *\'*)
2694           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2695       esac
2696       baseargs="$baseargs '$ac_arg'"
2697       if test X"$skip_targ" = Xno; then
2698         tbaseargs="$tbaseargs '$ac_arg'"
2699       fi
2700       keep_next=$separate_arg
2701       ;;
2702     *)
2703       # Either a variable assignment, or a nonopt (triplet).  Don't
2704       # pass it down; let the Makefile handle this.
2705       continue
2706       ;;
2707   esac
2708 done
2709 # Remove the initial space we just introduced and, as these will be
2710 # expanded by make, quote '$'.
2711 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2712
2713 # Add in --program-transform-name, after --program-prefix and
2714 # --program-suffix have been applied to it.  Autoconf has already
2715 # doubled dollar signs and backslashes in program_transform_name; we want
2716 # the backslashes un-doubled, and then the entire thing wrapped in single
2717 # quotes, because this will be expanded first by make and then by the shell.
2718 # Also, because we want to override the logic in subdir configure scripts to
2719 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2720 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2721 ${program_transform_name}
2722 EOF_SED
2723 gcc_transform_name=`cat conftestsed.out`
2724 rm -f conftestsed.out
2725 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2726 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2727 if test "$silent" = yes; then
2728   baseargs="$baseargs --silent"
2729   tbaseargs="$tbaseargs --silent"
2730 fi
2731 baseargs="$baseargs --disable-option-checking"
2732 tbaseargs="$tbaseargs --disable-option-checking"
2733
2734 # Record and document user additions to sub configure arguments.
2735 AC_ARG_VAR([build_configargs],
2736            [additional configure arguments for build directories])
2737 AC_ARG_VAR([host_configargs],
2738            [additional configure arguments for host directories])
2739 AC_ARG_VAR([target_configargs],
2740            [additional configure arguments for target directories])
2741
2742 # For the build-side libraries, we just need to pretend we're native,
2743 # and not use the same cache file.  Multilibs are neither needed nor
2744 # desired.
2745 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2746
2747 # For host modules, accept cache file option, or specification as blank.
2748 case "${cache_file}" in
2749 "") # empty
2750   cache_file_option="" ;;
2751 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2752   cache_file_option="--cache-file=${cache_file}" ;;
2753 *) # relative path
2754   cache_file_option="--cache-file=../${cache_file}" ;;
2755 esac
2756
2757 # Host dirs don't like to share a cache file either, horribly enough.
2758 # This seems to be due to autoconf 2.5x stupidity.
2759 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2760
2761 target_configargs="$target_configargs ${tbaseargs}"
2762
2763 # Passing a --with-cross-host argument lets the target libraries know
2764 # whether they are being built with a cross-compiler or being built
2765 # native.  However, it would be better to use other mechanisms to make the
2766 # sorts of decisions they want to make on this basis.  Please consider
2767 # this option to be deprecated.  FIXME.
2768 if test x${is_cross_compiler} = xyes ; then
2769   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2770 fi
2771
2772 # Default to --enable-multilib.
2773 if test x${enable_multilib} = x ; then
2774   target_configargs="--enable-multilib ${target_configargs}"
2775 fi
2776
2777 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2778 # changed from the earlier setting of with_newlib.
2779 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2780   target_configargs="--with-newlib ${target_configargs}"
2781 fi
2782
2783 # Different target subdirs use different values of certain variables
2784 # (notably CXX).  Worse, multilibs use *lots* of different values.
2785 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2786 # it doesn't automatically accept command-line overrides of them.
2787 # This means it's not safe for target subdirs to share a cache file,
2788 # which is disgusting, but there you have it.  Hopefully this can be
2789 # fixed in future.  It's still worthwhile to use a cache file for each
2790 # directory.  I think.
2791
2792 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2793 # We need to pass --target, as newer autoconf's requires consistency
2794 # for target_alias and gcc doesn't manage it consistently.
2795 target_configargs="--cache-file=./config.cache ${target_configargs}"
2796
2797 FLAGS_FOR_TARGET=
2798 case " $target_configdirs " in
2799  *" newlib "*)
2800   case " $target_configargs " in
2801   *" --with-newlib "*)
2802    case "$target" in
2803     *-cygwin*)
2804       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2805       ;;
2806    esac
2807
2808    # If we're not building GCC, don't discard standard headers.
2809    if test -d ${srcdir}/gcc; then
2810      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2811
2812      if test "${build}" != "${host}"; then
2813        # On Canadian crosses, CC_FOR_TARGET will have already been set
2814        # by `configure', so we won't have an opportunity to add -Bgcc/
2815        # to it.  This is right: we don't want to search that directory
2816        # for binaries, but we want the header files in there, so add
2817        # them explicitly.
2818        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2819
2820        # Someone might think of using the pre-installed headers on
2821        # Canadian crosses, in case the installed compiler is not fully
2822        # compatible with the compiler being built.  In this case, it
2823        # would be better to flag an error than risking having
2824        # incompatible object files being constructed.  We can't
2825        # guarantee that an error will be flagged, but let's hope the
2826        # compiler will do it, when presented with incompatible header
2827        # files.
2828      fi
2829    fi
2830
2831    case "${target}-${is_cross_compiler}" in
2832    i[[3456789]]86-*-linux*-no)
2833       # Here host == target, so we don't need to build gcc,
2834       # so we don't want to discard standard headers.
2835       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2836       ;;
2837    *)
2838       # If we're building newlib, use its generic headers last, but search
2839       # for any libc-related directories first (so make it the last -B
2840       # switch).
2841       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2842
2843       # If we're building libgloss, find the startup file, simulator library
2844       # and linker script.
2845       case " $target_configdirs " in
2846         *" libgloss "*)
2847         # Look for startup file, simulator library and maybe linker script.
2848         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2849         # Look for libnosys.a in case the target needs it.
2850         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2851         # Most targets have the linker script in the source directory.
2852         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2853         ;;
2854       esac
2855       ;;
2856    esac
2857    ;;
2858   esac
2859   ;;
2860 esac
2861
2862 case "$target" in
2863   x86_64-*mingw* | *-w64-mingw*)
2864   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2865   # however, use a symlink named 'mingw' in ${prefix} .
2866     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2867     ;;
2868   *-mingw*)
2869   # MinGW can't be handled as Cygwin above since it does not use newlib.
2870     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2871     ;;
2872 esac
2873
2874 # Allow the user to override the flags for
2875 # our build compiler if desired.
2876 if test x"${build}" = x"${host}" ; then
2877   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2878   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2879   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2880 fi
2881
2882 # On Canadian crosses, we'll be searching the right directories for
2883 # the previously-installed cross compiler, so don't bother to add
2884 # flags for directories within the install tree of the compiler
2885 # being built; programs in there won't even run.
2886 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2887   # Search for pre-installed headers if nothing else fits.
2888   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2889 fi
2890
2891 if test "x${use_gnu_ld}" = x &&
2892    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2893   # Arrange for us to find uninstalled linker scripts.
2894   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2895 fi
2896
2897 # Search for other target-specific linker scripts and such.
2898 case "${target}" in
2899   mep*)
2900     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2901     ;;
2902 esac
2903
2904 # Makefile fragments.
2905 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2906 do
2907   eval fragval=\$$frag
2908   if test $fragval != /dev/null; then
2909     eval $frag=${srcdir}/$fragval
2910   fi
2911 done
2912 AC_SUBST_FILE(host_makefile_frag)
2913 AC_SUBST_FILE(target_makefile_frag)
2914 AC_SUBST_FILE(alphaieee_frag)
2915 AC_SUBST_FILE(ospace_frag)
2916
2917 # Miscellanea: directories, flags, etc.
2918 AC_SUBST(RPATH_ENVVAR)
2919 AC_SUBST(GCC_SHLIB_SUBDIR)
2920 AC_SUBST(tooldir)
2921 AC_SUBST(build_tooldir)
2922 AC_SUBST(CONFIGURE_GDB_TK)
2923 AC_SUBST(GDB_TK)
2924 AC_SUBST(INSTALL_GDB_TK)
2925
2926 # Build module lists & subconfigure args.
2927 AC_SUBST(build_configargs)
2928 AC_SUBST(build_configdirs)
2929
2930 # Host module lists & subconfigure args.
2931 AC_SUBST(host_configargs)
2932 AC_SUBST(configdirs)
2933 AC_SUBST(target_configdirs)
2934
2935 # Target module lists & subconfigure args.
2936 AC_SUBST(target_configargs)
2937
2938
2939 # Build tools.
2940 AC_SUBST(AR_FOR_BUILD)
2941 AC_SUBST(AS_FOR_BUILD)
2942 AC_SUBST(CC_FOR_BUILD)
2943 AC_SUBST(CFLAGS_FOR_BUILD)
2944 AC_SUBST(CXXFLAGS_FOR_BUILD)
2945 AC_SUBST(CXX_FOR_BUILD)
2946 AC_SUBST(DLLTOOL_FOR_BUILD)
2947 AC_SUBST(GCJ_FOR_BUILD)
2948 AC_SUBST(GFORTRAN_FOR_BUILD)
2949 AC_SUBST(GOC_FOR_BUILD)
2950 AC_SUBST(LDFLAGS_FOR_BUILD)
2951 AC_SUBST(LD_FOR_BUILD)
2952 AC_SUBST(NM_FOR_BUILD)
2953 AC_SUBST(RANLIB_FOR_BUILD)
2954 AC_SUBST(WINDMC_FOR_BUILD)
2955 AC_SUBST(WINDRES_FOR_BUILD)
2956
2957 # Generate default definitions for YACC, M4, LEX and other programs that run
2958 # on the build machine.  These are used if the Makefile can't locate these
2959 # programs in objdir.
2960 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
2961
2962 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
2963 case " $build_configdirs " in
2964   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
2965 esac
2966
2967 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
2968 case " $build_configdirs " in
2969   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
2970 esac
2971
2972 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
2973 case " $build_configdirs " in
2974   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
2975 esac
2976
2977 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
2978 case " $build_configdirs " in
2979   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2980   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
2981 esac
2982
2983 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
2984 case " $build_configdirs " in
2985   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2986 esac
2987
2988 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
2989 case " $build_configdirs " in
2990   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
2991   *)
2992 changequote(,)
2993     # For an installed makeinfo, we require it to be from texinfo 4.7 or
2994     # higher, else we use the "missing" dummy.
2995     if ${MAKEINFO} --version \
2996        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
2997       :
2998     else
2999       MAKEINFO="$MISSING makeinfo"
3000     fi
3001     ;;
3002 changequote([,])
3003 esac
3004
3005 # FIXME: expect and dejagnu may become build tools?
3006
3007 AC_CHECK_PROGS(EXPECT, expect, expect)
3008 case " $configdirs " in
3009   *" expect "*)
3010     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3011     ;;
3012 esac
3013
3014 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3015 case " $configdirs " in
3016   *" dejagnu "*)
3017     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3018     ;;
3019 esac
3020
3021
3022 # Host tools.
3023 NCN_STRICT_CHECK_TOOLS(AR, ar)
3024 NCN_STRICT_CHECK_TOOLS(AS, as)
3025 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3026 NCN_STRICT_CHECK_TOOLS(LD, ld)
3027 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3028 NCN_STRICT_CHECK_TOOLS(NM, nm)
3029 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3030 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3031 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3032 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3033 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3034 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3035 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3036 AC_SUBST(CC)
3037 AC_SUBST(CXX)
3038 AC_SUBST(CFLAGS)
3039 AC_SUBST(CXXFLAGS)
3040
3041 # Target tools.
3042 AC_ARG_WITH([build-time-tools],
3043   [AS_HELP_STRING([--with-build-time-tools=PATH],
3044                   [use given path to find target tools during the build])],
3045   [case x"$withval" in
3046      x/*) ;;
3047      *)
3048        with_build_time_tools=
3049        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3050        ;;
3051    esac],
3052   [with_build_time_tools=])
3053
3054 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3055 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3056 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3057 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3058 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3059 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3060
3061 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3062 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3063 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3064 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3065 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3066 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3067 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3068 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3069 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3070 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3071 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3072 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3073
3074 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3075
3076 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3077 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3078 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3079 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3080 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3081                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3082                 c++)
3083 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3084                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3085                 c++)
3086 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3087 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3088 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3089                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3090 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3091                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3092 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3093                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3094 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3095 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3096 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3097 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3098 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3099 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3100 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3101 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3102 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3103
3104 AC_SUBST(FLAGS_FOR_TARGET)
3105 AC_SUBST(RAW_CXX_FOR_TARGET)
3106
3107 # Certain tools may need extra flags.
3108 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3109 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3110 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3111
3112 # When building target libraries, except in a Canadian cross, we use
3113 # the same toolchain as the compiler we just built.
3114 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3115 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3116 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3117 if test $host = $build; then
3118   case " $configdirs " in
3119     *" gcc "*)
3120       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3121       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3122       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3123       ;;
3124   esac
3125 fi
3126
3127 AC_SUBST(COMPILER_AS_FOR_TARGET)
3128 AC_SUBST(COMPILER_LD_FOR_TARGET)
3129 AC_SUBST(COMPILER_NM_FOR_TARGET)
3130
3131 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3132 AC_ARG_ENABLE(maintainer-mode,
3133 [AS_HELP_STRING([--enable-maintainer-mode],
3134                 [enable make rules and dependencies not useful
3135                  (and sometimes confusing) to the casual installer])],
3136       USE_MAINTAINER_MODE=$enableval,
3137       USE_MAINTAINER_MODE=no)
3138 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3139 AC_SUBST(MAINTAINER_MODE_TRUE)
3140 AC_SUBST(MAINTAINER_MODE_FALSE)
3141 if test "$USE_MAINTAINER_MODE" = yes; then
3142   MAINTAINER_MODE_TRUE=
3143   MAINTAINER_MODE_FALSE='#'
3144 else
3145   MAINTAINER_MODE_TRUE='#'
3146   MAINTAINER_MODE_FALSE=
3147 fi
3148 MAINT=$MAINTAINER_MODE_TRUE
3149 AC_SUBST(MAINT)dnl
3150
3151 # ---------------------
3152 # GCC bootstrap support
3153 # ---------------------
3154
3155 # Stage specific cflags for build.
3156 stage1_cflags="-g"
3157 case $build in
3158   vax-*-*)
3159     case ${GCC} in
3160       yes) stage1_cflags="-g -Wa,-J" ;;
3161       *) stage1_cflags="-g -J" ;;
3162     esac ;;
3163 esac
3164
3165 AC_SUBST(stage1_cflags)
3166
3167 # Enable --enable-checking in stage1 of the compiler.
3168 AC_ARG_ENABLE(stage1-checking,
3169 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3170                 [choose additional checking for stage1 of the compiler])],
3171 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3172 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3173   stage1_checking=--enable-checking=yes,types
3174 else
3175   stage1_checking=--enable-checking=$enable_checking,types
3176 fi])
3177 AC_SUBST(stage1_checking)
3178
3179 # Enable -Werror in bootstrap stage2 and later.
3180 AC_ARG_ENABLE(werror,
3181 [AS_HELP_STRING([--enable-werror],
3182                 [enable -Werror in bootstrap stage2 and later])], [],
3183 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3184   enable_werror=yes
3185 else
3186   enable_werror=no
3187 fi])
3188 case ${enable_werror} in
3189   yes) stage2_werror_flag="--enable-werror-always" ;;
3190   *) stage2_werror_flag="" ;;
3191 esac
3192 AC_SUBST(stage2_werror_flag)
3193
3194 # Specify what files to not compare during bootstrap.
3195
3196 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3197 case "$target" in
3198   hppa*64*-*-hpux*) ;;
3199   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3200   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3201 esac
3202 AC_SUBST(compare_exclusions)
3203
3204 AC_CONFIG_FILES([Makefile],
3205   [sed "$extrasub_build" Makefile |
3206    sed "$extrasub_host" |
3207    sed "$extrasub_target" > mf$$
3208    mv -f mf$$ Makefile],
3209   [extrasub_build="$extrasub_build"
3210    extrasub_host="$extrasub_host"
3211    extrasub_target="$extrasub_target"])
3212 AC_OUTPUT