texinfo/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Id: configure.in,v 1.5 1998/03/24 18:05:13 law Exp $
   3 dnl
   4 AC_INIT(makeinfo/makeinfo.c)
   5 AC_PREREQ(2.12)dnl Minimum Autoconf version required.
   6 AM_CONFIG_HEADER(config.h)
   7
   8 AM_INIT_AUTOMAKE([texinfo], [3.11])
   9
  10 dnl Checks for programs.
  11 AC_PROG_CC
  12 AC_PROG_GCC_TRADITIONAL
  13 EGCS_PROG_INSTALL
  14 AC_PROG_RANLIB
  15
  16 # We do this for the sake of a more helpful warning in doc/Makefile.
  17 TEXMF='$(datadir)/texmf'
  18 AC_CHECK_PROG(TEXCONFIG, texconfig, true, false)
  19 $TEXCONFIG && eval `texconfig confall | grep '^TEXMF='`
  20 AC_SUBST(TEXMF)
  21
  22 AC_ISC_POSIX
  23 AC_MINIX
  24
  25 dnl CYGNUS LOCAL: Add AM_MAINTAINER_MODE and AM_EXEEXT
  26 AM_MAINTAINER_MODE
  27 AM_EXEEXT
  28
  29 dnl Checks for libraries.
  30 # Needed on sysV68 for sigblock, sigsetmask.
  31 AC_CHECK_LIB(bsd, sigblock)
  32
  33 # Some GNU/Linux systems (e.g., SuSE 4.3, 1996) don't have curses, but
  34 # rather ncurses.  So we check for it.
  35 TERMLIBS=
  36 for termlib in ncurses curses termcap terminfo termlib ; do
  37    AC_CHECK_LIB(${termlib}, tputs,
  38      [TERMLIBS="${TERMLIBS} -l${termlib}"; break])
  39 done
  40 AC_SUBST(TERMLIBS)
  41
  42 dnl Checks for header files.
  43 AC_HEADER_STDC
  44 AC_CHECK_HEADERS(fcntl.h pwd.h string.h strings.h termcap.h termio.h \
  45   termios.h unistd.h \
  46   sys/fcntl.h sys/file.h sys/ptem.h sys/time.h sys/ttold.h sys/wait.h)
  47
  48 dnl Do not use <ncurses/termcap.h> unless we're linking with ncurses.
  49 if test "x$termlib" = xncurses; then
  50   AC_CHECK_HEADER(ncurses/termcap.h)
  51 fi
  52
  53 dnl Checks for typedefs, structures, and compiler characteristics.
  54 AC_TYPE_OFF_T
  55 AC_TYPE_SIGNAL
  56 AC_C_CONST
  57 AC_STRUCT_TM
  58
  59 dnl Checks for library functions.
  60 AC_FUNC_ALLOCA
  61 AC_FUNC_VPRINTF
  62 if test "$ac_cv_c_cross" = no; then
  63   AC_FUNC_SETVBUF_REVERSED
  64 fi
  65 AC_CHECK_FUNCS(setvbuf getcwd memset bzero strchr strcasecmp \
  66   sigprocmask sigsetmask)
  67 dnl strcasecmp, strerror, xmalloc, xrealloc, probably others should be added.
  68 AC_REPLACE_FUNCS(memcpy memmove strdup strerror)
  69
  70 dnl Set of available languages and i18n macros.
  71 ALL_LINGUAS="de fr"
  72 AM_GNU_GETTEXT
  73 AC_LINK_FILES($nls_cv_header_libgt, $nls_cv_header_intl)
  74
  75 AC_OUTPUT([Makefile             \
  76            doc/Makefile         \
  77            emacs/Makefile       \
  78            info/Makefile        \
  79            intl/Makefile        \
  80            lib/Makefile         \
  81            makeinfo/Makefile    \
  82            po/Makefile.in       \
  83            util/Makefile        \
  84            ],
  85           [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in >po/Makefile])